acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        : # Linux 3.x
 138     elif test "$version" = 2 && test "$patchlevel" -ge 6; then
 139        : # Linux 2.6.x
 140     else
 141        if test "$KBUILD" = "$KSRC"; then
 142          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6 or later is required])
 143        else
 144          AC_ERROR([Linux kernel in build tree $KBUILD (source tree $KSRC) is version $kversion, but version 2.6 or later is required])
 145        fi
 146     fi
 147     if (test ! -e "$KBUILD"/include/linux/version.h && \
 148         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 149        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 150         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 151         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 152     fi
 153     OVS_CHECK_LINUX_COMPAT
 154   fi
 155   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 156 ])
 157
 158 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 159 dnl
 160 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 161 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 162 dnl <REGEX> translated to uppercase.
 163 AC_DEFUN([OVS_GREP_IFELSE], [
 164   AC_MSG_CHECKING([whether $2 matches in $1])
 165   if test -f $1; then
 166     grep '$2' $1 >/dev/null 2>&1
 167     status=$?
 168     case $status in
 169       0)
 170         AC_MSG_RESULT([yes])
 171         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 172         ;;
 173       1)
 174         AC_MSG_RESULT([no])
 175         $4
 176         ;;
 177       *)
 178         AC_MSG_ERROR([grep exited with status $status])
 179         ;;
 180     esac
 181   else
 182     AC_MSG_RESULT([file not found])
 183     $4
 184   fi
 185 ])
 186
 187 dnl OVS_DEFINE(NAME)
 188 dnl
 189 dnl Defines NAME to 1 in kcompat.h.
 190 AC_DEFUN([OVS_DEFINE], [
 191   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 192 ])
 193
 194 AC_DEFUN([OVS_CHECK_LOG2_H], [
 195   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 196   if test -e $KSRC/include/linux/log2.h; then
 197     AC_MSG_RESULT([yes])
 198     OVS_DEFINE([HAVE_LOG2_H])
 199   else
 200     AC_MSG_RESULT([no])
 201   fi
 202 ])
 203
 204 dnl OVS_CHECK_LINUX_COMPAT
 205 dnl
 206 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 207 dnl the directory in $KBUILD.
 208 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 209   rm -f datapath/linux/kcompat.h.new
 210   mkdir -p datapath/linux
 211   : > datapath/linux/kcompat.h.new
 212
 213   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 214                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 215
 216   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 217
 218   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 219
 220   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 221   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 222   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 223
 224   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 225                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 226                                    [rcu_read_lock_held])])
 227
 228   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 229   # is necessary because some versions of this header remove the
 230   # member but retain the kerneldoc comment that describes it (which
 231   # starts with @).  The brackets must be doubled because of m4
 232   # quoting rules.
 233   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 234                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 235   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [raw],
 236                   [OVS_DEFINE([HAVE_MAC_RAW])])
 237   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 238                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 239   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 240                   [skb_copy_from_linear_data_offset])
 241   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 242                   [skb_reset_tail_pointer])
 243   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 244   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 245                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 246   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 247                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 248   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 249                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 250   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 251   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 252
 253   OVS_GREP_IFELSE([$KSRC/include/linux/string.h], [kmemdup], [],
 254                   [OVS_GREP_IFELSE([$KSRC/include/linux/slab.h], [kmemdup])])
 255
 256   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 257                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 258   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 259                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 260
 261   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 262   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 263
 264   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [NLA_NUL_STRING])
 265   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 266   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 267
 268   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 269                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 270
 271   OVS_CHECK_LOG2_H
 272
 273   if cmp -s datapath/linux/kcompat.h.new \
 274             datapath/linux/kcompat.h >/dev/null 2>&1; then
 275     rm datapath/linux/kcompat.h.new
 276   else
 277     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 278   fi
 279 ])
 280
 281 dnl Checks for net/if_packet.h.
 282 AC_DEFUN([OVS_CHECK_IF_PACKET],
 283   [AC_CHECK_HEADER([net/if_packet.h],
 284                    [HAVE_IF_PACKET=yes],
 285                    [HAVE_IF_PACKET=no])
 286    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 287    if test "$HAVE_IF_PACKET" = yes; then
 288       AC_DEFINE([HAVE_IF_PACKET], [1],
 289                 [Define to 1 if net/if_packet.h is available.])
 290    fi])
 291
 292 dnl Checks for net/if_dl.h.
 293 AC_DEFUN([OVS_CHECK_IF_DL],
 294   [AC_CHECK_HEADER([net/if_dl.h],
 295                    [HAVE_IF_DL=yes],
 296                    [HAVE_IF_DL=no])
 297    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 298    if test "$HAVE_IF_DL" = yes; then
 299       AC_DEFINE([HAVE_IF_DL], [1],
 300                 [Define to 1 if net/if_dl.h is available.])
 301    fi])
 302
 303 dnl Checks for buggy strtok_r.
 304 dnl
 305 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 306 dnl with optimization that can cause segfaults:
 307 dnl
 308 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 309 AC_DEFUN([OVS_CHECK_STRTOK_R],
 310   [AC_CACHE_CHECK(
 311      [whether strtok_r macro segfaults on some inputs],
 312      [ovs_cv_strtok_r_bug],
 313      [AC_RUN_IFELSE(
 314         [AC_LANG_PROGRAM([#include <stdio.h>
 315                           #include <string.h>
 316                          ],
 317                          [[char string[] = ":::";
 318                            char *save_ptr = (char *) 0xc0ffee;
 319                            char *token1, *token2;
 320                            token1 = strtok_r(string, ":", &save_ptr);
 321                            token2 = strtok_r(NULL, ":", &save_ptr);
 322                            freopen ("/dev/null", "w", stdout);
 323                            printf ("%s %s\n", token1, token2);
 324                            return 0;
 325                           ]])],
 326         [ovs_cv_strtok_r_bug=no],
 327         [ovs_cv_strtok_r_bug=yes],
 328         [ovs_cv_strtok_r_bug=yes])])
 329    if test $ovs_cv_strtok_r_bug = yes; then
 330      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 331                [Define if strtok_r macro segfaults on some inputs])
 332    fi
 333 ])
 334
 335 dnl ----------------------------------------------------------------------
 336 dnl These macros are from GNU PSPP, with the following original license:
 337 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 338 dnl This file is free software; the Free Software Foundation
 339 dnl gives unlimited permission to copy and/or distribute it,
 340 dnl with or without modifications, as long as this notice is preserved.
 341
 342 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 343 dnl Check whether the given C compiler OPTION is accepted.
 344 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 345 AC_DEFUN([OVS_CHECK_CC_OPTION],
 346 [
 347   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 348   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 349     [ovs_save_CFLAGS="$CFLAGS"
 350      CFLAGS="$CFLAGS $1"
 351      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 352      CFLAGS="$ovs_save_CFLAGS"])
 353   if test $ovs_cv_name = yes; then
 354     m4_if([$2], [], [:], [$2])
 355   else
 356     m4_if([$3], [], [:], [$3])
 357   fi
 358 ])
 359
 360 dnl OVS_ENABLE_OPTION([OPTION])
 361 dnl Check whether the given C compiler OPTION is accepted.
 362 dnl If so, add it to WARNING_FLAGS.
 363 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 364 AC_DEFUN([OVS_ENABLE_OPTION],
 365   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 366    AC_SUBST([WARNING_FLAGS])])
 367
 368 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 369 dnl Check whether the given C compiler OPTION is accepted.
 370 dnl If so, enable the given Automake CONDITIONAL.
 371
 372 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 373 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 374   [OVS_CHECK_CC_OPTION(
 375     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 376    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 377 dnl ----------------------------------------------------------------------
 378
 379 dnl Check for too-old XenServer.
 380 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 381   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 382     [if test -e /etc/redhat-release; then
 383        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 384      fi
 385      if test -z "$ovs_cv_xsversion"; then
 386        ovs_cv_xsversion=none
 387      fi])
 388   case $ovs_cv_xsversion in
 389     none)
 390       ;;
 391
 392     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 393     [[6-9]]* |                           dnl XenServer 6 or later
 394     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 395     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 396     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 397     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 398       ;;
 399
 400     *)
 401       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 402       ;;
 403   esac])
 404
 405 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 406 dnl
 407 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 408 dnl Runs 'if-true' if so, 'if-false' otherwise.
 409 AC_DEFUN([OVS_CHECK_MAKE_IF],
 410   [AC_CACHE_CHECK(
 411      [whether ${MAKE-make} has GNU make \$(if) extension],
 412      [ovs_cv_gnu_make_if],
 413      [cat <<'EOF' > conftest.mk
 414 conftest.out:
 415         echo $(if x,y,z) > conftest.out
 416 .PHONY: all
 417 EOF
 418       rm -f conftest.out
 419       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 420       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 421       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 422       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 423       result=`cat conftest.out`
 424       rm -f conftest.mk conftest.out
 425       if test "X$result" = "Xy"; then
 426         ovs_cv_gnu_make_if=yes
 427       else
 428         ovs_cv_gnu_make_if=no
 429       fi])])
 430
 431 dnl OVS_CHECK_GNU_MAKE
 432 dnl
 433 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 434 dnl only work with GNU make).
 435 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 436   [AC_CACHE_CHECK(
 437      [whether ${MAKE-make} is GNU make],
 438      [ovs_cv_gnu_make],
 439      [rm -f conftest.out
 440       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 441       ${MAKE-make} --version >conftest.out 2>&1
 442       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 443       result=`cat conftest.out`
 444       rm -f conftest.mk conftest.out
 445
 446       case $result in # (
 447         GNU*) ovs_cv_gnu_make=yes ;; # (
 448         *) ovs_cv_gnu_make=no ;;
 449       esac])
 450    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 451
 452 dnl OVS_CHECK_SPARSE_TARGET
 453 dnl
 454 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 455 dnl target for which the code is being built.  This helps it out.
 456 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 457   [AC_CACHE_CHECK(
 458     [target hint for cgcc],
 459     [ac_cv_sparse_target],
 460     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 461        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 462        [x86_64-*], [ac_cv_sparse_target=x86_64],
 463        [ac_cv_sparse_target=other])])
 464    AS_CASE([$ac_cv_sparse_target],
 465      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 466      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 467      [SPARSEFLAGS= CGCCFLAGS=])
 468    AC_SUBST([SPARSEFLAGS])
 469    AC_SUBST([CGCCFLAGS])])
 470
 471 dnl OVS_ENABLE_SPARSE
 472 AC_DEFUN([OVS_ENABLE_SPARSE],
 473   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 474    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 475    : ${SPARSE=sparse}
 476    AC_SUBST([SPARSE])
 477    AC_CONFIG_COMMANDS_PRE(
 478      [if test $ovs_cv_gnu_make_if = yes; then
 479         CC='$(if $(C),REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS)" cgcc $(CGCCFLAGS),'"$CC"')'
 480       fi])])