PVE/VZDump/QemuServer.pm

   1 package PVE::VZDump::QemuServer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Basename;
   7 use File::Path;
   8 use IO::File;
   9 use IPC::Open3;
  10 use JSON;
  11 use POSIX qw(EINTR EAGAIN);
  12
  13 use PVE::Cluster qw(cfs_read_file);
  14 use PVE::INotify;
  15 use PVE::IPCC;
  16 use PVE::JSONSchema;
  17 use PVE::PBSClient;
  18 use PVE::RESTEnvironment qw(log_warn);
  19 use PVE::QMPClient;
  20 use PVE::Storage::Plugin;
  21 use PVE::Storage::PBSPlugin;
  22 use PVE::Storage;
  23 use PVE::Tools;
  24 use PVE::VZDump;
  25 use PVE::Format qw(render_duration render_bytes);
  26
  27 use PVE::QemuConfig;
  28 use PVE::QemuServer;
  29 use PVE::QemuServer::Machine;
  30 use PVE::QemuServer::Monitor qw(mon_cmd);
  31
  32 use base qw (PVE::VZDump::Plugin);
  33
  34 sub new {
  35     my ($class, $vzdump) = @_;
  36
  37     PVE::VZDump::check_bin('qm');
  38
  39     my $self = bless { vzdump => $vzdump }, $class;
  40
  41     $self->{vmlist} = PVE::QemuServer::vzlist();
  42     $self->{storecfg} = PVE::Storage::config();
  43
  44     return $self;
  45 };
  46
  47 sub type {
  48     return 'qemu';
  49 }
  50
  51 sub vmlist {
  52     my ($self) = @_;
  53     return [ keys %{$self->{vmlist}} ];
  54 }
  55
  56 sub prepare {
  57     my ($self, $task, $vmid, $mode) = @_;
  58
  59     $task->{disks} = [];
  60
  61     my $conf = $self->{vmlist}->{$vmid} = PVE::QemuConfig->load_config($vmid);
  62
  63     $self->loginfo("VM Name: $conf->{name}")
  64         if defined($conf->{name});
  65
  66     $self->{vm_was_running} = 1;
  67     $self->{vm_was_paused} = 0;
  68     if (!PVE::QemuServer::check_running($vmid)) {
  69         $self->{vm_was_running} = 0;
  70     } elsif (PVE::QemuServer::vm_is_paused($vmid)) {
  71         $self->{vm_was_paused} = 1;
  72     }
  73
  74     $task->{hostname} = $conf->{name};
  75
  76     my $hostname = PVE::INotify::nodename();
  77
  78     my $vollist = [];
  79     my $drivehash = {};
  80     my $backup_volumes = PVE::QemuConfig->get_backup_volumes($conf);
  81
  82     foreach my $volume (@{$backup_volumes}) {
  83         my $name = $volume->{key};
  84         my $volume_config = $volume->{volume_config};
  85         my $volid = $volume_config->{file};
  86
  87         if (!$volume->{included}) {
  88             $self->loginfo("exclude disk '$name' '$volid' ($volume->{reason})");
  89             next;
  90         } elsif ($self->{vm_was_running} && $volume_config->{iothread} &&
  91                  !PVE::QemuServer::Machine::runs_at_least_qemu_version($vmid, 4, 0, 1)) {
  92             die "disk '$name' '$volid' (iothread=on) can't use backup feature with running QEMU " .
  93                 "version < 4.0.1! Either set backup=no for this drive or upgrade QEMU and restart VM\n";
  94         } else {
  95             my $log = "include disk '$name' '$volid'";
  96             if (defined(my $size = $volume_config->{size})) {
  97                 my $readable_size = PVE::JSONSchema::format_size($size);
  98                 $log .= " $readable_size";
  99             }
 100             $self->loginfo($log);
 101         }
 102
 103         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 104         push @$vollist, $volid if $storeid;
 105         $drivehash->{$name} = $volume->{volume_config};
 106     }
 107
 108     PVE::Storage::activate_volumes($self->{storecfg}, $vollist);
 109
 110     foreach my $ds (sort keys %$drivehash) {
 111         my $drive = $drivehash->{$ds};
 112
 113         my $volid = $drive->{file};
 114         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 115
 116         my $path = $volid;
 117         if ($storeid) {
 118             $path = PVE::Storage::path($self->{storecfg}, $volid);
 119         }
 120         next if !$path;
 121
 122         my ($size, $format) = eval { PVE::Storage::volume_size_info($self->{storecfg}, $volid, 5) };
 123         die "no such volume '$volid'\n" if $@;
 124
 125         my $diskinfo = {
 126             path => $path,
 127             volid => $volid,
 128             storeid => $storeid,
 129             format => $format,
 130             virtdev => $ds,
 131             qmdevice => "drive-$ds",
 132         };
 133
 134         if ($ds eq 'tpmstate0') {
 135             # TPM drive only exists for backup, which is reflected in the name
 136             $diskinfo->{qmdevice} = 'drive-tpmstate0-backup';
 137             $task->{tpmpath} = $path;
 138         }
 139
 140         if (-b $path) {
 141             $diskinfo->{type} = 'block';
 142         } else {
 143             $diskinfo->{type} = 'file';
 144         }
 145
 146         push @{$task->{disks}}, $diskinfo;
 147     }
 148 }
 149
 150 sub vm_status {
 151     my ($self, $vmid) = @_;
 152
 153     my $running = PVE::QemuServer::check_running($vmid) ? 1 : 0;
 154
 155     return wantarray ? ($running, $running ? 'running' : 'stopped') : $running;
 156 }
 157
 158 sub lock_vm {
 159     my ($self, $vmid) = @_;
 160
 161     PVE::QemuConfig->set_lock($vmid, 'backup');
 162 }
 163
 164 sub unlock_vm {
 165     my ($self, $vmid) = @_;
 166
 167     PVE::QemuConfig->remove_lock($vmid, 'backup');
 168 }
 169
 170 sub stop_vm {
 171     my ($self, $task, $vmid) = @_;
 172
 173     my $opts = $self->{vzdump}->{opts};
 174
 175     my $wait = $opts->{stopwait} * 60;
 176     # send shutdown and wait
 177     $self->cmd ("qm shutdown $vmid --skiplock --keepActive --timeout $wait");
 178 }
 179
 180 sub start_vm {
 181     my ($self, $task, $vmid) = @_;
 182
 183     $self->cmd ("qm start $vmid --skiplock");
 184 }
 185
 186 sub suspend_vm {
 187     my ($self, $task, $vmid) = @_;
 188
 189     return if $self->{vm_was_paused};
 190
 191     $self->cmd ("qm suspend $vmid --skiplock");
 192 }
 193
 194 sub resume_vm {
 195     my ($self, $task, $vmid) = @_;
 196
 197     return if $self->{vm_was_paused};
 198
 199     $self->cmd ("qm resume $vmid --skiplock");
 200 }
 201
 202 sub assemble {
 203     my ($self, $task, $vmid) = @_;
 204
 205     my $conffile = PVE::QemuConfig->config_file($vmid);
 206
 207     my $outfile = "$task->{tmpdir}/qemu-server.conf";
 208     my $firewall_src = "/etc/pve/firewall/$vmid.fw";
 209     my $firewall_dest = "$task->{tmpdir}/qemu-server.fw";
 210
 211     my $outfd = IO::File->new (">$outfile") ||
 212         die "unable to open '$outfile'";
 213     my $conffd = IO::File->new ($conffile, 'r') ||
 214         die "unable open '$conffile'";
 215
 216     my $found_snapshot;
 217     my $found_pending;
 218     my $found_cloudinit;
 219     while (defined (my $line = <$conffd>)) {
 220         next if $line =~ m/^\#vzdump\#/; # just to be sure
 221         next if $line =~ m/^\#qmdump\#/; # just to be sure
 222         if ($line =~ m/^\[(.*)\]\s*$/) {
 223             if ($1 =~ m/PENDING/i) {
 224                 $found_pending = 1;
 225             } elsif ($1 =~ m/special:cloudinit/) {
 226                 $found_cloudinit = 1;
 227             } else {
 228                 $found_snapshot = 1;
 229             }
 230         }
 231         next if $found_snapshot || $found_pending || $found_cloudinit; # skip all snapshots,pending changes and cloudinit config data
 232
 233         if ($line =~ m/^unused\d+:\s*(\S+)\s*/) {
 234             $self->loginfo("skip unused drive '$1' (not included into backup)");
 235             next;
 236         }
 237         next if $line =~ m/^lock:/ || $line =~ m/^parent:/;
 238
 239         print $outfd $line;
 240     }
 241
 242     foreach my $di (@{$task->{disks}}) {
 243         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 244             my $storeid = $di->{storeid} || '';
 245             my $format = $di->{format} || '';
 246             print $outfd "#qmdump#map:$di->{virtdev}:$di->{qmdevice}:$storeid:$format:\n";
 247         } else {
 248             die "internal error";
 249         }
 250     }
 251
 252     if ($found_snapshot) {
 253         $self->loginfo("snapshots found (not included into backup)");
 254     }
 255     if ($found_pending) {
 256         $self->loginfo("pending configuration changes found (not included into backup)");
 257     }
 258
 259     PVE::Tools::file_copy($firewall_src, $firewall_dest) if -f $firewall_src;
 260 }
 261
 262 sub archive {
 263     my ($self, $task, $vmid, $filename, $comp) = @_;
 264
 265     my $opts = $self->{vzdump}->{opts};
 266     my $scfg = $opts->{scfg};
 267
 268     if ($self->{vzdump}->{opts}->{pbs}) {
 269         $self->archive_pbs($task, $vmid);
 270     } else {
 271         $self->archive_vma($task, $vmid, $filename, $comp);
 272     }
 273 }
 274
 275 my $bitmap_action_to_human = sub {
 276     my ($self, $info) = @_;
 277
 278     my $action = $info->{action};
 279
 280     if ($action eq "not-used") {
 281         return "disabled (no support)";
 282     } elsif ($action eq "not-used-removed") {
 283         return "disabled (old bitmap cleared)";
 284     } elsif ($action eq "new") {
 285         return "created new";
 286     } elsif ($action eq "used") {
 287         if ($info->{dirty} == 0) {
 288             return "OK (drive clean)";
 289         } else {
 290             my $size = render_bytes($info->{size}, 1);
 291             my $dirty = render_bytes($info->{dirty}, 1);
 292             return "OK ($dirty of $size dirty)";
 293         }
 294     } elsif ($action eq "invalid") {
 295         return "existing bitmap was invalid and has been cleared";
 296     } else {
 297         return "unknown";
 298     }
 299 };
 300
 301 my $query_backup_status_loop = sub {
 302     my ($self, $vmid, $job_uuid, $qemu_support) = @_;
 303
 304     my $starttime = time ();
 305     my $last_time = $starttime;
 306     my ($last_percent, $last_total, $last_target, $last_zero, $last_transferred) = (-1, 0, 0, 0, 0);
 307     my ($transferred, $reused);
 308
 309     my $get_mbps = sub {
 310         my ($mb, $delta) = @_;
 311         return "0 B/s" if $mb <= 0;
 312         my $bw = int(($mb / $delta));
 313         return render_bytes($bw, 1) . "/s";
 314     };
 315
 316     my $target = 0;
 317     my $last_reused = 0;
 318     my $has_query_bitmap = $qemu_support && $qemu_support->{'query-bitmap-info'};
 319     my $is_template = PVE::QemuConfig->is_template($self->{vmlist}->{$vmid});
 320     if ($has_query_bitmap) {
 321         my $total = 0;
 322         my $bitmap_info = mon_cmd($vmid, 'query-pbs-bitmap-info');
 323         for my $info (sort { $a->{drive} cmp $b->{drive} } @$bitmap_info) {
 324             if (!$is_template) {
 325                 my $text = $bitmap_action_to_human->($self, $info);
 326                 my $drive = $info->{drive};
 327                 $drive =~ s/^drive-//; # for consistency
 328                 $self->loginfo("$drive: dirty-bitmap status: $text");
 329             }
 330             $target += $info->{dirty};
 331             $total += $info->{size};
 332             $last_reused += $info->{size} - $info->{dirty};
 333         }
 334         if ($target < $total) {
 335             my $total_h = render_bytes($total, 1);
 336             my $target_h = render_bytes($target, 1);
 337             $self->loginfo("using fast incremental mode (dirty-bitmap), $target_h dirty of $total_h total");
 338         }
 339     }
 340
 341     my $last_finishing = 0;
 342     while(1) {
 343         my $status = mon_cmd($vmid, 'query-backup');
 344
 345         my $total = $status->{total} || 0;
 346         my $dirty = $status->{dirty};
 347         $target = (defined($dirty) && $dirty < $total) ? $dirty : $total if !$has_query_bitmap;
 348         $transferred = $status->{transferred} || 0;
 349         $reused = $status->{reused};
 350         my $percent = $target ? int(($transferred * 100)/$target) : 100;
 351         my $zero = $status->{'zero-bytes'} || 0;
 352
 353         die "got unexpected uuid\n" if !$status->{uuid} || ($status->{uuid} ne $job_uuid);
 354
 355         my $ctime = time();
 356         my $duration = $ctime - $starttime;
 357
 358         my $rbytes = $transferred - $last_transferred;
 359         my $wbytes;
 360         if ($reused) {
 361             # reused includes zero bytes for PBS
 362             $wbytes = $rbytes - ($reused - $last_reused);
 363         } else {
 364             $wbytes = $rbytes - ($zero - $last_zero);
 365         }
 366
 367         my $timediff = ($ctime - $last_time) || 1; # fixme
 368         my $mbps_read = $get_mbps->($rbytes, $timediff);
 369         my $mbps_write = $get_mbps->($wbytes, $timediff);
 370         my $target_h = render_bytes($target, 1);
 371         my $transferred_h = render_bytes($transferred, 1);
 372
 373         my $statusline = sprintf("%3d%% ($transferred_h of $target_h) in %s"
 374             .", read: $mbps_read, write: $mbps_write", $percent, render_duration($duration));
 375
 376         my $res = $status->{status} || 'unknown';
 377         if ($res ne 'active') {
 378             if ($last_percent < 100) {
 379                 $self->loginfo($statusline);
 380             }
 381             if ($res ne 'done') {
 382                 die (($status->{errmsg} || "unknown error") . "\n") if $res eq 'error';
 383                 die "got unexpected status '$res'\n";
 384             }
 385             $last_target = $target if $target;
 386             $last_total = $total if $total;
 387             $last_zero = $zero if $zero;
 388             $last_transferred = $transferred if $transferred;
 389             last;
 390         }
 391         if ($percent != $last_percent && ($timediff > 2)) {
 392             $self->loginfo($statusline);
 393             $last_percent = $percent;
 394             $last_target = $target if $target;
 395             $last_total = $total if $total;
 396             $last_zero = $zero if $zero;
 397             $last_transferred = $transferred if $transferred;
 398             $last_time = $ctime;
 399             $last_reused = $reused;
 400
 401             if (!$last_finishing && $status->{finishing}) {
 402                 $self->loginfo("Waiting for server to finish backup validation...");
 403             }
 404             $last_finishing = $status->{finishing};
 405         }
 406         sleep(1);
 407     }
 408
 409     my $duration = time() - $starttime;
 410
 411     if ($last_zero) {
 412         my $zero_per = $last_target ? int(($last_zero * 100)/$last_target) : 0;
 413         my $zero_h = render_bytes($last_zero);
 414         $self->loginfo("backup is sparse: $zero_h (${zero_per}%) total zero data");
 415     }
 416     if ($reused) {
 417         my $reused_h = render_bytes($reused);
 418         my $reuse_per = int($reused * 100 / $last_total);
 419         $self->loginfo("backup was done incrementally, reused $reused_h (${reuse_per}%)");
 420     }
 421     if ($transferred) {
 422         my $transferred_h = render_bytes($transferred);
 423         if ($duration) {
 424             my $mbps = $get_mbps->($transferred, $duration);
 425             $self->loginfo("transferred $transferred_h in $duration seconds ($mbps)");
 426         } else {
 427             $self->loginfo("transferred $transferred_h in <1 seconds");
 428         }
 429     }
 430
 431     return {
 432         total => $last_total,
 433         reused => $reused,
 434     };
 435 };
 436
 437 my $attach_tpmstate_drive = sub {
 438     my ($self, $task, $vmid) = @_;
 439
 440     return if !$task->{tpmpath};
 441
 442     # unconditionally try to remove the tpmstate-named drive - it only exists
 443     # for backing up, and avoids errors if left over from some previous event
 444     eval { PVE::QemuServer::qemu_drivedel($vmid, "tpmstate0-backup"); };
 445
 446     $self->loginfo('attaching TPM drive to QEMU for backup');
 447
 448     my $drive = "file=$task->{tpmpath},if=none,read-only=on,id=drive-tpmstate0-backup";
 449     $drive =~ s/\\/\\\\/g;
 450     my $ret = PVE::QemuServer::Monitor::hmp_cmd($vmid, "drive_add auto \"$drive\"");
 451     die "attaching TPM drive failed - $ret\n" if $ret !~ m/OK/s;
 452 };
 453
 454 my $detach_tpmstate_drive = sub {
 455     my ($task, $vmid) = @_;
 456     return if !$task->{tpmpath} || !PVE::QemuServer::check_running($vmid);
 457     eval { PVE::QemuServer::qemu_drivedel($vmid, "tpmstate0-backup"); };
 458 };
 459
 460 my sub add_backup_performance_options {
 461     my ($qmp_param, $perf, $qemu_support) = @_;
 462
 463     return if !$perf || scalar(keys $perf->%*) == 0;
 464
 465     if (!$qemu_support) {
 466         my $settings_string = join(', ', sort keys $perf->%*);
 467         log_warn("ignoring setting(s): $settings_string - issue checking if supported");
 468         return;
 469     }
 470
 471     if (defined($perf->{'max-workers'})) {
 472         if ($qemu_support->{'backup-max-workers'}) {
 473             $qmp_param->{'max-workers'} = int($perf->{'max-workers'});
 474         } else {
 475             log_warn("ignoring 'max-workers' setting - not supported by running QEMU");
 476         }
 477     }
 478 }
 479
 480 sub archive_pbs {
 481     my ($self, $task, $vmid) = @_;
 482
 483     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 484     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 485
 486     my $opts = $self->{vzdump}->{opts};
 487     my $scfg = $opts->{scfg};
 488
 489     my $starttime = time();
 490
 491     my $fingerprint = $scfg->{fingerprint};
 492     my $repo = PVE::PBSClient::get_repository($scfg);
 493     my $password = PVE::Storage::PBSPlugin::pbs_get_password($scfg, $opts->{storage});
 494     my $keyfile = PVE::Storage::PBSPlugin::pbs_encryption_key_file_name($scfg, $opts->{storage});
 495     my $master_keyfile = PVE::Storage::PBSPlugin::pbs_master_pubkey_file_name($scfg, $opts->{storage});
 496
 497     my $diskcount = scalar(@{$task->{disks}});
 498     # proxmox-backup-client can only handle raw files and block devs
 499     # only use it (directly) for disk-less VMs
 500     if (!$diskcount) {
 501         my @pathlist;
 502         $self->loginfo("backup contains no disks");
 503
 504         local $ENV{PBS_PASSWORD} = $password;
 505         local $ENV{PBS_FINGERPRINT} = $fingerprint if defined($fingerprint);
 506         my $cmd = [
 507             '/usr/bin/proxmox-backup-client',
 508             'backup',
 509             '--repository', $repo,
 510             '--backup-type', 'vm',
 511             '--backup-id', "$vmid",
 512             '--backup-time', $task->{backup_time},
 513         ];
 514         if (defined(my $ns = $scfg->{namespace})) {
 515             push @$cmd, '--ns', $ns;
 516         }
 517
 518         push @$cmd, "qemu-server.conf:$conffile";
 519         push @$cmd, "fw.conf:$firewall" if -e $firewall;
 520
 521         $self->loginfo("starting template backup");
 522         $self->loginfo(join(' ', @$cmd));
 523
 524         $self->cmd($cmd);
 525
 526         return;
 527     }
 528
 529     # get list early so we die on unkown drive types before doing anything
 530     my $devlist = _get_task_devlist($task);
 531
 532     $self->enforce_vm_running_for_backup($vmid);
 533     $self->{qmeventd_fh} = PVE::QemuServer::register_qmeventd_handle($vmid);
 534
 535     my $backup_job_uuid;
 536     eval {
 537         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 538             die "interrupted by signal\n";
 539         };
 540
 541         my $qemu_support = eval { mon_cmd($vmid, "query-proxmox-support") };
 542         my $err = $@;
 543         if (!$qemu_support || $err) {
 544             die "query-proxmox-support returned empty value\n" if !$err;
 545             if ($err =~ m/The command query-proxmox-support has not been found/) {
 546                 die "PBS backups are not supported by the running QEMU version. Please make "
 547                   . "sure you've installed the latest version and the VM has been restarted.\n";
 548             } else {
 549                 die "QMP command query-proxmox-support failed - $err\n";
 550             }
 551         }
 552
 553         if (!defined($qemu_support->{"pbs-masterkey"}) && -e $master_keyfile) {
 554             $self->loginfo("WARNING: backup target is configured with master key, but running QEMU version does not support master keys.");
 555             $self->loginfo("Please make sure you've installed the latest version and the VM has been restarted to use master key feature.");
 556             $master_keyfile = undef; # skip rest of master key handling below
 557         }
 558
 559         $attach_tpmstate_drive->($self, $task, $vmid);
 560
 561         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 562
 563         my $params = {
 564             format => "pbs",
 565             'backup-file' => $repo,
 566             'backup-id' => "$vmid",
 567             'backup-time' => $task->{backup_time},
 568             password => $password,
 569             devlist => $devlist,
 570             'config-file' => $conffile,
 571         };
 572         if (defined(my $ns = $scfg->{namespace})) {
 573             $params->{'backup-ns'} = $ns;
 574         }
 575
 576         $params->{speed} = $opts->{bwlimit}*1024 if $opts->{bwlimit};
 577         add_backup_performance_options($params, $opts->{performance}, $qemu_support);
 578
 579         $params->{fingerprint} = $fingerprint if defined($fingerprint);
 580         $params->{'firewall-file'} = $firewall if -e $firewall;
 581         if (-e $keyfile) {
 582             $self->loginfo("enabling encryption");
 583             $params->{keyfile} = $keyfile;
 584             $params->{encrypt} = JSON::true;
 585             if (defined($master_keyfile)) {
 586                 if (-e $master_keyfile) {
 587                     $self->loginfo("enabling master key feature");
 588                     $params->{"master-keyfile"} = $master_keyfile;
 589                 } elsif ($scfg->{'master-pubkey'}) {
 590                     die "master public key configured but no key file found\n";
 591                 }
 592             }
 593         } else {
 594             my $encryption_fp = $scfg->{'encryption-key'};
 595             die "encryption configured ('$encryption_fp') but no encryption key file found!\n"
 596                 if $encryption_fp;
 597             $self->loginfo("WARNING: backup target is configured with master key, but this backup is not encrypted - master key settings will be ignored!")
 598                 if defined($master_keyfile) && -e $master_keyfile;
 599             $params->{encrypt} = JSON::false;
 600         }
 601
 602         my $is_template = PVE::QemuConfig->is_template($self->{vmlist}->{$vmid});
 603         $params->{'use-dirty-bitmap'} = JSON::true
 604             if $qemu_support->{'pbs-dirty-bitmap'} && !$is_template;
 605
 606         $params->{timeout} = 125; # give some time to connect to the backup server
 607
 608         my $res = eval { mon_cmd($vmid, "backup", %$params) };
 609         my $qmperr = $@;
 610         $backup_job_uuid = $res->{UUID} if $res;
 611
 612         if ($fs_frozen) {
 613             $self->qga_fs_thaw($vmid);
 614         }
 615
 616         die $qmperr if $qmperr;
 617         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 618
 619         $self->loginfo("started backup task '$backup_job_uuid'");
 620
 621         $self->resume_vm_after_job_start($task, $vmid);
 622
 623         my $stat = $query_backup_status_loop->($self, $vmid, $backup_job_uuid, $qemu_support);
 624         $task->{size} = $stat->{total};
 625     };
 626     my $err = $@;
 627     if ($err) {
 628         $self->logerr($err);
 629         $self->mon_backup_cancel($vmid);
 630         $self->resume_vm_after_job_start($task, $vmid);
 631     }
 632     $self->restore_vm_power_state($vmid);
 633
 634     die $err if $err;
 635 }
 636
 637 my $fork_compressor_pipe = sub {
 638     my ($self, $comp, $outfileno) = @_;
 639
 640     my @pipefd = POSIX::pipe();
 641     my $cpid = fork();
 642     die "unable to fork worker - $!" if !defined($cpid) || $cpid < 0;
 643     if ($cpid == 0) {
 644         eval {
 645             POSIX::close($pipefd[1]);
 646             # redirect STDIN
 647             my $fd = fileno(STDIN);
 648             close STDIN;
 649             POSIX::close(0) if $fd != 0;
 650             die "unable to redirect STDIN - $!"
 651                 if !open(STDIN, "<&", $pipefd[0]);
 652
 653             # redirect STDOUT
 654             $fd = fileno(STDOUT);
 655             close STDOUT;
 656             POSIX::close (1) if $fd != 1;
 657
 658             die "unable to redirect STDOUT - $!"
 659                 if !open(STDOUT, ">&", $outfileno);
 660
 661             exec($comp);
 662             die "fork compressor '$comp' failed\n";
 663         };
 664         if (my $err = $@) {
 665             $self->logerr($err);
 666             POSIX::_exit(1);
 667         }
 668         POSIX::_exit(0);
 669         kill(-9, $$);
 670     } else {
 671         POSIX::close($pipefd[0]);
 672         $outfileno = $pipefd[1];
 673     }
 674
 675     return ($cpid, $outfileno);
 676 };
 677
 678 sub archive_vma {
 679     my ($self, $task, $vmid, $filename, $comp) = @_;
 680
 681     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 682     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 683
 684     my $opts = $self->{vzdump}->{opts};
 685
 686     my $starttime = time();
 687
 688     my $speed = 0;
 689     if ($opts->{bwlimit}) {
 690         $speed = $opts->{bwlimit}*1024;
 691     }
 692
 693     my $diskcount = scalar(@{$task->{disks}});
 694     if (PVE::QemuConfig->is_template($self->{vmlist}->{$vmid}) || !$diskcount) {
 695         my @pathlist;
 696         foreach my $di (@{$task->{disks}}) {
 697             if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 698                 push @pathlist, "$di->{qmdevice}=$di->{path}";
 699             } else {
 700                 die "implement me";
 701             }
 702         }
 703
 704         if (!$diskcount) {
 705             $self->loginfo("backup contains no disks");
 706         }
 707
 708         my $outcmd;
 709         if ($comp) {
 710             $outcmd = "exec:$comp";
 711         } else {
 712             $outcmd = "exec:cat";
 713         }
 714
 715         $outcmd .= " > $filename" if !$opts->{stdout};
 716
 717         my $cmd = ['/usr/bin/vma', 'create', '-v', '-c', $conffile];
 718         push @$cmd, '-c', $firewall if -e $firewall;
 719         push @$cmd, $outcmd, @pathlist;
 720
 721         $self->loginfo("starting template backup");
 722         $self->loginfo(join(' ', @$cmd));
 723
 724         if ($opts->{stdout}) {
 725             $self->cmd($cmd, output => ">&" . fileno($opts->{stdout}));
 726         } else {
 727             $self->cmd($cmd);
 728         }
 729
 730         return;
 731     }
 732
 733     my $devlist = _get_task_devlist($task);
 734
 735     $self->enforce_vm_running_for_backup($vmid);
 736     $self->{qmeventd_fh} = PVE::QemuServer::register_qmeventd_handle($vmid);
 737
 738     my $cpid;
 739     my $backup_job_uuid;
 740
 741     eval {
 742         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 743             die "interrupted by signal\n";
 744         };
 745
 746         # Currently, failing to determine Proxmox support is not critical here, because it's only
 747         # used for performance settings like 'max-workers'.
 748         my $qemu_support = eval { mon_cmd($vmid, "query-proxmox-support") };
 749         log_warn($@) if $@;
 750
 751         $attach_tpmstate_drive->($self, $task, $vmid);
 752
 753         my $outfh;
 754         if ($opts->{stdout}) {
 755             $outfh = $opts->{stdout};
 756         } else {
 757             $outfh = IO::File->new($filename, "w") ||
 758                 die "unable to open file '$filename' - $!\n";
 759         }
 760         my $outfileno = fileno($outfh);
 761
 762         if ($comp) {
 763             ($cpid, $outfileno) = $fork_compressor_pipe->($self, $comp, $outfileno);
 764         }
 765
 766         my $qmpclient = PVE::QMPClient->new();
 767         my $backup_cb = sub {
 768             my ($vmid, $resp) = @_;
 769             $backup_job_uuid = $resp->{return}->{UUID};
 770         };
 771         my $add_fd_cb = sub {
 772             my ($vmid, $resp) = @_;
 773
 774             my $params = {
 775                 'backup-file' => "/dev/fdname/backup",
 776                 speed => $speed,
 777                 'config-file' => $conffile,
 778                 devlist => $devlist
 779             };
 780             $params->{'firewall-file'} = $firewall if -e $firewall;
 781             add_backup_performance_options($params, $opts->{performance}, $qemu_support);
 782
 783             $qmpclient->queue_cmd($vmid, $backup_cb, 'backup', %$params);
 784         };
 785
 786         $qmpclient->queue_cmd($vmid, $add_fd_cb, 'getfd', fd => $outfileno, fdname => "backup");
 787
 788         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 789
 790         eval { $qmpclient->queue_execute(30) };
 791         my $qmperr = $@;
 792
 793         if ($fs_frozen) {
 794             $self->qga_fs_thaw($vmid);
 795         }
 796
 797         die $qmperr if $qmperr;
 798         die $qmpclient->{errors}->{$vmid} if $qmpclient->{errors}->{$vmid};
 799
 800         if ($cpid) {
 801             POSIX::close($outfileno) == 0 ||
 802                 die "close output file handle failed\n";
 803         }
 804
 805         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 806
 807         $self->loginfo("started backup task '$backup_job_uuid'");
 808
 809         $self->resume_vm_after_job_start($task, $vmid);
 810
 811         $query_backup_status_loop->($self, $vmid, $backup_job_uuid);
 812     };
 813     my $err = $@;
 814     if ($err) {
 815         $self->logerr($err);
 816         $self->mon_backup_cancel($vmid);
 817         $self->resume_vm_after_job_start($task, $vmid);
 818     }
 819
 820     $self->restore_vm_power_state($vmid);
 821
 822     if ($err) {
 823         if ($cpid) {
 824             kill(9, $cpid);
 825             waitpid($cpid, 0);
 826         }
 827         die $err;
 828     }
 829
 830     if ($cpid && (waitpid($cpid, 0) > 0)) {
 831         my $stat = $?;
 832         my $ec = $stat >> 8;
 833         my $signal = $stat & 127;
 834         if ($ec || $signal) {
 835             die "$comp failed - wrong exit status $ec" .
 836                 ($signal ? " (signal $signal)\n" : "\n");
 837         }
 838     }
 839 }
 840
 841 sub _get_task_devlist {
 842     my ($task) = @_;
 843
 844     my $devlist = '';
 845     foreach my $di (@{$task->{disks}}) {
 846         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 847             $devlist .= ',' if $devlist;
 848             $devlist .= $di->{qmdevice};
 849         } else {
 850             die "implement me (type '$di->{type}')";
 851         }
 852     }
 853     return $devlist;
 854 }
 855
 856 sub qga_fs_freeze {
 857     my ($self, $task, $vmid) = @_;
 858     return if !$self->{vmlist}->{$vmid}->{agent} || $task->{mode} eq 'stop' || !$self->{vm_was_running} || $self->{vm_was_paused};
 859
 860     if (!PVE::QemuServer::qga_check_running($vmid, 1)) {
 861         $self->loginfo("skipping guest-agent 'fs-freeze', agent configured but not running?");
 862         return;
 863     }
 864
 865     my $freeze = PVE::QemuServer::get_qga_key($self->{vmlist}->{$vmid}, 'freeze-fs-on-backup') // 1;
 866     if (!$freeze) {
 867         $self->loginfo("skipping guest-agent 'fs-freeze', disabled in VM options");
 868         return;
 869     }
 870
 871     $self->loginfo("issuing guest-agent 'fs-freeze' command");
 872     eval { mon_cmd($vmid, "guest-fsfreeze-freeze") };
 873     $self->logerr($@) if $@;
 874
 875     return 1; # even on mon command error, ensure we always thaw again
 876 }
 877
 878 # only call if fs_freeze return 1
 879 sub qga_fs_thaw {
 880     my ($self, $vmid) = @_;
 881
 882     $self->loginfo("issuing guest-agent 'fs-thaw' command");
 883     eval { mon_cmd($vmid, "guest-fsfreeze-thaw") };
 884     $self->logerr($@) if $@;
 885 }
 886
 887 # we need a running QEMU/KVM process for backup, starts a paused (prelaunch)
 888 # one if VM isn't already running
 889 sub enforce_vm_running_for_backup {
 890     my ($self, $vmid) = @_;
 891
 892     if (PVE::QemuServer::check_running($vmid)) {
 893         $self->{vm_was_running} = 1;
 894         return;
 895     }
 896
 897     eval {
 898         $self->loginfo("starting kvm to execute backup task");
 899         # start with skiplock
 900         my $params = {
 901             skiplock => 1,
 902             skiptemplate => 1,
 903             paused => 1,
 904         };
 905         PVE::QemuServer::vm_start($self->{storecfg}, $vmid, $params);
 906     };
 907     die $@ if $@;
 908 }
 909
 910 # resume VM again once in a clear state (stop mode backup of running VM)
 911 sub resume_vm_after_job_start {
 912     my ($self, $task, $vmid) = @_;
 913
 914     return if !$self->{vm_was_running} || $self->{vm_was_paused};
 915
 916     if (my $stoptime = $task->{vmstoptime}) {
 917         my $delay = time() - $task->{vmstoptime};
 918         $task->{vmstoptime} = undef; # avoid printing 'online after ..' twice
 919         $self->loginfo("resuming VM again after $delay seconds");
 920     } else {
 921         $self->loginfo("resuming VM again");
 922     }
 923     mon_cmd($vmid, 'cont', timeout => 45);
 924 }
 925
 926 # stop again if VM was not running before
 927 sub restore_vm_power_state {
 928     my ($self, $vmid) = @_;
 929
 930     # we always let VMs keep running
 931     return if $self->{vm_was_running};
 932
 933     eval {
 934         my $resp = mon_cmd($vmid, 'query-status');
 935         my $status = $resp && $resp->{status} ?  $resp->{status} : 'unknown';
 936         if ($status eq 'prelaunch') {
 937             $self->loginfo("stopping kvm after backup task");
 938             PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1);
 939         } else {
 940             $self->loginfo("kvm status changed after backup ('$status') - keep VM running");
 941         }
 942     };
 943     warn $@ if $@;
 944 }
 945
 946 sub mon_backup_cancel {
 947     my ($self, $vmid) = @_;
 948
 949     $self->loginfo("aborting backup job");
 950     eval { mon_cmd($vmid, 'backup-cancel') };
 951     $self->logerr($@) if $@;
 952 }
 953
 954 sub snapshot {
 955     my ($self, $task, $vmid) = @_;
 956
 957     # nothing to do
 958 }
 959
 960 sub cleanup {
 961     my ($self, $task, $vmid) = @_;
 962
 963     $detach_tpmstate_drive->($task, $vmid);
 964
 965     if ($self->{qmeventd_fh}) {
 966         close($self->{qmeventd_fh});
 967     }
 968 }
 969
 970 1;