acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2019 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 5; then
 154        if test "$version" = 5 && test "$patchlevel" -le 5; then
 155           : # Linux 5.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 5.5.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 4; then
 160        : # Linux 4.x
 161     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 162        : # Linux 3.x
 163     else
 164        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 165     fi
 166     if (test ! -e "$KBUILD"/include/linux/version.h && \
 167         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 168        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 169         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 170         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 171     fi
 172     OVS_CHECK_LINUX_COMPAT
 173   fi
 174   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 175 ])
 176
 177 dnl OVS_CHECK_LINUX_NETLINK
 178 dnl
 179 dnl Configure Linux netlink compat.
 180 AC_DEFUN([OVS_CHECK_LINUX_NETLINK], [
 181   AC_COMPILE_IFELSE([
 182     AC_LANG_PROGRAM([#include <linux/netlink.h>], [
 183         struct nla_bitfield32 x =  { 0 };
 184     ])],
 185     [AC_DEFINE([HAVE_NLA_BITFIELD32], [1],
 186     [Define to 1 if struct nla_bitfield32 is available.])])
 187 ])
 188
 189 dnl OVS_CHECK_LINUX_TC
 190 dnl
 191 dnl Configure Linux tc compat.
 192 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 193   AC_COMPILE_IFELSE([
 194     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 195         int x = TCA_ACT_FLAGS;
 196     ])],
 197     [AC_DEFINE([HAVE_TCA_ACT_FLAGS], [1],
 198                [Define to 1 if TCA_ACT_FLAGS is available.])])
 199
 200   AC_CHECK_MEMBERS([struct tcf_t.firstuse], [], [], [#include <linux/pkt_cls.h>])
 201
 202   AC_COMPILE_IFELSE([
 203     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 204         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 205     ])],
 206     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 207                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 208
 209   AC_COMPILE_IFELSE([
 210     AC_LANG_PROGRAM([#include <linux/tc_act/tc_mpls.h>], [
 211         int x = TCA_MPLS_TTL;
 212     ])],
 213     [AC_DEFINE([HAVE_TCA_MPLS_TTL], [1],
 214                [Define to 1 if HAVE_TCA_MPLS_TTL is available.])])
 215
 216   AC_COMPILE_IFELSE([
 217     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 218         int x = TCA_TUNNEL_KEY_ENC_TTL;
 219     ])],
 220     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 221                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 222
 223   AC_COMPILE_IFELSE([
 224     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 225         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 226     ])],
 227     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 228                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 229
 230   AC_COMPILE_IFELSE([
 231     AC_LANG_PROGRAM([#include <linux/tc_act/tc_skbedit.h>], [
 232         int x = TCA_SKBEDIT_FLAGS;
 233     ])],
 234     [AC_DEFINE([HAVE_TCA_SKBEDIT_FLAGS], [1],
 235                [Define to 1 if TCA_SKBEDIT_FLAGS is available.])])
 236 ])
 237
 238 dnl OVS_CHECK_LINUX_SCTP_CT
 239 dnl
 240 dnl Checks for kernels which need additional SCTP state
 241 AC_DEFUN([OVS_CHECK_LINUX_SCTP_CT], [
 242   AC_COMPILE_IFELSE([
 243     AC_LANG_PROGRAM([#include <linux/netfilter/nfnetlink.h>
 244 #include <linux/netfilter/nfnetlink_conntrack.h>
 245 #include <linux/netfilter/nf_conntrack_common.h>
 246 #include <linux/netfilter/nf_conntrack_sctp.h>], [
 247         int x = SCTP_CONNTRACK_HEARTBEAT_SENT;
 248     ])],
 249     [AC_DEFINE([HAVE_SCTP_CONNTRACK_HEARTBEATS], [1],
 250                [Define to 1 if SCTP_CONNTRACK_HEARTBEAT_SENT is available.])])
 251 ])
 252
 253 dnl OVS_FIND_DEPENDENCY(FUNCTION, SEARCH_LIBS, NAME_TO_PRINT)
 254 dnl
 255 dnl Check for a function in a library list.
 256 AC_DEFUN([OVS_FIND_DEPENDENCY], [
 257   AC_SEARCH_LIBS([$1], [$2], [], [
 258     AC_MSG_ERROR([unable to find $3, install the dependency package])
 259   ])
 260 ])
 261
 262 dnl OVS_CHECK_LINUX_AF_XDP
 263 dnl
 264 dnl Check both Linux kernel AF_XDP and libbpf support
 265 AC_DEFUN([OVS_CHECK_LINUX_AF_XDP], [
 266   AC_ARG_ENABLE([afxdp],
 267                 [AC_HELP_STRING([--enable-afxdp], [Enable AF-XDP support])],
 268                 [], [enable_afxdp=no])
 269   AC_MSG_CHECKING([whether AF_XDP is enabled])
 270   if test "$enable_afxdp" != yes; then
 271     AC_MSG_RESULT([no])
 272     AF_XDP_ENABLE=false
 273   else
 274     AC_MSG_RESULT([yes])
 275     AF_XDP_ENABLE=true
 276
 277     AC_CHECK_HEADER([bpf/libbpf.h], [],
 278       [AC_MSG_ERROR([unable to find bpf/libbpf.h for AF_XDP support])])
 279
 280     AC_CHECK_HEADER([linux/if_xdp.h], [],
 281       [AC_MSG_ERROR([unable to find linux/if_xdp.h for AF_XDP support])])
 282
 283     AC_CHECK_HEADER([bpf/xsk.h], [],
 284       [AC_MSG_ERROR([unable to find bpf/xsk.h for AF_XDP support])])
 285
 286     AC_CHECK_FUNCS([pthread_spin_lock], [],
 287       [AC_MSG_ERROR([unable to find pthread_spin_lock for AF_XDP support])])
 288
 289     OVS_FIND_DEPENDENCY([numa_alloc_onnode], [numa], [libnuma])
 290
 291     AC_DEFINE([HAVE_AF_XDP], [1],
 292               [Define to 1 if AF_XDP support is available and enabled.])
 293     LIBBPF_LDADD=" -lbpf -lelf"
 294     AC_SUBST([LIBBPF_LDADD])
 295
 296     AC_CHECK_DECL([xsk_ring_prod__needs_wakeup], [
 297       AC_DEFINE([HAVE_XDP_NEED_WAKEUP], [1],
 298         [XDP need wakeup support detected in xsk.h.])
 299     ], [], [[#include <bpf/xsk.h>]])
 300   fi
 301   AM_CONDITIONAL([HAVE_AF_XDP], test "$AF_XDP_ENABLE" = true)
 302 ])
 303
 304 dnl OVS_CHECK_DPDK
 305 dnl
 306 dnl Configure DPDK source tree
 307 AC_DEFUN([OVS_CHECK_DPDK], [
 308   AC_ARG_WITH([dpdk],
 309               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 310                               [Specify the DPDK build directory])],
 311               [have_dpdk=true])
 312
 313   AC_MSG_CHECKING([whether dpdk is enabled])
 314   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 315     AC_MSG_RESULT([no])
 316     DPDKLIB_FOUND=false
 317   else
 318     AC_MSG_RESULT([yes])
 319     case "$with_dpdk" in
 320       yes)
 321         DPDK_AUTO_DISCOVER="true"
 322         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 323             DPDK_INCLUDE="$DPDK_CFLAGS"
 324             DPDK_LIB="$DPDK_LIBS"], [
 325             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 326             DPDK_LIB="-ldpdk"])
 327         ;;
 328       *)
 329         DPDK_AUTO_DISCOVER="false"
 330         DPDK_INCLUDE_PATH="$with_dpdk/include"
 331         # If 'with_dpdk' is passed install directory, point to headers
 332         # installed in $DESTDIR/$prefix/include/dpdk
 333         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 334            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 335         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 336            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 337         fi
 338         DPDK_LIB_DIR="$with_dpdk/lib"
 339         DPDK_LIB="-ldpdk"
 340         ;;
 341     esac
 342
 343     ovs_save_CFLAGS="$CFLAGS"
 344     ovs_save_LDFLAGS="$LDFLAGS"
 345     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 346     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 347       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 348     fi
 349
 350     AC_CHECK_HEADERS([rte_config.h], [], [
 351       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 352     ], [AC_INCLUDES_DEFAULT])
 353
 354     AC_CHECK_DECLS([RTE_LIBRTE_VHOST_NUMA, RTE_EAL_NUMA_AWARE_HUGEPAGES], [
 355       OVS_FIND_DEPENDENCY([get_mempolicy], [numa], [libnuma])
 356     ], [], [[#include <rte_config.h>]])
 357
 358     AC_CHECK_DECL([RTE_LIBRTE_PMD_PCAP], [
 359       OVS_FIND_DEPENDENCY([pcap_dump_close], [pcap], [libpcap])
 360     ], [], [[#include <rte_config.h>]])
 361
 362     AC_CHECK_DECL([RTE_LIBRTE_PMD_AF_XDP], [
 363       LIBBPF_LDADD="-lbpf"
 364     ], [], [[#include <rte_config.h>]])
 365
 366     AC_CHECK_DECL([RTE_LIBRTE_VHOST_NUMA], [
 367       AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])
 368     ], [], [[#include <rte_config.h>]])
 369
 370     AC_CHECK_DECL([RTE_LIBRTE_MLX5_PMD], [dnl found
 371       OVS_FIND_DEPENDENCY([mnl_attr_put], [mnl], [libmnl])
 372       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 373         OVS_FIND_DEPENDENCY([mlx5dv_create_wq], [mlx5], [libmlx5])
 374         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 375       ], [[#include <rte_config.h>]])
 376     ], [], [[#include <rte_config.h>]])
 377
 378     AC_CHECK_DECL([RTE_LIBRTE_MLX4_PMD], [dnl found
 379       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 380         OVS_FIND_DEPENDENCY([mlx4dv_init_obj], [mlx4], [libmlx4])
 381         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 382       ], [[#include <rte_config.h>]])
 383     ], [], [[#include <rte_config.h>]])
 384
 385     # DPDK uses dlopen to load plugins.
 386     OVS_FIND_DEPENDENCY([dlopen], [dl], [libdl])
 387
 388     AC_MSG_CHECKING([whether linking with dpdk works])
 389     LIBS="$DPDK_LIB $LIBS"
 390     AC_LINK_IFELSE(
 391       [AC_LANG_PROGRAM([#include <rte_config.h>
 392                         #include <rte_eal.h>],
 393                        [int rte_argc; char ** rte_argv;
 394                         rte_eal_init(rte_argc, rte_argv);])],
 395       [AC_MSG_RESULT([yes])
 396        DPDKLIB_FOUND=true],
 397       [AC_MSG_RESULT([no])
 398        if test "$DPDK_AUTO_DISCOVER" = "true"; then
 399          AC_MSG_ERROR(m4_normalize([
 400             Could not find DPDK library in default search path, Use --with-dpdk
 401             to specify the DPDK library installed in non-standard location]))
 402        else
 403          AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 404        fi
 405       ])
 406
 407     CFLAGS="$ovs_save_CFLAGS"
 408     LDFLAGS="$ovs_save_LDFLAGS"
 409     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 410       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 411     fi
 412     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 413     OVS_ENABLE_OPTION([-mssse3])
 414
 415     # DPDK pmd drivers are not linked unless --whole-archive is used.
 416     #
 417     # This happens because the rest of the DPDK code doesn't use any symbol in
 418     # the pmd driver objects, and the drivers register themselves using an
 419     # __attribute__((constructor)) function.
 420     #
 421     # These options are specified inside a single -Wl directive to prevent
 422     # autotools from reordering them.
 423     #
 424     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 425     # will already have flagged just the right set of libs with
 426     # --whole-archive - in those cases do not wrap it once more.
 427     case "$DPDK_LIB" in
 428       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 429       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 430     esac
 431     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 432     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 433   fi
 434
 435   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 436 ])
 437
 438 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 439 dnl
 440 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 441 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 442 dnl <REGEX> translated to uppercase.
 443 AC_DEFUN([OVS_GREP_IFELSE], [
 444   AC_MSG_CHECKING([whether $2 matches in $1])
 445   if test -f $1; then
 446     grep '$2' $1 >/dev/null 2>&1
 447     status=$?
 448     case $status in
 449       0)
 450         AC_MSG_RESULT([yes])
 451         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 452         ;;
 453       1)
 454         AC_MSG_RESULT([no])
 455         $4
 456         ;;
 457       *)
 458         AC_MSG_ERROR([grep exited with status $status])
 459         ;;
 460     esac
 461   else
 462     AC_MSG_RESULT([file not found])
 463     $4
 464   fi
 465 ])
 466
 467 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 468 dnl
 469 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 470 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 471 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 472 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 473 dnl translated to uppercase.
 474 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 475   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 476   if test -f $1; then
 477     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 478     status=$?
 479     case $status in
 480       0)
 481         AC_MSG_RESULT([yes])
 482         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 483         ;;
 484       1)
 485         AC_MSG_RESULT([no])
 486         $5
 487         ;;
 488       *)
 489         AC_MSG_ERROR([grep exited with status $status])
 490         ;;
 491     esac
 492   else
 493     AC_MSG_RESULT([file not found])
 494     $5
 495   fi
 496 ])
 497
 498 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 499 dnl
 500 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 501 dnl the function signature starting from the line matching FUNCTION
 502 dnl and ending with the line containing the closing parenthesis.  If
 503 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 504 dnl IF-MATCH is empty then it defines to
 505 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 506 dnl <REGEX> translated to uppercase.
 507 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 508   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 509   if test -f $1; then
 510     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 511     status=$?
 512     case $status in
 513       0)
 514         AC_MSG_RESULT([yes])
 515         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 516         ;;
 517       1)
 518         AC_MSG_RESULT([no])
 519         $5
 520         ;;
 521       *)
 522         AC_MSG_ERROR([grep exited with status $status])
 523         ;;
 524     esac
 525   else
 526     AC_MSG_RESULT([file not found])
 527     $5
 528   fi
 529 ])
 530
 531 dnl OVS_FIND_OP_PARAM_IFELSE(FILE, OP, REGEX, [IF-MATCH], [IF-NO-MATCH])
 532 dnl
 533 dnl Looks for OP in FILE. If it is found, greps for REGEX within the
 534 dnl OP definition. If this is successful, runs IF-MATCH, otherwise
 535 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 536 dnl OVS_DEFINE(HAVE_<OP>_WITH_<REGEX>), with <OP> and <REGEX>
 537 dnl translated to uppercase.
 538 AC_DEFUN([OVS_FIND_OP_PARAM_IFELSE], [
 539   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 540   if test -f $1; then
 541     awk '/$2[[ \t\n]]*\)\(/,/;/' $1 2>/dev/null | grep '$3' >/dev/null
 542     status=$?
 543     case $status in
 544       0)
 545         AC_MSG_RESULT([yes])
 546         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 547         ;;
 548       1)
 549         AC_MSG_RESULT([no])
 550         $5
 551         ;;
 552       *)
 553         AC_MSG_ERROR([grep exited with status $status])
 554         ;;
 555     esac
 556   else
 557     AC_MSG_RESULT([file not found])
 558     $5
 559   fi
 560 ])
 561
 562 dnl OVS_DEFINE(NAME)
 563 dnl
 564 dnl Defines NAME to 1 in kcompat.h.
 565 AC_DEFUN([OVS_DEFINE], [
 566   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 567 ])
 568
 569 dnl OVS_CHECK_LINUX_COMPAT
 570 dnl
 571 dnl Runs various Autoconf checks on the Linux kernel source in
 572 dnl the directory in $KBUILD.
 573 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 574   rm -f datapath/linux/kcompat.h.new
 575   mkdir -p datapath/linux
 576   : > datapath/linux/kcompat.h.new
 577
 578   echo '#include <linux/version.h>
 579 #ifndef RHEL_RELEASE_CODE
 580 #define RHEL_RELEASE_CODE 0
 581 #define RHEL_RELEASE_VERSION(a, b) 0
 582 #endif' >> datapath/linux/kcompat.h.new
 583
 584   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 585                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 586
 587   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 588                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 589
 590   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub],
 591                         [dst_entry])
 592   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 593                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 594   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup_flow.*net],
 595                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_FLOW_NET])])
 596   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 597   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup_flow])
 598
 599   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 600   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 601   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 602
 603   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 604                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 605   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 606                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 607
 608   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 609   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 610
 611   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 612   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 613   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 614   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 615   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 616   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_hwaccel_clear_tag])
 617
 618   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 619   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 620   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 621                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 622   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 623                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 624
 625   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 626                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 627   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 628                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 629   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 630                         [ip_do_fragment], [net],
 631                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 632   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 633                         [ip_local_out], [net],
 634                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 635
 636   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 637
 638   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 639                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 640   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 641   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 642                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 643   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 644                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 645   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 646   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 647   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 648                         [frags_work])
 649   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 650                         [rwlock])
 651   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 652                         [list_evictor])
 653   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 654   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 655                         [sub_frag_mem_limit], [struct.netns_frags],
 656                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 657   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 658                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 659   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 660                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 661
 662   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 663   dnl OVS does not really need ipv6 label field, but its presence signifies that
 664   dnl the stack has all required ipv6 support.
 665   dnl OVS also does not need dst_cache But this dependency allows us to write
 666   dnl much cleaner code.
 667
 668   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 669                         [label],
 670                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 671                                          [iptunnel_pull_offloads],
 672                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 673                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 674                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 675
 676   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 677                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 678   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 679                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 680   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 681                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 682   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 683   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 684   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 685   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 686   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 687   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 688   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 689   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 690   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 691   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 692                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 693   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 694   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 695   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 696   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 697   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 698   dnl So check type of tstats.
 699   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 700                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 701   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 702                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 703   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 704   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 705   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 706                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 707   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 708   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 709   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 710                         [extended])
 711   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 712                         [netdev_master_upper_dev_link], [upper_priv],
 713                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 714   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 715                   [netdev_master_upper_dev_link_rh],
 716                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 717
 718   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 719                         [max_mtu])
 720   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 721                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 722   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 723                         [dev_change_flags], [extack],
 724                         [OVS_DEFINE([HAVE_DEV_CHANGE_FLAGS_TAKES_EXTACK])])
 725
 726   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 727   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state],
 728                         [struct net ], [OVS_DEFINE([HAVE_NF_HOOK_STATE_NET])])
 729   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 730   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 731                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 732   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 733                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 734   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 735                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 736   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 737   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [CONFIG_NF_NAT_NEEDED])
 738
 739
 740   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 741                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 742
 743   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 744                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 745                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 746   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 747                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 748
 749   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 750                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 751                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 752   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 753                   [nf_ct_get_tuplepr], [struct.net],
 754                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 755   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 756                   [nf_ct_set])
 757   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 758                   [nf_ct_is_untracked])
 759   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 760                   [nf_ct_invert_tuplepr])
 761   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 762                   [nf_ct_zone_init])
 763   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 764                   [net_ns_get])
 765   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 766                   [nf_connlabels_get])
 767   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 768                   [nf_connlabels_get], [int bit],
 769                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 770   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 771                         [nf_conn_labels], [words])
 772   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 773   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 774   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 775   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_packet],
 776                   [OVS_DEFINE([HAVE_UPSTREAM_NF_NAT])])
 777   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 778   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 779                   [OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h],
 780                                    [int nf_conncount_add],
 781                                    [], [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])])
 782   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [nf_ct_set_timeout])
 783   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [struct nf_ct_timeout],
 784                   [OVS_DEFINE([HAVE_NF_CT_TIMEOUT])])
 785   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h],
 786                         [\(*nf_ct_timeout_find_get_hook\)], [net],
 787                         [OVS_DEFINE([HAVE_NF_CT_TIMEOUT_FIND_GET_HOOK_NET])])
 788
 789   OVS_GREP_IFELSE([$KSRC/include/linux/random.h],
 790                   [prandom_u32[[\(]]],
 791                   [OVS_DEFINE([HAVE_PRANDOM_U32])])
 792   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 793
 794   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 795   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 796   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 797                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 798   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 799
 800   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 801                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 802                                    [rcu_read_lock_held])])
 803   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 804   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 805   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
 806                         [rtnl_create_link], [extack],
 807                         [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_TAKES_EXTACK])])
 808   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [nf_reset_ct])
 809
 810   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 811   # is necessary because some versions of this header remove the
 812   # member but retain the kerneldoc comment that describes it (which
 813   # starts with @).  The brackets must be doubled because of m4
 814   # quoting rules.
 815   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 816                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 817   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 818   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 819   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 820   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 821   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 822   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 823   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 824                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 825   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 826                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 827   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 828                   [skb_copy_from_linear_data_offset])
 829   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 830                   [skb_reset_tail_pointer])
 831   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 832   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 833                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 834   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 835   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 836   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 837   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 838   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 839   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 840   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 841   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 842                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 843   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 844   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 845                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 846   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 847                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 848   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 849   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 850   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 851   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 852   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 853   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 854   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 855   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 856   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 857
 858   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 859                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 860   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 861                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 862
 863   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 864   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 865
 866   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 867   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 868
 869   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 870   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 871   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 872   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 873                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 874   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 875   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 876                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 877   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_validate_flags])
 878   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 879                         [genl_notify], [net],
 880                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 881
 882
 883   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 884                         [genl_multicast_group], [id])
 885   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 886
 887   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 888   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 889   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 890   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 891   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 892   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 893                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 894   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 895                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 896
 897   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 898   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 899   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 900   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 901   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 902   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 903   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 904   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 905   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_nest_start_noflag])
 906   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 907                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 908   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 909                         [nla_parse], [netlink_ext_ack],
 910                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 911
 912   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 913
 914   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 915   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 916   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 917   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 918   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 919
 920   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 921                         [metadata_dst_alloc], [metadata_type])
 922
 923   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 924
 925   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 926                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 927   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 928                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 929                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 930   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 931   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 932   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 933                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 934   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 935                         [gro_receive])
 936
 937   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 938                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 939   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 940                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 941
 942   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 943   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 944   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 945                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 946   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 947                         [udp_add_offload], [net],
 948                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 949   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 950                         [nf_defrag_ipv6_enable], [net],
 951                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 952   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 953                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 954   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 955                         [needs_free_netdev],
 956                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 957   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 958                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 959   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 960                   [nf_conntrack_helper_put],
 961                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 962   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 963                   [nf_nat_helper_try_module_get])
 964   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 965                   [nf_nat_helper_put])
 966   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 967                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 968   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 969                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 970   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 971                         [extack],
 972                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 973   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 974                         [list],
 975                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 976   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 977                   [IP_CT_UNTRACKED])
 978   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 979                         [netdev_master_upper_dev_link], [extack],
 980                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 981   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 982                   [__LINUX_COMPILER_TYPES_H],
 983                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 984   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 985                   [ktime_get_ts64],
 986                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 987   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 988                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 989                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 990   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 991                   [ktime_get_ns],
 992                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 993   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 994                   frag_percpu_counter_batch[],
 995                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 996   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 997                   [null_compute_pseudo],
 998                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 999   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1000                   [__skb_checksum_convert],
