acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 4; then
 137        if test "$version" = 4 && test "$patchlevel" -le 3; then
 138           : # Linux 4.x
 139        else
 140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.3.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 143        : # Linux 3.x
 144     else
 145        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 146     fi
 147     if (test ! -e "$KBUILD"/include/linux/version.h && \
 148         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 149        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 150         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 151         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 152     fi
 153     OVS_CHECK_LINUX_COMPAT
 154   fi
 155   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 156 ])
 157
 158 dnl OVS_CHECK_DPDK
 159 dnl
 160 dnl Configure DPDK source tree
 161 AC_DEFUN([OVS_CHECK_DPDK], [
 162   AC_ARG_WITH([dpdk],
 163               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 164                               [Specify the DPDK build directory])],
 165               [have_dpdk=true])
 166
 167   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 168   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 169     AC_MSG_RESULT([no])
 170     DPDKLIB_FOUND=false
 171   else
 172     AC_MSG_RESULT([yes])
 173     case "$with_dpdk" in
 174       yes)
 175         DPDK_AUTO_DISCOVER="true"
 176         DPDK_INCLUDE="/usr/local/include/dpdk -I/usr/include/dpdk"
 177         ;;
 178       *)
 179         DPDK_AUTO_DISCOVER="false"
 180         DPDK_INCLUDE="$with_dpdk/include"
 181         # If 'with_dpdk' is passed install directory, point to headers
 182         # installed in $DESTDIR/$prefix/include/dpdk
 183         AC_CHECK_FILE([$DPDK_INCLUDE/rte_config.h], [],
 184                       [AC_CHECK_FILE([$DPDK_INCLUDE/dpdk/rte_config.h],
 185                                      [DPDK_INCLUDE=$DPDK_INCLUDE/dpdk], [])])
 186         DPDK_LIB_DIR="$with_dpdk/lib"
 187         ;;
 188     esac
 189
 190     DPDK_LIB="-ldpdk"
 191     DPDK_EXTRA_LIB=""
 192
 193     ovs_save_CFLAGS="$CFLAGS"
 194     ovs_save_LDFLAGS="$LDFLAGS"
 195     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 196     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 197       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 198     fi
 199
 200     AC_COMPILE_IFELSE([
 201       AC_LANG_PROGRAM(
 202         [
 203           #include <rte_config.h>
 204 #if !RTE_LIBRTE_VHOST_USER
 205 #error
 206 #endif
 207         ], [])
 208       ], [],
 209       [AC_DEFINE([VHOST_CUSE], [1], [DPDK vhost-cuse support enabled, vhost-user disabled.])
 210        DPDK_EXTRA_LIB="-lfuse"])
 211
 212     # On some systems we have to add -ldl to link with dpdk
 213     #
 214     # This code, at first, tries to link without -ldl (""),
 215     # then adds it and tries again.
 216     # Before each attempt the search cache must be unset,
 217     # otherwise autoconf will stick with the old result
 218
 219     DPDKLIB_FOUND=false
 220     save_LIBS=$LIBS
 221     for extras in "" "-ldl"; do
 222         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 223         AC_LINK_IFELSE(
 224            [AC_LANG_PROGRAM([#include <rte_config.h>
 225                              #include <rte_eal.h>],
 226                             [int rte_argc; char ** rte_argv;
 227                              rte_eal_init(rte_argc, rte_argv);])],
 228            [DPDKLIB_FOUND=true])
 229         if $DPDKLIB_FOUND; then
 230             break
 231         fi
 232     done
 233
 234     # If linking unsuccessful
 235     if test "$DPDKLIB_FOUND" = "false" ; then
 236       if $DPDK_AUTO_DISCOVER; then
 237         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 238       else
 239         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 240       fi
 241     fi
 242     CFLAGS="$ovs_save_CFLAGS"
 243     LDFLAGS="$ovs_save_LDFLAGS"
 244     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 245       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 246     fi
 247     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE"
 248     OVS_ENABLE_OPTION([-mssse3])
 249
 250     # DPDK pmd drivers are not linked unless --whole-archive is used.
 251     #
 252     # This happens because the rest of the DPDK code doesn't use any symbol in
 253     # the pmd driver objects, and the drivers register themselves using an
 254     # __attribute__((constructor)) function.
 255     #
 256     # These options are specified inside a single -Wl directive to prevent
 257     # autotools from reordering them.
 258     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 259     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 260     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 261   fi
 262
 263   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 264 ])
 265
 266 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 267 dnl
 268 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 269 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 270 dnl <REGEX> translated to uppercase.
 271 AC_DEFUN([OVS_GREP_IFELSE], [
 272   AC_MSG_CHECKING([whether $2 matches in $1])
 273   if test -f $1; then
 274     grep '$2' $1 >/dev/null 2>&1
 275     status=$?
 276     case $status in
 277       0)
 278         AC_MSG_RESULT([yes])
 279         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 280         ;;
 281       1)
 282         AC_MSG_RESULT([no])
 283         $4
 284         ;;
 285       *)
 286         AC_MSG_ERROR([grep exited with status $status])
 287         ;;
 288     esac
 289   else
 290     AC_MSG_RESULT([file not found])
 291     $4
 292   fi
 293 ])
 294
 295 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 296 dnl
 297 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 298 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 299 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 300 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 301 dnl translated to uppercase.
 302 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 303   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 304   if test -f $1; then
 305     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 306     status=$?
 307     case $status in
 308       0)
 309         AC_MSG_RESULT([yes])
 310         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 311         ;;
 312       1)
 313         AC_MSG_RESULT([no])
 314         $5
 315         ;;
 316       *)
 317         AC_MSG_ERROR([grep exited with status $status])
 318         ;;
 319     esac
 320   else
 321     AC_MSG_RESULT([file not found])
 322     $5
 323   fi
 324 ])
 325
 326 dnl OVS_DEFINE(NAME)
 327 dnl
 328 dnl Defines NAME to 1 in kcompat.h.
 329 AC_DEFUN([OVS_DEFINE], [
 330   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 331 ])
 332
 333 dnl OVS_CHECK_LINUX_COMPAT
 334 dnl
 335 dnl Runs various Autoconf checks on the Linux kernel source in
 336 dnl the directory in $KBUILD.
 337 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 338   rm -f datapath/linux/kcompat.h.new
 339   mkdir -p datapath/linux
 340   : > datapath/linux/kcompat.h.new
 341
 342   echo '#include <linux/version.h>
 343 #ifndef RHEL_RELEASE_CODE
 344 #define RHEL_RELEASE_CODE 0
 345 #define RHEL_RELEASE_VERSION(a, b) 0
 346 #endif' >> datapath/linux/kcompat.h.new
 347
 348   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 349                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 350
 351   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 352                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 353   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 354
 355   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 356   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 357
 358   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 359   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 360
 361   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 362   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 363   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 364   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 365   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 366
 367   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 368   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 369   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 370                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 371   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 372                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 373
 374   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 375                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 376   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 377                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 378   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_do_fragment])
 379   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 380
 381   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 382                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 383   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 384   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 385                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 386   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 387                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 388   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 389   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 390                         [frags_work])
 391   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 392                         [rwlock])
 393   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 394                         [list_evictor])
 395   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 396                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 397
 398   OVS_GREP_IFELSE([$KSRC/include/net/dst_metadata.h], [metadata_dst])
 399
 400   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 401                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 402   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 403   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 404   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 405   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 406   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 407   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 408   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 409   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 410   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 411   dnl So check type of tstats.
 412   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 413                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 414   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 415                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 416   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 417   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 418                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 419   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 420
 421   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 422   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 423   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 424                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 425   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 426                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 427
 428   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 429                   [tmpl_alloc.*conntrack_zone],
 430                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 431   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 432                   [l3num.*struct.net],
 433                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 434   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 435                   [nf_ct_zone_init])
 436   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 437                   [nf_connlabels_get])
 438   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 439                   [nf_ct_frag6_consume_orig])
 440   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 441                   [nf_ct_frag6_output])
 442
 443   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 444   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 445
 446   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 447   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 448   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 449                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 450   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 451
 452   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 453                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 454                                    [rcu_read_lock_held])])
 455   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 456
 457   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 458   # is necessary because some versions of this header remove the
 459   # member but retain the kerneldoc comment that describes it (which
 460   # starts with @).  The brackets must be doubled because of m4
 461   # quoting rules.
 462   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 463                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 464   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 465   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 466   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_mac_header])
 467   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_network_header])
 468   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 469   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_scrub_packet.*xnet],
 470                   [OVS_DEFINE([HAVE_SKB_SCRUB_PACKET_XNET])])
 471   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 472   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 473                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 474   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 475                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 476   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 477                   [skb_copy_from_linear_data_offset])
 478   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 479                   [skb_reset_tail_pointer])
 480   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 481   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 482                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 483   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 484   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 485   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 486   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 487   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 488   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 489   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 490   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 491                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 492   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 493   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 494                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 495   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 496                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 497   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 498   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 499   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 500
 501   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 502                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 503   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 504                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 505   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 506                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 507
 508   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 509   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 510
 511   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 512   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 513
 514   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 515   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 516   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 517   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 518   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 519                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 520   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 521   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 522                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 523
 524   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 525                         [genl_multicast_group], [id])
 526   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 527
 528   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 529   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 530   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 531   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 532   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 533   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 534                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 535   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 536                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 537
 538   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 539   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 540   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 541   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 542   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 543   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 544   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 545   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 546                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 547
 548   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 549
 550   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 551                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 552   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 553   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 554   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 555
 556   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 557
 558   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 559                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 560   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [VXLAN_HF_RCO])
 561   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 562                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 563                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 564   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 565   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
 566   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 567   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [ipv6_v6only],
 568                   [OVS_DEFINE([HAVE_UDP_TUNNEL_IPV6])])
 569
 570   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 571                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 572   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 573                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 574
 575   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 576                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 577
 578   if cmp -s datapath/linux/kcompat.h.new \
 579             datapath/linux/kcompat.h >/dev/null 2>&1; then
 580     rm datapath/linux/kcompat.h.new
 581   else
 582     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 583   fi
 584 ])
 585
 586 dnl Checks for net/if_packet.h.
 587 AC_DEFUN([OVS_CHECK_IF_PACKET],
 588   [AC_CHECK_HEADER([net/if_packet.h],
 589                    [HAVE_IF_PACKET=yes],
 590                    [HAVE_IF_PACKET=no])
 591    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 592    if test "$HAVE_IF_PACKET" = yes; then
 593       AC_DEFINE([HAVE_IF_PACKET], [1],
 594                 [Define to 1 if net/if_packet.h is available.])
 595    fi])
 596
 597 dnl Checks for net/if_dl.h.
 598 dnl
 599 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 600 dnl or NetBSD.)
 601 AC_DEFUN([OVS_CHECK_IF_DL],
 602   [AC_CHECK_HEADER([net/if_dl.h],
 603                    [HAVE_IF_DL=yes],
 604                    [HAVE_IF_DL=no])
 605    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 606    if test "$HAVE_IF_DL" = yes; then
 607       AC_DEFINE([HAVE_IF_DL], [1],
 608                 [Define to 1 if net/if_dl.h is available.])
 609
 610       # On these platforms we use libpcap to access network devices.
 611       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 612    fi])
 613
 614 dnl Checks for buggy strtok_r.
 615 dnl
 616 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 617 dnl with optimization that can cause segfaults:
 618 dnl
 619 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 620 AC_DEFUN([OVS_CHECK_STRTOK_R],
 621   [AC_CACHE_CHECK(
 622      [whether strtok_r macro segfaults on some inputs],
 623      [ovs_cv_strtok_r_bug],
 624      [AC_RUN_IFELSE(
 625         [AC_LANG_PROGRAM([#include <stdio.h>
 626                           #include <string.h>
 627                          ],
 628                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 629                            /* Assume bug is present, because relatively minor
 630                               changes in compiler settings (e.g. optimization
 631                               level) can make it crop up. */
 632                            return 1;
 633                            #else
 634                            char string[] = ":::";
 635                            char *save_ptr = (char *) 0xc0ffee;
 636                            char *token1, *token2;
 637                            token1 = strtok_r(string, ":", &save_ptr);
 638                            token2 = strtok_r(NULL, ":", &save_ptr);
 639                            freopen ("/dev/null", "w", stdout);
 640                            printf ("%s %s\n", token1, token2);
 641                            return 0;
 642                            #endif
 643                           ]])],
 644         [ovs_cv_strtok_r_bug=no],
 645         [ovs_cv_strtok_r_bug=yes],
 646         [ovs_cv_strtok_r_bug=yes])])
 647    if test $ovs_cv_strtok_r_bug = yes; then
 648      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 649                [Define if strtok_r macro segfaults on some inputs])
 650    fi
 651 ])
 652
 653 dnl ----------------------------------------------------------------------
 654 dnl These macros are from GNU PSPP, with the following original license:
 655 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 656 dnl This file is free software; the Free Software Foundation
 657 dnl gives unlimited permission to copy and/or distribute it,
 658 dnl with or without modifications, as long as this notice is preserved.
 659
 660 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 661   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 662   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 663     [ovs_save_CFLAGS="$CFLAGS"
 664      dnl Include -Werror in the compiler options, because without -Werror
 665      dnl clang's GCC-compatible compiler driver does not return a failure
 666      dnl exit status even though it complains about options it does not
 667      dnl understand.
 668      dnl
 669      dnl Also, check stderr as gcc exits with status 0 for options
 670      dnl rejected at getopt level.
 671      dnl    % touch /tmp/a.c
 672      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 673      dnl    gcc: unrecognized option '-Qunused-arguments'
 674      dnl    0
 675      dnl    %
 676      CFLAGS="$CFLAGS $WERROR $1"
 677      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 678      CFLAGS="$ovs_save_CFLAGS"])
 679   if test $ovs_cv_name = yes; then
 680     m4_if([$2], [], [:], [$2])
 681   else
 682     m4_if([$3], [], [:], [$3])
 683   fi
 684 ])
 685
 686 dnl OVS_CHECK_WERROR
 687 dnl
 688 dnl Check whether the C compiler accepts -Werror.
 689 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 690 AC_DEFUN([OVS_CHECK_WERROR],
 691   [WERROR=
 692    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 693
 694 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 695 dnl Check whether the given C compiler OPTION is accepted.
 696 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 697 AC_DEFUN([OVS_CHECK_CC_OPTION],
 698   [AC_REQUIRE([OVS_CHECK_WERROR])
 699    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 700
 701 dnl OVS_ENABLE_OPTION([OPTION])
 702 dnl Check whether the given C compiler OPTION is accepted.
 703 dnl If so, add it to WARNING_FLAGS.
 704 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 705 AC_DEFUN([OVS_ENABLE_OPTION],
 706   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 707    AC_SUBST([WARNING_FLAGS])])
 708
 709 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 710 dnl Check whether the given C compiler OPTION is accepted.
 711 dnl If so, enable the given Automake CONDITIONAL.
 712
 713 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 714 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 715   [OVS_CHECK_CC_OPTION(
 716     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 717    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 718 dnl ----------------------------------------------------------------------
 719
 720 dnl Check for too-old XenServer.
 721 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 722   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 723     [if test -e /etc/redhat-release; then
 724        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 725      fi
 726      if test -z "$ovs_cv_xsversion"; then
 727        ovs_cv_xsversion=none
 728      fi])
 729   case $ovs_cv_xsversion in
 730     none)
 731       ;;
 732
 733     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 734     [[6-9]]* |                           dnl XenServer 6 or later
 735     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 736     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 737     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 738     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 739       ;;
 740
 741     *)
 742       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 743       ;;
 744   esac])
 745
 746 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 747 dnl
 748 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 749 dnl Runs 'if-true' if so, 'if-false' otherwise.
 750 AC_DEFUN([OVS_CHECK_MAKE_IF],
 751   [AC_CACHE_CHECK(
 752      [whether ${MAKE-make} has GNU make \$(if) extension],
 753      [ovs_cv_gnu_make_if],
 754      [cat <<'EOF' > conftest.mk
 755 conftest.out:
 756         echo $(if x,y,z) > conftest.out
 757 .PHONY: all
 758 EOF
 759       rm -f conftest.out
 760       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 761       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 762       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 763       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 764       result=`cat conftest.out`
 765       rm -f conftest.mk conftest.out
 766       if test "X$result" = "Xy"; then
 767         ovs_cv_gnu_make_if=yes
 768       else
 769         ovs_cv_gnu_make_if=no
 770       fi])])
 771
 772 dnl OVS_CHECK_GNU_MAKE
 773 dnl
 774 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 775 dnl only work with GNU make).
 776 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 777   [AC_CACHE_CHECK(
 778      [whether ${MAKE-make} is GNU make],
 779      [ovs_cv_gnu_make],
 780      [rm -f conftest.out
 781       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 782       ${MAKE-make} --version >conftest.out 2>&1
 783       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 784       result=`cat conftest.out`
 785       rm -f conftest.mk conftest.out
 786
 787       case $result in # (
 788         GNU*) ovs_cv_gnu_make=yes ;; # (
 789         *) ovs_cv_gnu_make=no ;;
 790       esac])
 791    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 792
 793 dnl OVS_CHECK_SPARSE_TARGET
 794 dnl
 795 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 796 dnl target for which the code is being built.  This helps it out.
 797 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 798   [AC_CACHE_CHECK(
 799     [target hint for cgcc],
 800     [ac_cv_sparse_target],
 801     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 802        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 803        [x86_64-*], [ac_cv_sparse_target=x86_64],
 804        [ac_cv_sparse_target=other])])
 805    AS_CASE([$ac_cv_sparse_target],
 806      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 807      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 808      [SPARSEFLAGS= CGCCFLAGS=])
 809    AC_SUBST([SPARSEFLAGS])
 810    AC_SUBST([CGCCFLAGS])])
 811
 812 dnl OVS_SPARSE_EXTRA_INCLUDES
 813 dnl
 814 dnl The cgcc script from "sparse" does not search gcc's default
 815 dnl search path. Get the default search path from GCC and pass
 816 dnl them to sparse.
 817 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 818     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 819            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 820
 821 dnl OVS_ENABLE_SPARSE
 822 AC_DEFUN([OVS_ENABLE_SPARSE],
 823   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 824    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 825    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 826    : ${SPARSE=sparse}
 827    AC_SUBST([SPARSE])
 828    AC_CONFIG_COMMANDS_PRE(
 829      [if test $ovs_cv_gnu_make_if = yes; then
 830         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 831       fi])])
 832
 833 dnl OVS_PTHREAD_SET_NAME
 834 dnl
 835 dnl This checks for three known variants of pthreads functions for setting
 836 dnl the name of the current thread:
 837 dnl
 838 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 839 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 840 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 841 dnl
 842 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 843 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 844 dnl provide to it.
 845 dnl
 846 dnl This macro defines:
 847 dnl
 848 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 849 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 850 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 851 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 852   [AC_CHECK_FUNCS([pthread_set_name_np])
 853    if test $ac_cv_func_pthread_set_name_np != yes; then
 854      AC_CACHE_CHECK(
 855        [for pthread_setname_np() variant],
 856        [ovs_cv_pthread_setname_np],
 857        [AC_LINK_IFELSE(
 858          [AC_LANG_PROGRAM([#include <pthread.h>
 859   ], [pthread_setname_np(pthread_self(), "name");])],
 860          [ovs_cv_pthread_setname_np=glibc],
 861          [AC_LINK_IFELSE(
 862            [AC_LANG_PROGRAM([#include <pthread.h>
 863 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 864            [ovs_cv_pthread_setname_np=netbsd],
 865            [ovs_cv_pthread_setname_np=none])])])
 866      case $ovs_cv_pthread_setname_np in # (
 867        glibc)
 868           AC_DEFINE(
 869             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 870             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 871           ;; # (
 872        netbsd)
 873           AC_DEFINE(
 874             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 875             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 876           ;;
 877      esac
 878    fi])
 879
 880 dnl OVS_CHECK_LINUX_HOST.
 881 dnl
 882 dnl Checks whether we're building for a Linux host, based on the presence of
 883 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 884 dnl LINUX based on the result.
 885 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 886   [AC_CACHE_CHECK(
 887      [whether __linux__ is defined],
 888      [ovs_cv_linux],
 889      [AC_COMPILE_IFELSE(
 890         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 891         [ovs_cv_linux=true],
 892         [ovs_cv_linux=false])])
 893    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])