acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        if test "$version" = 3 && test "$patchlevel" -le 17; then
 138           : # Linux 3.x
 139        else
 140          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 3.17.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     else
 143        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 144          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 145        else
 146          : # Linux 2.6.x
 147        fi
 148     fi
 149     if (test ! -e "$KBUILD"/include/linux/version.h && \
 150         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 151        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 152         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 153         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 154     fi
 155     OVS_CHECK_LINUX_COMPAT
 156   fi
 157   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 158 ])
 159
 160 dnl OVS_CHECK_DPDK
 161 dnl
 162 dnl Configure DPDK source tree
 163 AC_DEFUN([OVS_CHECK_DPDK], [
 164   AC_ARG_WITH([dpdk],
 165               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 166                               [Specify the DPDK build directory])])
 167
 168   if test X"$with_dpdk" != X; then
 169     RTE_SDK=$with_dpdk
 170
 171     DPDK_INCLUDE=$RTE_SDK/include
 172     DPDK_LIB_DIR=$RTE_SDK/lib
 173     DPDK_LIB=-lintel_dpdk
 174
 175     ovs_save_CFLAGS="$CFLAGS"
 176     ovs_save_LDFLAGS="$LDFLAGS"
 177     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
 178     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 179
 180     # On some systems we have to add -ldl to link with dpdk
 181     #
 182     # This code, at first, tries to link without -ldl (""),
 183     # then adds it and tries again.
 184     # Before each attempt the search cache must be unset,
 185     # otherwise autoconf will stick with the old result
 186
 187     found=false
 188     save_LIBS=$LIBS
 189     for extras in "" "-ldl"; do
 190         LIBS="$DPDK_LIB $extras $save_LIBS"
 191         AC_LINK_IFELSE(
 192            [AC_LANG_PROGRAM([#include <rte_config.h>
 193                              #include <rte_eal.h>],
 194                             [int rte_argc; char ** rte_argv;
 195                              rte_eal_init(rte_argc, rte_argv);])],
 196            [found=true])
 197         if $found; then
 198             break
 199         fi
 200     done
 201     if $found; then :; else
 202         AC_MSG_ERROR([cannot link with dpdk])
 203     fi
 204     CFLAGS="$ovs_save_CFLAGS"
 205     LDFLAGS="$ovs_save_LDFLAGS"
 206     OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 207     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE"
 208
 209     # DPDK 1.7 pmd drivers are not linked unless --whole-archive is used.
 210     #
 211     # This happens because the rest of the DPDK code doesn't use any symbol in
 212     # the pmd driver objects, and the drivers register themselves using an
 213     # __attribute__((constructor)) function.
 214     #
 215     # These options are specified inside a single -Wl directive to prevent
 216     # autotools from reordering them.
 217     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 218     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 219     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 220   else
 221     RTE_SDK=
 222   fi
 223
 224   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 225 ])
 226
 227 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 228 dnl
 229 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 230 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 231 dnl <REGEX> translated to uppercase.
 232 AC_DEFUN([OVS_GREP_IFELSE], [
 233   AC_MSG_CHECKING([whether $2 matches in $1])
 234   if test -f $1; then
 235     grep '$2' $1 >/dev/null 2>&1
 236     status=$?
 237     case $status in
 238       0)
 239         AC_MSG_RESULT([yes])
 240         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 241         ;;
 242       1)
 243         AC_MSG_RESULT([no])
 244         $4
 245         ;;
 246       *)
 247         AC_MSG_ERROR([grep exited with status $status])
 248         ;;
 249     esac
 250   else
 251     AC_MSG_RESULT([file not found])
 252     $4
 253   fi
 254 ])
 255
 256 dnl OVS_DEFINE(NAME)
 257 dnl
 258 dnl Defines NAME to 1 in kcompat.h.
 259 AC_DEFUN([OVS_DEFINE], [
 260   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 261 ])
 262
 263 AC_DEFUN([OVS_CHECK_LOG2_H], [
 264   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 265   if test -e $KSRC/include/linux/log2.h; then
 266     AC_MSG_RESULT([yes])
 267     OVS_DEFINE([HAVE_LOG2_H])
 268   else
 269     AC_MSG_RESULT([no])
 270   fi
 271 ])
 272
 273 dnl OVS_CHECK_LINUX_COMPAT
 274 dnl
 275 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 276 dnl the directory in $KBUILD.
 277 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 278   rm -f datapath/linux/kcompat.h.new
 279   mkdir -p datapath/linux
 280   : > datapath/linux/kcompat.h.new
 281
 282   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 283                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 284
 285   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 286   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 287   OVS_GREP_IFELSE([$KSRC/include/linux/hash.h], [fast_hash_ops])
 288
 289   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 290   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 291
 292   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 293
 294   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 295   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 296                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 297
 298   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 299   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 300   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 301   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 302   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 303   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 304   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 305
 306   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 307
 308   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 309                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 310                                    [rcu_read_lock_held])])
 311   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 312
 313   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 314   # is necessary because some versions of this header remove the
 315   # member but retain the kerneldoc comment that describes it (which
 316   # starts with @).  The brackets must be doubled because of m4
 317   # quoting rules.
 318   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 319                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 320   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 321   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 322                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 323   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 324                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 325   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 326                   [skb_copy_from_linear_data_offset])
 327   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 328                   [skb_reset_tail_pointer])
 329   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 330   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 331                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 332   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 333                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 334   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 335                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 336   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 337   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 338   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 339   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 340   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 341   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 342   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 343   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 344   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 345   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 346                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 347   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [l4_rxhash])
 348
 349   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 350                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 351   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 352                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 353   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 354                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 355
 356   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 357   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 358
 359   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 360   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 361   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 362   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 363   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 364   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 365   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [iptunnel_xmit.*net],
 366                   [OVS_DEFINE([HAVE_IPTUNNEL_XMIT_NET])])
 367   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 368   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 369   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 370   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 371   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 372   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 373
 374   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 375
 376   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 377                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 378
 379   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 380
 381   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 382                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 383   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_xmit_skb])
 384   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [bool xnet],
 385                   [OVS_DEFINE([HAVE_VXLAN_XMIT_SKB_XNET_ARG])])
 386   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 387                   [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])
 388   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df:1],
 389                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 390   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 391                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 392
 393   OVS_CHECK_LOG2_H
 394
 395   if cmp -s datapath/linux/kcompat.h.new \
 396             datapath/linux/kcompat.h >/dev/null 2>&1; then
 397     rm datapath/linux/kcompat.h.new
 398   else
 399     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 400   fi
 401 ])
 402
 403 dnl Checks for net/if_packet.h.
 404 AC_DEFUN([OVS_CHECK_IF_PACKET],
 405   [AC_CHECK_HEADER([net/if_packet.h],
 406                    [HAVE_IF_PACKET=yes],
 407                    [HAVE_IF_PACKET=no])
 408    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 409    if test "$HAVE_IF_PACKET" = yes; then
 410       AC_DEFINE([HAVE_IF_PACKET], [1],
 411                 [Define to 1 if net/if_packet.h is available.])
 412    fi])
 413
 414 dnl Checks for net/if_dl.h.
 415 dnl
 416 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 417 dnl or NetBSD.)
 418 AC_DEFUN([OVS_CHECK_IF_DL],
 419   [AC_CHECK_HEADER([net/if_dl.h],
 420                    [HAVE_IF_DL=yes],
 421                    [HAVE_IF_DL=no])
 422    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 423    if test "$HAVE_IF_DL" = yes; then
 424       AC_DEFINE([HAVE_IF_DL], [1],
 425                 [Define to 1 if net/if_dl.h is available.])
 426
 427       # On these platforms we use libpcap to access network devices.
 428       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 429    fi])
 430
 431 dnl Checks for buggy strtok_r.
 432 dnl
 433 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 434 dnl with optimization that can cause segfaults:
 435 dnl
 436 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 437 AC_DEFUN([OVS_CHECK_STRTOK_R],
 438   [AC_CACHE_CHECK(
 439      [whether strtok_r macro segfaults on some inputs],
 440      [ovs_cv_strtok_r_bug],
 441      [AC_RUN_IFELSE(
 442         [AC_LANG_PROGRAM([#include <stdio.h>
 443                           #include <string.h>
 444                          ],
 445                          [[char string[] = ":::";
 446                            char *save_ptr = (char *) 0xc0ffee;
 447                            char *token1, *token2;
 448                            token1 = strtok_r(string, ":", &save_ptr);
 449                            token2 = strtok_r(NULL, ":", &save_ptr);
 450                            freopen ("/dev/null", "w", stdout);
 451                            printf ("%s %s\n", token1, token2);
 452                            return 0;
 453                           ]])],
 454         [ovs_cv_strtok_r_bug=no],
 455         [ovs_cv_strtok_r_bug=yes],
 456         [ovs_cv_strtok_r_bug=yes])])
 457    if test $ovs_cv_strtok_r_bug = yes; then
 458      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 459                [Define if strtok_r macro segfaults on some inputs])
 460    fi
 461 ])
 462
 463 dnl ----------------------------------------------------------------------
 464 dnl These macros are from GNU PSPP, with the following original license:
 465 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 466 dnl This file is free software; the Free Software Foundation
 467 dnl gives unlimited permission to copy and/or distribute it,
 468 dnl with or without modifications, as long as this notice is preserved.
 469
 470 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 471   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 472   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 473     [ovs_save_CFLAGS="$CFLAGS"
 474      dnl Include -Werror in the compiler options, because without -Werror
 475      dnl clang's GCC-compatible compiler driver does not return a failure
 476      dnl exit status even though it complains about options it does not
 477      dnl understand.
 478      CFLAGS="$CFLAGS $WERROR $1"
 479      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 480      CFLAGS="$ovs_save_CFLAGS"])
 481   if test $ovs_cv_name = yes; then
 482     m4_if([$2], [], [:], [$2])
 483   else
 484     m4_if([$3], [], [:], [$3])
 485   fi
 486 ])
 487
 488 dnl OVS_CHECK_WERROR
 489 dnl
 490 dnl Check whether the C compiler accepts -Werror.
 491 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 492 AC_DEFUN([OVS_CHECK_WERROR],
 493   [WERROR=
 494    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 495
 496 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 497 dnl Check whether the given C compiler OPTION is accepted.
 498 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 499 AC_DEFUN([OVS_CHECK_CC_OPTION],
 500   [AC_REQUIRE([OVS_CHECK_WERROR])
 501    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 502
 503 dnl OVS_ENABLE_OPTION([OPTION])
 504 dnl Check whether the given C compiler OPTION is accepted.
 505 dnl If so, add it to WARNING_FLAGS.
 506 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 507 AC_DEFUN([OVS_ENABLE_OPTION],
 508   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 509    AC_SUBST([WARNING_FLAGS])])
 510
 511 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 512 dnl Check whether the given C compiler OPTION is accepted.
 513 dnl If so, enable the given Automake CONDITIONAL.
 514
 515 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 516 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 517   [OVS_CHECK_CC_OPTION(
 518     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 519    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 520 dnl ----------------------------------------------------------------------
 521
 522 dnl Check for too-old XenServer.
 523 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 524   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 525     [if test -e /etc/redhat-release; then
 526        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 527      fi
 528      if test -z "$ovs_cv_xsversion"; then
 529        ovs_cv_xsversion=none
 530      fi])
 531   case $ovs_cv_xsversion in
 532     none)
 533       ;;
 534
 535     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 536     [[6-9]]* |                           dnl XenServer 6 or later
 537     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 538     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 539     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 540     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 541       ;;
 542
 543     *)
 544       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 545       ;;
 546   esac])
 547
 548 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 549 dnl
 550 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 551 dnl Runs 'if-true' if so, 'if-false' otherwise.
 552 AC_DEFUN([OVS_CHECK_MAKE_IF],
 553   [AC_CACHE_CHECK(
 554      [whether ${MAKE-make} has GNU make \$(if) extension],
 555      [ovs_cv_gnu_make_if],
 556      [cat <<'EOF' > conftest.mk
 557 conftest.out:
 558         echo $(if x,y,z) > conftest.out
 559 .PHONY: all
 560 EOF
 561       rm -f conftest.out
 562       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 563       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 564       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 565       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 566       result=`cat conftest.out`
 567       rm -f conftest.mk conftest.out
 568       if test "X$result" = "Xy"; then
 569         ovs_cv_gnu_make_if=yes
 570       else
 571         ovs_cv_gnu_make_if=no
 572       fi])])
 573
 574 dnl OVS_CHECK_GNU_MAKE
 575 dnl
 576 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 577 dnl only work with GNU make).
 578 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 579   [AC_CACHE_CHECK(
 580      [whether ${MAKE-make} is GNU make],
 581      [ovs_cv_gnu_make],
 582      [rm -f conftest.out
 583       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 584       ${MAKE-make} --version >conftest.out 2>&1
 585       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 586       result=`cat conftest.out`
 587       rm -f conftest.mk conftest.out
 588
 589       case $result in # (
 590         GNU*) ovs_cv_gnu_make=yes ;; # (
 591         *) ovs_cv_gnu_make=no ;;
 592       esac])
 593    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 594
 595 dnl OVS_CHECK_SPARSE_TARGET
 596 dnl
 597 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 598 dnl target for which the code is being built.  This helps it out.
 599 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 600   [AC_CACHE_CHECK(
 601     [target hint for cgcc],
 602     [ac_cv_sparse_target],
 603     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 604        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 605        [x86_64-*], [ac_cv_sparse_target=x86_64],
 606        [ac_cv_sparse_target=other])])
 607    AS_CASE([$ac_cv_sparse_target],
 608      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 609      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 610      [SPARSEFLAGS= CGCCFLAGS=])
 611    AC_SUBST([SPARSEFLAGS])
 612    AC_SUBST([CGCCFLAGS])])
 613
 614 dnl OVS_SPARSE_EXTRA_INCLUDES
 615 dnl
 616 dnl The cgcc script from "sparse" does not search gcc's default
 617 dnl search path. Get the default search path from GCC and pass
 618 dnl them to sparse.
 619 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 620     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 621            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 622
 623 dnl OVS_ENABLE_SPARSE
 624 AC_DEFUN([OVS_ENABLE_SPARSE],
 625   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 626    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 627    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 628    : ${SPARSE=sparse}
 629    AC_SUBST([SPARSE])
 630    AC_CONFIG_COMMANDS_PRE(
 631      [if test $ovs_cv_gnu_make_if = yes; then
 632         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 633       fi])])
 634
 635 dnl OVS_PTHREAD_SET_NAME
 636 dnl
 637 dnl This checks for three known variants of pthreads functions for setting
 638 dnl the name of the current thread:
 639 dnl
 640 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 641 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 642 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 643 dnl
 644 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 645 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 646 dnl provide to it.
 647 dnl
 648 dnl This macro defines:
 649 dnl
 650 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 651 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 652 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 653 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 654   [AC_CHECK_FUNCS([pthread_set_name_np])
 655    if test $ac_cv_func_pthread_set_name_np != yes; then
 656      AC_CACHE_CHECK(
 657        [for pthread_setname_np() variant],
 658        [ovs_cv_pthread_setname_np],
 659        [AC_LINK_IFELSE(
 660          [AC_LANG_PROGRAM([#include <pthread.h>
 661   ], [pthread_setname_np(pthread_self(), "name");])],
 662          [ovs_cv_pthread_setname_np=glibc],
 663          [AC_LINK_IFELSE(
 664            [AC_LANG_PROGRAM([#include <pthread.h>
 665 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 666            [ovs_cv_pthread_setname_np=netbsd],
 667            [ovs_cv_pthread_setname_np=none])])])
 668      case $ovs_cv_pthread_setname_np in # (
 669        glibc)
 670           AC_DEFINE(
 671             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 672             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 673           ;; # (
 674        netbsd)
 675           AC_DEFINE(
 676             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 677             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 678           ;;
 679      esac
 680    fi])
 681
 682 dnl OVS_CHECK_LINUX_HOST.
 683 dnl
 684 dnl Checks whether we're building for a Linux host, based on the presence of
 685 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 686 dnl LINUX based on the result.
 687 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 688   [AC_CACHE_CHECK(
 689      [whether __linux__ is defined],
 690      [ovs_cv_linux],
 691      [AC_COMPILE_IFELSE(
 692         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 693         [ovs_cv_linux=true],
 694         [ovs_cv_linux=false])])
 695    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])