acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011 Nicira Networks.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX26
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX26], [
  32   AC_ARG_WITH([l26],
  33               [AC_HELP_STRING([--with-l26=/path/to/linux-2.6],
  34                               [Specify the linux 2.6 kernel build directory])],
  35               [KBUILD26="$withval"], [KBUILD26=])dnl
  36   AC_ARG_WITH([l26-source],
  37               [AC_HELP_STRING([--with-l26-source=/path/to/linux-2.6-source],
  38                               [Specify the linux 2.6 kernel source directory
  39                                (usually figured out automatically from build
  40                                directory)])],
  41               [KSRC26="$withval"], [KSRC26=])dnl
  42   if test -n "$KBUILD26"; then
  43     KBUILD26=`eval echo "$KBUILD26"`
  44     case $KBUILD26 in
  45         /*) ;;
  46         *) KBUILD26=`pwd`/$KBUILD26 ;;
  47     esac
  48
  49     # The build directory is what the user provided.
  50     # Make sure that it exists.
  51     AC_MSG_CHECKING([for Linux 2.6 build directory])
  52     if test -d "$KBUILD26"; then
  53         AC_MSG_RESULT([$KBUILD26])
  54         AC_SUBST(KBUILD26)
  55     else
  56         AC_MSG_RESULT([no])
  57         AC_ERROR([source dir $KBUILD26 doesn't exist])
  58     fi
  59
  60     # Debian breaks kernel headers into "source" header and "build" headers.
  61     # We want the source headers, but $KBUILD26 gives us the "build" headers.
  62     # Use heuristics to find the source headers.
  63     AC_MSG_CHECKING([for Linux 2.6 source directory])
  64     if test -n "$KSRC26"; then
  65       KSRC26=`eval echo "$KSRC26"`
  66       case $KSRC26 in
  67           /*) ;;
  68           *) KSRC26=`pwd`/$KSRC26 ;;
  69       esac
  70       if test ! -e $KSRC26/include/linux/kernel.h; then
  71         AC_MSG_ERROR([$KSRC26 is not a kernel source directory)])
  72       fi
  73     else
  74       KSRC26=$KBUILD26
  75       if test ! -e $KSRC26/include/linux/kernel.h; then
  76         case `echo "$KBUILD26" | sed 's,/*$,,'` in # (
  77           */build)
  78             KSRC26=`echo "$KBUILD26" | sed 's,/build/*$,/source,'`
  79             ;; # (
  80           *)
  81             KSRC26=`(cd $KBUILD26 && pwd -P) | sed 's,-[[^-]]*$,-common,'`
  82             ;;
  83         esac
  84       fi
  85       if test ! -e $KSRC26/include/linux/kernel.h; then
  86         AC_MSG_ERROR([cannot find source directory (please use --with-l26-source)])
  87       fi
  88     fi
  89     AC_MSG_RESULT([$KSRC26])
  90
  91     AC_MSG_CHECKING([for kernel version])
  92     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC26/Makefile"`
  93     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC26/Makefile"`
  94     if test -z "$patchlevel" || test -z "$sublevel"; then
  95        AC_ERROR([cannot determine kernel version])
  96     fi
  97     AC_MSG_RESULT([2.$patchlevel.$sublevel])
  98     if test "2.$patchlevel" != '2.6'; then
  99        if test "$BUILD26" = "$KSRC26"; then
 100          AC_ERROR([Linux kernel in $KBUILD26 is not version 2.6])
 101        else
 102          AC_ERROR([Linux kernel in build tree $KBUILD26 (source tree $KSRC26) is not version 2.6])
 103        fi
 104     fi
 105     if test ! -e "$KBUILD26"/include/linux/version.h || \
 106        (test ! -e "$KBUILD26"/include/linux/autoconf.h && \
 107         test ! -e "$KBUILD26"/include/generated/autoconf.h); then
 108         AC_MSG_ERROR([Linux kernel source in $KBUILD26 is not configured])
 109     fi
 110     OVS_CHECK_LINUX26_COMPAT
 111   elif test -n "$KSRC26"; then
 112     AC_MSG_ERROR([--with-l26-source may not be specified without --with-l26])
 113   fi
 114   AM_CONDITIONAL(L26_ENABLED, test -n "$KBUILD26")
 115 ])
 116
 117 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 118 dnl
 119 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 120 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 121 dnl <REGEX> translated to uppercase.
 122 AC_DEFUN([OVS_GREP_IFELSE], [
 123   AC_MSG_CHECKING([whether $2 matches in $1])
 124   if test -f $1; then
 125     grep '$2' $1 >/dev/null 2>&1
 126     status=$?
 127     case $status in
 128       0)
 129         AC_MSG_RESULT([yes])
 130         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 131         ;;
 132       1)
 133         AC_MSG_RESULT([no])
 134         $4
 135         ;;
 136       *)
 137         AC_MSG_ERROR([grep exited with status $status])
 138         ;;
 139     esac
 140   else
 141     AC_MSG_RESULT([file not found])
 142     $4
 143   fi
 144 ])
 145
 146 dnl OVS_DEFINE(NAME)
 147 dnl
 148 dnl Defines NAME to 1 in kcompat.h.
 149 AC_DEFUN([OVS_DEFINE], [
 150   echo '#define $1 1' >> datapath/linux-2.6/kcompat.h.new
 151 ])
 152
 153 AC_DEFUN([OVS_CHECK_LOG2_H], [
 154   AC_MSG_CHECKING([for $KSRC26/include/linux/log2.h])
 155   if test -e $KSRC26/include/linux/log2.h; then
 156     AC_MSG_RESULT([yes])
 157     OVS_DEFINE([HAVE_LOG2_H])
 158   else
 159     AC_MSG_RESULT([no])
 160   fi
 161 ])
 162
 163 dnl OVS_CHECK_LINUX26_COMPAT
 164 dnl
 165 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 166 dnl the directory in $KBUILD26.
 167 AC_DEFUN([OVS_CHECK_LINUX26_COMPAT], [
 168   rm -f datapath/linux-2.6/kcompat.h.new
 169   mkdir -p datapath/linux-2.6
 170   : > datapath/linux-2.6/kcompat.h.new
 171
 172   OVS_GREP_IFELSE([$KSRC26/arch/x86/include/asm/checksum_32.h], [src_err,],
 173                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 174
 175   OVS_GREP_IFELSE([$KSRC26/include/linux/err.h], [ERR_CAST])
 176
 177   OVS_GREP_IFELSE([$KSRC26/include/linux/in.h], [ipv4_is_multicast])
 178
 179   OVS_GREP_IFELSE([$KSRC26/include/linux/netdevice.h], [dev_disable_lro])
 180   OVS_GREP_IFELSE([$KSRC26/include/linux/netdevice.h], [dev_get_stats])
 181   OVS_GREP_IFELSE([$KSRC26/include/linux/netdevice.h], [dev_get_by_index_rcu])
 182
 183   OVS_GREP_IFELSE([$KSRC26/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 184                   [OVS_GREP_IFELSE([$KSRC26/include/linux/rtnetlink.h],
 185                                    [rcu_read_lock_held])])
 186
 187   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 188   # is necessary because some versions of this header remove the
 189   # member but retain the kerneldoc comment that describes it (which
 190   # starts with @).  The brackets must be doubled because of m4
 191   # quoting rules.
 192   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 193                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 194   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [raw],
 195                   [OVS_DEFINE([HAVE_MAC_RAW])])
 196   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_dst(],
 197                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 198   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h],
 199                   [skb_copy_from_linear_data_offset])
 200   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_cow_head])
 201   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_transport_header],
 202                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 203   OVS_GREP_IFELSE([$KSRC26/include/linux/icmpv6.h], [icmp6_hdr],
 204                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 205   OVS_GREP_IFELSE([$KSRC26/include/linux/skbuff.h], [skb_warn_if_lro],
 206                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 207
 208   OVS_GREP_IFELSE([$KSRC26/include/linux/string.h], [kmemdup], [],
 209                   [OVS_GREP_IFELSE([$KSRC26/include/linux/slab.h], [kmemdup])])
 210
 211   OVS_GREP_IFELSE([$KSRC26/include/linux/types.h], [bool],
 212                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 213   OVS_GREP_IFELSE([$KSRC26/include/linux/types.h], [__wsum],
 214                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 215
 216   OVS_GREP_IFELSE([$KSRC26/include/net/checksum.h], [csum_replace4])
 217   OVS_GREP_IFELSE([$KSRC26/include/net/checksum.h], [csum_unfold])
 218
 219   OVS_GREP_IFELSE([$KSRC26/include/net/netlink.h], [NLA_NUL_STRING])
 220   OVS_GREP_IFELSE([$KSRC26/include/net/netlink.h], [nla_get_be16])
 221   OVS_GREP_IFELSE([$KSRC26/include/net/netlink.h], [nla_find_nested])
 222
 223   OVS_GREP_IFELSE([$KSRC26/include/linux/if_link.h], [rtnl_link_stats64])
 224
 225   OVS_GREP_IFELSE([$KSRC26/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 226                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 227
 228   OVS_CHECK_LOG2_H
 229
 230   if cmp -s datapath/linux-2.6/kcompat.h.new \
 231             datapath/linux-2.6/kcompat.h >/dev/null 2>&1; then
 232     rm datapath/linux-2.6/kcompat.h.new
 233   else
 234     mv datapath/linux-2.6/kcompat.h.new datapath/linux-2.6/kcompat.h
 235   fi
 236 ])
 237
 238 dnl Checks for net/if_packet.h.
 239 AC_DEFUN([OVS_CHECK_IF_PACKET],
 240   [AC_CHECK_HEADER([net/if_packet.h],
 241                    [HAVE_IF_PACKET=yes],
 242                    [HAVE_IF_PACKET=no])
 243    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 244    if test "$HAVE_IF_PACKET" = yes; then
 245       AC_DEFINE([HAVE_IF_PACKET], [1],
 246                 [Define to 1 if net/if_packet.h is available.])
 247    fi])
 248
 249 dnl Checks for buggy strtok_r.
 250 dnl
 251 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 252 dnl with optimization that can cause segfaults:
 253 dnl
 254 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 255 AC_DEFUN([OVS_CHECK_STRTOK_R],
 256   [AC_CACHE_CHECK(
 257      [whether strtok_r macro segfaults on some inputs],
 258      [ovs_cv_strtok_r_bug],
 259      [AC_RUN_IFELSE(
 260         [AC_LANG_PROGRAM([#include <stdio.h>
 261                           #include <string.h>
 262                          ],
 263                          [[char string[] = ":::";
 264                            char *save_ptr = (char *) 0xc0ffee;
 265                            char *token1, *token2;
 266                            token1 = strtok_r(string, ":", &save_ptr);
 267                            token2 = strtok_r(NULL, ":", &save_ptr);
 268                            freopen ("/dev/null", "w", stdout);
 269                            printf ("%s %s\n", token1, token2);
 270                            return 0;
 271                           ]])],
 272         [ovs_cv_strtok_r_bug=no],
 273         [ovs_cv_strtok_r_bug=yes],
 274         [ovs_cv_strtok_r_bug=yes])])
 275    if test $ovs_cv_strtok_r_bug = yes; then
 276      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 277                [Define if strtok_r macro segfaults on some inputs])
 278    fi
 279 ])
 280
 281 dnl ----------------------------------------------------------------------
 282 dnl These macros are from GNU PSPP, with the following original license:
 283 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 284 dnl This file is free software; the Free Software Foundation
 285 dnl gives unlimited permission to copy and/or distribute it,
 286 dnl with or without modifications, as long as this notice is preserved.
 287
 288 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 289 dnl Check whether the given C compiler OPTION is accepted.
 290 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 291 AC_DEFUN([OVS_CHECK_CC_OPTION],
 292 [
 293   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 294   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 295     [ovs_save_CFLAGS="$CFLAGS"
 296      CFLAGS="$CFLAGS $1"
 297      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 298      CFLAGS="$ovs_save_CFLAGS"])
 299   if test $ovs_cv_name = yes; then
 300     m4_if([$2], [], [:], [$2])
 301   else
 302     m4_if([$3], [], [:], [$3])
 303   fi
 304 ])
 305
 306 dnl OVS_ENABLE_OPTION([OPTION])
 307 dnl Check whether the given C compiler OPTION is accepted.
 308 dnl If so, add it to WARNING_FLAGS.
 309 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 310 AC_DEFUN([OVS_ENABLE_OPTION],
 311   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 312    AC_SUBST([WARNING_FLAGS])])
 313
 314 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 315 dnl Check whether the given C compiler OPTION is accepted.
 316 dnl If so, enable the given Automake CONDITIONAL.
 317
 318 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 319 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 320   [OVS_CHECK_CC_OPTION(
 321     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 322    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 323 dnl ----------------------------------------------------------------------
 324
 325 dnl Check for too-old XenServer.
 326 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 327   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 328     [if test -e /etc/redhat-release; then
 329        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 330      fi
 331      if test -z "$ovs_cv_xsversion"; then
 332        ovs_cv_xsversion=none
 333      fi])
 334   case $ovs_cv_xsversion in
 335     none)
 336       ;;
 337
 338     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 339     [[6-9]]* |                           dnl XenServer 6 or later
 340     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 341     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 342     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 343     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 344       ;;
 345
 346     *)
 347       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 348       ;;
 349   esac])