PVE/VZDump/QemuServer.pm

   1 package PVE::VZDump::QemuServer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Basename;
   7 use File::Path;
   8 use IO::File;
   9 use IPC::Open3;
  10 use JSON;
  11
  12 use PVE::Cluster qw(cfs_read_file);
  13 use PVE::INotify;
  14 use PVE::IPCC;
  15 use PVE::JSONSchema;
  16 use PVE::QMPClient;
  17 use PVE::Storage::Plugin;
  18 use PVE::Storage::PBSPlugin;
  19 use PVE::Storage;
  20 use PVE::Tools;
  21 use PVE::VZDump;
  22
  23 use PVE::QemuConfig;
  24 use PVE::QemuServer;
  25 use PVE::QemuServer::Machine;
  26 use PVE::QemuServer::Monitor qw(mon_cmd);
  27
  28 use base qw (PVE::VZDump::Plugin);
  29
  30 sub new {
  31     my ($class, $vzdump) = @_;
  32
  33     PVE::VZDump::check_bin('qm');
  34
  35     my $self = bless { vzdump => $vzdump }, $class;
  36
  37     $self->{vmlist} = PVE::QemuServer::vzlist();
  38     $self->{storecfg} = PVE::Storage::config();
  39
  40     return $self;
  41 };
  42
  43 sub type {
  44     return 'qemu';
  45 }
  46
  47 sub vmlist {
  48     my ($self) = @_;
  49     return [ keys %{$self->{vmlist}} ];
  50 }
  51
  52 sub prepare {
  53     my ($self, $task, $vmid, $mode) = @_;
  54
  55     $task->{disks} = [];
  56
  57     my $conf = $self->{vmlist}->{$vmid} = PVE::QemuConfig->load_config($vmid);
  58
  59     $self->loginfo("VM Name: $conf->{name}")
  60         if defined($conf->{name});
  61
  62     $self->{vm_was_running} = 1;
  63     if (!PVE::QemuServer::check_running($vmid)) {
  64         $self->{vm_was_running} = 0;
  65     }
  66
  67     $task->{hostname} = $conf->{name};
  68
  69     my $hostname = PVE::INotify::nodename();
  70
  71     my $vollist = [];
  72     my $drivehash = {};
  73     my $backup_volumes = PVE::QemuConfig->get_backup_volumes($conf);
  74
  75     foreach my $volume (@{$backup_volumes}) {
  76         my $name = $volume->{key};
  77         my $volume_config = $volume->{volume_config};
  78         my $volid = $volume_config->{file};
  79
  80         if (!$volume->{included}) {
  81             $self->loginfo("exclude disk '$name' '$volid' ($volume->{reason})");
  82             next;
  83         } elsif ($self->{vm_was_running} && $volume_config->{iothread}) {
  84             if (!PVE::QemuServer::Machine::runs_at_least_qemu_version($vmid, 4, 0, 1)) {
  85                 die "disk '$name' '$volid' (iothread=on) can't use backup feature with running QEMU " .
  86                     "version < 4.0.1! Either set backup=no for this drive or upgrade QEMU and restart VM\n";
  87             }
  88         } else {
  89             my $log = "include disk '$name' '$volid'";
  90             if (defined(my $size = $volume_config->{size})) {
  91                 my $readable_size = PVE::JSONSchema::format_size($size);
  92                 $log .= " $readable_size";
  93             }
  94             $self->loginfo($log);
  95         }
  96
  97         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
  98         push @$vollist, $volid if $storeid;
  99         $drivehash->{$name} = $volume->{volume_config};
 100     }
 101
 102     PVE::Storage::activate_volumes($self->{storecfg}, $vollist);
 103
 104     foreach my $ds (sort keys %$drivehash) {
 105         my $drive = $drivehash->{$ds};
 106
 107         my $volid = $drive->{file};
 108         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 109
 110         my $path = $volid;
 111         if ($storeid) {
 112             $path = PVE::Storage::path($self->{storecfg}, $volid);
 113         }
 114         next if !$path;
 115
 116         my ($size, $format) = eval { PVE::Storage::volume_size_info($self->{storecfg}, $volid, 5) };
 117         die "no such volume '$volid'\n" if $@;
 118
 119         my $diskinfo = {
 120             path => $path,
 121             volid => $volid,
 122             storeid => $storeid,
 123             format => $format,
 124             virtdev => $ds,
 125             qmdevice => "drive-$ds",
 126         };
 127
 128         if (-b $path) {
 129             $diskinfo->{type} = 'block';
 130         } else {
 131             $diskinfo->{type} = 'file';
 132         }
 133
 134         push @{$task->{disks}}, $diskinfo;
 135     }
 136 }
 137
 138 sub vm_status {
 139     my ($self, $vmid) = @_;
 140
 141     my $running = PVE::QemuServer::check_running($vmid) ? 1 : 0;
 142
 143     return wantarray ? ($running, $running ? 'running' : 'stopped') : $running;
 144 }
 145
 146 sub lock_vm {
 147     my ($self, $vmid) = @_;
 148
 149     PVE::QemuConfig->set_lock($vmid, 'backup');
 150 }
 151
 152 sub unlock_vm {
 153     my ($self, $vmid) = @_;
 154
 155     PVE::QemuConfig->remove_lock($vmid, 'backup');
 156 }
 157
 158 sub stop_vm {
 159     my ($self, $task, $vmid) = @_;
 160
 161     my $opts = $self->{vzdump}->{opts};
 162
 163     my $wait = $opts->{stopwait} * 60;
 164     # send shutdown and wait
 165     $self->cmd ("qm shutdown $vmid --skiplock --keepActive --timeout $wait");
 166 }
 167
 168 sub start_vm {
 169     my ($self, $task, $vmid) = @_;
 170
 171     $self->cmd ("qm start $vmid --skiplock");
 172 }
 173
 174 sub suspend_vm {
 175     my ($self, $task, $vmid) = @_;
 176
 177     $self->cmd ("qm suspend $vmid --skiplock");
 178 }
 179
 180 sub resume_vm {
 181     my ($self, $task, $vmid) = @_;
 182
 183     $self->cmd ("qm resume $vmid --skiplock");
 184 }
 185
 186 sub assemble {
 187     my ($self, $task, $vmid) = @_;
 188
 189     my $conffile = PVE::QemuConfig->config_file($vmid);
 190
 191     my $outfile = "$task->{tmpdir}/qemu-server.conf";
 192     my $firewall_src = "/etc/pve/firewall/$vmid.fw";
 193     my $firewall_dest = "$task->{tmpdir}/qemu-server.fw";
 194
 195     my $outfd = IO::File->new (">$outfile") ||
 196         die "unable to open '$outfile'";
 197     my $conffd = IO::File->new ($conffile, 'r') ||
 198         die "unable open '$conffile'";
 199
 200     my $found_snapshot;
 201     my $found_pending;
 202     while (defined (my $line = <$conffd>)) {
 203         next if $line =~ m/^\#vzdump\#/; # just to be sure
 204         next if $line =~ m/^\#qmdump\#/; # just to be sure
 205         if ($line =~ m/^\[(.*)\]\s*$/) {
 206             if ($1 =~ m/PENDING/i) {
 207                 $found_pending = 1;
 208             } else {
 209                 $found_snapshot = 1;
 210             }
 211         }
 212         next if $found_snapshot || $found_pending; # skip all snapshots and pending changes config data
 213
 214         if ($line =~ m/^unused\d+:\s*(\S+)\s*/) {
 215             $self->loginfo("skip unused drive '$1' (not included into backup)");
 216             next;
 217         }
 218         next if $line =~ m/^lock:/ || $line =~ m/^parent:/;
 219
 220         print $outfd $line;
 221     }
 222
 223     foreach my $di (@{$task->{disks}}) {
 224         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 225             my $storeid = $di->{storeid} || '';
 226             my $format = $di->{format} || '';
 227             print $outfd "#qmdump#map:$di->{virtdev}:$di->{qmdevice}:$storeid:$format:\n";
 228         } else {
 229             die "internal error";
 230         }
 231     }
 232
 233     if ($found_snapshot) {
 234         $self->loginfo("snapshots found (not included into backup)");
 235     }
 236     if ($found_pending) {
 237         $self->loginfo("pending configuration changes found (not included into backup)");
 238     }
 239
 240     PVE::Tools::file_copy($firewall_src, $firewall_dest) if -f $firewall_src;
 241 }
 242
 243 sub archive {
 244     my ($self, $task, $vmid, $filename, $comp) = @_;
 245
 246     my $opts = $self->{vzdump}->{opts};
 247     my $scfg = $opts->{scfg};
 248
 249     if ($self->{vzdump}->{opts}->{pbs}) {
 250         $self->archive_pbs($task, $vmid);
 251     } else {
 252         $self->archive_vma($task, $vmid, $filename, $comp);
 253     }
 254 }
 255
 256 # number, [precision=1]
 257 my $num2str = sub {
 258     return sprintf( "%." . ( $_[1] || 1 ) . "f", $_[0] );
 259 };
 260 sub bytes_to_human {
 261     my ($bytes, $precission) = @_;
 262
 263     return $num2str->($bytes, $precission) . ' B' if $bytes < 1024;
 264     my $kb = $bytes/1024;
 265
 266     return $num2str->($kb, $precission) . " KiB" if $kb < 1024;
 267     my $mb = $kb/1024;
 268
 269     return $num2str->($mb, $precission) . " MiB" if $mb < 1024;
 270     my $gb = $mb/1024;
 271
 272     return $num2str->($gb, $precission) . " GiB" if $gb < 1024;
 273     my $tb = $gb/1024;
 274
 275     return $num2str->($tb, $precission) . " TiB";
 276 };
 277
 278 my $query_backup_status_loop = sub {
 279     my ($self, $vmid, $job_uuid) = @_;
 280
 281     my $starttime = time ();
 282     my $last_time = $starttime;
 283     my ($last_percent, $last_total, $last_target,  $last_zero, $last_transferred) = (-1, 0, 0, 0, 0);
 284     my ($transferred, $reused);
 285     my $first_round = 1;
 286
 287     my $get_mbps = sub {
 288         my ($mb, $delta) = @_;
 289         return "0 B/s" if $mb <= 0;
 290         my $bw = int(($mb / $delta));
 291         return bytes_to_human($bw) . "/s";
 292     };
 293
 294     while(1) {
 295         my $status = mon_cmd($vmid, 'query-backup');
 296
 297         my $total = $status->{total} || 0;
 298         my $dirty = $status->{dirty};
 299         my $target = (defined($dirty) && $dirty < $total) ? $dirty : $total;
 300         $transferred = $status->{transferred} || 0;
 301         $reused = $status->{reused};
 302         my $percent = $target ? int(($transferred * 100)/$target) : 0;
 303         my $zero = $status->{'zero-bytes'} || 0;
 304
 305         die "got unexpected uuid\n" if !$status->{uuid} || ($status->{uuid} ne $job_uuid);
 306
 307         my $ctime = time();
 308         my $duration = $ctime - $starttime;
 309
 310         my $rbytes = $transferred - $last_transferred;
 311         my $wbytes = $rbytes - ($zero - $last_zero);
 312
 313         my $timediff = ($ctime - $last_time) || 1; # fixme
 314         my $mbps_read = $get_mbps->($rbytes, $timediff);
 315         my $mbps_write = $get_mbps->($wbytes, $timediff);
 316         my $target_h = bytes_to_human($target);
 317         my $transferred_h = bytes_to_human($transferred);
 318
 319         if ($first_round && $target != $total) {
 320             my $total_h = bytes_to_human($total);
 321             $self->loginfo("using fast incremental mode (dirty-bitmap), $target_h dirty of $total_h total");
 322         }
 323
 324         my $statusline = "status: $percent% ($transferred_h of $target_h), duration $duration"
 325             .", read: $mbps_read, write: $mbps_write";
 326
 327         my $res = $status->{status} || 'unknown';
 328         if ($res ne 'active') {
 329             $self->loginfo($statusline);
 330             if ($res ne 'done') {
 331                 die (($status->{errmsg} || "unknown error") . "\n") if $res eq 'error';
 332                 die "got unexpected status '$res'\n";
 333             }
 334             $last_target = $target if $target;
 335             $last_total = $total if $total;
 336             $last_zero = $zero if $zero;
 337             $last_transferred = $transferred if $transferred;
 338             last;
 339         }
 340         if ($percent != $last_percent && ($timediff > 2)) {
 341             $self->loginfo($statusline);
 342             $last_percent = $percent;
 343             $last_target = $target if $target;
 344             $last_total = $total if $total;
 345             $last_zero = $zero if $zero;
 346             $last_transferred = $transferred if $transferred;
 347             $last_time = $ctime;
 348         }
 349         sleep(1);
 350         $first_round = 0;
 351     }
 352
 353     my $duration = time() - $starttime;
 354     if ($transferred && $duration) {
 355         my $transferred_h = bytes_to_human($transferred, 2);
 356         my $mbps = $get_mbps->($transferred, $duration);
 357         if ($reused) {
 358             my $reused_h = bytes_to_human($reused, 2);
 359             my $reuse_per = int($reused * 100 / $last_total);
 360             $self->loginfo("backup was done incrementally, reused $reused_h (${reuse_per}%) from last backup");
 361             $self->loginfo("transferred $transferred_h in $duration seconds ($mbps)");
 362         } else {
 363             $self->loginfo("transferred $transferred_h in $duration seconds ($mbps)");
 364         }
 365     }
 366
 367     if ($last_zero) {
 368         my $zero_per = $last_target ? int(($last_zero * 100)/$last_target) : 0;
 369         my $zero_h = bytes_to_human($last_zero, 2);
 370         $self->loginfo("Backup is sparse: ${zero_per}% ($zero_h) zero data");
 371     }
 372
 373     return {
 374         total => $last_total,
 375         reused => $reused,
 376     };
 377 };
 378
 379 sub archive_pbs {
 380     my ($self, $task, $vmid) = @_;
 381
 382     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 383     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 384
 385     my $opts = $self->{vzdump}->{opts};
 386     my $scfg = $opts->{scfg};
 387
 388     my $starttime = time();
 389
 390     my $server = $scfg->{server};
 391     my $datastore = $scfg->{datastore};
 392     my $username = $scfg->{username} // 'root@pam';
 393     my $fingerprint = $scfg->{fingerprint};
 394
 395     my $repo = "$username\@$server:$datastore";
 396     my $password = PVE::Storage::PBSPlugin::pbs_get_password($scfg, $opts->{storage});
 397
 398     my $diskcount = scalar(@{$task->{disks}});
 399     if (PVE::QemuConfig->is_template($self->{vmlist}->{$vmid}) || !$diskcount) {
 400         my @pathlist;
 401         # FIXME: accumulate disk sizes to use for backup job (email) log
 402         foreach my $di (@{$task->{disks}}) {
 403             if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 404                 push @pathlist, "$di->{qmdevice}.img:$di->{path}";
 405             } else {
 406                 die "implement me (type $di->{type})";
 407             }
 408         }
 409
 410         if (!$diskcount) {
 411             $self->loginfo("backup contains no disks");
 412         }
 413
 414         local $ENV{PBS_PASSWORD} = $password;
 415         local $ENV{PBS_FINGERPRINT} = $fingerprint if defined($fingerprint);
 416         my $cmd = [
 417             '/usr/bin/proxmox-backup-client',
 418             'backup',
 419             '--repository', $repo,
 420             '--backup-type', 'vm',
 421             '--backup-id', "$vmid",
 422             '--backup-time', $task->{backup_time},
 423         ];
 424
 425         push @$cmd, "qemu-server.conf:$conffile";
 426         push @$cmd, "fw.conf:$firewall" if -e $firewall;
 427         push @$cmd, @pathlist if scalar(@pathlist);
 428
 429         $self->loginfo("starting template backup");
 430         $self->loginfo(join(' ', @$cmd));
 431
 432         $self->cmd($cmd);
 433
 434         return;
 435     }
 436
 437     # get list early so we die on unkown drive types before doing anything
 438     my $devlist = _get_task_devlist($task);
 439
 440     $self->enforce_vm_running_for_backup($vmid);
 441
 442     my $backup_job_uuid;
 443     eval {
 444         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 445             die "interrupted by signal\n";
 446         };
 447
 448         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 449
 450         my $params = {
 451             format => "pbs",
 452             'backup-file' => $repo,
 453             'backup-id' => "$vmid",
 454             'backup-time' => $task->{backup_time},
 455             password => $password,
 456             devlist => $devlist,
 457             'config-file' => $conffile,
 458             'use-dirty-bitmap' => JSON::true,
 459         };
 460         $params->{fingerprint} = $fingerprint if defined($fingerprint);
 461         $params->{'firewall-file'} = $firewall if -e $firewall;
 462
 463         $params->{timeout} = 60; # give some time to connect to the backup server
 464
 465         my $res = eval { mon_cmd($vmid, "backup", %$params) };
 466         my $qmperr = $@;
 467         $backup_job_uuid = $res->{UUID} if $res;
 468
 469         if ($fs_frozen) {
 470             $self->qga_fs_thaw($vmid);
 471         }
 472
 473         die $qmperr if $qmperr;
 474         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 475
 476         $self->loginfo("started backup task '$backup_job_uuid'");
 477
 478         $self->resume_vm_after_job_start($task, $vmid);
 479
 480         my $stat = $query_backup_status_loop->($self, $vmid, $backup_job_uuid);
 481         $task->{size} = $stat->{total};
 482     };
 483     my $err = $@;
 484     if ($err) {
 485         $self->logerr($err);
 486         $self->mon_backup_cancel($vmid) if defined($backup_job_uuid);
 487     }
 488     $self->restore_vm_power_state($vmid);
 489
 490     die $err if $err;
 491 }
 492
 493 my $fork_compressor_pipe = sub {
 494     my ($self, $comp, $outfileno) = @_;
 495
 496     my @pipefd = POSIX::pipe();
 497     my $cpid = fork();
 498     die "unable to fork worker - $!" if !defined($cpid) || $cpid < 0;
 499     if ($cpid == 0) {
 500         eval {
 501             POSIX::close($pipefd[1]);
 502             # redirect STDIN
 503             my $fd = fileno(STDIN);
 504             close STDIN;
 505             POSIX::close(0) if $fd != 0;
 506             die "unable to redirect STDIN - $!"
 507                 if !open(STDIN, "<&", $pipefd[0]);
 508
 509             # redirect STDOUT
 510             $fd = fileno(STDOUT);
 511             close STDOUT;
 512             POSIX::close (1) if $fd != 1;
 513
 514             die "unable to redirect STDOUT - $!"
 515                 if !open(STDOUT, ">&", $outfileno);
 516
 517             exec($comp);
 518             die "fork compressor '$comp' failed\n";
 519         };
 520         if (my $err = $@) {
 521             $self->logerr($err);
 522             POSIX::_exit(1);
 523         }
 524         POSIX::_exit(0);
 525         kill(-9, $$);
 526     } else {
 527         POSIX::close($pipefd[0]);
 528         $outfileno = $pipefd[1];
 529     }
 530
 531     return ($cpid, $outfileno);
 532 };
 533
 534 sub archive_vma {
 535     my ($self, $task, $vmid, $filename, $comp) = @_;
 536
 537     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 538     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 539
 540     my $opts = $self->{vzdump}->{opts};
 541
 542     my $starttime = time();
 543
 544     my $speed = 0;
 545     if ($opts->{bwlimit}) {
 546         $speed = $opts->{bwlimit}*1024;
 547     }
 548
 549     my $diskcount = scalar(@{$task->{disks}});
 550     if (PVE::QemuConfig->is_template($self->{vmlist}->{$vmid}) || !$diskcount) {
 551         my @pathlist;
 552         foreach my $di (@{$task->{disks}}) {
 553             if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 554                 push @pathlist, "$di->{qmdevice}=$di->{path}";
 555             } else {
 556                 die "implement me";
 557             }
 558         }
 559
 560         if (!$diskcount) {
 561             $self->loginfo("backup contains no disks");
 562         }
 563
 564         my $outcmd;
 565         if ($comp) {
 566             $outcmd = "exec:$comp";
 567         } else {
 568             $outcmd = "exec:cat";
 569         }
 570
 571         $outcmd .= " > $filename" if !$opts->{stdout};
 572
 573         my $cmd = ['/usr/bin/vma', 'create', '-v', '-c', $conffile];
 574         push @$cmd, '-c', $firewall if -e $firewall;
 575         push @$cmd, $outcmd, @pathlist;
 576
 577         $self->loginfo("starting template backup");
 578         $self->loginfo(join(' ', @$cmd));
 579
 580         if ($opts->{stdout}) {
 581             $self->cmd($cmd, output => ">&" . fileno($opts->{stdout}));
 582         } else {
 583             $self->cmd($cmd);
 584         }
 585
 586         return;
 587     }
 588
 589     my $devlist = _get_task_devlist($task);
 590
 591     $self->enforce_vm_running_for_backup($vmid);
 592
 593     my $cpid;
 594     my $backup_job_uuid;
 595
 596     eval {
 597         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 598             die "interrupted by signal\n";
 599         };
 600
 601         my $outfh;
 602         if ($opts->{stdout}) {
 603             $outfh = $opts->{stdout};
 604         } else {
 605             $outfh = IO::File->new($filename, "w") ||
 606                 die "unable to open file '$filename' - $!\n";
 607         }
 608         my $outfileno = fileno($outfh);
 609
 610         if ($comp) {
 611             ($cpid, $outfileno) = $fork_compressor_pipe->($self, $comp, $outfileno);
 612         }
 613
 614         my $qmpclient = PVE::QMPClient->new();
 615         my $backup_cb = sub {
 616             my ($vmid, $resp) = @_;
 617             $backup_job_uuid = $resp->{return}->{UUID};
 618         };
 619         my $add_fd_cb = sub {
 620             my ($vmid, $resp) = @_;
 621
 622             my $params = {
 623                 'backup-file' => "/dev/fdname/backup",
 624                 speed => $speed,
 625                 'config-file' => $conffile,
 626                 devlist => $devlist
 627             };
 628             $params->{'firewall-file'} = $firewall if -e $firewall;
 629
 630             $qmpclient->queue_cmd($vmid, $backup_cb, 'backup', %$params);
 631         };
 632
 633         $qmpclient->queue_cmd($vmid, $add_fd_cb, 'getfd', fd => $outfileno, fdname => "backup");
 634
 635         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 636
 637         eval { $qmpclient->queue_execute(30) };
 638         my $qmperr = $@;
 639
 640         if ($fs_frozen) {
 641             $self->qga_fs_thaw($vmid);
 642         }
 643
 644         die $qmperr if $qmperr;
 645         die $qmpclient->{errors}->{$vmid} if $qmpclient->{errors}->{$vmid};
 646
 647         if ($cpid) {
 648             POSIX::close($outfileno) == 0 ||
 649                 die "close output file handle failed\n";
 650         }
 651
 652         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 653
 654         $self->loginfo("started backup task '$backup_job_uuid'");
 655
 656         $self->resume_vm_after_job_start($task, $vmid);
 657
 658         $query_backup_status_loop->($self, $vmid, $backup_job_uuid);
 659     };
 660     my $err = $@;
 661     if ($err) {
 662         $self->logerr($err);
 663         $self->mon_backup_cancel($vmid) if defined($backup_job_uuid);
 664     }
 665
 666     $self->restore_vm_power_state($vmid);
 667
 668     if ($err) {
 669         if ($cpid) {
 670             kill(9, $cpid);
 671             waitpid($cpid, 0);
 672         }
 673         die $err;
 674     }
 675
 676     if ($cpid && (waitpid($cpid, 0) > 0)) {
 677         my $stat = $?;
 678         my $ec = $stat >> 8;
 679         my $signal = $stat & 127;
 680         if ($ec || $signal) {
 681             die "$comp failed - wrong exit status $ec" .
 682                 ($signal ? " (signal $signal)\n" : "\n");
 683         }
 684     }
 685 }
 686
 687 sub _get_task_devlist {
 688     my ($task) = @_;
 689
 690     my $devlist = '';
 691     foreach my $di (@{$task->{disks}}) {
 692         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 693             $devlist .= ',' if $devlist;
 694             $devlist .= $di->{qmdevice};
 695         } else {
 696             die "implement me (type '$di->{type}')";
 697         }
 698     }
 699     return $devlist;
 700 }
 701
 702 sub qga_fs_freeze {
 703     my ($self, $task, $vmid) = @_;
 704     return if !$self->{vmlist}->{$vmid}->{agent} || $task->{mode} eq 'stop' || !$self->{vm_was_running};
 705
 706     if (!PVE::QemuServer::qga_check_running($vmid, 1)) {
 707         $self->loginfo("skipping guest-agent 'fs-freeze', agent configured but not running?");
 708         return;
 709     }
 710
 711     $self->loginfo("issuing guest-agent 'fs-freeze' command");
 712     eval { mon_cmd($vmid, "guest-fsfreeze-freeze") };
 713     $self->logerr($@) if $@;
 714
 715     return 1; # even on mon command error, ensure we always thaw again
 716 }
 717
 718 # only call if fs_freeze return 1
 719 sub qga_fs_thaw {
 720     my ($self, $vmid) = @_;
 721
 722     $self->loginfo("issuing guest-agent 'fs-thaw' command");
 723     eval { mon_cmd($vmid, "guest-fsfreeze-thaw") };
 724     $self->logerr($@) if $@;
 725 }
 726
 727 # we need a running QEMU/KVM process for backup, starts a paused (prelaunch)
 728 # one if VM isn't already running
 729 sub enforce_vm_running_for_backup {
 730     my ($self, $vmid) = @_;
 731
 732     if (PVE::QemuServer::check_running($vmid)) {
 733         $self->{vm_was_running} = 1;
 734         return;
 735     }
 736
 737     eval {
 738         $self->loginfo("starting kvm to execute backup task");
 739         # start with skiplock
 740         my $params = {
 741             skiplock => 1,
 742             paused => 1,
 743         };
 744         PVE::QemuServer::vm_start($self->{storecfg}, $vmid, $params);
 745     };
 746     die $@ if $@;
 747 }
 748
 749 # resume VM againe once we got in a clear state (stop mode backup of running VM)
 750 sub resume_vm_after_job_start {
 751     my ($self, $task, $vmid) = @_;
 752
 753     return if !$self->{vm_was_running};
 754
 755     if (my $stoptime = $task->{vmstoptime}) {
 756         my $delay = time() - $task->{vmstoptime};
 757         $task->{vmstoptime} = undef; # avoid printing 'online after ..' twice
 758         $self->loginfo("resuming VM again after $delay seconds");
 759     } else {
 760         $self->loginfo("resuming VM again");
 761     }
 762     mon_cmd($vmid, 'cont');
 763 }
 764
 765 # stop again if VM was not running before
 766 sub restore_vm_power_state {
 767     my ($self, $vmid) = @_;
 768
 769     # we always let VMs keep running
 770     return if $self->{vm_was_running};
 771
 772     eval {
 773         my $resp = mon_cmd($vmid, 'query-status');
 774         my $status = $resp && $resp->{status} ?  $resp->{status} : 'unknown';
 775         if ($status eq 'prelaunch') {
 776             $self->loginfo("stopping kvm after backup task");
 777             PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1);
 778         } else {
 779             $self->loginfo("kvm status changed after backup ('$status') - keep VM running");
 780         }
 781     };
 782     warn $@ if $@;
 783 }
 784
 785 sub mon_backup_cancel {
 786     my ($self, $vmid) = @_;
 787
 788     $self->loginfo("aborting backup job");
 789     eval { mon_cmd($vmid, 'backup-cancel') };
 790     $self->logerr($@) if $@;
 791 }
 792
 793 sub snapshot {
 794     my ($self, $task, $vmid) = @_;
 795
 796     # nothing to do
 797 }
 798
 799 sub cleanup {
 800     my ($self, $task, $vmid) = @_;
 801
 802     # nothing to do ?
 803 }
 804
 805 1;