acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 4; then
 137        if test "$version" = 4 && test "$patchlevel" -le 3; then
 138           : # Linux 4.x
 139        else
 140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.3.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     elif test "$version" = 3; then
 143        : # Linux 3.x
 144     else
 145        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 146          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 147        else
 148          : # Linux 2.6.x
 149        fi
 150     fi
 151     if (test ! -e "$KBUILD"/include/linux/version.h && \
 152         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 153        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 154         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 155         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 156     fi
 157     OVS_CHECK_LINUX_COMPAT
 158   fi
 159   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 160 ])
 161
 162 dnl OVS_CHECK_DPDK
 163 dnl
 164 dnl Configure DPDK source tree
 165 AC_DEFUN([OVS_CHECK_DPDK], [
 166   AC_ARG_WITH([dpdk],
 167               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 168                               [Specify the DPDK build directory])])
 169
 170   if test X"$with_dpdk" != X; then
 171     RTE_SDK=$with_dpdk
 172
 173     DPDK_INCLUDE=$RTE_SDK/include
 174     DPDK_LIB_DIR=$RTE_SDK/lib
 175     DPDK_LIB="-ldpdk"
 176     DPDK_EXTRA_LIB=""
 177     RTE_SDK_FULL=`readlink -f $RTE_SDK`
 178
 179     AC_COMPILE_IFELSE(
 180       [AC_LANG_PROGRAM([#include <$RTE_SDK_FULL/include/rte_config.h>
 181 #if !RTE_LIBRTE_VHOST_USER
 182 #error
 183 #endif], [])],
 184                     [], [AC_DEFINE([VHOST_CUSE], [1], [DPDK vhost-cuse support enabled, vhost-user disabled.])
 185                          DPDK_EXTRA_LIB="-lfuse"])
 186
 187     ovs_save_CFLAGS="$CFLAGS"
 188     ovs_save_LDFLAGS="$LDFLAGS"
 189     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
 190     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 191
 192     # On some systems we have to add -ldl to link with dpdk
 193     #
 194     # This code, at first, tries to link without -ldl (""),
 195     # then adds it and tries again.
 196     # Before each attempt the search cache must be unset,
 197     # otherwise autoconf will stick with the old result
 198
 199     found=false
 200     save_LIBS=$LIBS
 201     for extras in "" "-ldl"; do
 202         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 203         AC_LINK_IFELSE(
 204            [AC_LANG_PROGRAM([#include <rte_config.h>
 205                              #include <rte_eal.h>],
 206                             [int rte_argc; char ** rte_argv;
 207                              rte_eal_init(rte_argc, rte_argv);])],
 208            [found=true])
 209         if $found; then
 210             break
 211         fi
 212     done
 213     if $found; then :; else
 214         AC_MSG_ERROR([cannot link with dpdk])
 215     fi
 216     CFLAGS="$ovs_save_CFLAGS"
 217     LDFLAGS="$ovs_save_LDFLAGS"
 218     OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 219     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE"
 220     OVS_ENABLE_OPTION([-mssse3])
 221
 222     # DPDK pmd drivers are not linked unless --whole-archive is used.
 223     #
 224     # This happens because the rest of the DPDK code doesn't use any symbol in
 225     # the pmd driver objects, and the drivers register themselves using an
 226     # __attribute__((constructor)) function.
 227     #
 228     # These options are specified inside a single -Wl directive to prevent
 229     # autotools from reordering them.
 230     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 231     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 232     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 233
 234   else
 235     RTE_SDK=
 236   fi
 237
 238   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 239 ])
 240
 241 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 242 dnl
 243 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 244 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 245 dnl <REGEX> translated to uppercase.
 246 AC_DEFUN([OVS_GREP_IFELSE], [
 247   AC_MSG_CHECKING([whether $2 matches in $1])
 248   if test -f $1; then
 249     grep '$2' $1 >/dev/null 2>&1
 250     status=$?
 251     case $status in
 252       0)
 253         AC_MSG_RESULT([yes])
 254         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 255         ;;
 256       1)
 257         AC_MSG_RESULT([no])
 258         $4
 259         ;;
 260       *)
 261         AC_MSG_ERROR([grep exited with status $status])
 262         ;;
 263     esac
 264   else
 265     AC_MSG_RESULT([file not found])
 266     $4
 267   fi
 268 ])
 269
 270 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 271 dnl
 272 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 273 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 274 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 275 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 276 dnl translated to uppercase.
 277 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 278   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 279   if test -f $1; then
 280     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 281     status=$?
 282     case $status in
 283       0)
 284         AC_MSG_RESULT([yes])
 285         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 286         ;;
 287       1)
 288         AC_MSG_RESULT([no])
 289         $5
 290         ;;
 291       *)
 292         AC_MSG_ERROR([grep exited with status $status])
 293         ;;
 294     esac
 295   else
 296     AC_MSG_RESULT([file not found])
 297     $5
 298   fi
 299 ])
 300
 301 dnl OVS_DEFINE(NAME)
 302 dnl
 303 dnl Defines NAME to 1 in kcompat.h.
 304 AC_DEFUN([OVS_DEFINE], [
 305   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 306 ])
 307
 308 dnl OVS_CHECK_LINUX_COMPAT
 309 dnl
 310 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 311 dnl the directory in $KBUILD.
 312 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 313   rm -f datapath/linux/kcompat.h.new
 314   mkdir -p datapath/linux
 315   : > datapath/linux/kcompat.h.new
 316
 317   echo '#include <linux/version.h>
 318 #ifndef RHEL_RELEASE_CODE
 319 #define RHEL_RELEASE_CODE 0
 320 #define RHEL_RELEASE_VERSION(a, b) 0
 321 #endif' >> datapath/linux/kcompat.h.new
 322
 323   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 324                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 325
 326   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 327                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 328   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 329
 330   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 331   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 332
 333   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 334   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 335
 336   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 337   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 338   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 339   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 340   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 341
 342   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 343   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 344   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 345                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 346   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 347                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 348
 349   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 350                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 351   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_do_fragment])
 352   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_is_fragment])
 353   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 354   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 355                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 356   OVS_GREP_IFELSE([$KSRC/include/net/dst_metadata.h], [metadata_dst])
 357
 358   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 359                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 360   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 361   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 362   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 363   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 364   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 365   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 366   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 367   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 368   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 369   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_rx_handler_register])
 370   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_extended])
 371   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [rx_handler_func_t.*pskb],
 372                   [OVS_DEFINE([HAVE_RX_HANDLER_PSKB])])
 373   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 374                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 375   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 376   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 377                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 378   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 379
 380   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 381   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 382   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 383                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 384
 385   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 386                   [tmpl_alloc.*conntrack_zone],
 387                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 388
 389   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 390   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 391
 392   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 393   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 394   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 395                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 396   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 397
 398   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 399                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 400                                    [rcu_read_lock_held])])
 401   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 402
 403   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 404   # is necessary because some versions of this header remove the
 405   # member but retain the kerneldoc comment that describes it (which
 406   # starts with @).  The brackets must be doubled because of m4
 407   # quoting rules.
 408   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 409                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 410   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 411   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 412   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_mac_header])
 413   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_network_header])
 414   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 415   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_scrub_packet.*xnet],
 416                   [OVS_DEFINE([HAVE_SKB_SCRUB_PACKET_XNET])])
 417   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 418   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 419                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 420   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 421                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 422   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 423                   [skb_copy_from_linear_data_offset])
 424   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 425                   [skb_reset_tail_pointer])
 426   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 427   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 428                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 429   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 430                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 431   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 432                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 433   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 434   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 435   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 436   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 437   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 438   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 439   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 440   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 441   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 442   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 443                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 444   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 445                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 446   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 447   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 448   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 449
 450   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 451                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 452   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 453                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 454   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 455                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 456
 457   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 458   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 459
 460   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 461
 462   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 463   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 464   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 465   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 466   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 467                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 468   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 469   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 470                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 471
 472   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 473                         [genl_multicast_group], [id])
 474   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 475
 476   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 477   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 478   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 479   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 480   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 481   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 482                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 483   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 484                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 485
 486   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 487   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 488   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 489   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 490   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 491   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 492   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 493
 494   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 495
 496   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 497                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 498   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 499   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 500   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 501
 502   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 503
 504   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 505                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 506   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 507                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 508   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [VXLAN_HF_RCO])
 509   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 510                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 511                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 512   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 513   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
 514   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 515   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [ipv6_v6only],
 516                   [OVS_DEFINE([HAVE_UDP_TUNNEL_IPV6])])
 517
 518   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 519                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 520   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 521                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 522
 523   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 524                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 525
 526   if test "$version" = 4 && test "$patchlevel" -le 2; then
 527         OVS_DEFINE([OVS_FRAGMENT_BACKPORT])
 528   elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 529         OVS_DEFINE([OVS_FRAGMENT_BACKPORT])
 530   fi
 531
 532   if cmp -s datapath/linux/kcompat.h.new \
 533             datapath/linux/kcompat.h >/dev/null 2>&1; then
 534     rm datapath/linux/kcompat.h.new
 535   else
 536     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 537   fi
 538 ])
 539
 540 dnl Checks for net/if_packet.h.
 541 AC_DEFUN([OVS_CHECK_IF_PACKET],
 542   [AC_CHECK_HEADER([net/if_packet.h],
 543                    [HAVE_IF_PACKET=yes],
 544                    [HAVE_IF_PACKET=no])
 545    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 546    if test "$HAVE_IF_PACKET" = yes; then
 547       AC_DEFINE([HAVE_IF_PACKET], [1],
 548                 [Define to 1 if net/if_packet.h is available.])
 549    fi])
 550
 551 dnl Checks for net/if_dl.h.
 552 dnl
 553 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 554 dnl or NetBSD.)
 555 AC_DEFUN([OVS_CHECK_IF_DL],
 556   [AC_CHECK_HEADER([net/if_dl.h],
 557                    [HAVE_IF_DL=yes],
 558                    [HAVE_IF_DL=no])
 559    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 560    if test "$HAVE_IF_DL" = yes; then
 561       AC_DEFINE([HAVE_IF_DL], [1],
 562                 [Define to 1 if net/if_dl.h is available.])
 563
 564       # On these platforms we use libpcap to access network devices.
 565       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 566    fi])
 567
 568 dnl Checks for buggy strtok_r.
 569 dnl
 570 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 571 dnl with optimization that can cause segfaults:
 572 dnl
 573 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 574 AC_DEFUN([OVS_CHECK_STRTOK_R],
 575   [AC_CACHE_CHECK(
 576      [whether strtok_r macro segfaults on some inputs],
 577      [ovs_cv_strtok_r_bug],
 578      [AC_RUN_IFELSE(
 579         [AC_LANG_PROGRAM([#include <stdio.h>
 580                           #include <string.h>
 581                          ],
 582                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 583                            /* Assume bug is present, because relatively minor
 584                               changes in compiler settings (e.g. optimization
 585                               level) can make it crop up. */
 586                            return 1;
 587                            #else
 588                            char string[] = ":::";
 589                            char *save_ptr = (char *) 0xc0ffee;
 590                            char *token1, *token2;
 591                            token1 = strtok_r(string, ":", &save_ptr);
 592                            token2 = strtok_r(NULL, ":", &save_ptr);
 593                            freopen ("/dev/null", "w", stdout);
 594                            printf ("%s %s\n", token1, token2);
 595                            return 0;
 596                            #endif
 597                           ]])],
 598         [ovs_cv_strtok_r_bug=no],
 599         [ovs_cv_strtok_r_bug=yes],
 600         [ovs_cv_strtok_r_bug=yes])])
 601    if test $ovs_cv_strtok_r_bug = yes; then
 602      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 603                [Define if strtok_r macro segfaults on some inputs])
 604    fi
 605 ])
 606
 607 dnl ----------------------------------------------------------------------
 608 dnl These macros are from GNU PSPP, with the following original license:
 609 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 610 dnl This file is free software; the Free Software Foundation
 611 dnl gives unlimited permission to copy and/or distribute it,
 612 dnl with or without modifications, as long as this notice is preserved.
 613
 614 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 615   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 616   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 617     [ovs_save_CFLAGS="$CFLAGS"
 618      dnl Include -Werror in the compiler options, because without -Werror
 619      dnl clang's GCC-compatible compiler driver does not return a failure
 620      dnl exit status even though it complains about options it does not
 621      dnl understand.
 622      dnl
 623      dnl Also, check stderr as gcc exits with status 0 for options
 624      dnl rejected at getopt level.
 625      dnl    % touch /tmp/a.c
 626      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 627      dnl    gcc: unrecognized option '-Qunused-arguments'
 628      dnl    0
 629      dnl    %
 630      CFLAGS="$CFLAGS $WERROR $1"
 631      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 632      CFLAGS="$ovs_save_CFLAGS"])
 633   if test $ovs_cv_name = yes; then
 634     m4_if([$2], [], [:], [$2])
 635   else
 636     m4_if([$3], [], [:], [$3])
 637   fi
 638 ])
 639
 640 dnl OVS_CHECK_WERROR
 641 dnl
 642 dnl Check whether the C compiler accepts -Werror.
 643 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 644 AC_DEFUN([OVS_CHECK_WERROR],
 645   [WERROR=
 646    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 647
 648 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 649 dnl Check whether the given C compiler OPTION is accepted.
 650 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 651 AC_DEFUN([OVS_CHECK_CC_OPTION],
 652   [AC_REQUIRE([OVS_CHECK_WERROR])
 653    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 654
 655 dnl OVS_ENABLE_OPTION([OPTION])
 656 dnl Check whether the given C compiler OPTION is accepted.
 657 dnl If so, add it to WARNING_FLAGS.
 658 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 659 AC_DEFUN([OVS_ENABLE_OPTION],
 660   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 661    AC_SUBST([WARNING_FLAGS])])
 662
 663 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 664 dnl Check whether the given C compiler OPTION is accepted.
 665 dnl If so, enable the given Automake CONDITIONAL.
 666
 667 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 668 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 669   [OVS_CHECK_CC_OPTION(
 670     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 671    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 672 dnl ----------------------------------------------------------------------
 673
 674 dnl Check for too-old XenServer.
 675 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 676   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 677     [if test -e /etc/redhat-release; then
 678        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 679      fi
 680      if test -z "$ovs_cv_xsversion"; then
 681        ovs_cv_xsversion=none
 682      fi])
 683   case $ovs_cv_xsversion in
 684     none)
 685       ;;
 686
 687     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 688     [[6-9]]* |                           dnl XenServer 6 or later
 689     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 690     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 691     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 692     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 693       ;;
 694
 695     *)
 696       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 697       ;;
 698   esac])
 699
 700 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 701 dnl
 702 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 703 dnl Runs 'if-true' if so, 'if-false' otherwise.
 704 AC_DEFUN([OVS_CHECK_MAKE_IF],
 705   [AC_CACHE_CHECK(
 706      [whether ${MAKE-make} has GNU make \$(if) extension],
 707      [ovs_cv_gnu_make_if],
 708      [cat <<'EOF' > conftest.mk
 709 conftest.out:
 710         echo $(if x,y,z) > conftest.out
 711 .PHONY: all
 712 EOF
 713       rm -f conftest.out
 714       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 715       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 716       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 717       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 718       result=`cat conftest.out`
 719       rm -f conftest.mk conftest.out
 720       if test "X$result" = "Xy"; then
 721         ovs_cv_gnu_make_if=yes
 722       else
 723         ovs_cv_gnu_make_if=no
 724       fi])])
 725
 726 dnl OVS_CHECK_GNU_MAKE
 727 dnl
 728 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 729 dnl only work with GNU make).
 730 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 731   [AC_CACHE_CHECK(
 732      [whether ${MAKE-make} is GNU make],
 733      [ovs_cv_gnu_make],
 734      [rm -f conftest.out
 735       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 736       ${MAKE-make} --version >conftest.out 2>&1
 737       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 738       result=`cat conftest.out`
 739       rm -f conftest.mk conftest.out
 740
 741       case $result in # (
 742         GNU*) ovs_cv_gnu_make=yes ;; # (
 743         *) ovs_cv_gnu_make=no ;;
 744       esac])
 745    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 746
 747 dnl OVS_CHECK_SPARSE_TARGET
 748 dnl
 749 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 750 dnl target for which the code is being built.  This helps it out.
 751 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 752   [AC_CACHE_CHECK(
 753     [target hint for cgcc],
 754     [ac_cv_sparse_target],
 755     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 756        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 757        [x86_64-*], [ac_cv_sparse_target=x86_64],
 758        [ac_cv_sparse_target=other])])
 759    AS_CASE([$ac_cv_sparse_target],
 760      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 761      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 762      [SPARSEFLAGS= CGCCFLAGS=])
 763    AC_SUBST([SPARSEFLAGS])
 764    AC_SUBST([CGCCFLAGS])])
 765
 766 dnl OVS_SPARSE_EXTRA_INCLUDES
 767 dnl
 768 dnl The cgcc script from "sparse" does not search gcc's default
 769 dnl search path. Get the default search path from GCC and pass
 770 dnl them to sparse.
 771 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 772     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 773            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 774
 775 dnl OVS_ENABLE_SPARSE
 776 AC_DEFUN([OVS_ENABLE_SPARSE],
 777   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 778    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 779    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 780    : ${SPARSE=sparse}
 781    AC_SUBST([SPARSE])
 782    AC_CONFIG_COMMANDS_PRE(
 783      [if test $ovs_cv_gnu_make_if = yes; then
 784         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 785       fi])])
 786
 787 dnl OVS_PTHREAD_SET_NAME
 788 dnl
 789 dnl This checks for three known variants of pthreads functions for setting
 790 dnl the name of the current thread:
 791 dnl
 792 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 793 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 794 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 795 dnl
 796 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 797 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 798 dnl provide to it.
 799 dnl
 800 dnl This macro defines:
 801 dnl
 802 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 803 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 804 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 805 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 806   [AC_CHECK_FUNCS([pthread_set_name_np])
 807    if test $ac_cv_func_pthread_set_name_np != yes; then
 808      AC_CACHE_CHECK(
 809        [for pthread_setname_np() variant],
 810        [ovs_cv_pthread_setname_np],
 811        [AC_LINK_IFELSE(
 812          [AC_LANG_PROGRAM([#include <pthread.h>
 813   ], [pthread_setname_np(pthread_self(), "name");])],
 814          [ovs_cv_pthread_setname_np=glibc],
 815          [AC_LINK_IFELSE(
 816            [AC_LANG_PROGRAM([#include <pthread.h>
 817 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 818            [ovs_cv_pthread_setname_np=netbsd],
 819            [ovs_cv_pthread_setname_np=none])])])
 820      case $ovs_cv_pthread_setname_np in # (
 821        glibc)
 822           AC_DEFINE(
 823             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 824             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 825           ;; # (
 826        netbsd)
 827           AC_DEFINE(
 828             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 829             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 830           ;;
 831      esac
 832    fi])
 833
 834 dnl OVS_CHECK_LINUX_HOST.
 835 dnl
 836 dnl Checks whether we're building for a Linux host, based on the presence of
 837 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 838 dnl LINUX based on the result.
 839 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 840   [AC_CACHE_CHECK(
 841      [whether __linux__ is defined],
 842      [ovs_cv_linux],
 843      [AC_COMPILE_IFELSE(
 844         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 845         [ovs_cv_linux=true],
 846         [ovs_cv_linux=false])])
 847    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])