acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])])
  36
  37 dnl OVS_CHECK_LINUX
  38 dnl
  39 dnl Configure linux kernel source tree
  40 AC_DEFUN([OVS_CHECK_LINUX], [
  41   AC_ARG_WITH([linux],
  42               [AC_HELP_STRING([--with-linux=/path/to/linux],
  43                               [Specify the Linux kernel build directory])])
  44   AC_ARG_WITH([linux-source],
  45               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  46                               [Specify the Linux kernel source directory
  47                                (usually figured out automatically from build
  48                                directory)])])
  49
  50   # Deprecated equivalents to --with-linux, --with-linux-source.
  51   AC_ARG_WITH([l26])
  52   AC_ARG_WITH([l26-source])
  53
  54   if test X"$with_linux" != X; then
  55     KBUILD=$with_linux
  56   elif test X"$with_l26" != X; then
  57     KBUILD=$with_l26
  58     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  59   else
  60     KBUILD=
  61   fi
  62
  63   if test X"$KBUILD" != X; then
  64     if test X"$with_linux_source" != X; then
  65       KSRC=$with_linux_source
  66     elif test X"$with_l26_source" != X; then
  67       KSRC=$with_l26_source
  68       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  69     else
  70       KSRC=
  71     fi
  72   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  73     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  74   fi
  75
  76   if test -n "$KBUILD"; then
  77     KBUILD=`eval echo "$KBUILD"`
  78     case $KBUILD in
  79         /*) ;;
  80         *) KBUILD=`pwd`/$KBUILD ;;
  81     esac
  82
  83     # The build directory is what the user provided.
  84     # Make sure that it exists.
  85     AC_MSG_CHECKING([for Linux build directory])
  86     if test -d "$KBUILD"; then
  87         AC_MSG_RESULT([$KBUILD])
  88         AC_SUBST(KBUILD)
  89     else
  90         AC_MSG_RESULT([no])
  91         AC_ERROR([source dir $KBUILD doesn't exist])
  92     fi
  93
  94     # Debian breaks kernel headers into "source" header and "build" headers.
  95     # We want the source headers, but $KBUILD gives us the "build" headers.
  96     # Use heuristics to find the source headers.
  97     AC_MSG_CHECKING([for Linux source directory])
  98     if test -n "$KSRC"; then
  99       KSRC=`eval echo "$KSRC"`
 100       case $KSRC in
 101           /*) ;;
 102           *) KSRC=`pwd`/$KSRC ;;
 103       esac
 104       if test ! -e $KSRC/include/linux/kernel.h; then
 105         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 106       fi
 107     else
 108       KSRC=$KBUILD
 109       if test ! -e $KSRC/include/linux/kernel.h; then
 110         # Debian kernel build Makefiles tend to include a line of the form:
 111         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 112         # First try to extract the source directory from this line.
 113         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 114         if test ! -e "$KSRC"/include/linux/kernel.h; then
 115           # Didn't work.  Fall back to name-based heuristics that used to work.
 116           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 117             */build)
 118               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 119               ;; # (
 120             *)
 121               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 122               ;;
 123           esac
 124         fi
 125       fi
 126       if test ! -e "$KSRC"/include/linux/kernel.h; then
 127         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 128       fi
 129     fi
 130     AC_MSG_RESULT([$KSRC])
 131
 132     AC_MSG_CHECKING([for kernel version])
 133     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 134     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 135     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 136     if test X"$version" = X || test X"$patchlevel" = X; then
 137        AC_ERROR([cannot determine kernel version])
 138     elif test X"$sublevel" = X; then
 139        kversion=$version.$patchlevel
 140     else
 141        kversion=$version.$patchlevel.$sublevel
 142     fi
 143     AC_MSG_RESULT([$kversion])
 144
 145     if test "$version" -ge 4; then
 146        if test "$version" = 4 && test "$patchlevel" -le 13; then
 147           : # Linux 4.x
 148        else
 149           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.13.x is not supported (please refer to the FAQ for advice)])
 150        fi
 151     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 152        : # Linux 3.x
 153     else
 154        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 155     fi
 156     if (test ! -e "$KBUILD"/include/linux/version.h && \
 157         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 158        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 159         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 160         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 161     fi
 162     OVS_CHECK_LINUX_COMPAT
 163   fi
 164   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 165 ])
 166
 167 dnl OVS_CHECK_LINUX_TC
 168 dnl
 169 dnl Configure Linux tc compat.
 170 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 171   AC_COMPILE_IFELSE([
 172     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 173         int x = TCA_FLOWER_KEY_IP_TTL_MASK;
 174     ])],
 175     [AC_DEFINE([HAVE_TCA_FLOWER_KEY_IP_TTL_MASK], [1],
 176                [Define to 1 if TCA_FLOWER_KEY_IP_TTL_MASK is avaiable.])])
 177
 178   AC_COMPILE_IFELSE([
 179     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 180         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 181     ])],
 182     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 183                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is avaiable.])])
 184
 185   AC_COMPILE_IFELSE([
 186     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 187         int x = TCA_TUNNEL_KEY_ENC_DST_PORT;
 188     ])],
 189     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_DST_PORT], [1],
 190                [Define to 1 if TCA_TUNNEL_KEY_ENC_DST_PORT is avaiable.])])
 191
 192   AC_COMPILE_IFELSE([
 193     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 194         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 195     ])],
 196     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 197                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is avaiable.])])
 198 ])
 199
 200 dnl OVS_CHECK_DPDK
 201 dnl
 202 dnl Configure DPDK source tree
 203 AC_DEFUN([OVS_CHECK_DPDK], [
 204   AC_ARG_WITH([dpdk],
 205               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 206                               [Specify the DPDK build directory])],
 207               [have_dpdk=true])
 208
 209   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 210   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 211     AC_MSG_RESULT([no])
 212     DPDKLIB_FOUND=false
 213   else
 214     AC_MSG_RESULT([yes])
 215     case "$with_dpdk" in
 216       yes)
 217         DPDK_AUTO_DISCOVER="true"
 218         PKG_CHECK_MODULES([DPDK], [libdpdk],
 219                           [DPDK_INCLUDE="$DPDK_CFLAGS"],
 220                           [DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"])
 221         ;;
 222       *)
 223         DPDK_AUTO_DISCOVER="false"
 224         DPDK_INCLUDE_PATH="$with_dpdk/include"
 225         # If 'with_dpdk' is passed install directory, point to headers
 226         # installed in $DESTDIR/$prefix/include/dpdk
 227         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 228            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 229         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 230            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 231         fi
 232         DPDK_LIB_DIR="$with_dpdk/lib"
 233         ;;
 234     esac
 235
 236     DPDK_LIB="-ldpdk"
 237     DPDK_EXTRA_LIB=""
 238
 239     ovs_save_CFLAGS="$CFLAGS"
 240     ovs_save_LDFLAGS="$LDFLAGS"
 241     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 242     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 243       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 244     fi
 245
 246     AC_COMPILE_IFELSE([
 247       AC_LANG_PROGRAM(
 248         [
 249           #include <rte_config.h>
 250 #if RTE_LIBRTE_VHOST_NUMA
 251 #error
 252 #endif
 253         ], [])
 254       ], [],
 255       [AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])])
 256        DPDK_EXTRA_LIB="-lnuma"
 257        AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])])
 258
 259     AC_COMPILE_IFELSE([
 260       AC_LANG_PROGRAM(
 261         [
 262           #include <rte_config.h>
 263 #if RTE_LIBRTE_PMD_PCAP
 264 #error
 265 #endif
 266         ], [])
 267       ], [],
 268       [AC_SEARCH_LIBS([pcap_dump],[pcap],[],[AC_MSG_ERROR([unable to find libpcap, install the dependency package])])
 269        DPDK_EXTRA_LIB="-lpcap"
 270        AC_COMPILE_IFELSE([
 271          AC_LANG_PROGRAM(
 272            [
 273              #include <rte_config.h>
 274 #if RTE_LIBRTE_PDUMP
 275 #error
 276 #endif
 277          ], [])
 278        ], [],
 279        [AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])])
 280      ])
 281
 282     # On some systems we have to add -ldl to link with dpdk
 283     #
 284     # This code, at first, tries to link without -ldl (""),
 285     # then adds it and tries again.
 286     # Before each attempt the search cache must be unset,
 287     # otherwise autoconf will stick with the old result
 288
 289     DPDKLIB_FOUND=false
 290     save_LIBS=$LIBS
 291     for extras in "" "-ldl"; do
 292         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 293         AC_LINK_IFELSE(
 294            [AC_LANG_PROGRAM([#include <rte_config.h>
 295                              #include <rte_eal.h>],
 296                             [int rte_argc; char ** rte_argv;
 297                              rte_eal_init(rte_argc, rte_argv);])],
 298            [DPDKLIB_FOUND=true])
 299         if $DPDKLIB_FOUND; then
 300             break
 301         fi
 302     done
 303
 304     # If linking unsuccessful
 305     if test "$DPDKLIB_FOUND" = "false" ; then
 306       if $DPDK_AUTO_DISCOVER; then
 307         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 308       else
 309         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 310       fi
 311     fi
 312     CFLAGS="$ovs_save_CFLAGS"
 313     LDFLAGS="$ovs_save_LDFLAGS"
 314     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 315       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 316     fi
 317     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 318     OVS_ENABLE_OPTION([-mssse3])
 319
 320     # DPDK pmd drivers are not linked unless --whole-archive is used.
 321     #
 322     # This happens because the rest of the DPDK code doesn't use any symbol in
 323     # the pmd driver objects, and the drivers register themselves using an
 324     # __attribute__((constructor)) function.
 325     #
 326     # These options are specified inside a single -Wl directive to prevent
 327     # autotools from reordering them.
 328     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 329     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 330     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 331   fi
 332
 333   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 334 ])
 335
 336 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 337 dnl
 338 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 339 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 340 dnl <REGEX> translated to uppercase.
 341 AC_DEFUN([OVS_GREP_IFELSE], [
 342   AC_MSG_CHECKING([whether $2 matches in $1])
 343   if test -f $1; then
 344     grep '$2' $1 >/dev/null 2>&1
 345     status=$?
 346     case $status in
 347       0)
 348         AC_MSG_RESULT([yes])
 349         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 350         ;;
 351       1)
 352         AC_MSG_RESULT([no])
 353         $4
 354         ;;
 355       *)
 356         AC_MSG_ERROR([grep exited with status $status])
 357         ;;
 358     esac
 359   else
 360     AC_MSG_RESULT([file not found])
 361     $4
 362   fi
 363 ])
 364
 365 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 366 dnl
 367 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 368 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 369 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 370 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 371 dnl translated to uppercase.
 372 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 373   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 374   if test -f $1; then
 375     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 376     status=$?
 377     case $status in
 378       0)
 379         AC_MSG_RESULT([yes])
 380         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 381         ;;
 382       1)
 383         AC_MSG_RESULT([no])
 384         $5
 385         ;;
 386       *)
 387         AC_MSG_ERROR([grep exited with status $status])
 388         ;;
 389     esac
 390   else
 391     AC_MSG_RESULT([file not found])
 392     $5
 393   fi
 394 ])
 395
 396 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 397 dnl
 398 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 399 dnl the function signature starting from the line matching FUNCTION
 400 dnl and ending with the line containing the closing parenthesis.  If
 401 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 402 dnl IF-MATCH is empty then it defines to
 403 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 404 dnl <REGEX> translated to uppercase.
 405 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 406   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 407   if test -f $1; then
 408     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 409     status=$?
 410     case $status in
 411       0)
 412         AC_MSG_RESULT([yes])
 413         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 414         ;;
 415       1)
 416         AC_MSG_RESULT([no])
 417         $5
 418         ;;
 419       *)
 420         AC_MSG_ERROR([grep exited with status $status])
 421         ;;
 422     esac
 423   else
 424     AC_MSG_RESULT([file not found])
 425     $5
 426   fi
 427 ])
 428
 429 dnl OVS_DEFINE(NAME)
 430 dnl
 431 dnl Defines NAME to 1 in kcompat.h.
 432 AC_DEFUN([OVS_DEFINE], [
 433   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 434 ])
 435
 436 dnl OVS_CHECK_LINUX_COMPAT
 437 dnl
 438 dnl Runs various Autoconf checks on the Linux kernel source in
 439 dnl the directory in $KBUILD.
 440 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 441   rm -f datapath/linux/kcompat.h.new
 442   mkdir -p datapath/linux
 443   : > datapath/linux/kcompat.h.new
 444
 445   echo '#include <linux/version.h>
 446 #ifndef RHEL_RELEASE_CODE
 447 #define RHEL_RELEASE_CODE 0
 448 #define RHEL_RELEASE_VERSION(a, b) 0
 449 #endif' >> datapath/linux/kcompat.h.new
 450
 451   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 452                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 453
 454   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 455                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 456   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 457
 458   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 459   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 460   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 461
 462   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 463   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 464
 465   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 466   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 467   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 468   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 469   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 470
 471   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 472   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 473   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 474                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 475   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 476                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 477
 478   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 479                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 480   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 481                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 482   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 483                         [ip_do_fragment], [net],
 484                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 485   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 486                         [ip_local_out], [net],
 487                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 488
 489   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 490
 491   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 492                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 493   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 494   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 495                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 496   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 497                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 498   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 499   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 500   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 501                         [frags_work])
 502   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 503                         [rwlock])
 504   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 505                         [list_evictor])
 506   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 507   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 508                         [sub_frag_mem_limit], [struct.netns_frags],
 509                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 510   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 511                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 512   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 513                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 514
 515   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 516   dnl OVS does not really need ipv6 label field, but its presence signifies that
 517   dnl the stack has all required ipv6 support.
 518   dnl OVS also does not need dst_cache But this dependency allows us to write
 519   dnl much cleaner code.
 520
 521   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 522                         [label],
 523                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 524                                          [iptunnel_pull_offloads],
 525                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 526                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])
 527
 528   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 529                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 530   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 531                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 532   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 533   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 534   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 535   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 536   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 537   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 538   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 539   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 540   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 541                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 542   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 543   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 544   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 545   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 546   dnl So check type of tstats.
 547   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 548                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 549   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 550                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 551   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 552   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 553   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 554                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 555   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 556   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 557   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 558                         [extended])
 559   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 560                         [netdev_master_upper_dev_link], [upper_priv],
 561                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 562   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 563                   [netdev_master_upper_dev_link_rh],
 564                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 565
 566   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 567                         [max_mtu])
 568
 569   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 570   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 571   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 572                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 573   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 574                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 575   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 576                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 577
 578   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 579                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 580
 581   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 582                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 583                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 584   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 585                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 586
 587   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 588                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 589                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 590   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 591                   [nf_ct_get_tuplepr], [struct.net],
 592                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 593   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 594                   [nf_ct_set])
 595   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 596                   [nf_ct_is_untracked])
 597   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 598                   [nf_ct_zone_init])
 599   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 600                   [nf_connlabels_get])
 601   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 602                   [nf_connlabels_get], [int bit],
 603                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 604   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 605                         [nf_conn_labels], [words])
 606   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 607   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 608   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 609
 610   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 611   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 612
 613   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 614   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 615   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 616                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 617   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 618
 619   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 620                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 621                                    [rcu_read_lock_held])])
 622   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 623
 624   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 625   # is necessary because some versions of this header remove the
 626   # member but retain the kerneldoc comment that describes it (which
 627   # starts with @).  The brackets must be doubled because of m4
 628   # quoting rules.
 629   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 630                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 631   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 632   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 633   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 634   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 635   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 636   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 637   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 638                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 639   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 640                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 641   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 642                   [skb_copy_from_linear_data_offset])
 643   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 644                   [skb_reset_tail_pointer])
 645   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 646   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 647                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 648   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 649   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 650   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 651   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 652   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 653   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 654   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 655   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 656                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 657   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 658   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 659                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 660   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 661                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 662   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 663   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 664   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 665   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 666   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 667   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 668   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 669   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 670   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 671
 672   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 673                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 674   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 675                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 676   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 677                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 678
 679   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 680   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 681
 682   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 683   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 684
 685   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 686   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 687   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 688   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 689                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 690   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 691   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 692                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 693   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 694                         [genl_notify], [net],
 695                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 696
 697
 698   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 699                         [genl_multicast_group], [id])
 700   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 701
 702   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 703   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 704   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 705   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 706   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 707   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 708                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 709   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 710                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 711
 712   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 713   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 714   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 715   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 716   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 717   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 718   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 719   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 720   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 721                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 722   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 723                         [nla_parse], [netlink_ext_ack],
 724                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 725
 726   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 727
 728   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 729                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 730   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 731   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 732   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 733   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 734   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 735
 736   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 737                         [metadata_dst_alloc], [metadata_type])
 738
 739   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 740
 741   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 742                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 743   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 744                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 745                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 746   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 747   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 748   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 749                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 750   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 751                         [gro_receive])
 752
 753   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 754                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 755   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 756                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 757
 758   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 759   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 760   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 761                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 762   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 763                         [udp_add_offload], [net],
 764                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 765   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 766                         [nf_defrag_ipv6_enable], [net],
 767                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 768   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 769                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 770   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 771                         [needs_free_netdev],
 772                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 773   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 774                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 775   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 776                   [nf_conntrack_helper_put],
 777                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 778   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 779                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 780   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 781                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 782   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 783                         [extack],
 784                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 785   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 786                         [list],
 787                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 788
 789   if cmp -s datapath/linux/kcompat.h.new \
 790             datapath/linux/kcompat.h >/dev/null 2>&1; then
 791     rm datapath/linux/kcompat.h.new
 792   else
 793     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 794   fi
 795 ])
 796
 797 dnl Checks for net/if_packet.h.
 798 AC_DEFUN([OVS_CHECK_IF_PACKET],
 799   [AC_CHECK_HEADER([net/if_packet.h],
 800                    [HAVE_IF_PACKET=yes],
 801                    [HAVE_IF_PACKET=no])
 802    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 803    if test "$HAVE_IF_PACKET" = yes; then
 804       AC_DEFINE([HAVE_IF_PACKET], [1],
 805                 [Define to 1 if net/if_packet.h is available.])
 806    fi])
 807
 808 dnl Checks for net/if_dl.h.
 809 dnl
 810 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 811 dnl or NetBSD.)
 812 AC_DEFUN([OVS_CHECK_IF_DL],
 813   [AC_CHECK_HEADER([net/if_dl.h],
 814                    [HAVE_IF_DL=yes],
 815                    [HAVE_IF_DL=no])
 816    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 817    if test "$HAVE_IF_DL" = yes; then
 818       AC_DEFINE([HAVE_IF_DL], [1],
 819                 [Define to 1 if net/if_dl.h is available.])
 820
 821       # On these platforms we use libpcap to access network devices.
 822       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 823    fi])
 824
 825 dnl Checks for buggy strtok_r.
 826 dnl
 827 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 828 dnl with optimization that can cause segfaults:
 829 dnl
 830 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 831 AC_DEFUN([OVS_CHECK_STRTOK_R],
 832   [AC_CACHE_CHECK(
 833      [whether strtok_r macro segfaults on some inputs],
 834      [ovs_cv_strtok_r_bug],
 835      [AC_RUN_IFELSE(
 836         [AC_LANG_PROGRAM([#include <stdio.h>
 837                           #include <string.h>
 838                          ],
 839                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 840                            /* Assume bug is present, because relatively minor
 841                               changes in compiler settings (e.g. optimization
 842                               level) can make it crop up. */
 843                            return 1;
 844                            #else
 845                            char string[] = ":::";
 846                            char *save_ptr = (char *) 0xc0ffee;
 847                            char *token1, *token2;
 848                            token1 = strtok_r(string, ":", &save_ptr);
 849                            token2 = strtok_r(NULL, ":", &save_ptr);
 850                            freopen ("/dev/null", "w", stdout);
 851                            printf ("%s %s\n", token1, token2);
 852                            return 0;
 853                            #endif
 854                           ]])],
 855         [ovs_cv_strtok_r_bug=no],
 856         [ovs_cv_strtok_r_bug=yes],
 857         [ovs_cv_strtok_r_bug=yes])])
 858    if test $ovs_cv_strtok_r_bug = yes; then
 859      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 860                [Define if strtok_r macro segfaults on some inputs])
 861    fi
 862 ])
 863
 864 dnl ----------------------------------------------------------------------
 865 dnl These macros are from GNU PSPP, with the following original license:
 866 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 867 dnl This file is free software; the Free Software Foundation
 868 dnl gives unlimited permission to copy and/or distribute it,
 869 dnl with or without modifications, as long as this notice is preserved.
 870
 871 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 872   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
 873   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 874     [ovs_save_CFLAGS="$CFLAGS"
 875      dnl Include -Werror in the compiler options, because without -Werror
 876      dnl clang's GCC-compatible compiler driver does not return a failure
 877      dnl exit status even though it complains about options it does not
 878      dnl understand.
 879      dnl
 880      dnl Also, check stderr as gcc exits with status 0 for options
 881      dnl rejected at getopt level.
 882      dnl    % touch /tmp/a.c
 883      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 884      dnl    gcc: unrecognized option '-Qunused-arguments'
 885      dnl    0
 886      dnl    %
 887      CFLAGS="$CFLAGS $WERROR $1"
 888      AC_COMPILE_IFELSE(
 889        [AC_LANG_SOURCE([int x;])],
 890        [if test -s conftest.err && grep "unrecognized option" conftest.err
 891         then
 892           ovs_cv_name[]=no
 893         else
 894           ovs_cv_name[]=yes
 895         fi],
 896        [ovs_cv_name[]=no])
 897      CFLAGS="$ovs_save_CFLAGS"])
 898   if test $ovs_cv_name = yes; then
 899     m4_if([$2], [], [:], [$2])
 900   else
 901     m4_if([$3], [], [:], [$3])
 902   fi
 903 ])
 904
 905 dnl OVS_CHECK_WERROR
 906 dnl
 907 dnl Check whether the C compiler accepts -Werror.
 908 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 909 AC_DEFUN([OVS_CHECK_WERROR],
 910   [WERROR=
 911    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 912
 913 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 914 dnl Check whether the given C compiler OPTION is accepted.
 915 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 916 AC_DEFUN([OVS_CHECK_CC_OPTION],
 917   [AC_REQUIRE([OVS_CHECK_WERROR])
 918    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 919
 920 dnl OVS_ENABLE_OPTION([OPTION])
 921 dnl Check whether the given C compiler OPTION is accepted.
 922 dnl If so, add it to WARNING_FLAGS.
 923 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 924 AC_DEFUN([OVS_ENABLE_OPTION],
 925   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 926    AC_SUBST([WARNING_FLAGS])])
 927
 928 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 929 dnl Check whether the given C compiler OPTION is accepted.
 930 dnl If so, enable the given Automake CONDITIONAL.
 931
 932 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 933 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 934   [OVS_CHECK_CC_OPTION(
 935     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 936    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 937 dnl ----------------------------------------------------------------------
 938
 939 dnl Check for too-old XenServer.
 940 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 941   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 942     [if test -e /etc/redhat-release; then
 943        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 944      fi
 945      if test -z "$ovs_cv_xsversion"; then
 946        ovs_cv_xsversion=none
 947      fi])
 948   case $ovs_cv_xsversion in
 949     none)
 950       ;;
 951
 952     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 953     [[6-9]]* |                           dnl XenServer 6 or later
 954     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 955     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 956     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 957     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 958       ;;
 959
 960     *)
 961       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 962       ;;
 963   esac])
 964
 965 dnl OVS_CHECK_SPARSE_TARGET
 966 dnl
 967 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 968 dnl target for which the code is being built.  This helps it out.
 969 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 970   [AC_CACHE_CHECK(
 971     [target hint for cgcc],
 972     [ac_cv_sparse_target],
 973     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 974        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 975        [x86_64-*], [ac_cv_sparse_target=x86_64],
 976        [ac_cv_sparse_target=other])])
 977    AS_CASE([$ac_cv_sparse_target],
 978      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 979      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 980      [SPARSEFLAGS= CGCCFLAGS=])
 981    AC_SUBST([SPARSEFLAGS])
 982    AC_SUBST([CGCCFLAGS])])
 983
 984 dnl OVS_SPARSE_EXTRA_INCLUDES
 985 dnl
 986 dnl The cgcc script from "sparse" does not search gcc's default
 987 dnl search path. Get the default search path from GCC and pass
 988 dnl them to sparse.
 989 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 990     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 991            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 992
 993 dnl OVS_ENABLE_SPARSE
 994 AC_DEFUN([OVS_ENABLE_SPARSE],
 995   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 996    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 997    : ${SPARSE=sparse}
 998    AC_SUBST([SPARSE])
 999    AC_CONFIG_COMMANDS_PRE(
1000      [CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])])
1001
1002 dnl OVS_CTAGS_IDENTIFIERS
1003 dnl
1004 dnl ctags ignores symbols with extras identifiers. This builds a list of
1005 dnl specially handled identifiers to be ignored.
1006 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1007     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1008            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1009
1010 dnl OVS_PTHREAD_SET_NAME
1011 dnl
1012 dnl This checks for three known variants of pthreads functions for setting
1013 dnl the name of the current thread:
1014 dnl
1015 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1016 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1017 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1018 dnl
1019 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1020 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1021 dnl provide to it.
1022 dnl
1023 dnl This macro defines:
1024 dnl
1025 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1026 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1027 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1028 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1029   [AC_CHECK_FUNCS([pthread_set_name_np])
1030    if test $ac_cv_func_pthread_set_name_np != yes; then
1031      AC_CACHE_CHECK(
1032        [for pthread_setname_np() variant],
1033        [ovs_cv_pthread_setname_np],
1034        [AC_LINK_IFELSE(
1035          [AC_LANG_PROGRAM([#include <pthread.h>
1036   ], [pthread_setname_np(pthread_self(), "name");])],
1037          [ovs_cv_pthread_setname_np=glibc],
1038          [AC_LINK_IFELSE(
1039            [AC_LANG_PROGRAM([#include <pthread.h>
1040 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1041            [ovs_cv_pthread_setname_np=netbsd],
1042            [ovs_cv_pthread_setname_np=none])])])
1043      case $ovs_cv_pthread_setname_np in # (
1044        glibc)
1045           AC_DEFINE(
1046             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1047             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1048           ;; # (
1049        netbsd)
1050           AC_DEFINE(
1051             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1052             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1053           ;;
1054      esac
1055    fi])
1056
1057 dnl OVS_CHECK_LINUX_HOST.
1058 dnl
1059 dnl Checks whether we're building for a Linux host, based on the presence of
1060 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1061 dnl LINUX based on the result.
1062 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1063   [AC_CACHE_CHECK(
1064      [whether __linux__ is defined],
1065      [ovs_cv_linux],
1066      [AC_COMPILE_IFELSE(
1067         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1068         [ovs_cv_linux=true],
1069         [ovs_cv_linux=false])])
1070    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])