PVE/Storage.pm

   1 package PVE::Storage;
   2
   3 use strict;
   4 use POSIX;
   5 use IO::Select;
   6 use IO::File;
   7 use File::Basename;
   8 use File::Path;
   9 use Cwd 'abs_path';
  10 use Socket;
  11
  12 use PVE::Tools qw(run_command file_read_firstline);
  13 use PVE::Cluster qw(cfs_read_file cfs_lock_file);
  14 use PVE::Exception qw(raise_param_exc);
  15 use PVE::JSONSchema;
  16 use PVE::INotify;
  17 use PVE::RPCEnvironment;
  18
  19 use PVE::Storage::Plugin;
  20 use PVE::Storage::DirPlugin;
  21 use PVE::Storage::LVMPlugin;
  22 use PVE::Storage::NFSPlugin;
  23 use PVE::Storage::ISCSIPlugin;
  24 use PVE::Storage::RBDPlugin;
  25 use PVE::Storage::SheepdogPlugin;
  26 use PVE::Storage::ISCSIDirectPlugin;
  27 use PVE::Storage::NexentaPlugin;
  28 use PVE::Storage::GlusterfsPlugin;
  29
  30 # load and initialize all plugins
  31 PVE::Storage::DirPlugin->register();
  32 PVE::Storage::LVMPlugin->register();
  33 PVE::Storage::NFSPlugin->register();
  34 PVE::Storage::ISCSIPlugin->register();
  35 PVE::Storage::RBDPlugin->register();
  36 PVE::Storage::SheepdogPlugin->register();
  37 PVE::Storage::ISCSIDirectPlugin->register();
  38 PVE::Storage::NexentaPlugin->register();
  39 PVE::Storage::GlusterfsPlugin->register();
  40 PVE::Storage::Plugin->init();
  41
  42 my $UDEVADM = '/sbin/udevadm';
  43
  44 #  PVE::Storage utility functions
  45
  46 sub config {
  47     return cfs_read_file("storage.cfg");
  48 }
  49
  50 sub lock_storage_config {
  51     my ($code, $errmsg) = @_;
  52
  53     cfs_lock_file("storage.cfg", undef, $code);
  54     my $err = $@;
  55     if ($err) {
  56         $errmsg ? die "$errmsg: $err" : die $err;
  57     }
  58 }
  59
  60 sub storage_config {
  61     my ($cfg, $storeid, $noerr) = @_;
  62
  63     die "no storage id specified\n" if !$storeid;
  64
  65     my $scfg = $cfg->{ids}->{$storeid};
  66
  67     die "storage '$storeid' does not exists\n" if (!$noerr && !$scfg);
  68
  69     return $scfg;
  70 }
  71
  72 sub storage_check_node {
  73     my ($cfg, $storeid, $node, $noerr) = @_;
  74
  75     my $scfg = storage_config($cfg, $storeid);
  76
  77     if ($scfg->{nodes}) {
  78         $node = PVE::INotify::nodename() if !$node || ($node eq 'localhost');
  79         if (!$scfg->{nodes}->{$node}) {
  80             die "storage '$storeid' is not available on node '$node'\n" if !$noerr;
  81             return undef;
  82         }
  83     }
  84
  85     return $scfg;
  86 }
  87
  88 sub storage_check_enabled {
  89     my ($cfg, $storeid, $node, $noerr) = @_;
  90
  91     my $scfg = storage_config($cfg, $storeid);
  92
  93     if ($scfg->{disable}) {
  94         die "storage '$storeid' is disabled\n" if !$noerr;
  95         return undef;
  96     }
  97
  98     return storage_check_node($cfg, $storeid, $node, $noerr);
  99 }
 100
 101 sub storage_ids {
 102     my ($cfg) = @_;
 103
 104     return keys %{$cfg->{ids}};
 105 }
 106
 107 sub file_size_info {
 108     my ($filename, $timeout) = @_;
 109
 110     return PVE::Storage::Plugin::file_size_info($filename, $timeout);
 111 }
 112
 113 sub volume_size_info {
 114     my ($cfg, $volid, $timeout) = @_;
 115
 116     my ($storeid, $volname) = parse_volume_id($volid, 1);
 117     if ($storeid) {
 118         my $scfg = storage_config($cfg, $storeid);
 119         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 120         return $plugin->volume_size_info($scfg, $storeid, $volname, $timeout);
 121     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 122         return file_size_info($volid, $timeout);
 123     } else {
 124         return 0;
 125     }
 126 }
 127
 128 sub volume_resize {
 129     my ($cfg, $volid, $size, $running) = @_;
 130
 131     my ($storeid, $volname) = parse_volume_id($volid, 1);
 132     if ($storeid) {
 133         my $scfg = storage_config($cfg, $storeid);
 134         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 135         return $plugin->volume_resize($scfg, $storeid, $volname, $size, $running);
 136     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 137         die "resize device is not possible";
 138     } else {
 139         die "can't resize";
 140     }
 141 }
 142
 143 sub volume_snapshot {
 144     my ($cfg, $volid, $snap, $running) = @_;
 145
 146     my ($storeid, $volname) = parse_volume_id($volid, 1);
 147     if ($storeid) {
 148         my $scfg = storage_config($cfg, $storeid);
 149         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 150         return $plugin->volume_snapshot($scfg, $storeid, $volname, $snap, $running);
 151     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 152         die "snapshot device is not possible";
 153     } else {
 154         die "can't snapshot";
 155     }
 156 }
 157
 158 sub volume_snapshot_rollback {
 159     my ($cfg, $volid, $snap) = @_;
 160
 161     my ($storeid, $volname) = parse_volume_id($volid, 1);
 162     if ($storeid) {
 163         my $scfg = storage_config($cfg, $storeid);
 164         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 165         return $plugin->volume_snapshot_rollback($scfg, $storeid, $volname, $snap);
 166     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 167         die "snapshot rollback device is not possible";
 168     } else {
 169         die "can't snapshot";
 170     }
 171 }
 172
 173 sub volume_snapshot_delete {
 174     my ($cfg, $volid, $snap, $running) = @_;
 175
 176     my ($storeid, $volname) = parse_volume_id($volid, 1);
 177     if ($storeid) {
 178         my $scfg = storage_config($cfg, $storeid);
 179         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 180         return $plugin->volume_snapshot_delete($scfg, $storeid, $volname, $snap, $running);
 181     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 182         die "snapshot delete device is not possible";
 183     } else {
 184         die "can't delete snapshot";
 185     }
 186 }
 187
 188 sub volume_has_feature {
 189     my ($cfg, $feature, $volid, $snap, $running) = @_;
 190
 191     my ($storeid, $volname) = parse_volume_id($volid, 1);
 192     if ($storeid) {
 193         my $scfg = storage_config($cfg, $storeid);
 194         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 195         return $plugin->volume_has_feature($scfg, $feature, $storeid, $volname, $snap, $running);
 196     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 197         return undef;
 198     } else {
 199         return undef;
 200     }
 201 }
 202
 203 sub get_image_dir {
 204     my ($cfg, $storeid, $vmid) = @_;
 205
 206     my $scfg = storage_config($cfg, $storeid);
 207     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 208
 209     my $path = $plugin->get_subdir($scfg, 'images');
 210
 211     return $vmid ? "$path/$vmid" : $path;
 212 }
 213
 214 sub get_private_dir {
 215     my ($cfg, $storeid, $vmid) = @_;
 216
 217     my $scfg = storage_config($cfg, $storeid);
 218     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 219
 220     my $path = $plugin->get_subdir($scfg, 'rootdir');
 221
 222     return $vmid ? "$path/$vmid" : $path;
 223 }
 224
 225 sub get_iso_dir {
 226     my ($cfg, $storeid) = @_;
 227
 228     my $scfg = storage_config($cfg, $storeid);
 229     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 230
 231     return $plugin->get_subdir($scfg, 'iso');
 232 }
 233
 234 sub get_vztmpl_dir {
 235     my ($cfg, $storeid) = @_;
 236
 237     my $scfg = storage_config($cfg, $storeid);
 238     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 239
 240     return $plugin->get_subdir($scfg, 'vztmpl');
 241 }
 242
 243 sub get_backup_dir {
 244     my ($cfg, $storeid) = @_;
 245
 246     my $scfg = storage_config($cfg, $storeid);
 247     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 248
 249     return $plugin->get_subdir($scfg, 'backup');
 250 }
 251
 252 # library implementation
 253
 254 sub parse_vmid {
 255     my $vmid = shift;
 256
 257     die "VMID '$vmid' contains illegal characters\n" if $vmid !~ m/^\d+$/;
 258
 259     return int($vmid);
 260 }
 261
 262 sub parse_volume_id {
 263     my ($volid, $noerr) = @_;
 264
 265     return PVE::Storage::Plugin::parse_volume_id($volid, $noerr);
 266 }
 267
 268 sub volume_is_base {
 269     my ($cfg, $volid) = @_;
 270
 271     my ($sid, $volname) = parse_volume_id($volid, 1);
 272     return 0 if !$sid;
 273
 274     if (my $scfg = $cfg->{ids}->{$sid}) {
 275         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 276         my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 277             $plugin->parse_volname($volname);
 278         return $isBase ? 1 : 0;
 279     } else {
 280         # stale volid with undefined storage - so we can just guess
 281         if ($volid =~ m/base-/) {
 282             return 1;
 283         }
 284     }
 285
 286     return 0;
 287 }
 288
 289 # try to map a filesystem path to a volume identifier
 290 sub path_to_volume_id {
 291     my ($cfg, $path) = @_;
 292
 293     my $ids = $cfg->{ids};
 294
 295     my ($sid, $volname) = parse_volume_id($path, 1);
 296     if ($sid) {
 297         if (my $scfg = $ids->{$sid}) {
 298             if ($scfg->{path}) {
 299                 my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 300                 my ($vtype, $name, $vmid) = $plugin->parse_volname($volname);
 301                 return ($vtype, $path);
 302             }
 303         }
 304         return ('');
 305     }
 306
 307     # Note: abs_path() return undef if $path doesn not exist
 308     # for example when nfs storage is not mounted
 309     $path = abs_path($path) || $path;
 310
 311     foreach my $sid (keys %$ids) {
 312         my $scfg = $ids->{$sid};
 313         next if !$scfg->{path};
 314         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 315         my $imagedir = $plugin->get_subdir($scfg, 'images');
 316         my $isodir = $plugin->get_subdir($scfg, 'iso');
 317         my $tmpldir = $plugin->get_subdir($scfg, 'vztmpl');
 318         my $backupdir = $plugin->get_subdir($scfg, 'backup');
 319         my $privatedir = $plugin->get_subdir($scfg, 'rootdir');
 320
 321         if ($path =~ m!^$imagedir/(\d+)/([^/\s]+)$!) {
 322             my $vmid = $1;
 323             my $name = $2;
 324
 325             my $vollist = $plugin->list_images($sid, $scfg, $vmid);
 326             foreach my $info (@$vollist) {
 327                 my ($storeid, $volname) = parse_volume_id($info->{volid});
 328                 my $volpath = $plugin->path($scfg, $volname, $storeid);
 329                 if ($volpath eq $path) {
 330                     return ('images', $info->{volid});
 331                 }
 332             }
 333         } elsif ($path =~ m!^$isodir/([^/]+\.[Ii][Ss][Oo])$!) {
 334             my $name = $1;
 335             return ('iso', "$sid:iso/$name");
 336         } elsif ($path =~ m!^$tmpldir/([^/]+\.tar\.gz)$!) {
 337             my $name = $1;
 338             return ('vztmpl', "$sid:vztmpl/$name");
 339         } elsif ($path =~ m!^$privatedir/(\d+)$!) {
 340             my $vmid = $1;
 341             return ('rootdir', "$sid:rootdir/$vmid");
 342         } elsif ($path =~ m!^$backupdir/([^/]+\.(tar|tar\.gz|tar\.lzo|tgz|vma|vma\.gz|vma\.lzo))$!) {
 343             my $name = $1;
 344             return ('iso', "$sid:backup/$name");
 345         }
 346     }
 347
 348     # can't map path to volume id
 349     return ('');
 350 }
 351
 352 sub path {
 353     my ($cfg, $volid, $snapname) = @_;
 354
 355     my ($storeid, $volname) = parse_volume_id($volid);
 356
 357     my $scfg = storage_config($cfg, $storeid);
 358
 359     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 360     my ($path, $owner, $vtype) = $plugin->path($scfg, $volname, $storeid, $snapname);
 361     return wantarray ? ($path, $owner, $vtype) : $path;
 362 }
 363
 364 sub storage_migrate {
 365     my ($cfg, $volid, $target_host, $target_storeid, $target_volname) = @_;
 366
 367     my ($storeid, $volname) = parse_volume_id($volid);
 368     $target_volname = $volname if !$target_volname;
 369
 370     my $scfg = storage_config($cfg, $storeid);
 371
 372     # no need to migrate shared content
 373     return if $storeid eq $target_storeid && $scfg->{shared};
 374
 375     my $tcfg = storage_config($cfg, $target_storeid);
 376
 377     my $target_volid = "${target_storeid}:${target_volname}";
 378
 379     my $errstr = "unable to migrate '$volid' to '${target_volid}' on host '$target_host'";
 380
 381     my $sshoptions = "-o 'BatchMode=yes'";
 382     my $ssh = "/usr/bin/ssh $sshoptions";
 383
 384     local $ENV{RSYNC_RSH} = $ssh;
 385
 386     # only implemented for file system based storage
 387     if ($scfg->{path}) {
 388         if ($tcfg->{path}) {
 389
 390             my $src_plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 391             my $dst_plugin = PVE::Storage::Plugin->lookup($tcfg->{type});
 392             my $src = $src_plugin->path($scfg, $volname, $storeid);
 393             my $dst = $dst_plugin->path($tcfg, $target_volname, $target_storeid);
 394
 395             my $dirname = dirname($dst);
 396
 397             if ($tcfg->{shared}) { # we can do a local copy
 398
 399                 run_command(['/bin/mkdir', '-p', $dirname]);
 400
 401                 run_command(['/bin/cp', $src, $dst]);
 402
 403             } else {
 404
 405                 run_command(['/usr/bin/ssh', "root\@${target_host}",
 406                              '/bin/mkdir', '-p', $dirname]);
 407
 408                 # we use rsync with --sparse, so we can't use --inplace,
 409                 # so we remove file on the target if it already exists to
 410                 # save space
 411                 my ($size, $format) = PVE::Storage::Plugin::file_size_info($src);
 412                 if ($format && ($format eq 'raw') && $size) {
 413                     run_command(['/usr/bin/ssh', "root\@${target_host}",
 414                                  'rm', '-f', $dst],
 415                                 outfunc => sub {});
 416                 }
 417
 418                 my $cmd = ['/usr/bin/rsync', '--progress', '--sparse', '--whole-file',
 419                            $src, "root\@${target_host}:$dst"];
 420
 421                 my $percent = -1;
 422
 423                 run_command($cmd, outfunc => sub {
 424                     my $line = shift;
 425
 426                     if ($line =~ m/^\s*(\d+\s+(\d+)%\s.*)$/) {
 427                         if ($2 > $percent) {
 428                             $percent = $2;
 429                             print "rsync status: $1\n";
 430                             *STDOUT->flush();
 431                         }
 432                     } else {
 433                         print "$line\n";
 434                         *STDOUT->flush();
 435                     }
 436                 });
 437             }
 438         } else {
 439             die "$errstr - target type '$tcfg->{type}' not implemented\n";
 440         }
 441     } else {
 442         die "$errstr - source type '$scfg->{type}' not implemented\n";
 443     }
 444 }
 445
 446 sub vdisk_clone {
 447     my ($cfg, $volid, $vmid) = @_;
 448
 449     my ($storeid, $volname) = parse_volume_id($volid);
 450
 451     my $scfg = storage_config($cfg, $storeid);
 452
 453     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 454
 455     activate_storage($cfg, $storeid);
 456
 457     # lock shared storage
 458     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 459         my $volname = $plugin->clone_image($scfg, $storeid, $volname, $vmid);
 460         return "$storeid:$volname";
 461     });
 462 }
 463
 464 sub vdisk_create_base {
 465     my ($cfg, $volid) = @_;
 466
 467     my ($storeid, $volname) = parse_volume_id($volid);
 468
 469     my $scfg = storage_config($cfg, $storeid);
 470
 471     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 472
 473     activate_storage($cfg, $storeid);
 474
 475     # lock shared storage
 476     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 477         my $volname = $plugin->create_base($storeid, $scfg, $volname);
 478         return "$storeid:$volname";
 479     });
 480 }
 481
 482 sub vdisk_alloc {
 483     my ($cfg, $storeid, $vmid, $fmt, $name, $size) = @_;
 484
 485     die "no storage id specified\n" if !$storeid;
 486
 487     PVE::JSONSchema::parse_storage_id($storeid);
 488
 489     my $scfg = storage_config($cfg, $storeid);
 490
 491     die "no VMID specified\n" if !$vmid;
 492
 493     $vmid = parse_vmid($vmid);
 494
 495     my $defformat = PVE::Storage::Plugin::default_format($scfg);
 496
 497     $fmt = $defformat if !$fmt;
 498
 499     activate_storage($cfg, $storeid);
 500
 501     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 502
 503     # lock shared storage
 504     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 505         my $volname = $plugin->alloc_image($storeid, $scfg, $vmid, $fmt, $name, $size);
 506         return "$storeid:$volname";
 507     });
 508 }
 509
 510 sub vdisk_free {
 511     my ($cfg, $volid) = @_;
 512
 513     my ($storeid, $volname) = parse_volume_id($volid);
 514
 515     my $scfg = storage_config($cfg, $storeid);
 516
 517     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 518
 519     activate_storage($cfg, $storeid);
 520
 521     my $cleanup_worker;
 522
 523     # lock shared storage
 524     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 525
 526         my ($vtype, $name, $vmid, undef, undef, $isBase) =
 527             $plugin->parse_volname($volname);
 528         if ($isBase) {
 529             my $vollist = $plugin->list_images($storeid, $scfg);
 530             foreach my $info (@$vollist) {
 531                 my (undef, $tmpvolname) = parse_volume_id($info->{volid});
 532                 my $basename = undef;
 533                 my $basevmid = undef;
 534
 535                 eval{
 536                     (undef, undef, undef, $basename, $basevmid) =
 537                         $plugin->parse_volname($tmpvolname);
 538                 };
 539
 540                 if ($basename && defined($basevmid) && $basevmid == $vmid && $basename eq $name) {
 541                     die "base volume '$volname' is still in use " .
 542                         "(use by '$tmpvolname')\n";
 543                 }
 544             }
 545         }
 546         my $cleanup_worker = $plugin->free_image($storeid, $scfg, $volname, $isBase);
 547     });
 548
 549     return if !$cleanup_worker;
 550
 551     my $rpcenv = PVE::RPCEnvironment::get();
 552     my $authuser = $rpcenv->get_user();
 553
 554     $rpcenv->fork_worker('imgdel', undef, $authuser, $cleanup_worker);
 555 }
 556
 557 #list iso or openvz template ($tt = <iso|vztmpl|backup>)
 558 sub template_list {
 559     my ($cfg, $storeid, $tt) = @_;
 560
 561     die "unknown template type '$tt'\n"
 562         if !($tt eq 'iso' || $tt eq 'vztmpl' || $tt eq 'backup');
 563
 564     my $ids = $cfg->{ids};
 565
 566     storage_check_enabled($cfg, $storeid) if ($storeid);
 567
 568     my $res = {};
 569
 570     # query the storage
 571
 572     foreach my $sid (keys %$ids) {
 573         next if $storeid && $storeid ne $sid;
 574
 575         my $scfg = $ids->{$sid};
 576         my $type = $scfg->{type};
 577
 578         next if !storage_check_enabled($cfg, $sid, undef, 1);
 579
 580         next if $tt eq 'iso' && !$scfg->{content}->{iso};
 581         next if $tt eq 'vztmpl' && !$scfg->{content}->{vztmpl};
 582         next if $tt eq 'backup' && !$scfg->{content}->{backup};
 583
 584         activate_storage($cfg, $sid);
 585
 586         if ($scfg->{path}) {
 587             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 588
 589             my $path = $plugin->get_subdir($scfg, $tt);
 590
 591             foreach my $fn (<$path/*>) {
 592
 593                 my $info;
 594
 595                 if ($tt eq 'iso') {
 596                     next if $fn !~ m!/([^/]+\.[Ii][Ss][Oo])$!;
 597
 598                     $info = { volid => "$sid:iso/$1", format => 'iso' };
 599
 600                 } elsif ($tt eq 'vztmpl') {
 601                     next if $fn !~ m!/([^/]+\.tar\.gz)$!;
 602
 603                     $info = { volid => "$sid:vztmpl/$1", format => 'tgz' };
 604
 605                 } elsif ($tt eq 'backup') {
 606                     next if $fn !~ m!/([^/]+\.(tar|tar\.gz|tar\.lzo|tgz|vma|vma\.gz|vma\.lzo))$!;
 607
 608                     $info = { volid => "$sid:backup/$1", format => $2 };
 609                 }
 610
 611                 $info->{size} = -s $fn;
 612
 613                 push @{$res->{$sid}}, $info;
 614             }
 615
 616         }
 617
 618         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 619     }
 620
 621     return $res;
 622 }
 623
 624
 625 sub vdisk_list {
 626     my ($cfg, $storeid, $vmid, $vollist) = @_;
 627
 628     my $ids = $cfg->{ids};
 629
 630     storage_check_enabled($cfg, $storeid) if ($storeid);
 631
 632     my $res = {};
 633
 634     # prepare/activate/refresh all storages
 635
 636     my $storage_list = [];
 637     if ($vollist) {
 638         foreach my $volid (@$vollist) {
 639             my ($sid, undef) = parse_volume_id($volid);
 640             next if !defined($ids->{$sid});
 641             next if !storage_check_enabled($cfg, $sid, undef, 1);
 642             push @$storage_list, $sid;
 643         }
 644     } else {
 645         foreach my $sid (keys %$ids) {
 646             next if $storeid && $storeid ne $sid;
 647             next if !storage_check_enabled($cfg, $sid, undef, 1);
 648             push @$storage_list, $sid;
 649         }
 650     }
 651
 652     my $cache = {};
 653
 654     activate_storage_list($cfg, $storage_list, $cache);
 655
 656     foreach my $sid (keys %$ids) {
 657         next if $storeid && $storeid ne $sid;
 658         next if !storage_check_enabled($cfg, $sid, undef, 1);
 659
 660         my $scfg = $ids->{$sid};
 661         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 662         $res->{$sid} = $plugin->list_images($sid, $scfg, $vmid, $vollist, $cache);
 663         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 664     }
 665
 666     return $res;
 667 }
 668
 669 sub uevent_seqnum {
 670
 671     my $filename = "/sys/kernel/uevent_seqnum";
 672
 673     my $seqnum = 0;
 674     if (my $fh = IO::File->new($filename, "r")) {
 675         my $line = <$fh>;
 676         if ($line =~ m/^(\d+)$/) {
 677             $seqnum = int($1);
 678         }
 679         close ($fh);
 680     }
 681     return $seqnum;
 682 }
 683
 684 sub activate_storage {
 685     my ($cfg, $storeid, $cache) = @_;
 686
 687     $cache = {} if !$cache;
 688
 689     my $scfg = storage_check_enabled($cfg, $storeid);
 690
 691     return if $cache->{activated}->{$storeid};
 692
 693     $cache->{uevent_seqnum} = uevent_seqnum() if !$cache->{uevent_seqnum};
 694
 695     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 696
 697     if ($scfg->{base}) {
 698         my ($baseid, undef) = parse_volume_id ($scfg->{base});
 699         activate_storage($cfg, $baseid, $cache);
 700     }
 701
 702     if (!$plugin->check_connection($storeid, $scfg)) {
 703         die "storage '$storeid' is not online\n";
 704     }
 705
 706     $plugin->activate_storage($storeid, $scfg, $cache);
 707
 708     my $newseq = uevent_seqnum ();
 709
 710     # only call udevsettle if there are events
 711     if ($newseq > $cache->{uevent_seqnum}) {
 712         my $timeout = 30;
 713         system ("$UDEVADM settle --timeout=$timeout"); # ignore errors
 714         $cache->{uevent_seqnum} = $newseq;
 715     }
 716
 717     $cache->{activated}->{$storeid} = 1;
 718 }
 719
 720 sub activate_storage_list {
 721     my ($cfg, $storeid_list, $cache) = @_;
 722
 723     $cache = {} if !$cache;
 724
 725     foreach my $storeid (@$storeid_list) {
 726         activate_storage($cfg, $storeid, $cache);
 727     }
 728 }
 729
 730 sub deactivate_storage {
 731     my ($cfg, $storeid) = @_;
 732
 733     my $scfg = storage_config ($cfg, $storeid);
 734     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 735
 736     my $cache = {};
 737     $plugin->deactivate_storage($storeid, $scfg, $cache);
 738 }
 739
 740 sub activate_volumes {
 741     my ($cfg, $vollist, $exclusive) = @_;
 742
 743     return if !($vollist && scalar(@$vollist));
 744
 745     my $storagehash = {};
 746     foreach my $volid (@$vollist) {
 747         my ($storeid, undef) = parse_volume_id($volid);
 748         $storagehash->{$storeid} = 1;
 749     }
 750
 751     my $cache = {};
 752
 753     activate_storage_list($cfg, [keys %$storagehash], $cache);
 754
 755     foreach my $volid (@$vollist) {
 756         my ($storeid, $volname) = parse_volume_id($volid);
 757         my $scfg = storage_config($cfg, $storeid);
 758         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 759         $plugin->activate_volume($storeid, $scfg, $volname, $exclusive, $cache);
 760     }
 761 }
 762
 763 sub deactivate_volumes {
 764     my ($cfg, $vollist) = @_;
 765
 766     return if !($vollist && scalar(@$vollist));
 767
 768     my $cache = {};
 769
 770     my @errlist = ();
 771     foreach my $volid (@$vollist) {
 772         my ($storeid, $volname) = parse_volume_id($volid);
 773
 774         my $scfg = storage_config($cfg, $storeid);
 775         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 776
 777         eval {
 778             $plugin->deactivate_volume($storeid, $scfg, $volname, $cache);
 779         };
 780         if (my $err = $@) {
 781             warn $err;
 782             push @errlist, $volid;
 783         }
 784     }
 785
 786     die "volume deativation failed: " . join(' ', @errlist)
 787         if scalar(@errlist);
 788 }
 789
 790 sub storage_info {
 791     my ($cfg, $content) = @_;
 792
 793     my $ids = $cfg->{ids};
 794
 795     my $info = {};
 796
 797     my $slist = [];
 798     foreach my $storeid (keys %$ids) {
 799
 800         next if $content && !$ids->{$storeid}->{content}->{$content};
 801
 802         next if !storage_check_enabled($cfg, $storeid, undef, 1);
 803
 804         my $type = $ids->{$storeid}->{type};
 805
 806         $info->{$storeid} = {
 807             type => $type,
 808             total => 0,
 809             avail => 0,
 810             used => 0,
 811             shared => $ids->{$storeid}->{shared} ? 1 : 0,
 812             content => PVE::Storage::Plugin::content_hash_to_string($ids->{$storeid}->{content}),
 813             active => 0,
 814         };
 815
 816         push @$slist, $storeid;
 817     }
 818
 819     my $cache = {};
 820
 821     foreach my $storeid (keys %$ids) {
 822         my $scfg = $ids->{$storeid};
 823         next if !$info->{$storeid};
 824
 825         eval { activate_storage($cfg, $storeid, $cache); };
 826         if (my $err = $@) {
 827             warn $err;
 828             next;
 829         }
 830
 831         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 832         my ($total, $avail, $used, $active);
 833         eval { ($total, $avail, $used, $active) = $plugin->status($storeid, $scfg, $cache); };
 834         warn $@ if $@;
 835         next if !$active;
 836         $info->{$storeid}->{total} = $total;
 837         $info->{$storeid}->{avail} = $avail;
 838         $info->{$storeid}->{used} = $used;
 839         $info->{$storeid}->{active} = $active;
 840     }
 841
 842     return $info;
 843 }
 844
 845 sub resolv_server {
 846     my ($server) = @_;
 847
 848     my $packed_ip = gethostbyname($server);
 849     if (defined $packed_ip) {
 850         return inet_ntoa($packed_ip);
 851     }
 852     return undef;
 853 }
 854
 855 sub scan_nfs {
 856     my ($server_in) = @_;
 857
 858     my $server;
 859     if (!($server = resolv_server ($server_in))) {
 860         die "unable to resolve address for server '${server_in}'\n";
 861     }
 862
 863     my $cmd = ['/sbin/showmount',  '--no-headers', '--exports', $server];
 864
 865     my $res = {};
 866     run_command($cmd, outfunc => sub {
 867         my $line = shift;
 868
 869         # note: howto handle white spaces in export path??
 870         if ($line =~ m!^(/\S+)\s+(.+)$!) {
 871             $res->{$1} = $2;
 872         }
 873     });
 874
 875     return $res;
 876 }
 877
 878 sub resolv_portal {
 879     my ($portal, $noerr) = @_;
 880
 881     if ($portal =~ m/^([^:]+)(:(\d+))?$/) {
 882         my $server = $1;
 883         my $port = $3;
 884
 885         if (my $ip = resolv_server($server)) {
 886             $server = $ip;
 887             return $port ? "$server:$port" : $server;
 888         }
 889     }
 890     return undef if $noerr;
 891
 892     raise_param_exc({ portal => "unable to resolve portal address '$portal'" });
 893 }
 894
 895 # idea is from usbutils package (/usr/bin/usb-devices) script
 896 sub __scan_usb_device {
 897     my ($res, $devpath, $parent, $level) = @_;
 898
 899     return if ! -d $devpath;
 900     return if $level && $devpath !~ m/^.*[-.](\d+)$/;
 901     my $port = $level ? int($1 - 1) : 0;
 902
 903     my $busnum = int(file_read_firstline("$devpath/busnum"));
 904     my $devnum = int(file_read_firstline("$devpath/devnum"));
 905
 906     my $d = {
 907         port => $port,
 908         level => $level,
 909         busnum => $busnum,
 910         devnum => $devnum,
 911         speed => file_read_firstline("$devpath/speed"),
 912         class => hex(file_read_firstline("$devpath/bDeviceClass")),
 913         vendid => file_read_firstline("$devpath/idVendor"),
 914         prodid => file_read_firstline("$devpath/idProduct"),
 915     };
 916
 917     if ($level) {
 918         my $usbpath = $devpath;
 919         $usbpath =~ s|^.*/\d+\-||;
 920         $d->{usbpath} = $usbpath;
 921     }
 922
 923     my $product = file_read_firstline("$devpath/product");
 924     $d->{product} = $product if $product;
 925
 926     my $manu = file_read_firstline("$devpath/manufacturer");
 927     $d->{manufacturer} = $manu if $manu;
 928
 929     my $serial => file_read_firstline("$devpath/serial");
 930     $d->{serial} = $serial if $serial;
 931
 932     push @$res, $d;
 933
 934     foreach my $subdev (<$devpath/$busnum-*>) {
 935         next if $subdev !~ m|/$busnum-[0-9]+(\.[0-9]+)*$|;
 936         __scan_usb_device($res, $subdev, $devnum, $level + 1);
 937     }
 938
 939 };
 940
 941 sub scan_usb {
 942
 943     my $devlist = [];
 944
 945     foreach my $device (</sys/bus/usb/devices/usb*>) {
 946         __scan_usb_device($devlist, $device, 0, 0);
 947     }
 948
 949     return $devlist;
 950 }
 951
 952 sub scan_iscsi {
 953     my ($portal_in) = @_;
 954
 955     my $portal;
 956     if (!($portal = resolv_portal($portal_in))) {
 957         die "unable to parse/resolve portal address '${portal_in}'\n";
 958     }
 959
 960     return PVE::Storage::ISCSIPlugin::iscsi_discovery($portal);
 961 }
 962
 963 sub storage_default_format {
 964     my ($cfg, $storeid) = @_;
 965
 966     my $scfg = storage_config ($cfg, $storeid);
 967
 968     return PVE::Storage::Plugin::default_format($scfg);
 969 }
 970
 971 sub vgroup_is_used {
 972     my ($cfg, $vgname) = @_;
 973
 974     foreach my $storeid (keys %{$cfg->{ids}}) {
 975         my $scfg = storage_config($cfg, $storeid);
 976         if ($scfg->{type} eq 'lvm' && $scfg->{vgname} eq $vgname) {
 977             return 1;
 978         }
 979     }
 980
 981     return undef;
 982 }
 983
 984 sub target_is_used {
 985     my ($cfg, $target) = @_;
 986
 987     foreach my $storeid (keys %{$cfg->{ids}}) {
 988         my $scfg = storage_config($cfg, $storeid);
 989         if ($scfg->{type} eq 'iscsi' && $scfg->{target} eq $target) {
 990             return 1;
 991         }
 992     }
 993
 994     return undef;
 995 }
 996
 997 sub volume_is_used {
 998     my ($cfg, $volid) = @_;
 999
1000     foreach my $storeid (keys %{$cfg->{ids}}) {
1001         my $scfg = storage_config($cfg, $storeid);
1002         if ($scfg->{base} && $scfg->{base} eq $volid) {
1003             return 1;
1004         }
1005     }
1006
1007     return undef;
1008 }
1009
1010 sub storage_is_used {
1011     my ($cfg, $storeid) = @_;
1012
1013     foreach my $sid (keys %{$cfg->{ids}}) {
1014         my $scfg = storage_config($cfg, $sid);
1015         next if !$scfg->{base};
1016         my ($st) = parse_volume_id($scfg->{base});
1017         return 1 if $st && $st eq $storeid;
1018     }
1019
1020     return undef;
1021 }
1022
1023 sub foreach_volid {
1024     my ($list, $func) = @_;
1025
1026     return if !$list;
1027
1028     foreach my $sid (keys %$list) {
1029        foreach my $info (@{$list->{$sid}}) {
1030            my $volid = $info->{volid};
1031            my ($sid1, $volname) = parse_volume_id($volid, 1);
1032            if ($sid1 && $sid1 eq $sid) {
1033                &$func ($volid, $sid, $info);
1034            } else {
1035                warn "detected strange volid '$volid' in volume list for '$sid'\n";
1036            }
1037        }
1038     }
1039 }
1040
1041 1;