acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011 Nicira Networks.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 102           */build)
 103             KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 104             ;; # (
 105           *)
 106             KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 107             ;;
 108         esac
 109       fi
 110       if test ! -e $KSRC/include/linux/kernel.h; then
 111         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 112       fi
 113     fi
 114     AC_MSG_RESULT([$KSRC])
 115
 116     AC_MSG_CHECKING([for kernel version])
 117     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 118     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 119     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 120     if test X"$version" = X || test X"$patchlevel" = X; then
 121        AC_ERROR([cannot determine kernel version])
 122     elif test X"$sublevel" = X; then
 123        kversion=$version.$patchlevel
 124     else
 125        kversion=$version.$patchlevel.$sublevel
 126     fi
 127     AC_MSG_RESULT([$kversion])
 128
 129     if test "$version" -ge 3; then
 130        : # Linux 3.x
 131     elif test "$version" = 2 && test "$patchlevel" -ge 6; then
 132        : # Linux 2.6.x
 133     else
 134        if test "$KBUILD" = "$KSRC"; then
 135          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6 or later is required])
 136        else
 137          AC_ERROR([Linux kernel in build tree $KBUILD (source tree $KSRC) is version $kversion, but version 2.6 or later is required])
 138        fi
 139     fi
 140     if test ! -e "$KBUILD"/include/linux/version.h || \
 141        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 142         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 143         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 144     fi
 145     OVS_CHECK_LINUX_COMPAT
 146   fi
 147   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 148 ])
 149
 150 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 151 dnl
 152 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 153 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 154 dnl <REGEX> translated to uppercase.
 155 AC_DEFUN([OVS_GREP_IFELSE], [
 156   AC_MSG_CHECKING([whether $2 matches in $1])
 157   if test -f $1; then
 158     grep '$2' $1 >/dev/null 2>&1
 159     status=$?
 160     case $status in
 161       0)
 162         AC_MSG_RESULT([yes])
 163         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 164         ;;
 165       1)
 166         AC_MSG_RESULT([no])
 167         $4
 168         ;;
 169       *)
 170         AC_MSG_ERROR([grep exited with status $status])
 171         ;;
 172     esac
 173   else
 174     AC_MSG_RESULT([file not found])
 175     $4
 176   fi
 177 ])
 178
 179 dnl OVS_DEFINE(NAME)
 180 dnl
 181 dnl Defines NAME to 1 in kcompat.h.
 182 AC_DEFUN([OVS_DEFINE], [
 183   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 184 ])
 185
 186 AC_DEFUN([OVS_CHECK_LOG2_H], [
 187   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 188   if test -e $KSRC/include/linux/log2.h; then
 189     AC_MSG_RESULT([yes])
 190     OVS_DEFINE([HAVE_LOG2_H])
 191   else
 192     AC_MSG_RESULT([no])
 193   fi
 194 ])
 195
 196 dnl OVS_CHECK_LINUX_COMPAT
 197 dnl
 198 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 199 dnl the directory in $KBUILD.
 200 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 201   rm -f datapath/linux/kcompat.h.new
 202   mkdir -p datapath/linux
 203   : > datapath/linux/kcompat.h.new
 204
 205   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 206                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 207
 208   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 209
 210   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 211
 212   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 213   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 214   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 215
 216   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 217                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 218                                    [rcu_read_lock_held])])
 219
 220   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 221   # is necessary because some versions of this header remove the
 222   # member but retain the kerneldoc comment that describes it (which
 223   # starts with @).  The brackets must be doubled because of m4
 224   # quoting rules.
 225   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 226                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 227   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [raw],
 228                   [OVS_DEFINE([HAVE_MAC_RAW])])
 229   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 230                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 231   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 232                   [skb_copy_from_linear_data_offset])
 233   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 234   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 235                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 236   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 237                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 238   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 239                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 240   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 241
 242   OVS_GREP_IFELSE([$KSRC/include/linux/string.h], [kmemdup], [],
 243                   [OVS_GREP_IFELSE([$KSRC/include/linux/slab.h], [kmemdup])])
 244
 245   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 246                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 247   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 248                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 249
 250   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 251   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 252
 253   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [NLA_NUL_STRING])
 254   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 255   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 256
 257   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 258                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 259
 260   OVS_CHECK_LOG2_H
 261
 262   if cmp -s datapath/linux/kcompat.h.new \
 263             datapath/linux/kcompat.h >/dev/null 2>&1; then
 264     rm datapath/linux/kcompat.h.new
 265   else
 266     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 267   fi
 268 ])
 269
 270 dnl Checks for net/if_packet.h.
 271 AC_DEFUN([OVS_CHECK_IF_PACKET],
 272   [AC_CHECK_HEADER([net/if_packet.h],
 273                    [HAVE_IF_PACKET=yes],
 274                    [HAVE_IF_PACKET=no])
 275    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 276    if test "$HAVE_IF_PACKET" = yes; then
 277       AC_DEFINE([HAVE_IF_PACKET], [1],
 278                 [Define to 1 if net/if_packet.h is available.])
 279    fi])
 280
 281 dnl Checks for buggy strtok_r.
 282 dnl
 283 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 284 dnl with optimization that can cause segfaults:
 285 dnl
 286 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 287 AC_DEFUN([OVS_CHECK_STRTOK_R],
 288   [AC_CACHE_CHECK(
 289      [whether strtok_r macro segfaults on some inputs],
 290      [ovs_cv_strtok_r_bug],
 291      [AC_RUN_IFELSE(
 292         [AC_LANG_PROGRAM([#include <stdio.h>
 293                           #include <string.h>
 294                          ],
 295                          [[char string[] = ":::";
 296                            char *save_ptr = (char *) 0xc0ffee;
 297                            char *token1, *token2;
 298                            token1 = strtok_r(string, ":", &save_ptr);
 299                            token2 = strtok_r(NULL, ":", &save_ptr);
 300                            freopen ("/dev/null", "w", stdout);
 301                            printf ("%s %s\n", token1, token2);
 302                            return 0;
 303                           ]])],
 304         [ovs_cv_strtok_r_bug=no],
 305         [ovs_cv_strtok_r_bug=yes],
 306         [ovs_cv_strtok_r_bug=yes])])
 307    if test $ovs_cv_strtok_r_bug = yes; then
 308      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 309                [Define if strtok_r macro segfaults on some inputs])
 310    fi
 311 ])
 312
 313 dnl ----------------------------------------------------------------------
 314 dnl These macros are from GNU PSPP, with the following original license:
 315 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 316 dnl This file is free software; the Free Software Foundation
 317 dnl gives unlimited permission to copy and/or distribute it,
 318 dnl with or without modifications, as long as this notice is preserved.
 319
 320 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 321 dnl Check whether the given C compiler OPTION is accepted.
 322 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 323 AC_DEFUN([OVS_CHECK_CC_OPTION],
 324 [
 325   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 326   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 327     [ovs_save_CFLAGS="$CFLAGS"
 328      CFLAGS="$CFLAGS $1"
 329      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 330      CFLAGS="$ovs_save_CFLAGS"])
 331   if test $ovs_cv_name = yes; then
 332     m4_if([$2], [], [:], [$2])
 333   else
 334     m4_if([$3], [], [:], [$3])
 335   fi
 336 ])
 337
 338 dnl OVS_ENABLE_OPTION([OPTION])
 339 dnl Check whether the given C compiler OPTION is accepted.
 340 dnl If so, add it to WARNING_FLAGS.
 341 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 342 AC_DEFUN([OVS_ENABLE_OPTION],
 343   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 344    AC_SUBST([WARNING_FLAGS])])
 345
 346 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 347 dnl Check whether the given C compiler OPTION is accepted.
 348 dnl If so, enable the given Automake CONDITIONAL.
 349
 350 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 351 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 352   [OVS_CHECK_CC_OPTION(
 353     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 354    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 355 dnl ----------------------------------------------------------------------
 356
 357 dnl Check for too-old XenServer.
 358 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 359   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 360     [if test -e /etc/redhat-release; then
 361        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 362      fi
 363      if test -z "$ovs_cv_xsversion"; then
 364        ovs_cv_xsversion=none
 365      fi])
 366   case $ovs_cv_xsversion in
 367     none)
 368       ;;
 369
 370     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 371     [[6-9]]* |                           dnl XenServer 6 or later
 372     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 373     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 374     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 375     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 376       ;;
 377
 378     *)
 379       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 380       ;;
 381   esac])
 382
 383 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 384 dnl
 385 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 386 dnl Runs 'if-true' if so, 'if-false' otherwise.
 387 AC_DEFUN([OVS_MAKE_HAS_IF],
 388   [AC_CACHE_CHECK(
 389      [whether ${MAKE-make} has GNU make \$(if) extension],
 390      [ovs_cv_gnu_make_if],
 391      [cat <<'EOF' > conftest.mk
 392 conftest.out:
 393         echo $(if x,y,z) > conftest.out
 394 .PHONY: all
 395 EOF
 396       rm -f conftest.out
 397       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 398       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 399       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 400       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 401       result=`cat conftest.out`
 402       rm -f conftest.mk conftest.out
 403       if test "X$result" = "Xy"; then
 404         ovs_cv_gnu_make_if=yes
 405       else
 406         ovs_cv_gnu_make_if=no
 407       fi])
 408    AS_IF([test $ovs_cv_gnu_make_if = yes], [$1], [$2])])
 409
 410 dnl OVS_CHECK_SPARSE_TARGET
 411 dnl
 412 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 413 dnl target for which the code is being built.  This helps it out.
 414 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 415   [AC_CACHE_CHECK(
 416     [target hint for cgcc],
 417     [ac_cv_sparse_target],
 418     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 419        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 420        [x86_64-*], [ac_cv_sparse_target=x86_64],
 421        [ac_cv_sparse_target=other])])
 422    AS_CASE([$ac_cv_sparse_target],
 423      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 424      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 425      [SPARSEFLAGS= CGCCFLAGS=])
 426    AC_SUBST([SPARSEFLAGS])
 427    AC_SUBST([CGCCFLAGS])])
 428
 429 dnl OVS_ENABLE_SPARSE
 430 AC_DEFUN([OVS_ENABLE_SPARSE],
 431   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 432    OVS_MAKE_HAS_IF(
 433      [AC_CONFIG_COMMANDS_PRE(
 434         [: ${SPARSE=sparse}
 435          AC_SUBST([SPARSE])
 436          CC='$(if $(C),REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS)" cgcc $(CGCCFLAGS),'"$CC"')'])])])