acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 4; then
 137        if test "$version" = 4 && test "$patchlevel" -le 0; then
 138           : # Linux 4.x
 139        else
 140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.0.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     elif test "$version" = 3; then
 143        : # Linux 3.x
 144     else
 145        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 146          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 147        else
 148          : # Linux 2.6.x
 149        fi
 150     fi
 151     if (test ! -e "$KBUILD"/include/linux/version.h && \
 152         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 153        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 154         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 155         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 156     fi
 157     OVS_CHECK_LINUX_COMPAT
 158   fi
 159   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 160 ])
 161
 162 dnl OVS_CHECK_DPDK
 163 dnl
 164 dnl Configure DPDK source tree
 165 AC_DEFUN([OVS_CHECK_DPDK], [
 166   AC_ARG_WITH([dpdk],
 167               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 168                               [Specify the DPDK build directory])])
 169
 170   if test X"$with_dpdk" != X; then
 171     RTE_SDK=$with_dpdk
 172
 173     DPDK_INCLUDE=$RTE_SDK/include
 174     DPDK_LIB_DIR=$RTE_SDK/lib
 175     DPDK_LIB="-lintel_dpdk"
 176     DPDK_EXTRA_LIB=""
 177
 178     OVS_GREP_IFELSE([$RTE_SDK/include/rte_config.h], [define RTE_LIBRTE_VHOST_USER 1],
 179                     [], [AC_DEFINE([VHOST_CUSE], [1], [DPDK vhost-cuse support enabled, vhost-user disabled.])
 180                          DPDK_EXTRA_LIB="-lfuse"])
 181
 182     ovs_save_CFLAGS="$CFLAGS"
 183     ovs_save_LDFLAGS="$LDFLAGS"
 184     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
 185     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 186
 187     # On some systems we have to add -ldl to link with dpdk
 188     #
 189     # This code, at first, tries to link without -ldl (""),
 190     # then adds it and tries again.
 191     # Before each attempt the search cache must be unset,
 192     # otherwise autoconf will stick with the old result
 193
 194     found=false
 195     save_LIBS=$LIBS
 196     for extras in "" "-ldl"; do
 197         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 198         AC_LINK_IFELSE(
 199            [AC_LANG_PROGRAM([#include <rte_config.h>
 200                              #include <rte_eal.h>],
 201                             [int rte_argc; char ** rte_argv;
 202                              rte_eal_init(rte_argc, rte_argv);])],
 203            [found=true])
 204         if $found; then
 205             break
 206         fi
 207     done
 208     if $found; then :; else
 209         AC_MSG_ERROR([cannot link with dpdk])
 210     fi
 211     CFLAGS="$ovs_save_CFLAGS"
 212     LDFLAGS="$ovs_save_LDFLAGS"
 213     OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 214     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE -mssse3"
 215
 216     # DPDK pmd drivers are not linked unless --whole-archive is used.
 217     #
 218     # This happens because the rest of the DPDK code doesn't use any symbol in
 219     # the pmd driver objects, and the drivers register themselves using an
 220     # __attribute__((constructor)) function.
 221     #
 222     # These options are specified inside a single -Wl directive to prevent
 223     # autotools from reordering them.
 224     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 225     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 226     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 227
 228   else
 229     RTE_SDK=
 230   fi
 231
 232   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 233 ])
 234
 235 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 236 dnl
 237 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 238 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 239 dnl <REGEX> translated to uppercase.
 240 AC_DEFUN([OVS_GREP_IFELSE], [
 241   AC_MSG_CHECKING([whether $2 matches in $1])
 242   if test -f $1; then
 243     grep '$2' $1 >/dev/null 2>&1
 244     status=$?
 245     case $status in
 246       0)
 247         AC_MSG_RESULT([yes])
 248         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 249         ;;
 250       1)
 251         AC_MSG_RESULT([no])
 252         $4
 253         ;;
 254       *)
 255         AC_MSG_ERROR([grep exited with status $status])
 256         ;;
 257     esac
 258   else
 259     AC_MSG_RESULT([file not found])
 260     $4
 261   fi
 262 ])
 263
 264 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 265 dnl
 266 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 267 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 268 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 269 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 270 dnl translated to uppercase.
 271 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 272   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 273   if test -f $1; then
 274     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 275     status=$?
 276     case $status in
 277       0)
 278         AC_MSG_RESULT([yes])
 279         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 280         ;;
 281       1)
 282         AC_MSG_RESULT([no])
 283         $5
 284         ;;
 285       *)
 286         AC_MSG_ERROR([grep exited with status $status])
 287         ;;
 288     esac
 289   else
 290     AC_MSG_RESULT([file not found])
 291     $5
 292   fi
 293 ])
 294
 295 dnl OVS_DEFINE(NAME)
 296 dnl
 297 dnl Defines NAME to 1 in kcompat.h.
 298 AC_DEFUN([OVS_DEFINE], [
 299   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 300 ])
 301
 302 dnl OVS_CHECK_LINUX_COMPAT
 303 dnl
 304 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 305 dnl the directory in $KBUILD.
 306 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 307   rm -f datapath/linux/kcompat.h.new
 308   mkdir -p datapath/linux
 309   : > datapath/linux/kcompat.h.new
 310
 311   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 312                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 313
 314   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 315   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 316
 317   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 318   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 319
 320   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 321
 322   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 323   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 324                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 325   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 326                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 327
 328   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 329   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 330   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 331   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 332   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 333   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 334   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 335   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 336                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 337
 338   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 339
 340   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 341                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 342                                    [rcu_read_lock_held])])
 343   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 344
 345   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 346   # is necessary because some versions of this header remove the
 347   # member but retain the kerneldoc comment that describes it (which
 348   # starts with @).  The brackets must be doubled because of m4
 349   # quoting rules.
 350   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 351                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 352   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 353   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 354   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 355                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 356   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 357                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 358   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 359                   [skb_copy_from_linear_data_offset])
 360   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 361                   [skb_reset_tail_pointer])
 362   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 363   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 364                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 365   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 366                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 367   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 368                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 369   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 370   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 371   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 372   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 373   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 374   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 375   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 376   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 377   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 378   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 379                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 380   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [l4_rxhash])
 381   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 382   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 383   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 384
 385   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 386                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 387   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 388                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 389   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 390                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 391
 392   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 393   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 394
 395   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 396   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 397   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 398   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 399   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 400                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 401   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 402   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 403                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 404
 405   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 406                         [genl_multicast_group], [id])
 407
 408   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 409   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 410   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 411   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 412   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 413   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 414   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 415   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 416
 417   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 418
 419   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 420                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 421   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 422   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 423
 424
 425   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 426
 427   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 428                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 429   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 430                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 431   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 432                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 433                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 434   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 435   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
 436   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df:1],
 437                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 438   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_GRE_CSUM],
 439                   [OVS_DEFINE([HAVE_SKB_GSO_GRE_CSUM])])
 440   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [SKB_GSO_UDP_TUNNEL_CSUM],
 441                   [OVS_DEFINE([HAVE_SKB_GSO_UDP_TUNNEL_CSUM])])
 442   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 443                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 444
 445   if cmp -s datapath/linux/kcompat.h.new \
 446             datapath/linux/kcompat.h >/dev/null 2>&1; then
 447     rm datapath/linux/kcompat.h.new
 448   else
 449     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 450   fi
 451 ])
 452
 453 dnl Checks for net/if_packet.h.
 454 AC_DEFUN([OVS_CHECK_IF_PACKET],
 455   [AC_CHECK_HEADER([net/if_packet.h],
 456                    [HAVE_IF_PACKET=yes],
 457                    [HAVE_IF_PACKET=no])
 458    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 459    if test "$HAVE_IF_PACKET" = yes; then
 460       AC_DEFINE([HAVE_IF_PACKET], [1],
 461                 [Define to 1 if net/if_packet.h is available.])
 462    fi])
 463
 464 dnl Checks for net/if_dl.h.
 465 dnl
 466 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 467 dnl or NetBSD.)
 468 AC_DEFUN([OVS_CHECK_IF_DL],
 469   [AC_CHECK_HEADER([net/if_dl.h],
 470                    [HAVE_IF_DL=yes],
 471                    [HAVE_IF_DL=no])
 472    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 473    if test "$HAVE_IF_DL" = yes; then
 474       AC_DEFINE([HAVE_IF_DL], [1],
 475                 [Define to 1 if net/if_dl.h is available.])
 476
 477       # On these platforms we use libpcap to access network devices.
 478       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 479    fi])
 480
 481 dnl Checks for buggy strtok_r.
 482 dnl
 483 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 484 dnl with optimization that can cause segfaults:
 485 dnl
 486 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 487 AC_DEFUN([OVS_CHECK_STRTOK_R],
 488   [AC_CACHE_CHECK(
 489      [whether strtok_r macro segfaults on some inputs],
 490      [ovs_cv_strtok_r_bug],
 491      [AC_RUN_IFELSE(
 492         [AC_LANG_PROGRAM([#include <stdio.h>
 493                           #include <string.h>
 494                          ],
 495                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 496                            /* Assume bug is present, because relatively minor
 497                               changes in compiler settings (e.g. optimization
 498                               level) can make it crop up. */
 499                            return 1;
 500                            #else
 501                            char string[] = ":::";
 502                            char *save_ptr = (char *) 0xc0ffee;
 503                            char *token1, *token2;
 504                            token1 = strtok_r(string, ":", &save_ptr);
 505                            token2 = strtok_r(NULL, ":", &save_ptr);
 506                            freopen ("/dev/null", "w", stdout);
 507                            printf ("%s %s\n", token1, token2);
 508                            return 0;
 509                            #endif
 510                           ]])],
 511         [ovs_cv_strtok_r_bug=no],
 512         [ovs_cv_strtok_r_bug=yes],
 513         [ovs_cv_strtok_r_bug=yes])])
 514    if test $ovs_cv_strtok_r_bug = yes; then
 515      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 516                [Define if strtok_r macro segfaults on some inputs])
 517    fi
 518 ])
 519
 520 dnl ----------------------------------------------------------------------
 521 dnl These macros are from GNU PSPP, with the following original license:
 522 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 523 dnl This file is free software; the Free Software Foundation
 524 dnl gives unlimited permission to copy and/or distribute it,
 525 dnl with or without modifications, as long as this notice is preserved.
 526
 527 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 528   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 529   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 530     [ovs_save_CFLAGS="$CFLAGS"
 531      dnl Include -Werror in the compiler options, because without -Werror
 532      dnl clang's GCC-compatible compiler driver does not return a failure
 533      dnl exit status even though it complains about options it does not
 534      dnl understand.
 535      dnl
 536      dnl Also, check stderr as gcc exits with status 0 for options
 537      dnl rejected at getopt level.
 538      dnl    % touch /tmp/a.c
 539      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 540      dnl    gcc: unrecognized option '-Qunused-arguments'
 541      dnl    0
 542      dnl    %
 543      CFLAGS="$CFLAGS $WERROR $1"
 544      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 545      CFLAGS="$ovs_save_CFLAGS"])
 546   if test $ovs_cv_name = yes; then
 547     m4_if([$2], [], [:], [$2])
 548   else
 549     m4_if([$3], [], [:], [$3])
 550   fi
 551 ])
 552
 553 dnl OVS_CHECK_WERROR
 554 dnl
 555 dnl Check whether the C compiler accepts -Werror.
 556 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 557 AC_DEFUN([OVS_CHECK_WERROR],
 558   [WERROR=
 559    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 560
 561 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 562 dnl Check whether the given C compiler OPTION is accepted.
 563 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 564 AC_DEFUN([OVS_CHECK_CC_OPTION],
 565   [AC_REQUIRE([OVS_CHECK_WERROR])
 566    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 567
 568 dnl OVS_ENABLE_OPTION([OPTION])
 569 dnl Check whether the given C compiler OPTION is accepted.
 570 dnl If so, add it to WARNING_FLAGS.
 571 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 572 AC_DEFUN([OVS_ENABLE_OPTION],
 573   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 574    AC_SUBST([WARNING_FLAGS])])
 575
 576 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 577 dnl Check whether the given C compiler OPTION is accepted.
 578 dnl If so, enable the given Automake CONDITIONAL.
 579
 580 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 581 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 582   [OVS_CHECK_CC_OPTION(
 583     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 584    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 585 dnl ----------------------------------------------------------------------
 586
 587 dnl Check for too-old XenServer.
 588 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 589   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 590     [if test -e /etc/redhat-release; then
 591        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 592      fi
 593      if test -z "$ovs_cv_xsversion"; then
 594        ovs_cv_xsversion=none
 595      fi])
 596   case $ovs_cv_xsversion in
 597     none)
 598       ;;
 599
 600     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 601     [[6-9]]* |                           dnl XenServer 6 or later
 602     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 603     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 604     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 605     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 606       ;;
 607
 608     *)
 609       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 610       ;;
 611   esac])
 612
 613 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 614 dnl
 615 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 616 dnl Runs 'if-true' if so, 'if-false' otherwise.
 617 AC_DEFUN([OVS_CHECK_MAKE_IF],
 618   [AC_CACHE_CHECK(
 619      [whether ${MAKE-make} has GNU make \$(if) extension],
 620      [ovs_cv_gnu_make_if],
 621      [cat <<'EOF' > conftest.mk
 622 conftest.out:
 623         echo $(if x,y,z) > conftest.out
 624 .PHONY: all
 625 EOF
 626       rm -f conftest.out
 627       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 628       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 629       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 630       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 631       result=`cat conftest.out`
 632       rm -f conftest.mk conftest.out
 633       if test "X$result" = "Xy"; then
 634         ovs_cv_gnu_make_if=yes
 635       else
 636         ovs_cv_gnu_make_if=no
 637       fi])])
 638
 639 dnl OVS_CHECK_GNU_MAKE
 640 dnl
 641 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 642 dnl only work with GNU make).
 643 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 644   [AC_CACHE_CHECK(
 645      [whether ${MAKE-make} is GNU make],
 646      [ovs_cv_gnu_make],
 647      [rm -f conftest.out
 648       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 649       ${MAKE-make} --version >conftest.out 2>&1
 650       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 651       result=`cat conftest.out`
 652       rm -f conftest.mk conftest.out
 653
 654       case $result in # (
 655         GNU*) ovs_cv_gnu_make=yes ;; # (
 656         *) ovs_cv_gnu_make=no ;;
 657       esac])
 658    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 659
 660 dnl OVS_CHECK_SPARSE_TARGET
 661 dnl
 662 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 663 dnl target for which the code is being built.  This helps it out.
 664 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 665   [AC_CACHE_CHECK(
 666     [target hint for cgcc],
 667     [ac_cv_sparse_target],
 668     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 669        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 670        [x86_64-*], [ac_cv_sparse_target=x86_64],
 671        [ac_cv_sparse_target=other])])
 672    AS_CASE([$ac_cv_sparse_target],
 673      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 674      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 675      [SPARSEFLAGS= CGCCFLAGS=])
 676    AC_SUBST([SPARSEFLAGS])
 677    AC_SUBST([CGCCFLAGS])])
 678
 679 dnl OVS_SPARSE_EXTRA_INCLUDES
 680 dnl
 681 dnl The cgcc script from "sparse" does not search gcc's default
 682 dnl search path. Get the default search path from GCC and pass
 683 dnl them to sparse.
 684 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 685     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 686            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 687
 688 dnl OVS_ENABLE_SPARSE
 689 AC_DEFUN([OVS_ENABLE_SPARSE],
 690   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 691    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 692    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 693    : ${SPARSE=sparse}
 694    AC_SUBST([SPARSE])
 695    AC_CONFIG_COMMANDS_PRE(
 696      [if test $ovs_cv_gnu_make_if = yes; then
 697         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 698       fi])])
 699
 700 dnl OVS_PTHREAD_SET_NAME
 701 dnl
 702 dnl This checks for three known variants of pthreads functions for setting
 703 dnl the name of the current thread:
 704 dnl
 705 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 706 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 707 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 708 dnl
 709 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 710 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 711 dnl provide to it.
 712 dnl
 713 dnl This macro defines:
 714 dnl
 715 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 716 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 717 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 718 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 719   [AC_CHECK_FUNCS([pthread_set_name_np])
 720    if test $ac_cv_func_pthread_set_name_np != yes; then
 721      AC_CACHE_CHECK(
 722        [for pthread_setname_np() variant],
 723        [ovs_cv_pthread_setname_np],
 724        [AC_LINK_IFELSE(
 725          [AC_LANG_PROGRAM([#include <pthread.h>
 726   ], [pthread_setname_np(pthread_self(), "name");])],
 727          [ovs_cv_pthread_setname_np=glibc],
 728          [AC_LINK_IFELSE(
 729            [AC_LANG_PROGRAM([#include <pthread.h>
 730 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 731            [ovs_cv_pthread_setname_np=netbsd],
 732            [ovs_cv_pthread_setname_np=none])])])
 733      case $ovs_cv_pthread_setname_np in # (
 734        glibc)
 735           AC_DEFINE(
 736             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 737             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 738           ;; # (
 739        netbsd)
 740           AC_DEFINE(
 741             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 742             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 743           ;;
 744      esac
 745    fi])
 746
 747 dnl OVS_CHECK_LINUX_HOST.
 748 dnl
 749 dnl Checks whether we're building for a Linux host, based on the presence of
 750 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 751 dnl LINUX based on the result.
 752 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 753   [AC_CACHE_CHECK(
 754      [whether __linux__ is defined],
 755      [ovs_cv_linux],
 756      [AC_COMPILE_IFELSE(
 757         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 758         [ovs_cv_linux=true],
 759         [ovs_cv_linux=false])])
 760    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])