PVE/Storage/ZFSPoolPlugin.pm

   1 package PVE::Storage::ZFSPoolPlugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use Net::IP;
   8 use POSIX;
   9
  10 use PVE::ProcFSTools;
  11 use PVE::RPCEnvironment;
  12 use PVE::Storage::Plugin;
  13 use PVE::Tools qw(run_command);
  14
  15 use base qw(PVE::Storage::Plugin);
  16
  17 sub type {
  18     return 'zfspool';
  19 }
  20
  21 sub plugindata {
  22     return {
  23         content => [ {images => 1, rootdir => 1}, {images => 1 , rootdir => 1}],
  24         format => [ { raw => 1, subvol => 1 } , 'raw' ],
  25     };
  26 }
  27
  28 sub properties {
  29     return {
  30         blocksize => {
  31             description => "block size",
  32             type => 'string',
  33         },
  34         sparse => {
  35             description => "use sparse volumes",
  36             type => 'boolean',
  37         },
  38         mountpoint => {
  39             description => "mount point",
  40             type => 'string', format => 'pve-storage-path',
  41         },
  42     };
  43 }
  44
  45 sub options {
  46     return {
  47         pool => { fixed => 1 },
  48         blocksize => { optional => 1 },
  49         sparse => { optional => 1 },
  50         nodes => { optional => 1 },
  51         disable => { optional => 1 },
  52         content => { optional => 1 },
  53         bwlimit => { optional => 1 },
  54         mountpoint => { optional => 1 },
  55     };
  56 }
  57
  58 # static zfs helper methods
  59
  60 sub zfs_parse_zvol_list {
  61     my ($text) = @_;
  62
  63     my $list = ();
  64
  65     return $list if !$text;
  66
  67     my @lines = split /\n/, $text;
  68     foreach my $line (@lines) {
  69         my ($dataset, $size, $origin, $type, $refquota) = split(/\s+/, $line);
  70         next if !($type eq 'volume' || $type eq 'filesystem');
  71
  72         my $zvol = {};
  73         my @parts = split /\//, $dataset;
  74         next if scalar(@parts) < 2; # we need pool/name
  75         my $name = pop @parts;
  76         my $pool = join('/', @parts);
  77
  78         next unless $name =~ m!^(vm|base|subvol|basevol)-(\d+)-(\S+)$!;
  79         $zvol->{owner} = $2;
  80
  81         $zvol->{pool} = $pool;
  82         $zvol->{name} = $name;
  83         if ($type eq 'filesystem') {
  84             if ($refquota eq 'none') {
  85                 $zvol->{size} = 0;
  86             } else {
  87                 $zvol->{size} = $refquota + 0;
  88             }
  89             $zvol->{format} = 'subvol';
  90         } else {
  91             $zvol->{size} = $size + 0;
  92             $zvol->{format} = 'raw';
  93         }
  94         if ($origin !~ /^-$/) {
  95             $zvol->{origin} = $origin;
  96         }
  97         push @$list, $zvol;
  98     }
  99
 100     return $list;
 101 }
 102
 103 sub parse_volname {
 104     my ($class, $volname) = @_;
 105
 106     if ($volname =~ m/^(((base|basevol)-(\d+)-\S+)\/)?((base|basevol|vm|subvol)-(\d+)-\S+)$/) {
 107         my $format = ($6 eq 'subvol' || $6 eq 'basevol') ? 'subvol' : 'raw';
 108         my $isBase = ($6 eq 'base' || $6 eq 'basevol');
 109         return ('images', $5, $7, $2, $4, $isBase, $format);
 110     }
 111
 112     die "unable to parse zfs volume name '$volname'\n";
 113 }
 114
 115 # virtual zfs methods (subclass can overwrite them)
 116
 117 sub on_add_hook {
 118     my ($class, $storeid, $scfg, %param) = @_;
 119
 120     my $cfg_mountpoint = $scfg->{mountpoint};
 121
 122     # ignore failure, pool might currently not be imported
 123     my $mountpoint;
 124     eval {
 125         my $res = $class->zfs_get_properties($scfg, 'mountpoint', $scfg->{pool}, 1);
 126         $mountpoint = PVE::Storage::Plugin::verify_path($res, 1) if defined($res);
 127     };
 128
 129     if (defined($cfg_mountpoint)) {
 130         if (defined($mountpoint) && !($cfg_mountpoint =~ m|^\Q$mountpoint\E/?$|)) {
 131             warn "warning for $storeid - mountpoint: $cfg_mountpoint " .
 132                  "does not match current mount point: $mountpoint\n";
 133         }
 134     } else {
 135         $scfg->{mountpoint} = $mountpoint;
 136     }
 137
 138     return;
 139 }
 140
 141 sub path {
 142     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 143
 144     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 145
 146     my $path = '';
 147     my $mountpoint = $scfg->{mountpoint} // "/$scfg->{pool}";
 148
 149     if ($vtype eq "images") {
 150         if ($name =~ m/^subvol-/ || $name =~ m/^basevol-/) {
 151             $path = "$mountpoint/$name";
 152         } else {
 153             $path = "/dev/zvol/$scfg->{pool}/$name";
 154         }
 155         $path .= "\@$snapname" if defined($snapname);
 156     } else {
 157         die "$vtype is not allowed in ZFSPool!";
 158     }
 159
 160     return ($path, $vmid, $vtype);
 161 }
 162
 163 sub zfs_request {
 164     my ($class, $scfg, $timeout, $method, @params) = @_;
 165
 166     my $cmd = [];
 167
 168     if ($method eq 'zpool_list') {
 169         push @$cmd, 'zpool', 'list';
 170     } elsif ($method eq 'zpool_import') {
 171         push @$cmd, 'zpool', 'import';
 172         $timeout = 15 if !$timeout || $timeout < 15;
 173     } else {
 174         push @$cmd, 'zfs', $method;
 175     }
 176     push @$cmd, @params;
 177
 178     my $msg = '';
 179     my $output = sub { $msg .= "$_[0]\n" };
 180
 181     if (PVE::RPCEnvironment->is_worker()) {
 182         $timeout = 60*60 if !$timeout;
 183         $timeout = 60*5 if $timeout < 60*5;
 184     } else {
 185         $timeout = 10 if !$timeout;
 186     }
 187
 188     run_command($cmd, errmsg => "zfs error", outfunc => $output, timeout => $timeout);
 189
 190     return $msg;
 191 }
 192
 193 sub zfs_wait_for_zvol_link {
 194     my ($class, $scfg, $volname, $timeout) = @_;
 195
 196     my $default_timeout = PVE::RPCEnvironment->is_worker() ? 60*5 : 10;
 197     $timeout = $default_timeout if !defined($timeout);
 198
 199     my ($devname, undef, undef) = $class->path($scfg, $volname);
 200
 201     for (my $i = 1; $i <= $timeout; $i++) {
 202         last if -b $devname;
 203         die "timeout: no zvol device link for '$volname' found after $timeout sec found.\n"
 204             if $i == $timeout;
 205
 206         sleep(1);
 207     }
 208 }
 209
 210 sub alloc_image {
 211     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 212
 213     my $volname = $name;
 214
 215     if ($fmt eq 'raw') {
 216
 217         die "illegal name '$volname' - should be 'vm-$vmid-*'\n"
 218             if $volname && $volname !~ m/^vm-$vmid-/;
 219         $volname = $class->find_free_diskname($storeid, $scfg, $vmid, $fmt)
 220             if !$volname;
 221
 222         $class->zfs_create_zvol($scfg, $volname, $size);
 223         $class->zfs_wait_for_zvol_link($scfg, $volname);
 224
 225     } elsif ( $fmt eq 'subvol') {
 226
 227         die "illegal name '$volname' - should be 'subvol-$vmid-*'\n"
 228             if $volname && $volname !~ m/^subvol-$vmid-/;
 229         $volname = $class->find_free_diskname($storeid, $scfg, $vmid, $fmt)
 230             if !$volname;
 231
 232         die "illegal name '$volname' - should be 'subvol-$vmid-*'\n"
 233             if $volname !~ m/^subvol-$vmid-/;
 234
 235         $class->zfs_create_subvol($scfg, $volname, $size);
 236
 237     } else {
 238         die "unsupported format '$fmt'";
 239     }
 240
 241     return $volname;
 242 }
 243
 244 sub free_image {
 245     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 246
 247     my (undef, $name, undef) = $class->parse_volname($volname);
 248
 249     $class->zfs_delete_zvol($scfg, $name);
 250
 251     return undef;
 252 }
 253
 254 sub list_images {
 255     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 256
 257     my $zfs_list = $class->zfs_list_zvol($scfg);
 258
 259     my $res = [];
 260
 261     if (my $dat = $zfs_list) {
 262
 263         foreach my $image (keys %$dat) {
 264
 265             my $info = $dat->{$image};
 266
 267             my $volname = $info->{name};
 268             my $parent = $info->{parent};
 269             my $owner = $info->{vmid};
 270
 271             if ($parent && $parent =~ m/^(\S+)\@__base__$/) {
 272                 my ($basename) = ($1);
 273                 $info->{volid} = "$storeid:$basename/$volname";
 274             } else {
 275                 $info->{volid} = "$storeid:$volname";
 276             }
 277
 278             if ($vollist) {
 279                 my $found = grep { $_ eq $info->{volid} } @$vollist;
 280                 next if !$found;
 281             } else {
 282                 next if defined ($vmid) && ($owner ne $vmid);
 283             }
 284
 285             push @$res, $info;
 286         }
 287     }
 288     return $res;
 289 }
 290
 291 sub zfs_get_properties {
 292     my ($class, $scfg, $properties, $dataset, $timeout) = @_;
 293
 294     my $result = $class->zfs_request($scfg, $timeout, 'get', '-o', 'value',
 295                                      '-Hp', $properties, $dataset);
 296     my @values = split /\n/, $result;
 297     return wantarray ? @values : $values[0];
 298 }
 299
 300 sub zfs_get_pool_stats {
 301     my ($class, $scfg) = @_;
 302
 303     my $available = 0;
 304     my $used = 0;
 305
 306     my @lines = $class->zfs_get_properties($scfg, 'available,used', $scfg->{pool});
 307
 308     if($lines[0] =~ /^(\d+)$/) {
 309         $available = $1;
 310     }
 311
 312     if($lines[1] =~ /^(\d+)$/) {
 313         $used = $1;
 314     }
 315
 316     return ($available, $used);
 317 }
 318
 319 sub zfs_create_zvol {
 320     my ($class, $scfg, $zvol, $size) = @_;
 321
 322     # always align size to 1M as workaround until
 323     # https://github.com/zfsonlinux/zfs/issues/8541 is solved
 324     my $padding = (1024 - $size % 1024) % 1024;
 325     $size = $size + $padding;
 326
 327     my $cmd = ['create'];
 328
 329     push @$cmd, '-s' if $scfg->{sparse};
 330
 331     push @$cmd, '-b', $scfg->{blocksize} if $scfg->{blocksize};
 332
 333     push @$cmd, '-V', "${size}k", "$scfg->{pool}/$zvol";
 334
 335     $class->zfs_request($scfg, undef, @$cmd);
 336 }
 337
 338 sub zfs_create_subvol {
 339     my ($class, $scfg, $volname, $size) = @_;
 340
 341     my $dataset = "$scfg->{pool}/$volname";
 342     my $quota = $size ? "${size}k" : "none";
 343
 344     my $cmd = ['create', '-o', 'acltype=posixacl', '-o', 'xattr=sa',
 345                '-o', "refquota=${quota}", $dataset];
 346
 347     $class->zfs_request($scfg, undef, @$cmd);
 348 }
 349
 350 sub zfs_delete_zvol {
 351     my ($class, $scfg, $zvol) = @_;
 352
 353     my $err;
 354
 355     for (my $i = 0; $i < 6; $i++) {
 356
 357         eval { $class->zfs_request($scfg, undef, 'destroy', '-r', "$scfg->{pool}/$zvol"); };
 358         if ($err = $@) {
 359             if ($err =~ m/^zfs error:(.*): dataset is busy.*/) {
 360                 sleep(1);
 361             } elsif ($err =~ m/^zfs error:.*: dataset does not exist.*$/) {
 362                 $err = undef;
 363                 last;
 364             } else {
 365                 die $err;
 366             }
 367         } else {
 368             last;
 369         }
 370     }
 371
 372     die $err if $err;
 373 }
 374
 375 sub zfs_list_zvol {
 376     my ($class, $scfg) = @_;
 377
 378     my $text = $class->zfs_request(
 379         $scfg,
 380         10,
 381         'list',
 382         '-o',
 383         'name,volsize,origin,type,refquota',
 384         '-t',
 385         'volume,filesystem',
 386         '-Hrp',
 387         $scfg->{pool},
 388     );
 389     my $zvols = zfs_parse_zvol_list($text);
 390     return undef if !$zvols;
 391
 392     my $list = ();
 393     foreach my $zvol (@$zvols) {
 394         # The "pool" in $scfg is not the same as ZFS pool, so it's necessary to filter here.
 395         next if $scfg->{pool} ne $zvol->{pool};
 396
 397         my $name = $zvol->{name};
 398         my $parent = $zvol->{origin};
 399         if($zvol->{origin} && $zvol->{origin} =~ m/^$scfg->{pool}\/(\S+)$/){
 400             $parent = $1;
 401         }
 402
 403         $list->{$name} = {
 404             name => $name,
 405             size => $zvol->{size},
 406             parent => $parent,
 407             format => $zvol->{format},
 408             vmid => $zvol->{owner},
 409         };
 410     }
 411
 412     return $list;
 413 }
 414
 415 sub zfs_get_sorted_snapshot_list {
 416     my ($class, $scfg, $volname, $sort_params) = @_;
 417
 418     my @params = ('-H', '-r', '-t', 'snapshot', '-o', 'name', $sort_params->@*);
 419
 420     my $vname = ($class->parse_volname($volname))[1];
 421     push @params, "$scfg->{pool}\/$vname";
 422
 423     my $text = $class->zfs_request($scfg, undef, 'list', @params);
 424     my @snapshots = split(/\n/, $text);
 425
 426     my $snap_names = [];
 427     for my $snapshot (@snapshots) {
 428         (my $snap_name = $snapshot) =~ s/^.*@//;
 429         push $snap_names->@*, $snap_name;
 430     }
 431     return $snap_names;
 432 }
 433
 434 sub status {
 435     my ($class, $storeid, $scfg, $cache) = @_;
 436
 437     my $total = 0;
 438     my $free = 0;
 439     my $used = 0;
 440     my $active = 0;
 441
 442     eval {
 443         ($free, $used) = $class->zfs_get_pool_stats($scfg);
 444         $active = 1;
 445         $total = $free + $used;
 446     };
 447     warn $@ if $@;
 448
 449     return ($total, $free, $used, $active);
 450 }
 451
 452 sub volume_size_info {
 453     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 454
 455     my (undef, $vname, undef, undef, undef, undef, $format) =
 456         $class->parse_volname($volname);
 457
 458     my $attr = $format eq 'subvol' ? 'refquota' : 'volsize';
 459     my $value = $class->zfs_get_properties($scfg, $attr, "$scfg->{pool}/$vname");
 460     if ($value =~ /^(\d+)$/) {
 461         return $1;
 462     }
 463
 464     die "Could not get zfs volume size\n";
 465 }
 466
 467 sub volume_snapshot {
 468     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 469
 470     my $vname = ($class->parse_volname($volname))[1];
 471
 472     $class->zfs_request($scfg, undef, 'snapshot', "$scfg->{pool}/$vname\@$snap");
 473 }
 474
 475 sub volume_snapshot_delete {
 476     my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
 477
 478     my $vname = ($class->parse_volname($volname))[1];
 479
 480     $class->deactivate_volume($storeid, $scfg, $vname, $snap, {});
 481     $class->zfs_request($scfg, undef, 'destroy', "$scfg->{pool}/$vname\@$snap");
 482 }
 483
 484 sub volume_snapshot_rollback {
 485     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 486
 487     my (undef, $vname, undef, undef, undef, undef, $format) = $class->parse_volname($volname);
 488
 489     my $msg = $class->zfs_request($scfg, undef, 'rollback', "$scfg->{pool}/$vname\@$snap");
 490
 491     # we have to unmount rollbacked subvols, to invalidate wrong kernel
 492     # caches, they get mounted in activate volume again
 493     # see zfs bug #10931 https://github.com/openzfs/zfs/issues/10931
 494     if ($format eq 'subvol') {
 495         eval { $class->zfs_request($scfg, undef, 'unmount', "$scfg->{pool}/$vname"); };
 496         if (my $err = $@) {
 497             die $err if $err !~ m/not currently mounted$/;
 498         }
 499     }
 500
 501     return $msg;
 502 }
 503
 504 sub volume_rollback_is_possible {
 505     my ($class, $scfg, $storeid, $volname, $snap, $blockers) = @_;
 506
 507     # can't use '-S creation', because zfs list won't reverse the order when the
 508     # creation time is the same second, breaking at least our tests.
 509     my $snapshots = $class->zfs_get_sorted_snapshot_list($scfg, $volname, ['-s', 'creation']);
 510
 511     my $found;
 512     $blockers //= []; # not guaranteed to be set by caller
 513     for my $snapshot ($snapshots->@*) {
 514         if ($snapshot eq $snap) {
 515             $found = 1;
 516         } elsif ($found) {
 517             push $blockers->@*, $snapshot;
 518         }
 519     }
 520
 521     my $volid = "${storeid}:${volname}";
 522
 523     die "can't rollback, snapshot '$snap' does not exist on '$volid'\n"
 524         if !$found;
 525
 526     die "can't rollback, '$snap' is not most recent snapshot on '$volid'\n"
 527         if scalar($blockers->@*) > 0;
 528
 529     return 1;
 530 }
 531
 532 sub volume_snapshot_info {
 533     my ($class, $scfg, $storeid, $volname) = @_;
 534
 535     my @params = ('-Hp', '-r', '-t', 'snapshot', '-o', 'name,guid,creation');
 536
 537     my $vname = ($class->parse_volname($volname))[1];
 538     push @params, "$scfg->{pool}\/$vname";
 539
 540     my $text = $class->zfs_request($scfg, undef, 'list', @params);
 541     my @lines = split(/\n/, $text);
 542
 543     my $info = {};
 544     for my $line (@lines) {
 545         my ($snapshot, $guid, $creation) = split(/\s+/, $line);
 546         (my $snap_name = $snapshot) =~ s/^.*@//;
 547
 548         $info->{$snap_name} = {
 549             id => $guid,
 550             timestamp => $creation,
 551         };
 552     }
 553     return $info;
 554 }
 555
 556 my sub dataset_mounted_heuristic {
 557     my ($dataset) = @_;
 558
 559     my $mounts = PVE::ProcFSTools::parse_proc_mounts();
 560     for my $mp (@$mounts) {
 561         my ($what, $dir, $fs) = $mp->@*;
 562         next if $fs ne 'zfs';
 563         # check for root-dataset or any child-dataset (root-dataset could have 'canmount=off')
 564         # If any child is mounted heuristically assume that `zfs mount -a` was successful
 565         next if $what !~ m!^$dataset(?:/|$)!;
 566         return 1;
 567     }
 568     return 0;
 569 }
 570
 571 sub activate_storage {
 572     my ($class, $storeid, $scfg, $cache) = @_;
 573
 574     # Note: $scfg->{pool} can include dataset <pool>/<dataset>
 575     my $dataset = $scfg->{pool};
 576     my $pool = ($dataset =~ s!/.*$!!r);
 577
 578     return 1 if dataset_mounted_heuristic($dataset); # early return
 579
 580     my $pool_imported = sub {
 581         my @param = ('-o', 'name', '-H', $pool);
 582         my $res = eval { $class->zfs_request($scfg, undef, 'zpool_list', @param) };
 583         warn "$@\n" if $@;
 584
 585         return defined($res) && $res =~ m/$pool/;
 586     };
 587
 588     if (!$pool_imported->()) {
 589         # import can only be done if not yet imported!
 590         my @param = ('-d', '/dev/disk/by-id/', '-o', 'cachefile=none', $pool);
 591         eval { $class->zfs_request($scfg, undef, 'zpool_import', @param) };
 592         if (my $err = $@) {
 593             # just could've raced with another import, so recheck if it is imported
 594             die "could not activate storage '$storeid', $err\n" if !$pool_imported->();
 595         }
 596     }
 597     eval { $class->zfs_request($scfg, undef, 'mount', '-a') };
 598     die "could not activate storage '$storeid', $@\n" if $@;
 599     return 1;
 600 }
 601
 602 sub deactivate_storage {
 603     my ($class, $storeid, $scfg, $cache) = @_;
 604     return 1;
 605 }
 606
 607 sub activate_volume {
 608     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 609
 610     return 1 if defined($snapname);
 611
 612     my (undef, $dataset, undef, undef, undef, undef, $format) = $class->parse_volname($volname);
 613
 614     if ($format eq 'raw') {
 615         $class->zfs_wait_for_zvol_link($scfg, $volname);
 616     } elsif ($format eq 'subvol') {
 617         my $mounted = $class->zfs_get_properties($scfg, 'mounted', "$scfg->{pool}/$dataset");
 618         if ($mounted !~ m/^yes$/) {
 619             $class->zfs_request($scfg, undef, 'mount', "$scfg->{pool}/$dataset");
 620         }
 621     }
 622
 623     return 1;
 624 }
 625
 626 sub deactivate_volume {
 627     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 628     return 1;
 629 }
 630
 631 sub clone_image {
 632     my ($class, $scfg, $storeid, $volname, $vmid, $snap) = @_;
 633
 634     $snap ||= '__base__';
 635
 636     my ($vtype, $basename, $basevmid, undef, undef, $isBase, $format) =
 637         $class->parse_volname($volname);
 638
 639     die "clone_image only works on base images\n" if !$isBase;
 640
 641     my $name = $class->find_free_diskname($storeid, $scfg, $vmid, $format);
 642
 643     if ($format eq 'subvol') {
 644         my $size = $class->zfs_request($scfg, undef, 'list', '-Hp', '-o', 'refquota', "$scfg->{pool}/$basename");
 645         chomp($size);
 646         $class->zfs_request($scfg, undef, 'clone', "$scfg->{pool}/$basename\@$snap", "$scfg->{pool}/$name", '-o', "refquota=$size");
 647     } else {
 648         $class->zfs_request($scfg, undef, 'clone', "$scfg->{pool}/$basename\@$snap", "$scfg->{pool}/$name");
 649     }
 650
 651     return "$basename/$name";
 652 }
 653
 654 sub create_base {
 655     my ($class, $storeid, $scfg, $volname) = @_;
 656
 657     my $snap = '__base__';
 658
 659     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase, $format) =
 660         $class->parse_volname($volname);
 661
 662     die "create_base not possible with base image\n" if $isBase;
 663
 664     my $newname = $name;
 665     if ( $format eq 'subvol' ) {
 666         $newname =~ s/^subvol-/basevol-/;
 667     } else {
 668         $newname =~ s/^vm-/base-/;
 669     }
 670     my $newvolname = $basename ? "$basename/$newname" : "$newname";
 671
 672     $class->zfs_request($scfg, undef, 'rename', "$scfg->{pool}/$name", "$scfg->{pool}/$newname");
 673
 674     my $running  = undef; #fixme : is create_base always offline ?
 675
 676     $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running);
 677
 678     return $newvolname;
 679 }
 680
 681 sub volume_resize {
 682     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 683
 684     my $new_size = int($size/1024);
 685
 686     my (undef, $vname, undef, undef, undef, undef, $format) =
 687         $class->parse_volname($volname);
 688
 689     my $attr = $format eq 'subvol' ? 'refquota' : 'volsize';
 690
 691     # align size to 1M so we always have a valid multiple of the volume block size
 692     if ($format eq 'raw') {
 693         my $padding = (1024 - $new_size % 1024) % 1024;
 694         $new_size = $new_size + $padding;
 695     }
 696
 697     $class->zfs_request($scfg, undef, 'set', "$attr=${new_size}k", "$scfg->{pool}/$vname");
 698
 699     return $new_size;
 700 }
 701
 702 sub storage_can_replicate {
 703     my ($class, $scfg, $storeid, $format) = @_;
 704
 705     return 1 if $format eq 'raw' || $format eq 'subvol';
 706
 707     return 0;
 708 }
 709
 710 sub volume_has_feature {
 711     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 712
 713     my $features = {
 714         snapshot => { current => 1, snap => 1},
 715         clone => { base => 1},
 716         template => { current => 1},
 717         copy => { base => 1, current => 1},
 718         sparseinit => { base => 1, current => 1},
 719         replicate => { base => 1, current => 1},
 720         rename => {current => 1},
 721     };
 722
 723     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 724         $class->parse_volname($volname);
 725
 726     my $key = undef;
 727
 728     if ($snapname) {
 729         $key = 'snap';
 730     } else {
 731         $key = $isBase ? 'base' : 'current';
 732     }
 733
 734     return 1 if $features->{$feature}->{$key};
 735
 736     return undef;
 737 }
 738
 739 sub volume_export {
 740     my ($class, $scfg, $storeid, $fh, $volname, $format, $snapshot, $base_snapshot, $with_snapshots) = @_;
 741
 742     die "unsupported export stream format for $class: $format\n"
 743         if $format ne 'zfs';
 744
 745     die "$class storage can only export snapshots\n"
 746         if !defined($snapshot);
 747
 748     my $dataset = ($class->parse_volname($volname))[1];
 749
 750     my $fd = fileno($fh);
 751     die "internal error: invalid file handle for volume_export\n"
 752         if !defined($fd);
 753     $fd = ">&$fd";
 754
 755     # For zfs we always create a replication stream (-R) which means the remote
 756     # side will always delete non-existing source snapshots. This should work
 757     # for all our use cases.
 758     my $cmd = ['zfs', 'send', '-Rpv'];
 759     if (defined($base_snapshot)) {
 760         my $arg = $with_snapshots ? '-I' : '-i';
 761         push @$cmd, $arg, $base_snapshot;
 762     }
 763     push @$cmd, '--', "$scfg->{pool}/$dataset\@$snapshot";
 764
 765     run_command($cmd, output => $fd);
 766
 767     return;
 768 }
 769
 770 sub volume_export_formats {
 771     my ($class, $scfg, $storeid, $volname, $snapshot, $base_snapshot, $with_snapshots) = @_;
 772
 773     my @formats = ('zfs');
 774     # TODOs:
 775     # push @formats, 'fies' if $volname !~ /^(?:basevol|subvol)-/;
 776     # push @formats, 'raw' if !$base_snapshot && !$with_snapshots;
 777     return @formats;
 778 }
 779
 780 sub volume_import {
 781     my ($class, $scfg, $storeid, $fh, $volname, $format, $snapshot, $base_snapshot, $with_snapshots, $allow_rename) = @_;
 782
 783     die "unsupported import stream format for $class: $format\n"
 784         if $format ne 'zfs';
 785
 786     my $fd = fileno($fh);
 787     die "internal error: invalid file handle for volume_import\n"
 788         if !defined($fd);
 789
 790     my (undef, $dataset, $vmid, undef, undef, undef, $volume_format) =
 791         $class->parse_volname($volname);
 792
 793     my $zfspath = "$scfg->{pool}/$dataset";
 794     my $suffix = defined($base_snapshot) ? "\@$base_snapshot" : '';
 795     my $exists = 0 == run_command(['zfs', 'get', '-H', 'name', $zfspath.$suffix],
 796                                   noerr => 1, quiet => 1);
 797     if (defined($base_snapshot)) {
 798         die "base snapshot '$zfspath\@$base_snapshot' doesn't exist\n" if !$exists;
 799     } elsif ($exists) {
 800         die "volume '$zfspath' already exists\n" if !$allow_rename;
 801         warn "volume '$zfspath' already exists - importing with a different name\n";
 802         $dataset = $class->find_free_diskname($storeid, $scfg, $vmid, $volume_format);
 803         $zfspath = "$scfg->{pool}/$dataset";
 804     }
 805
 806     eval { run_command(['zfs', 'recv', '-F', '--', $zfspath], input => "<&$fd") };
 807     if (my $err = $@) {
 808         if (defined($base_snapshot)) {
 809             eval { run_command(['zfs', 'rollback', '-r', '--', "$zfspath\@$base_snapshot"]) };
 810         } else {
 811             eval { run_command(['zfs', 'destroy', '-r', '--', $zfspath]) };
 812         }
 813         die $err;
 814     }
 815
 816     return "$storeid:$dataset";
 817 }
 818
 819 sub volume_import_formats {
 820     my ($class, $scfg, $storeid, $volname, $snapshot, $base_snapshot, $with_snapshots) = @_;
 821
 822     return $class->volume_export_formats($scfg, $storeid, $volname, $snapshot, $base_snapshot, $with_snapshots);
 823 }
 824
 825 sub rename_volume {
 826     my ($class, $scfg, $storeid, $source_volname, $target_vmid, $target_volname) = @_;
 827
 828     my (
 829         undef,
 830         $source_image,
 831         $source_vmid,
 832         $base_name,
 833         $base_vmid,
 834         undef,
 835         $format
 836     ) = $class->parse_volname($source_volname);
 837     $target_volname = $class->find_free_diskname($storeid, $scfg, $target_vmid, $format)
 838         if !$target_volname;
 839
 840     my $pool = $scfg->{pool};
 841     my $source_zfspath = "${pool}/${source_image}";
 842     my $target_zfspath = "${pool}/${target_volname}";
 843
 844     my $exists = 0 == run_command(['zfs', 'get', '-H', 'name', $target_zfspath],
 845                                   noerr => 1, quiet => 1);
 846     die "target volume '${target_volname}' already exists\n" if $exists;
 847
 848     $class->zfs_request($scfg, 5, 'rename', ${source_zfspath}, ${target_zfspath});
 849
 850     $base_name = $base_name ? "${base_name}/" : '';
 851
 852     return "${storeid}:${base_name}${target_volname}";
 853 }
 854
 855 1;