1001                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
1002   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
1003                         [max_mtu],
1004                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
1005   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
1006                         [erspan_ver],
1007                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
1008   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1009                   [SKB_GSO_IPXIP6],
1010                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
1011   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
1012                         [ip6_make_flowlabel], [fl6],
1013                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
1014   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
1015                         [auto_flowlabels],
1016                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
1017   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
1018                   [netif_keep_dst],
1019                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
1020   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
1021                         [ndo_get_iflink],
1022                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
1023   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1024                   [skb_set_inner_ipproto],
1025                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
1026   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1027                   [tunnel_encap_types],
1028                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
1029   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1030                   [IFLA_IPTUN_ENCAP_TYPE],
1031                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
1032   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1033                   [IFLA_IPTUN_COLLECT_METADATA],
1034                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
1035   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1036                   [IFLA_GRE_ENCAP_DPORT])
1037   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1038                   [IFLA_GRE_COLLECT_METADATA])
1039   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1040                   [IFLA_GRE_IGNORE_DF])
1041   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1042                   [IFLA_GRE_FWMARK])
1043   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1044                   [IFLA_GRE_ERSPAN_INDEX])
1045   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1046                   [IFLA_GRE_ERSPAN_HWID])
1047   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1048                   [IFLA_IPTUN_FWMARK])
1049   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1050                         [csum_valid],
1051                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
1052   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1053                         [vlan_present],
1054                         [OVS_DEFINE([HAVE_SKBUFF_VLAN_PRESENT])])
1055   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1056                   [skb_checksum_simple_validate])
1057   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
1058                   [void.*ndo_get_stats64],
1059                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
1060   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
1061                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
1062   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
1063                         [ip_tunnel_info_opts_set], [flags],
1064                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
1065   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
1066                         [rnd],
1067                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
1068   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [__LINUX_OVERFLOW_H],
1069                   [OVS_DEFINE([HAVE_OVERFLOW_H])])
1070   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [struct_size],
1071                   [OVS_DEFINE([HAVE_STRUCT_SIZE])])
1072   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_array],
1073                   [OVS_DEFINE([HAVE_KVMALLOC_ARRAY])])
1074   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_node],
1075                   [OVS_DEFINE([HAVE_KVMALLOC_NODE])])
1076   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
1077                   [nf_conntrack_l3proto],
1078                   [OVS_DEFINE([HAVE_NF_CONNTRACK_L3PROATO_H])])
1079   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_core.h],
1080                         [nf_conntrack_in], [nf_hook_state],
1081                         [OVS_DEFINE([HAVE_NF_CONNTRACK_IN_TAKES_NF_HOOK_STATE])])
1082   OVS_GREP_IFELSE([$KSRC/include/net/ipv6_frag.h], [IP6_DEFRAG_CONNTRACK_IN],
1083                   [OVS_DEFINE([HAVE_IPV6_FRAG_H])])
1084   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
1085                         [nf_ct_helper_ext_add], [nf_conntrack_helper],
1086                         [OVS_DEFINE([HAVE_NF_CT_HELPER_EXT_ADD_TAKES_HELPER])])
1087   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_calc_hlen],
1088                   [OVS_DEFINE([HAVE_GRE_CALC_HLEN])])
1089   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [ip_gre_calc_hlen],
1090                   [OVS_DEFINE([HAVE_IP_GRE_CALC_HLEN])])
1091   OVS_GREP_IFELSE([$KSRC/include/linux/rbtree.h], [rb_link_node_rcu],
1092                   [OVS_DEFINE([HAVE_RBTREE_RB_LINK_NODE_RCU])])
1093   OVS_GREP_IFELSE([$KSRC/include/net/dst_ops.h], [bool confirm_neigh],
1094                   [OVS_DEFINE([HAVE_DST_OPS_CONFIRM_NEIGH])])
1095   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [fqdir],
1096                   [OVS_DEFINE([HAVE_INET_FRAG_FQDIR])])
1097   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h], [genl_ops],
1098                         [policy],
1099                         [OVS_DEFINE([HAVE_GENL_OPS_POLICY])])
1100   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h],
1101                   [nla_parse_deprecated_strict],
1102                   [OVS_DEFINE([HAVE_NLA_PARSE_DEPRECATED_STRICT])])
1103   OVS_FIND_OP_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
1104                            [validate], [extack],
1105                            [OVS_DEFINE([HAVE_RTNLOP_VALIDATE_WITH_EXTACK])])
1106   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1107                   [__skb_set_hash])
1108   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [sw_hash])
1109   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash_raw])
1110
1111   if cmp -s datapath/linux/kcompat.h.new \
1112             datapath/linux/kcompat.h >/dev/null 2>&1; then
1113     rm datapath/linux/kcompat.h.new
1114   else
1115     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
1116   fi
1117 ])
1118
1119 dnl Checks for net/if_dl.h.
1120 dnl
1121 dnl (We use this as a proxy for checking whether we're building on FreeBSD
1122 dnl or NetBSD.)
1123 AC_DEFUN([OVS_CHECK_IF_DL],
1124   [AC_CHECK_HEADER([net/if_dl.h],
1125                    [HAVE_IF_DL=yes],
1126                    [HAVE_IF_DL=no])
1127    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
1128    if test "$HAVE_IF_DL" = yes; then
1129       AC_DEFINE([HAVE_IF_DL], [1],
1130                 [Define to 1 if net/if_dl.h is available.])
1131
1132       # On these platforms we use libpcap to access network devices.
1133       AC_SEARCH_LIBS([pcap_open_live], [pcap])
1134    fi])
1135
1136 dnl Checks for buggy strtok_r.
1137 dnl
1138 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
1139 dnl with optimization that can cause segfaults:
1140 dnl
1141 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
1142 AC_DEFUN([OVS_CHECK_STRTOK_R],
1143   [AC_CACHE_CHECK(
1144      [whether strtok_r macro segfaults on some inputs],
1145      [ovs_cv_strtok_r_bug],
1146      [AC_RUN_IFELSE(
1147         [AC_LANG_PROGRAM([#include <stdio.h>
1148                           #include <string.h>
1149                          ],
1150                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
1151                            /* Assume bug is present, because relatively minor
1152                               changes in compiler settings (e.g. optimization
1153                               level) can make it crop up. */
1154                            return 1;
1155                            #else
1156                            char string[] = ":::";
1157                            char *save_ptr = (char *) 0xc0ffee;
1158                            char *token1, *token2;
1159                            token1 = strtok_r(string, ":", &save_ptr);
1160                            token2 = strtok_r(NULL, ":", &save_ptr);
1161                            freopen ("/dev/null", "w", stdout);
1162                            printf ("%s %s\n", token1, token2);
1163                            return 0;
1164                            #endif
1165                           ]])],
1166         [ovs_cv_strtok_r_bug=no],
1167         [ovs_cv_strtok_r_bug=yes],
1168         [ovs_cv_strtok_r_bug=yes])])
1169    if test $ovs_cv_strtok_r_bug = yes; then
1170      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1171                [Define if strtok_r macro segfaults on some inputs])
1172    fi
1173 ])
1174
1175 dnl ----------------------------------------------------------------------
1176 dnl These macros are from GNU PSPP, with the following original license:
1177 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1178 dnl This file is free software; the Free Software Foundation
1179 dnl gives unlimited permission to copy and/or distribute it,
1180 dnl with or without modifications, as long as this notice is preserved.
1181
1182 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1183   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1184   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1185     [ovs_save_CFLAGS="$CFLAGS"
1186      dnl Include -Werror in the compiler options, because without -Werror
1187      dnl clang's GCC-compatible compiler driver does not return a failure
1188      dnl exit status even though it complains about options it does not
1189      dnl understand.
1190      dnl
1191      dnl Also, check stderr as gcc exits with status 0 for options
1192      dnl rejected at getopt level.
1193      dnl    % touch /tmp/a.c
1194      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1195      dnl    gcc: unrecognized option '-Qunused-arguments'
1196      dnl    0
1197      dnl    %
1198      dnl
1199      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1200      dnl it does not understand, unless it has another error to report, so
1201      dnl instead of testing for -Wno-<foo>, test for the positive version.
1202      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1203      AC_COMPILE_IFELSE(
1204        [AC_LANG_SOURCE([int x;])],
1205        [if test -s conftest.err && grep "unrecognized option" conftest.err
1206         then
1207           ovs_cv_name[]=no
1208         else
1209           ovs_cv_name[]=yes
1210         fi],
1211        [ovs_cv_name[]=no])
1212      CFLAGS="$ovs_save_CFLAGS"])
1213   if test $ovs_cv_name = yes; then
1214     m4_if([$2], [], [:], [$2])
1215   else
1216     m4_if([$3], [], [:], [$3])
1217   fi
1218 ])
1219
1220 dnl OVS_CHECK_WERROR
1221 dnl
1222 dnl Check whether the C compiler accepts -Werror.
1223 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1224 AC_DEFUN([OVS_CHECK_WERROR],
1225   [WERROR=
1226    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1227
1228 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1229 dnl Check whether the given C compiler OPTION is accepted.
1230 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1231 AC_DEFUN([OVS_CHECK_CC_OPTION],
1232   [AC_REQUIRE([OVS_CHECK_WERROR])
1233    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1234
1235 dnl OVS_ENABLE_OPTION([OPTION])
1236 dnl Check whether the given C compiler OPTION is accepted.
1237 dnl If so, add it to WARNING_FLAGS.
1238 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1239 AC_DEFUN([OVS_ENABLE_OPTION],
1240   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1241    AC_SUBST([WARNING_FLAGS])])
1242
1243 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1244 dnl Check whether the given C compiler OPTION is accepted.
1245 dnl If so, enable the given Automake CONDITIONAL.
1246
1247 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1248 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1249   [OVS_CHECK_CC_OPTION(
1250     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1251    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1252 dnl ----------------------------------------------------------------------
1253
1254 dnl Check for too-old XenServer.
1255 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1256   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1257     [if test -e /etc/redhat-release; then
1258        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1259      fi
1260      if test -z "$ovs_cv_xsversion"; then
1261        ovs_cv_xsversion=none
1262      fi])
1263   case $ovs_cv_xsversion in
1264     none)
1265       ;;
1266
1267     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1268     [[6-9]]* |                           dnl XenServer 6 or later
1269     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1270     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1271     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1272     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1273       ;;
1274
1275     *)
1276       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1277       ;;
1278   esac])
1279
1280 dnl OVS_CHECK_SPARSE_TARGET
1281 dnl
1282 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1283 dnl target for which the code is being built.  This helps it out.
1284 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1285   [AC_CACHE_CHECK(
1286     [target hint for cgcc],
1287     [ac_cv_sparse_target],
1288     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1289        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1290        [x86_64-*], [ac_cv_sparse_target=x86_64],
1291        [ac_cv_sparse_target=other])])
1292    AS_CASE([$ac_cv_sparse_target],
1293      [x86], [SPARSEFLAGS= CGCCFLAGS="-target=i86 -target=host_os_specs"],
1294      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS="-target=x86_64 -target=host_os_specs"],
1295      [SPARSEFLAGS= CGCCFLAGS=])
1296
1297    dnl Get the default defines for vector instructions from compiler to
1298    dnl allow "sparse" correctly check the same code that will be built.
1299    dnl Required for checking DPDK headers.
1300    AC_MSG_CHECKING([vector options for cgcc])
1301    VECTOR=$($CC -dM -E - < /dev/null | grep -E "MMX|SSE|AVX" | \
1302             cut -c 9- | sed 's/ /=/' | sed 's/^/-D/' | tr '\n' ' ')
1303    AC_MSG_RESULT([$VECTOR])
1304    CGCCFLAGS="$CGCCFLAGS $VECTOR"
1305
1306    AC_SUBST([SPARSEFLAGS])
1307    AC_SUBST([CGCCFLAGS])])
1308
1309 dnl OVS_SPARSE_EXTRA_INCLUDES
1310 dnl
1311 dnl The cgcc script from "sparse" does not search gcc's default
1312 dnl search path. Get the default search path from GCC and pass
1313 dnl them to sparse.
1314 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1315     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1316            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1317
1318 dnl OVS_ENABLE_SPARSE
1319 AC_DEFUN([OVS_ENABLE_SPARSE],
1320   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1321    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1322    : ${SPARSE=sparse}
1323    AC_SUBST([SPARSE])
1324    AC_CONFIG_COMMANDS_PRE(
1325      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1326
1327    AC_ARG_ENABLE(
1328      [sparse],
1329      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1330      [], [enable_sparse=no])
1331    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1332
1333 dnl OVS_CTAGS_IDENTIFIERS
1334 dnl
1335 dnl ctags ignores symbols with extras identifiers. This builds a list of
1336 dnl specially handled identifiers to be ignored.
1337 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1338     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1339            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1340
1341 dnl OVS_PTHREAD_SET_NAME
1342 dnl
1343 dnl This checks for three known variants of pthreads functions for setting
1344 dnl the name of the current thread:
1345 dnl
1346 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1347 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1348 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1349 dnl
1350 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1351 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1352 dnl provide to it.
1353 dnl
1354 dnl This macro defines:
1355 dnl
1356 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1357 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1358 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1359 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1360   [AC_CHECK_FUNCS([pthread_set_name_np])
1361    if test $ac_cv_func_pthread_set_name_np != yes; then
1362      AC_CACHE_CHECK(
1363        [for pthread_setname_np() variant],
1364        [ovs_cv_pthread_setname_np],
1365        [AC_LINK_IFELSE(
1366          [AC_LANG_PROGRAM([#include <pthread.h>
1367   ], [pthread_setname_np(pthread_self(), "name");])],
1368          [ovs_cv_pthread_setname_np=glibc],
1369          [AC_LINK_IFELSE(
1370            [AC_LANG_PROGRAM([#include <pthread.h>
1371 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1372            [ovs_cv_pthread_setname_np=netbsd],
1373            [ovs_cv_pthread_setname_np=none])])])
1374      case $ovs_cv_pthread_setname_np in # (
1375        glibc)
1376           AC_DEFINE(
1377             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1378             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1379           ;; # (
1380        netbsd)
1381           AC_DEFINE(
1382             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1383             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1384           ;;
1385      esac
1386    fi])
1387
1388 dnl OVS_CHECK_LINUX_HOST.
1389 dnl
1390 dnl Checks whether we're building for a Linux host, based on the presence of
1391 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1392 dnl LINUX based on the result.
1393 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1394   [AC_CACHE_CHECK(
1395      [whether __linux__ is defined],
1396      [ovs_cv_linux],
1397      [AC_COMPILE_IFELSE(
1398         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1399         [ovs_cv_linux=true],
1400         [ovs_cv_linux=false])])
1401    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])