acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 4; then
 137        if test "$version" = 4 && test "$patchlevel" -le 6; then
 138           : # Linux 4.x
 139        else
 140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.6.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 143        : # Linux 3.x
 144     else
 145        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 146     fi
 147     if (test ! -e "$KBUILD"/include/linux/version.h && \
 148         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 149        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 150         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 151         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 152     fi
 153     OVS_CHECK_LINUX_COMPAT
 154   fi
 155   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 156 ])
 157
 158 dnl OVS_CHECK_DPDK
 159 dnl
 160 dnl Configure DPDK source tree
 161 AC_DEFUN([OVS_CHECK_DPDK], [
 162   AC_ARG_WITH([dpdk],
 163               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 164                               [Specify the DPDK build directory])],
 165               [have_dpdk=true])
 166
 167   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 168   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 169     AC_MSG_RESULT([no])
 170     DPDKLIB_FOUND=false
 171   else
 172     AC_MSG_RESULT([yes])
 173     case "$with_dpdk" in
 174       yes)
 175         DPDK_AUTO_DISCOVER="true"
 176         DPDK_INCLUDE="/usr/local/include/dpdk -I/usr/include/dpdk"
 177         ;;
 178       *)
 179         DPDK_AUTO_DISCOVER="false"
 180         DPDK_INCLUDE="$with_dpdk/include"
 181         # If 'with_dpdk' is passed install directory, point to headers
 182         # installed in $DESTDIR/$prefix/include/dpdk
 183         AC_CHECK_FILE([$DPDK_INCLUDE/rte_config.h], [],
 184                       [AC_CHECK_FILE([$DPDK_INCLUDE/dpdk/rte_config.h],
 185                                      [DPDK_INCLUDE=$DPDK_INCLUDE/dpdk], [])])
 186         DPDK_LIB_DIR="$with_dpdk/lib"
 187         ;;
 188     esac
 189
 190     DPDK_LIB="-ldpdk"
 191     DPDK_EXTRA_LIB=""
 192
 193     ovs_save_CFLAGS="$CFLAGS"
 194     ovs_save_LDFLAGS="$LDFLAGS"
 195     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 196     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 197       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 198     fi
 199
 200     AC_COMPILE_IFELSE([
 201       AC_LANG_PROGRAM(
 202         [
 203           #include <rte_config.h>
 204 #if RTE_LIBRTE_VHOST_NUMA
 205 #error
 206 #endif
 207         ], [])
 208       ], [],
 209       [AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])])
 210        DPDK_EXTRA_LIB="-lnuma"])
 211
 212     AC_COMPILE_IFELSE([
 213       AC_LANG_PROGRAM(
 214         [
 215           #include <rte_config.h>
 216 #if RTE_LIBRTE_PMD_PCAP
 217 #error
 218 #endif
 219         ], [])
 220       ], [],
 221       [AC_SEARCH_LIBS([pcap_dump],[pcap],[],[AC_MSG_ERROR([unable to find libpcap, install the dependency package])])
 222        DPDK_EXTRA_LIB="-lpcap"
 223        AC_COMPILE_IFELSE([
 224          AC_LANG_PROGRAM(
 225            [
 226              #include <rte_config.h>
 227 #if RTE_LIBRTE_PDUMP
 228 #error
 229 #endif
 230          ], [])
 231        ], [],
 232        [AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])])
 233      ])
 234
 235     # On some systems we have to add -ldl to link with dpdk
 236     #
 237     # This code, at first, tries to link without -ldl (""),
 238     # then adds it and tries again.
 239     # Before each attempt the search cache must be unset,
 240     # otherwise autoconf will stick with the old result
 241
 242     DPDKLIB_FOUND=false
 243     save_LIBS=$LIBS
 244     for extras in "" "-ldl"; do
 245         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 246         AC_LINK_IFELSE(
 247            [AC_LANG_PROGRAM([#include <rte_config.h>
 248                              #include <rte_eal.h>],
 249                             [int rte_argc; char ** rte_argv;
 250                              rte_eal_init(rte_argc, rte_argv);])],
 251            [DPDKLIB_FOUND=true])
 252         if $DPDKLIB_FOUND; then
 253             break
 254         fi
 255     done
 256
 257     # If linking unsuccessful
 258     if test "$DPDKLIB_FOUND" = "false" ; then
 259       if $DPDK_AUTO_DISCOVER; then
 260         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 261       else
 262         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 263       fi
 264     fi
 265     CFLAGS="$ovs_save_CFLAGS"
 266     LDFLAGS="$ovs_save_LDFLAGS"
 267     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 268       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 269     fi
 270     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE"
 271     OVS_ENABLE_OPTION([-mssse3])
 272
 273     # DPDK pmd drivers are not linked unless --whole-archive is used.
 274     #
 275     # This happens because the rest of the DPDK code doesn't use any symbol in
 276     # the pmd driver objects, and the drivers register themselves using an
 277     # __attribute__((constructor)) function.
 278     #
 279     # These options are specified inside a single -Wl directive to prevent
 280     # autotools from reordering them.
 281     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 282     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 283     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 284   fi
 285
 286   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 287 ])
 288
 289 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 290 dnl
 291 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 292 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 293 dnl <REGEX> translated to uppercase.
 294 AC_DEFUN([OVS_GREP_IFELSE], [
 295   AC_MSG_CHECKING([whether $2 matches in $1])
 296   if test -f $1; then
 297     grep '$2' $1 >/dev/null 2>&1
 298     status=$?
 299     case $status in
 300       0)
 301         AC_MSG_RESULT([yes])
 302         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 303         ;;
 304       1)
 305         AC_MSG_RESULT([no])
 306         $4
 307         ;;
 308       *)
 309         AC_MSG_ERROR([grep exited with status $status])
 310         ;;
 311     esac
 312   else
 313     AC_MSG_RESULT([file not found])
 314     $4
 315   fi
 316 ])
 317
 318 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 319 dnl
 320 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 321 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 322 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 323 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 324 dnl translated to uppercase.
 325 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 326   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 327   if test -f $1; then
 328     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 329     status=$?
 330     case $status in
 331       0)
 332         AC_MSG_RESULT([yes])
 333         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 334         ;;
 335       1)
 336         AC_MSG_RESULT([no])
 337         $5
 338         ;;
 339       *)
 340         AC_MSG_ERROR([grep exited with status $status])
 341         ;;
 342     esac
 343   else
 344     AC_MSG_RESULT([file not found])
 345     $5
 346   fi
 347 ])
 348
 349 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 350 dnl
 351 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 352 dnl the function signature starting from the line matching FUNCTION
 353 dnl and ending with the line containing the closing parenthesis.  If
 354 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 355 dnl IF-MATCH is empty then it defines to
 356 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 357 dnl <REGEX> translated to uppercase.
 358 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 359   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 360   if test -f $1; then
 361     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 362     status=$?
 363     case $status in
 364       0)
 365         AC_MSG_RESULT([yes])
 366         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 367         ;;
 368       1)
 369         AC_MSG_RESULT([no])
 370         $5
 371         ;;
 372       *)
 373         AC_MSG_ERROR([grep exited with status $status])
 374         ;;
 375     esac
 376   else
 377     AC_MSG_RESULT([file not found])
 378     $5
 379   fi
 380 ])
 381
 382 dnl OVS_DEFINE(NAME)
 383 dnl
 384 dnl Defines NAME to 1 in kcompat.h.
 385 AC_DEFUN([OVS_DEFINE], [
 386   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 387 ])
 388
 389 dnl OVS_CHECK_LINUX_COMPAT
 390 dnl
 391 dnl Runs various Autoconf checks on the Linux kernel source in
 392 dnl the directory in $KBUILD.
 393 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 394   rm -f datapath/linux/kcompat.h.new
 395   mkdir -p datapath/linux
 396   : > datapath/linux/kcompat.h.new
 397
 398   echo '#include <linux/version.h>
 399 #ifndef RHEL_RELEASE_CODE
 400 #define RHEL_RELEASE_CODE 0
 401 #define RHEL_RELEASE_VERSION(a, b) 0
 402 #endif' >> datapath/linux/kcompat.h.new
 403
 404   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 405                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 406
 407   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 408                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 409   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 410
 411   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 412   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 413   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 414
 415   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 416   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 417
 418   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 419   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 420   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 421   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 422   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 423
 424   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 425   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 426   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 427                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 428   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 429                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 430
 431   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 432                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 433   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 434                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 435   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 436                         [ip_do_fragment], [net],
 437                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 438   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 439                         [ip_local_out], [net],
 440                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 441
 442   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 443
 444   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 445                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 446   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 447   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 448                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 449   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 450                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 451   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 452   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 453   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 454                         [frags_work])
 455   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 456                         [rwlock])
 457   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 458                         [list_evictor])
 459   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 460   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 461                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 462
 463   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 464   dnl OVS does not really need ipv6 label field, but its presence signifies that
 465   dnl the stack has all required ipv6 support.
 466   dnl OVS also does not need dst_cache But this dependency allows us to write
 467   dnl much cleaner code.
 468
 469   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 470                         [label],
 471                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 472                                          [iptunnel_pull_offloads],
 473                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 474                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])
 475
 476   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 477                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 478   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 479   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 480   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 481   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 482   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 483   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 484   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 485   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 486   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 487                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 488   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 489   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 490   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 491   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 492   dnl So check type of tstats.
 493   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 494                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 495   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 496                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 497   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 498   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 499                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 500   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 501   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 502   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 503                         [netdev_master_upper_dev_link], [upper_priv],
 504                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 505
 506   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 507   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 508   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 509                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 510   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 511                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 512   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 513                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 514
 515   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 516                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 517
 518   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 519                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 520                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 521   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 522                   [nf_ct_get_tuplepr], [struct.net],
 523                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 524   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 525                   [nf_ct_zone_init])
 526   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 527                   [nf_connlabels_get])
 528   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 529                   [nf_connlabels_get], [int bit],
 530                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 531   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 532                   [nf_ct_frag6_consume_orig])
 533   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 534                   [nf_ct_frag6_output])
 535   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 536   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 537   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 538
 539   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 540   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 541
 542   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 543   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 544   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 545                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 546   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 547
 548   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 549                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 550                                    [rcu_read_lock_held])])
 551   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 552
 553   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 554   # is necessary because some versions of this header remove the
 555   # member but retain the kerneldoc comment that describes it (which
 556   # starts with @).  The brackets must be doubled because of m4
 557   # quoting rules.
 558   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 559                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 560   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 561   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 562   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 563   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 564   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 565   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 566   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 567                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 568   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 569                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 570   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 571                   [skb_copy_from_linear_data_offset])
 572   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 573                   [skb_reset_tail_pointer])
 574   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 575   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 576                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 577   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 578   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 579   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 580   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 581   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 582   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 583   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 584   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 585                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 586   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 587   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 588                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 589   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 590                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 591   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 592   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 593   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 594   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 595   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 596
 597   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 598                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 599   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 600                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 601   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 602                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 603
 604   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 605   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 606
 607   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 608   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 609
 610   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 611   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 612   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 613   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 614                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 615   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 616   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 617                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 618   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 619                         [genl_notify], [net],
 620                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 621
 622
 623   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 624                         [genl_multicast_group], [id])
 625   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 626
 627   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 628   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 629   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 630   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 631   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 632   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 633                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 634   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 635                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 636
 637   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 638   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 639   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 640   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 641   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 642   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 643   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 644   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 645   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 646                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 647
 648   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 649
 650   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 651                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 652   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 653   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 654   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 655
 656   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 657
 658   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 659                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 660   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 661                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 662                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 663   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 664   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 665   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 666                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 667   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 668                         [gro_receive])
 669
 670   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 671                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 672   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 673                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 674
 675   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 676   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 677   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 678                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 679   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 680                         [udp_add_offload], [net],
 681                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 682
 683
 684   if cmp -s datapath/linux/kcompat.h.new \
 685             datapath/linux/kcompat.h >/dev/null 2>&1; then
 686     rm datapath/linux/kcompat.h.new
 687   else
 688     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 689   fi
 690 ])
 691
 692 dnl Checks for net/if_packet.h.
 693 AC_DEFUN([OVS_CHECK_IF_PACKET],
 694   [AC_CHECK_HEADER([net/if_packet.h],
 695                    [HAVE_IF_PACKET=yes],
 696                    [HAVE_IF_PACKET=no])
 697    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 698    if test "$HAVE_IF_PACKET" = yes; then
 699       AC_DEFINE([HAVE_IF_PACKET], [1],
 700                 [Define to 1 if net/if_packet.h is available.])
 701    fi])
 702
 703 dnl Checks for net/if_dl.h.
 704 dnl
 705 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 706 dnl or NetBSD.)
 707 AC_DEFUN([OVS_CHECK_IF_DL],
 708   [AC_CHECK_HEADER([net/if_dl.h],
 709                    [HAVE_IF_DL=yes],
 710                    [HAVE_IF_DL=no])
 711    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 712    if test "$HAVE_IF_DL" = yes; then
 713       AC_DEFINE([HAVE_IF_DL], [1],
 714                 [Define to 1 if net/if_dl.h is available.])
 715
 716       # On these platforms we use libpcap to access network devices.
 717       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 718    fi])
 719
 720 dnl Checks for buggy strtok_r.
 721 dnl
 722 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 723 dnl with optimization that can cause segfaults:
 724 dnl
 725 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 726 AC_DEFUN([OVS_CHECK_STRTOK_R],
 727   [AC_CACHE_CHECK(
 728      [whether strtok_r macro segfaults on some inputs],
 729      [ovs_cv_strtok_r_bug],
 730      [AC_RUN_IFELSE(
 731         [AC_LANG_PROGRAM([#include <stdio.h>
 732                           #include <string.h>
 733                          ],
 734                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 735                            /* Assume bug is present, because relatively minor
 736                               changes in compiler settings (e.g. optimization
 737                               level) can make it crop up. */
 738                            return 1;
 739                            #else
 740                            char string[] = ":::";
 741                            char *save_ptr = (char *) 0xc0ffee;
 742                            char *token1, *token2;
 743                            token1 = strtok_r(string, ":", &save_ptr);
 744                            token2 = strtok_r(NULL, ":", &save_ptr);
 745                            freopen ("/dev/null", "w", stdout);
 746                            printf ("%s %s\n", token1, token2);
 747                            return 0;
 748                            #endif
 749                           ]])],
 750         [ovs_cv_strtok_r_bug=no],
 751         [ovs_cv_strtok_r_bug=yes],
 752         [ovs_cv_strtok_r_bug=yes])])
 753    if test $ovs_cv_strtok_r_bug = yes; then
 754      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 755                [Define if strtok_r macro segfaults on some inputs])
 756    fi
 757 ])
 758
 759 dnl ----------------------------------------------------------------------
 760 dnl These macros are from GNU PSPP, with the following original license:
 761 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 762 dnl This file is free software; the Free Software Foundation
 763 dnl gives unlimited permission to copy and/or distribute it,
 764 dnl with or without modifications, as long as this notice is preserved.
 765
 766 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 767   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 768   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 769     [ovs_save_CFLAGS="$CFLAGS"
 770      dnl Include -Werror in the compiler options, because without -Werror
 771      dnl clang's GCC-compatible compiler driver does not return a failure
 772      dnl exit status even though it complains about options it does not
 773      dnl understand.
 774      dnl
 775      dnl Also, check stderr as gcc exits with status 0 for options
 776      dnl rejected at getopt level.
 777      dnl    % touch /tmp/a.c
 778      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 779      dnl    gcc: unrecognized option '-Qunused-arguments'
 780      dnl    0
 781      dnl    %
 782      CFLAGS="$CFLAGS $WERROR $1"
 783      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 784      CFLAGS="$ovs_save_CFLAGS"])
 785   if test $ovs_cv_name = yes; then
 786     m4_if([$2], [], [:], [$2])
 787   else
 788     m4_if([$3], [], [:], [$3])
 789   fi
 790 ])
 791
 792 dnl OVS_CHECK_WERROR
 793 dnl
 794 dnl Check whether the C compiler accepts -Werror.
 795 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 796 AC_DEFUN([OVS_CHECK_WERROR],
 797   [WERROR=
 798    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 799
 800 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 801 dnl Check whether the given C compiler OPTION is accepted.
 802 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 803 AC_DEFUN([OVS_CHECK_CC_OPTION],
 804   [AC_REQUIRE([OVS_CHECK_WERROR])
 805    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 806
 807 dnl OVS_ENABLE_OPTION([OPTION])
 808 dnl Check whether the given C compiler OPTION is accepted.
 809 dnl If so, add it to WARNING_FLAGS.
 810 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 811 AC_DEFUN([OVS_ENABLE_OPTION],
 812   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 813    AC_SUBST([WARNING_FLAGS])])
 814
 815 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 816 dnl Check whether the given C compiler OPTION is accepted.
 817 dnl If so, enable the given Automake CONDITIONAL.
 818
 819 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 820 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 821   [OVS_CHECK_CC_OPTION(
 822     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 823    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 824 dnl ----------------------------------------------------------------------
 825
 826 dnl Check for too-old XenServer.
 827 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 828   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 829     [if test -e /etc/redhat-release; then
 830        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 831      fi
 832      if test -z "$ovs_cv_xsversion"; then
 833        ovs_cv_xsversion=none
 834      fi])
 835   case $ovs_cv_xsversion in
 836     none)
 837       ;;
 838
 839     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 840     [[6-9]]* |                           dnl XenServer 6 or later
 841     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 842     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 843     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 844     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 845       ;;
 846
 847     *)
 848       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 849       ;;
 850   esac])
 851
 852 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 853 dnl
 854 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 855 dnl Runs 'if-true' if so, 'if-false' otherwise.
 856 AC_DEFUN([OVS_CHECK_MAKE_IF],
 857   [AC_CACHE_CHECK(
 858      [whether ${MAKE-make} has GNU make \$(if) extension],
 859      [ovs_cv_gnu_make_if],
 860      [cat <<'EOF' > conftest.mk
 861 conftest.out:
 862         echo $(if x,y,z) > conftest.out
 863 .PHONY: all
 864 EOF
 865       rm -f conftest.out
 866       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 867       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 868       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 869       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 870       result=`cat conftest.out`
 871       rm -f conftest.mk conftest.out
 872       if test "X$result" = "Xy"; then
 873         ovs_cv_gnu_make_if=yes
 874       else
 875         ovs_cv_gnu_make_if=no
 876       fi])])
 877
 878 dnl OVS_CHECK_GNU_MAKE
 879 dnl
 880 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 881 dnl only work with GNU make).
 882 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 883   [AC_CACHE_CHECK(
 884      [whether ${MAKE-make} is GNU make],
 885      [ovs_cv_gnu_make],
 886      [rm -f conftest.out
 887       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 888       ${MAKE-make} --version >conftest.out 2>&1
 889       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 890       result=`cat conftest.out`
 891       rm -f conftest.mk conftest.out
 892
 893       case $result in # (
 894         GNU*) ovs_cv_gnu_make=yes ;; # (
 895         *) ovs_cv_gnu_make=no ;;
 896       esac])
 897    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 898
 899 dnl OVS_CHECK_SPARSE_TARGET
 900 dnl
 901 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 902 dnl target for which the code is being built.  This helps it out.
 903 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 904   [AC_CACHE_CHECK(
 905     [target hint for cgcc],
 906     [ac_cv_sparse_target],
 907     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 908        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 909        [x86_64-*], [ac_cv_sparse_target=x86_64],
 910        [ac_cv_sparse_target=other])])
 911    AS_CASE([$ac_cv_sparse_target],
 912      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 913      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 914      [SPARSEFLAGS= CGCCFLAGS=])
 915    AC_SUBST([SPARSEFLAGS])
 916    AC_SUBST([CGCCFLAGS])])
 917
 918 dnl OVS_SPARSE_EXTRA_INCLUDES
 919 dnl
 920 dnl The cgcc script from "sparse" does not search gcc's default
 921 dnl search path. Get the default search path from GCC and pass
 922 dnl them to sparse.
 923 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 924     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 925            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 926
 927 dnl OVS_ENABLE_SPARSE
 928 AC_DEFUN([OVS_ENABLE_SPARSE],
 929   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 930    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 931    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 932    : ${SPARSE=sparse}
 933    AC_SUBST([SPARSE])
 934    AC_CONFIG_COMMANDS_PRE(
 935      [if test $ovs_cv_gnu_make_if = yes; then
 936         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 937       fi])])
 938
 939 dnl OVS_PTHREAD_SET_NAME
 940 dnl
 941 dnl This checks for three known variants of pthreads functions for setting
 942 dnl the name of the current thread:
 943 dnl
 944 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 945 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 946 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 947 dnl
 948 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 949 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 950 dnl provide to it.
 951 dnl
 952 dnl This macro defines:
 953 dnl
 954 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 955 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 956 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 957 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 958   [AC_CHECK_FUNCS([pthread_set_name_np])
 959    if test $ac_cv_func_pthread_set_name_np != yes; then
 960      AC_CACHE_CHECK(
 961        [for pthread_setname_np() variant],
 962        [ovs_cv_pthread_setname_np],
 963        [AC_LINK_IFELSE(
 964          [AC_LANG_PROGRAM([#include <pthread.h>
 965   ], [pthread_setname_np(pthread_self(), "name");])],
 966          [ovs_cv_pthread_setname_np=glibc],
 967          [AC_LINK_IFELSE(
 968            [AC_LANG_PROGRAM([#include <pthread.h>
 969 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 970            [ovs_cv_pthread_setname_np=netbsd],
 971            [ovs_cv_pthread_setname_np=none])])])
 972      case $ovs_cv_pthread_setname_np in # (
 973        glibc)
 974           AC_DEFINE(
 975             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 976             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 977           ;; # (
 978        netbsd)
 979           AC_DEFINE(
 980             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 981             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 982           ;;
 983      esac
 984    fi])
 985
 986 dnl OVS_CHECK_LINUX_HOST.
 987 dnl
 988 dnl Checks whether we're building for a Linux host, based on the presence of
 989 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 990 dnl LINUX based on the result.
 991 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 992   [AC_CACHE_CHECK(
 993      [whether __linux__ is defined],
 994      [ovs_cv_linux],
 995      [AC_COMPILE_IFELSE(
 996         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 997         [ovs_cv_linux=true],
 998         [ovs_cv_linux=false])])
 999    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])