PVE/Storage/RBDPlugin.pm

   1 package PVE::Storage::RBDPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use Net::IP;
   7 use PVE::Tools qw(run_command trim);
   8 use PVE::Storage::Plugin;
   9 use PVE::JSONSchema qw(get_standard_option);
  10 use PVE::RADOS;
  11 use PVE::Storage::CephTools;
  12
  13 use base qw(PVE::Storage::Plugin);
  14
  15 my $rbd_unittobytes = {
  16     "k"  => 1024,
  17     "M"  => 1024*1024,
  18     "G"  => 1024*1024*1024,
  19     "T"  => 1024*1024*1024*1024,
  20 };
  21
  22 my $add_pool_to_disk = sub {
  23     my ($scfg, $disk) = @_;
  24
  25     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  26
  27     return "$pool/$disk";
  28 };
  29
  30 my $build_cmd = sub {
  31     my ($binary, $scfg, $storeid, $op, @options) = @_;
  32
  33     my $cmd_option = PVE::Storage::CephTools::ceph_connect_option($scfg, $storeid);
  34     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  35
  36     my $cmd = [$binary, '-p', $pool];
  37
  38     push @$cmd, '-c', $cmd_option->{ceph_conf} if ($cmd_option->{ceph_conf});
  39     push @$cmd, '-m', $cmd_option->{mon_host} if ($cmd_option->{mon_host});
  40     push @$cmd, '--auth_supported', $cmd_option->{auth_supported} if ($cmd_option->{auth_supported});
  41     push @$cmd, '-n', "client.$cmd_option->{userid}" if ($cmd_option->{userid});
  42     push @$cmd, '--keyring', $cmd_option->{keyring} if ($cmd_option->{keyring});
  43
  44     push @$cmd, $op;
  45
  46     push @$cmd, @options if scalar(@options);
  47
  48     return $cmd;
  49 };
  50
  51 my $rbd_cmd = sub {
  52     my ($scfg, $storeid, $op, @options) = @_;
  53
  54     return $build_cmd->('/usr/bin/rbd', $scfg, $storeid, $op, @options);
  55 };
  56
  57 my $rados_cmd = sub {
  58     my ($scfg, $storeid, $op, @options) = @_;
  59
  60     return $build_cmd->('/usr/bin/rados', $scfg, $storeid, $op, @options);
  61 };
  62
  63 my $librados_connect = sub {
  64     my ($scfg, $storeid, $options) = @_;
  65
  66     my $librados_config = PVE::Storage::CephTools::ceph_connect_option($scfg, $storeid);
  67
  68     my $rados = PVE::RADOS->new(%$librados_config);
  69
  70     return $rados;
  71 };
  72
  73 # needed for volumes created using ceph jewel (or higher)
  74 my $krbd_feature_disable = sub {
  75     my ($scfg, $storeid, $name) = @_;
  76
  77     return 1 if !$scfg->{krbd};
  78
  79     my ($major, undef, undef, undef) = ceph_version();
  80     return 1 if $major < 10;
  81
  82     my $krbd_feature_blacklist = ['deep-flatten', 'fast-diff', 'object-map', 'exclusive-lock'];
  83     my (undef, undef, undef, undef, $features) = rbd_volume_info($scfg, $storeid, $name);
  84
  85     my $active_features = { map { $_ => 1 } PVE::Tools::split_list($features)};
  86     my $incompatible_features = join(',', grep { %$active_features{$_} } @$krbd_feature_blacklist);
  87
  88     if ($incompatible_features) {
  89         my $feature_cmd = &$rbd_cmd($scfg, $storeid, 'feature', 'disable', $name, $incompatible_features);
  90         run_rbd_command($feature_cmd, errmsg => "could not disable krbd-incompatible image features of rbd volume $name");
  91     }
  92 };
  93
  94 my $ceph_version_parser = sub {
  95     my $line = shift;
  96     if ($line =~ m/^ceph version ((\d+)\.(\d+)\.(\d+))(?: \([a-fA-F0-9]+\))/) {
  97         return ($2, $3, $4, $1);
  98     } else {
  99         warn "Could not parse Ceph version: '$line'\n";
 100     }
 101 };
 102
 103 sub ceph_version {
 104     my ($cache) = @_;
 105
 106     my $version_string = $cache;
 107
 108     my $major;
 109     my $minor;
 110     my $bugfix;
 111
 112     if (defined($version_string)) {
 113         ($major, $minor, $bugfix, $version_string) = &$ceph_version_parser($version_string);
 114     } else {
 115         run_command('ceph --version', outfunc => sub {
 116             my $line = shift;
 117             ($major, $minor, $bugfix, $version_string) = &$ceph_version_parser($line);
 118         });
 119     }
 120     return undef if !defined($version_string);
 121     return wantarray ? ($major, $minor, $bugfix, $version_string) : $version_string;
 122 }
 123
 124 sub run_rbd_command {
 125     my ($cmd, %args) = @_;
 126
 127     my $lasterr;
 128     my $errmsg = $args{errmsg} . ": " || "";
 129     if (!exists($args{errfunc})) {
 130         # ' error: 2014-02-06 11:51:59.839135 7f09f94d0760 -1 librbd: snap_unprotect: can't unprotect;
 131         # at least 1 child(ren) in pool cephstor1
 132         $args{errfunc} = sub {
 133             my $line = shift;
 134             if ($line =~ m/^\d{4}-\d{2}-\d{2} \d{2}:\d{2}:\d{2}\.\d+ [0-9a-f]+ [\-\d]+ librbd: (.*)$/) {
 135                 $lasterr = "$1\n";
 136             } else {
 137                 $lasterr = $line;
 138             }
 139             print STDERR $lasterr;
 140             *STDERR->flush();
 141         };
 142     }
 143
 144     eval { run_command($cmd, %args); };
 145     if (my $err = $@) {
 146         die $errmsg . $lasterr if length($lasterr);
 147         die $err;
 148     }
 149
 150     return undef;
 151 }
 152
 153 sub rbd_ls {
 154     my ($scfg, $storeid) = @_;
 155
 156     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls', '-l');
 157     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 158
 159     my $list = {};
 160
 161     my $parser = sub {
 162         my $line = shift;
 163
 164         if ($line =~  m/^((vm|base)-(\d+)-\S+)\s+(\d+)(k|M|G|T)\s((\S+)\/((vm|base)-\d+-\S+@\S+))?/) {
 165             my ($image, $owner, $size, $unit, $parent) = ($1, $3, $4, $5, $8);
 166             return if $image =~ /@/; #skip snapshots
 167
 168             $list->{$pool}->{$image} = {
 169                 name => $image,
 170                 size => $size*$rbd_unittobytes->{$unit},
 171                 parent => $parent,
 172                 vmid => $owner
 173             };
 174         }
 175     };
 176
 177     eval {
 178         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 179     };
 180     my $err = $@;
 181
 182     die $err if $err && $err !~ m/doesn't contain rbd images/ ;
 183
 184     return $list;
 185 }
 186
 187 sub rbd_volume_info {
 188     my ($scfg, $storeid, $volname, $snap) = @_;
 189
 190     my $cmd = undef;
 191
 192     if($snap){
 193        $cmd = &$rbd_cmd($scfg, $storeid, 'info', $volname, '--snap', $snap);
 194     }else{
 195        $cmd = &$rbd_cmd($scfg, $storeid, 'info', $volname);
 196     }
 197
 198     my $size = undef;
 199     my $parent = undef;
 200     my $format = undef;
 201     my $protected = undef;
 202     my $features = undef;
 203
 204     my $parser = sub {
 205         my $line = shift;
 206
 207         if ($line =~ m/size (\d+) (k|M|G|T)B in (\d+) objects/) {
 208             $size = $1 * $rbd_unittobytes->{$2} if ($1);
 209         } elsif ($line =~ m/parent:\s(\S+)\/(\S+)/) {
 210             $parent = $2;
 211         } elsif ($line =~ m/format:\s(\d+)/) {
 212             $format = $1;
 213         } elsif ($line =~ m/protected:\s(\S+)/) {
 214             $protected = 1 if $1 eq "True";
 215         } elsif ($line =~ m/features:\s(.+)/) {
 216             $features = $1;
 217         }
 218
 219     };
 220
 221     run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 222
 223     return ($size, $parent, $format, $protected, $features);
 224 }
 225
 226 # Configuration
 227
 228 sub type {
 229     return 'rbd';
 230 }
 231
 232 sub plugindata {
 233     return {
 234         content => [ {images => 1, rootdir => 1}, { images => 1 }],
 235     };
 236 }
 237
 238 sub properties {
 239     return {
 240         monhost => {
 241             description => "IP addresses of monitors (for external clusters).",
 242             type => 'string', format => 'pve-storage-portal-dns-list',
 243         },
 244         pool => {
 245             description => "Pool.",
 246             type => 'string',
 247         },
 248         username => {
 249             description => "RBD Id.",
 250             type => 'string',
 251         },
 252         authsupported => {
 253             description => "Authsupported.",
 254             type => 'string',
 255         },
 256         krbd => {
 257             description => "Access rbd through krbd kernel module.",
 258             type => 'boolean',
 259         },
 260     };
 261 }
 262
 263 sub options {
 264     return {
 265         nodes => { optional => 1 },
 266         disable => { optional => 1 },
 267         monhost => { optional => 1},
 268         pool => { optional => 1 },
 269         username => { optional => 1 },
 270         content => { optional => 1 },
 271         krbd => { optional => 1 },
 272         bwlimit => { optional => 1 },
 273     };
 274 }
 275
 276 # Storage implementation
 277
 278 sub on_add_hook {
 279     my ($class, $storeid, $scfg, %param) = @_;
 280
 281     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 282
 283     my $ceph_admin_keyring = '/etc/pve/priv/ceph.client.admin.keyring';
 284     my $ceph_storage_keyring = "/etc/pve/priv/ceph/${storeid}.keyring";
 285
 286     die "ceph authx keyring file for storage '$storeid' already exists!\n"
 287         if -e $ceph_storage_keyring;
 288
 289     eval {
 290         mkdir '/etc/pve/priv/ceph';
 291         PVE::Tools::file_copy($ceph_admin_keyring, $ceph_storage_keyring);
 292     };
 293     if (my $err = $@) {
 294         unlink $ceph_storage_keyring;
 295         die "failed to copy ceph authx keyring for storage '$storeid': $err\n";
 296     }
 297
 298 }
 299
 300 sub on_delete_hook {
 301     my ($class, $storeid, $scfg) = @_;
 302
 303     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 304
 305     my $ceph_storage_keyring = "/etc/pve/priv/ceph/${storeid}.keyring";
 306     if (-f $ceph_storage_keyring) {
 307         unlink($ceph_storage_keyring) or warn "removing keyring of storage failed: $!\n";
 308     }
 309
 310 }
 311
 312 sub parse_volname {
 313     my ($class, $volname) = @_;
 314
 315     if ($volname =~ m/^((base-(\d+)-\S+)\/)?((base)?(vm)?-(\d+)-\S+)$/) {
 316         return ('images', $4, $7, $2, $3, $5, 'raw');
 317     }
 318
 319     die "unable to parse rbd volume name '$volname'\n";
 320 }
 321
 322 sub path {
 323     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 324
 325     my $cmd_option = PVE::Storage::CephTools::ceph_connect_option($scfg, $storeid);
 326     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 327     $name .= '@'.$snapname if $snapname;
 328
 329     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 330     return ("/dev/rbd/$pool/$name", $vmid, $vtype) if $scfg->{krbd};
 331
 332     my $path = "rbd:$pool/$name";
 333
 334     $path .= ":conf=$cmd_option->{ceph_conf}" if $cmd_option->{ceph_conf};
 335     if (defined($scfg->{monhost})) {
 336         my $monhost = PVE::Storage::CephTools::hostlist($scfg->{monhost}, ';');
 337         $monhost =~ s/:/\\:/g;
 338         $path .= ":mon_host=$monhost";
 339         $path .= ":auth_supported=$cmd_option->{auth_supported}";
 340     }
 341
 342     $path .= ":id=$cmd_option->{userid}:keyring=$cmd_option->{keyring}" if ($cmd_option->{keyring});
 343
 344     return ($path, $vmid, $vtype);
 345 }
 346
 347 my $find_free_diskname = sub {
 348     my ($storeid, $scfg, $vmid) = @_;
 349
 350     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls');
 351     my $disk_ids = {};
 352
 353     my $parser = sub {
 354         my $line = shift;
 355
 356         if ($line =~  m/^(vm|base)-\Q$vmid\E+-disk-(\d+)$/) {
 357             $disk_ids->{$2} = 1;
 358         }
 359     };
 360
 361     eval {
 362         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 363     };
 364     my $err = $@;
 365
 366     die $err if $err && $err !~ m/doesn't contain rbd images/;
 367
 368     #fix: can we search in $rbd hash key with a regex to find (vm|base) ?
 369     for (my $i = 1; $i < 100; $i++) {
 370         if (!$disk_ids->{$i}) {
 371             return "vm-$vmid-disk-$i";
 372         }
 373     }
 374
 375     die "unable to allocate an image name for VM $vmid in storage '$storeid'\n";
 376 };
 377
 378 sub create_base {
 379     my ($class, $storeid, $scfg, $volname) = @_;
 380
 381     my $snap = '__base__';
 382
 383     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 384         $class->parse_volname($volname);
 385
 386     die "create_base not possible with base image\n" if $isBase;
 387
 388     my ($size, $parent, $format, undef) = rbd_volume_info($scfg, $storeid, $name);
 389     die "rbd volume info on '$name' failed\n" if !($size);
 390
 391     die "rbd image must be at format V2" if $format ne "2";
 392
 393     die "volname '$volname' contains wrong information about parent $parent $basename\n"
 394         if $basename && (!$parent || $parent ne $basename."@".$snap);
 395
 396     my $newname = $name;
 397     $newname =~ s/^vm-/base-/;
 398
 399     my $newvolname = $basename ? "$basename/$newname" : "$newname";
 400
 401     my $cmd = &$rbd_cmd($scfg, $storeid, 'rename', &$add_pool_to_disk($scfg, $name), &$add_pool_to_disk($scfg, $newname));
 402     run_rbd_command($cmd, errmsg => "rbd rename '$name' error");
 403
 404     my $running  = undef; #fixme : is create_base always offline ?
 405
 406     $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running);
 407
 408     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $newname, $snap);
 409
 410     if (!$protected){
 411         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $newname, '--snap', $snap);
 412         run_rbd_command($cmd, errmsg => "rbd protect $newname snap '$snap' error");
 413     }
 414
 415     return $newvolname;
 416
 417 }
 418
 419 sub clone_image {
 420     my ($class, $scfg, $storeid, $volname, $vmid, $snapname) = @_;
 421
 422     my $snap = '__base__';
 423     $snap = $snapname if length $snapname;
 424
 425     my ($vtype, $basename, $basevmid, undef, undef, $isBase) =
 426         $class->parse_volname($volname);
 427
 428     die "$volname is not a base image and snapname is not provided\n"
 429         if !$isBase && !length($snapname);
 430
 431     my $name = &$find_free_diskname($storeid, $scfg, $vmid);
 432
 433     warn "clone $volname: $basename snapname $snap to $name\n";
 434
 435     if (length($snapname)) {
 436         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $volname, $snapname);
 437
 438         if (!$protected) {
 439             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $volname, '--snap', $snapname);
 440             run_rbd_command($cmd, errmsg => "rbd protect $volname snap $snapname error");
 441         }
 442     }
 443
 444     my $newvol = "$basename/$name";
 445     $newvol = $name if length($snapname);
 446
 447     my $cmd = &$rbd_cmd($scfg, $storeid, 'clone', &$add_pool_to_disk($scfg, $basename),
 448                         '--snap', $snap, &$add_pool_to_disk($scfg, $name));
 449
 450     run_rbd_command($cmd, errmsg => "rbd clone '$basename' error");
 451
 452     &$krbd_feature_disable($scfg, $storeid, $name);
 453
 454     return $newvol;
 455 }
 456
 457 sub alloc_image {
 458     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 459
 460
 461     die "illegal name '$name' - should be 'vm-$vmid-*'\n"
 462         if  $name && $name !~ m/^vm-$vmid-/;
 463
 464     $name = &$find_free_diskname($storeid, $scfg, $vmid) if !$name;
 465
 466     my $cmd = &$rbd_cmd($scfg, $storeid, 'create', '--image-format' , 2, '--size', int(($size+1023)/1024), $name);
 467     run_rbd_command($cmd, errmsg => "rbd create $name' error");
 468
 469     &$krbd_feature_disable($scfg, $storeid, $name);
 470
 471     return $name;
 472 }
 473
 474 sub free_image {
 475     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 476
 477     my ($vtype, $name, $vmid, undef, undef, undef) =
 478         $class->parse_volname($volname);
 479
 480     if ($isBase) {
 481         my $snap = '__base__';
 482         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 483         if ($protected){
 484             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 485             run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 486         }
 487     }
 488
 489     $class->deactivate_volume($storeid, $scfg, $volname);
 490
 491     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'purge',  $name);
 492     run_rbd_command($cmd, errmsg => "rbd snap purge '$volname' error");
 493
 494     $cmd = &$rbd_cmd($scfg, $storeid, 'rm', $name);
 495     run_rbd_command($cmd, errmsg => "rbd rm '$volname' error");
 496
 497     return undef;
 498 }
 499
 500 sub list_images {
 501     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 502
 503     $cache->{rbd} = rbd_ls($scfg, $storeid) if !$cache->{rbd};
 504     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 505
 506     my $res = [];
 507
 508     if (my $dat = $cache->{rbd}->{$pool}) {
 509         foreach my $image (keys %$dat) {
 510
 511             my $info = $dat->{$image};
 512
 513             my $volname = $info->{name};
 514             my $parent = $info->{parent};
 515             my $owner = $info->{vmid};
 516
 517             if ($parent && $parent =~ m/^(base-\d+-\S+)\@__base__$/) {
 518                 $info->{volid} = "$storeid:$1/$volname";
 519             } else {
 520                 $info->{volid} = "$storeid:$volname";
 521             }
 522
 523             if ($vollist) {
 524                 my $found = grep { $_ eq $info->{volid} } @$vollist;
 525                 next if !$found;
 526             } else {
 527                 next if defined ($vmid) && ($owner ne $vmid);
 528             }
 529
 530             $info->{format} = 'raw';
 531
 532             push @$res, $info;
 533         }
 534     }
 535
 536     return $res;
 537 }
 538
 539 sub status {
 540     my ($class, $storeid, $scfg, $cache) = @_;
 541
 542
 543     my $rados = &$librados_connect($scfg, $storeid);
 544     my $df = $rados->mon_command({ prefix => 'df', format => 'json' });
 545
 546     my ($d) = grep { $_->{name} eq $scfg->{pool} } @{$df->{pools}};
 547
 548     # max_avail -> max available space for data w/o replication in the pool
 549     # bytes_used -> data w/o replication in the pool
 550     my $free = $d->{stats}->{max_avail};
 551     my $used = $d->{stats}->{bytes_used};
 552     my $total = $used + $free;
 553     my $active = 1;
 554
 555     return ($total, $free, $used, $active);
 556 }
 557
 558 sub activate_storage {
 559     my ($class, $storeid, $scfg, $cache) = @_;
 560     return 1;
 561 }
 562
 563 sub deactivate_storage {
 564     my ($class, $storeid, $scfg, $cache) = @_;
 565     return 1;
 566 }
 567
 568 sub activate_volume {
 569     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 570
 571     return 1 if !$scfg->{krbd};
 572
 573     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 574     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 575
 576     my $path = "/dev/rbd/$pool/$name";
 577     $path .= '@'.$snapname if $snapname;
 578     return if -b $path;
 579
 580     $name .= '@'.$snapname if $snapname;
 581     my $cmd = &$rbd_cmd($scfg, $storeid, 'map', $name);
 582     run_rbd_command($cmd, errmsg => "can't mount rbd volume $name");
 583
 584     return 1;
 585 }
 586
 587 sub deactivate_volume {
 588     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 589
 590     return 1 if !$scfg->{krbd};
 591
 592     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 593     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 594
 595     my $path = "/dev/rbd/$pool/$name";
 596     $path .= '@'.$snapname if $snapname;
 597     return if ! -b $path;
 598
 599     my $cmd = &$rbd_cmd($scfg, $storeid, 'unmap', $path);
 600     run_rbd_command($cmd, errmsg => "can't unmap rbd volume $name");
 601
 602     return 1;
 603 }
 604
 605 sub volume_size_info {
 606     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 607
 608     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 609     my ($size, undef) = rbd_volume_info($scfg, $storeid, $name);
 610     return $size;
 611 }
 612
 613 sub volume_resize {
 614     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 615
 616     return 1 if $running && !$scfg->{krbd};
 617
 618     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 619
 620     my $cmd = &$rbd_cmd($scfg, $storeid, 'resize', '--allow-shrink', '--size', ($size/1024/1024), $name);
 621     run_rbd_command($cmd, errmsg => "rbd resize '$volname' error");
 622     return undef;
 623 }
 624
 625 sub volume_snapshot {
 626     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 627
 628     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 629
 630     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'create', '--snap', $snap, $name);
 631     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 632     return undef;
 633 }
 634
 635 sub volume_snapshot_rollback {
 636     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 637
 638     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 639
 640     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rollback', '--snap', $snap, $name);
 641     run_rbd_command($cmd, errmsg => "rbd snapshot $volname to '$snap' error");
 642 }
 643
 644 sub volume_snapshot_delete {
 645     my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
 646
 647     return 1 if $running && !$scfg->{krbd};
 648
 649     $class->deactivate_volume($storeid, $scfg, $volname, $snap, {});
 650
 651     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 652
 653     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 654     if ($protected){
 655         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 656         run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 657     }
 658
 659     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rm', '--snap', $snap, $name);
 660
 661     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 662
 663     return undef;
 664 }
 665
 666 sub volume_has_feature {
 667     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 668
 669    my $features = {
 670         snapshot => { current => 1, snap => 1},
 671         clone => { base => 1, snap => 1},
 672         template => { current => 1},
 673         copy => { base => 1, current => 1, snap => 1},
 674         sparseinit => { base => 1, current => 1},
 675     };
 676
 677     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 678         $class->parse_volname($volname);
 679
 680     my $key = undef;
 681     if($snapname){
 682         $key = 'snap';
 683     }else{
 684         $key =  $isBase ? 'base' : 'current';
 685     }
 686     return 1 if $features->{$feature}->{$key};
 687
 688     return undef;
 689 }
 690
 691 1;