acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2019 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 4; then
 154        if test "$version" = 4 && test "$patchlevel" -le 20; then
 155           : # Linux 4.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.20.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 160        : # Linux 3.x
 161     else
 162        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 163     fi
 164     if (test ! -e "$KBUILD"/include/linux/version.h && \
 165         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 166        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 167         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 168         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 169     fi
 170     OVS_CHECK_LINUX_COMPAT
 171   fi
 172   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 173 ])
 174
 175 dnl OVS_CHECK_LINUX_TC
 176 dnl
 177 dnl Configure Linux tc compat.
 178 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 179   AC_COMPILE_IFELSE([
 180     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 181         int x = TCA_FLOWER_KEY_ENC_IP_TTL_MASK;
 182     ])],
 183     [AC_DEFINE([HAVE_TCA_FLOWER_KEY_ENC_IP_TTL_MASK], [1],
 184                [Define to 1 if TCA_FLOWER_KEY_ENC_IP_TTL_MASK is available.])])
 185
 186   AC_COMPILE_IFELSE([
 187     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 188         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 189     ])],
 190     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 191                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 192
 193   AC_COMPILE_IFELSE([
 194     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 195         int x = TCA_TUNNEL_KEY_ENC_TTL;
 196     ])],
 197     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 198                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 199
 200   AC_COMPILE_IFELSE([
 201     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 202         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 203     ])],
 204     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 205                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 206
 207   AC_COMPILE_IFELSE([
 208     AC_LANG_PROGRAM([#include <linux/tc_act/tc_skbedit.h>], [
 209         int x = TCA_SKBEDIT_FLAGS;
 210     ])],
 211     [AC_DEFINE([HAVE_TCA_SKBEDIT_FLAGS], [1],
 212                [Define to 1 if TCA_SKBEDIT_FLAGS is available.])])
 213 ])
 214
 215 dnl OVS_CHECK_LINUX_SCTP_CT
 216 dnl
 217 dnl Checks for kernels which need additional SCTP state
 218 AC_DEFUN([OVS_CHECK_LINUX_SCTP_CT], [
 219   AC_COMPILE_IFELSE([
 220     AC_LANG_PROGRAM([#include <linux/netfilter/nfnetlink.h>
 221 #include <linux/netfilter/nfnetlink_conntrack.h>
 222 #include <linux/netfilter/nf_conntrack_common.h>
 223 #include <linux/netfilter/nf_conntrack_sctp.h>], [
 224         int x = SCTP_CONNTRACK_HEARTBEAT_SENT;
 225     ])],
 226     [AC_DEFINE([HAVE_SCTP_CONNTRACK_HEARTBEATS], [1],
 227                [Define to 1 if SCTP_CONNTRACK_HEARTBEAT_SENT is available.])])
 228 ])
 229
 230 dnl OVS_FIND_DEPENDENCY(FUNCTION, SEARCH_LIBS, NAME_TO_PRINT)
 231 dnl
 232 dnl Check for a function in a library list.
 233 AC_DEFUN([OVS_FIND_DEPENDENCY], [
 234   AC_SEARCH_LIBS([$1], [$2], [], [
 235     AC_MSG_ERROR([unable to find $3, install the dependency package])
 236   ])
 237 ])
 238
 239 dnl OVS_CHECK_DPDK
 240 dnl
 241 dnl Configure DPDK source tree
 242 AC_DEFUN([OVS_CHECK_DPDK], [
 243   AC_ARG_WITH([dpdk],
 244               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 245                               [Specify the DPDK build directory])],
 246               [have_dpdk=true])
 247
 248   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 249   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 250     AC_MSG_RESULT([no])
 251     DPDKLIB_FOUND=false
 252   else
 253     AC_MSG_RESULT([yes])
 254     case "$with_dpdk" in
 255       yes)
 256         DPDK_AUTO_DISCOVER="true"
 257         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 258             DPDK_INCLUDE="$DPDK_CFLAGS"
 259             DPDK_LIB="$DPDK_LIBS"], [
 260             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 261             DPDK_LIB="-ldpdk"])
 262         ;;
 263       *)
 264         DPDK_AUTO_DISCOVER="false"
 265         DPDK_INCLUDE_PATH="$with_dpdk/include"
 266         # If 'with_dpdk' is passed install directory, point to headers
 267         # installed in $DESTDIR/$prefix/include/dpdk
 268         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 269            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 270         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 271            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 272         fi
 273         DPDK_LIB_DIR="$with_dpdk/lib"
 274         DPDK_LIB="-ldpdk"
 275         ;;
 276     esac
 277
 278     ovs_save_CFLAGS="$CFLAGS"
 279     ovs_save_LDFLAGS="$LDFLAGS"
 280     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 281     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 282       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 283     fi
 284
 285     AC_CHECK_HEADERS([rte_config.h], [], [
 286       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 287     ], [AC_INCLUDES_DEFAULT])
 288
 289     AC_CHECK_DECLS([RTE_LIBRTE_VHOST_NUMA, RTE_EAL_NUMA_AWARE_HUGEPAGES], [
 290       OVS_FIND_DEPENDENCY([get_mempolicy], [numa], [libnuma])
 291     ], [], [[#include <rte_config.h>]])
 292
 293     AC_CHECK_DECL([RTE_LIBRTE_VHOST_NUMA], [
 294       AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])
 295     ], [], [[#include <rte_config.h>]])
 296
 297     AC_CHECK_DECL([RTE_LIBRTE_PMD_PCAP], [
 298       OVS_FIND_DEPENDENCY([pcap_dump], [pcap], [libpcap])
 299       AC_CHECK_DECL([RTE_LIBRTE_PDUMP], [
 300         AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])
 301       ], [], [[#include <rte_config.h>]])
 302     ], [], [[#include <rte_config.h>]])
 303
 304     AC_CHECK_DECL([RTE_LIBRTE_MLX5_PMD], [dnl found
 305       OVS_FIND_DEPENDENCY([mnl_attr_put], [mnl], [libmnl])
 306       AC_CHECK_DECL([RTE_LIBRTE_MLX5_DLOPEN_DEPS], [], [dnl not found
 307         OVS_FIND_DEPENDENCY([mlx5dv_create_wq], [mlx5], [libmlx5])
 308         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 309       ], [[#include <rte_config.h>]])
 310     ], [], [[#include <rte_config.h>]])
 311
 312     AC_CHECK_DECL([RTE_LIBRTE_MLX4_PMD], [dnl found
 313       AC_CHECK_DECL([RTE_LIBRTE_MLX4_DLOPEN_DEPS], [], [dnl not found
 314         OVS_FIND_DEPENDENCY([mlx4dv_init_obj], [mlx4], [libmlx4])
 315         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 316       ], [[#include <rte_config.h>]])
 317     ], [], [[#include <rte_config.h>]])
 318
 319     # DPDK uses dlopen to load plugins.
 320     OVS_FIND_DEPENDENCY([dlopen], [dl], [libdl])
 321
 322     AC_MSG_CHECKING([whether linking with dpdk works])
 323     LIBS="$DPDK_LIB $LIBS"
 324     AC_LINK_IFELSE(
 325       [AC_LANG_PROGRAM([#include <rte_config.h>
 326                         #include <rte_eal.h>],
 327                        [int rte_argc; char ** rte_argv;
 328                         rte_eal_init(rte_argc, rte_argv);])],
 329       [AC_MSG_RESULT([yes])
 330        DPDKLIB_FOUND=true],
 331       [AC_MSG_RESULT([no])
 332        if test "$DPDK_AUTO_DISCOVER" = "true"; then
 333          AC_MSG_ERROR(m4_normalize([
 334             Could not find DPDK library in default search path, Use --with-dpdk
 335             to specify the DPDK library installed in non-standard location]))
 336        else
 337          AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 338        fi
 339       ])
 340
 341     CFLAGS="$ovs_save_CFLAGS"
 342     LDFLAGS="$ovs_save_LDFLAGS"
 343     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 344       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 345     fi
 346     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 347     OVS_ENABLE_OPTION([-mssse3])
 348
 349     # DPDK pmd drivers are not linked unless --whole-archive is used.
 350     #
 351     # This happens because the rest of the DPDK code doesn't use any symbol in
 352     # the pmd driver objects, and the drivers register themselves using an
 353     # __attribute__((constructor)) function.
 354     #
 355     # These options are specified inside a single -Wl directive to prevent
 356     # autotools from reordering them.
 357     #
 358     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 359     # will already have flagged just the right set of libs with
 360     # --whole-archive - in those cases do not wrap it once more.
 361     case "$DPDK_LIB" in
 362       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 363       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 364     esac
 365     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 366     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 367   fi
 368
 369   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 370 ])
 371
 372 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 373 dnl
 374 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 375 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 376 dnl <REGEX> translated to uppercase.
 377 AC_DEFUN([OVS_GREP_IFELSE], [
 378   AC_MSG_CHECKING([whether $2 matches in $1])
 379   if test -f $1; then
 380     grep '$2' $1 >/dev/null 2>&1
 381     status=$?
 382     case $status in
 383       0)
 384         AC_MSG_RESULT([yes])
 385         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 386         ;;
 387       1)
 388         AC_MSG_RESULT([no])
 389         $4
 390         ;;
 391       *)
 392         AC_MSG_ERROR([grep exited with status $status])
 393         ;;
 394     esac
 395   else
 396     AC_MSG_RESULT([file not found])
 397     $4
 398   fi
 399 ])
 400
 401 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 402 dnl
 403 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 404 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 405 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 406 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 407 dnl translated to uppercase.
 408 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 409   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 410   if test -f $1; then
 411     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 412     status=$?
 413     case $status in
 414       0)
 415         AC_MSG_RESULT([yes])
 416         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 417         ;;
 418       1)
 419         AC_MSG_RESULT([no])
 420         $5
 421         ;;
 422       *)
 423         AC_MSG_ERROR([grep exited with status $status])
 424         ;;
 425     esac
 426   else
 427     AC_MSG_RESULT([file not found])
 428     $5
 429   fi
 430 ])
 431
 432 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 433 dnl
 434 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 435 dnl the function signature starting from the line matching FUNCTION
 436 dnl and ending with the line containing the closing parenthesis.  If
 437 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 438 dnl IF-MATCH is empty then it defines to
 439 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 440 dnl <REGEX> translated to uppercase.
 441 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 442   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 443   if test -f $1; then
 444     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 445     status=$?
 446     case $status in
 447       0)
 448         AC_MSG_RESULT([yes])
 449         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 450         ;;
 451       1)
 452         AC_MSG_RESULT([no])
 453         $5
 454         ;;
 455       *)
 456         AC_MSG_ERROR([grep exited with status $status])
 457         ;;
 458     esac
 459   else
 460     AC_MSG_RESULT([file not found])
 461     $5
 462   fi
 463 ])
 464
 465 dnl OVS_DEFINE(NAME)
 466 dnl
 467 dnl Defines NAME to 1 in kcompat.h.
 468 AC_DEFUN([OVS_DEFINE], [
 469   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 470 ])
 471
 472 dnl OVS_CHECK_LINUX_COMPAT
 473 dnl
 474 dnl Runs various Autoconf checks on the Linux kernel source in
 475 dnl the directory in $KBUILD.
 476 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 477   rm -f datapath/linux/kcompat.h.new
 478   mkdir -p datapath/linux
 479   : > datapath/linux/kcompat.h.new
 480
 481   echo '#include <linux/version.h>
 482 #ifndef RHEL_RELEASE_CODE
 483 #define RHEL_RELEASE_CODE 0
 484 #define RHEL_RELEASE_VERSION(a, b) 0
 485 #endif' >> datapath/linux/kcompat.h.new
 486
 487   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 488                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 489
 490   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 491                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 492
 493   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 494                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 495   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 496
 497   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 498   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 499   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 500
 501   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 502                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 503   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 504                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 505
 506   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 507   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 508
 509   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 510   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 511   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 512   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 513   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 514   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_hwaccel_clear_tag])
 515
 516   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 517   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 518   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 519                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 520   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 521                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 522
 523   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 524                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 525   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 526                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 527   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 528                         [ip_do_fragment], [net],
 529                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 530   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 531                         [ip_local_out], [net],
 532                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 533
 534   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 535
 536   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 537                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 538   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 539   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 540                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 541   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 542                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 543   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 544   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 545   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 546                         [frags_work])
 547   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 548                         [rwlock])
 549   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 550                         [list_evictor])
 551   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 552   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 553                         [sub_frag_mem_limit], [struct.netns_frags],
 554                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 555   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 556                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 557   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 558                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 559
 560   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 561   dnl OVS does not really need ipv6 label field, but its presence signifies that
 562   dnl the stack has all required ipv6 support.
 563   dnl OVS also does not need dst_cache But this dependency allows us to write
 564   dnl much cleaner code.
 565
 566   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 567                         [label],
 568                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 569                                          [iptunnel_pull_offloads],
 570                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 571                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 572                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 573
 574   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 575                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 576   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 577                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 578   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 579                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 580   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 581   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 582   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 583   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 584   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 585   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 586   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 587   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 588   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 589   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 590                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 591   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 592   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 593   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 594   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 595   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 596   dnl So check type of tstats.
 597   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 598                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 599   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 600                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 601   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 602   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 603   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 604                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 605   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 606   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 607   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 608                         [extended])
 609   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 610                         [netdev_master_upper_dev_link], [upper_priv],
 611                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 612   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 613                   [netdev_master_upper_dev_link_rh],
 614                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 615
 616   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 617                         [max_mtu])
 618   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 619                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 620   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 621                         [dev_change_flags], [extack],
 622                         [OVS_DEFINE([HAVE_DEV_CHANGE_FLAGS_TAKES_EXTACK])])
 623
 624   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 625   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state],
 626                         [struct net ], [OVS_DEFINE([HAVE_NF_HOOK_STATE_NET])])
 627   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 628   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 629                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 630   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 631                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 632   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 633                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 634   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 635
 636
 637   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 638                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 639
 640   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 641                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 642                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 643   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 644                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 645
 646   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 647                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 648                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 649   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 650                   [nf_ct_get_tuplepr], [struct.net],
 651                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 652   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 653                   [nf_ct_set])
 654   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 655                   [nf_ct_is_untracked])
 656   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 657                   [nf_ct_zone_init])
 658   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 659                   [net_ns_get])
 660   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 661                   [nf_connlabels_get])
 662   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 663                   [nf_connlabels_get], [int bit],
 664                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 665   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 666                         [nf_conn_labels], [words])
 667   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 668   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 669   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 670   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 671   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 672                   [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])
 673
 674   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 675   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 676
 677   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 678   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 679   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 680                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 681   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 682
 683   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 684                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 685                                    [rcu_read_lock_held])])
 686   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 687   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 688   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
 689                         [rtnl_create_link], [extack],
 690                         [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_TAKES_EXTACK])])
 691
 692   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 693   # is necessary because some versions of this header remove the
 694   # member but retain the kerneldoc comment that describes it (which
 695   # starts with @).  The brackets must be doubled because of m4
 696   # quoting rules.
 697   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 698                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 699   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 700   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 701   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 702   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 703   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 704   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 705   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 706                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 707   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 708                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 709   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 710                   [skb_copy_from_linear_data_offset])
 711   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 712                   [skb_reset_tail_pointer])
 713   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 714   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 715                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 716   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 717   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 718   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 719   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 720   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 721   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 722   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 723   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 724                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 725   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 726   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 727                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 728   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 729                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 730   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 731   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 732   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 733   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 734   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 735   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 736   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 737   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 738   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 739
 740   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 741                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 742   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 743                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 744   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 745                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 746
 747   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 748   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 749
 750   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 751   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 752
 753   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 754   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 755   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 756   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 757                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 758   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 759   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 760                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 761   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 762                         [genl_notify], [net],
 763                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 764
 765
 766   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 767                         [genl_multicast_group], [id])
 768   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 769
 770   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 771   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 772   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 773   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 774   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 775   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 776                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 777   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 778                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 779
 780   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 781   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 782   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 783   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 784   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 785   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 786   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 787   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 788   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 789                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 790   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 791                         [nla_parse], [netlink_ext_ack],
 792                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 793
 794   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 795
 796   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 797                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 798   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 799   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 800   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 801   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 802   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 803
 804   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 805                         [metadata_dst_alloc], [metadata_type])
 806
 807   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 808
 809   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 810                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 811   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 812                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 813                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 814   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 815   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 816   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 817                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 818   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 819                         [gro_receive])
 820
 821   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 822                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 823   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 824                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 825
 826   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 827   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 828   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 829                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 830   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 831                         [udp_add_offload], [net],
 832                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 833   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 834                         [nf_defrag_ipv6_enable], [net],
 835                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 836   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 837                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 838   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 839                         [needs_free_netdev],
 840                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 841   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 842                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 843   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 844                   [nf_conntrack_helper_put],
 845                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 846   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 847                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 848   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 849                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 850   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 851                         [extack],
 852                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 853   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 854                         [list],
 855                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 856   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 857                   [IP_CT_UNTRACKED])
 858   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 859                         [netdev_master_upper_dev_link], [extack],
 860                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 861   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 862                   [__LINUX_COMPILER_TYPES_H],
 863                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 864   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 865                   [ktime_get_ts64],
 866                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 867   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 868                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 869                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 870   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 871                   [ktime_get_ns],
 872                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 873   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 874                   frag_percpu_counter_batch[],
 875                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 876   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 877                   [null_compute_pseudo],
 878                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 879   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 880                   [__skb_checksum_convert],
 881                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
 882   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 883                         [max_mtu],
 884                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
 885   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
 886                         [erspan_ver],
 887                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
 888   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 889                   [SKB_GSO_IPXIP6],
 890                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
 891   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
 892                         [ip6_make_flowlabel], [fl6],
 893                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
 894   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
 895                         [auto_flowlabels],
 896                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
 897   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 898                   [netif_keep_dst],
 899                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
 900   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 901                         [ndo_get_iflink],
 902                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
 903   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 904                   [skb_set_inner_ipproto],
 905                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
 906   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 907                   [tunnel_encap_types],
 908                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
 909   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 910                   [IFLA_IPTUN_ENCAP_TYPE],
 911                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
 912   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 913                   [IFLA_IPTUN_COLLECT_METADATA],
 914                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
 915   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 916                   [IFLA_GRE_ENCAP_DPORT])
 917   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 918                   [IFLA_GRE_COLLECT_METADATA])
 919   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 920                   [IFLA_GRE_IGNORE_DF])
 921   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 922                   [IFLA_GRE_FWMARK])
 923   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 924                   [IFLA_GRE_ERSPAN_INDEX])
 925   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 926                   [IFLA_GRE_ERSPAN_HWID])
 927   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 928                   [IFLA_IPTUN_FWMARK])
 929   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
 930                         [csum_valid],
 931                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
 932   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
 933                         [vlan_present],
 934                         [OVS_DEFINE([HAVE_SKBUFF_VLAN_PRESENT])])
 935   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 936                   [skb_checksum_simple_validate])
 937   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 938                   [void.*ndo_get_stats64],
 939                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
 940   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
 941                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
 942   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
 943                         [ip_tunnel_info_opts_set], [flags],
 944                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
 945   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 946                         [rnd],
 947                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
 948   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [__LINUX_OVERFLOW_H],
 949                   [OVS_DEFINE([HAVE_OVERFLOW_H])])
 950   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [struct_size],
 951                   [OVS_DEFINE([HAVE_STRUCT_SIZE])])
 952   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_array],
 953                   [OVS_DEFINE([HAVE_KVMALLOC_ARRAY])])
 954   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_node],
 955                   [OVS_DEFINE([HAVE_KVMALLOC_NODE])])
 956   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 957                   [nf_conntrack_l3proto],
 958                   [OVS_DEFINE([HAVE_NF_CONNTRACK_L3PROATO_H])])
 959   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_core.h],
 960                         [nf_conntrack_in], [nf_hook_state],
 961                         [OVS_DEFINE([HAVE_NF_CONNTRACK_IN_TAKES_NF_HOOK_STATE])])
 962   OVS_GREP_IFELSE([$KSRC/include/net/ipv6_frag.h], [IP6_DEFRAG_CONNTRACK_IN],
 963                   [OVS_DEFINE([HAVE_IPV6_FRAG_H])])
 964   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 965                         [nf_ct_helper_ext_add], [nf_conntrack_helper],
 966                         [OVS_DEFINE([HAVE_NF_CT_HELPER_EXT_ADD_TAKES_HELPER])])
 967
 968   if cmp -s datapath/linux/kcompat.h.new \
 969             datapath/linux/kcompat.h >/dev/null 2>&1; then
 970     rm datapath/linux/kcompat.h.new
 971   else
 972     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 973   fi
 974 ])
 975
 976 dnl Checks for net/if_dl.h.
 977 dnl
 978 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 979 dnl or NetBSD.)
 980 AC_DEFUN([OVS_CHECK_IF_DL],
 981   [AC_CHECK_HEADER([net/if_dl.h],
 982                    [HAVE_IF_DL=yes],
 983                    [HAVE_IF_DL=no])
 984    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 985    if test "$HAVE_IF_DL" = yes; then
 986       AC_DEFINE([HAVE_IF_DL], [1],
 987                 [Define to 1 if net/if_dl.h is available.])
 988
 989       # On these platforms we use libpcap to access network devices.
 990       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 991    fi])
 992
 993 dnl Checks for buggy strtok_r.
 994 dnl
 995 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 996 dnl with optimization that can cause segfaults:
 997 dnl
 998 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 999 AC_DEFUN([OVS_CHECK_STRTOK_R],
1000   [AC_CACHE_CHECK(
1001      [whether strtok_r macro segfaults on some inputs],
1002      [ovs_cv_strtok_r_bug],
1003      [AC_RUN_IFELSE(
1004         [AC_LANG_PROGRAM([#include <stdio.h>
1005                           #include <string.h>
1006                          ],
1007                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
1008                            /* Assume bug is present, because relatively minor
1009                               changes in compiler settings (e.g. optimization
1010                               level) can make it crop up. */
1011                            return 1;
1012                            #else
1013                            char string[] = ":::";
1014                            char *save_ptr = (char *) 0xc0ffee;
1015                            char *token1, *token2;
1016                            token1 = strtok_r(string, ":", &save_ptr);
1017                            token2 = strtok_r(NULL, ":", &save_ptr);
1018                            freopen ("/dev/null", "w", stdout);
1019                            printf ("%s %s\n", token1, token2);
1020                            return 0;
1021                            #endif
1022                           ]])],
1023         [ovs_cv_strtok_r_bug=no],
1024         [ovs_cv_strtok_r_bug=yes],
1025         [ovs_cv_strtok_r_bug=yes])])
1026    if test $ovs_cv_strtok_r_bug = yes; then
1027      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1028                [Define if strtok_r macro segfaults on some inputs])
1029    fi
1030 ])
1031
1032 dnl ----------------------------------------------------------------------
1033 dnl These macros are from GNU PSPP, with the following original license:
1034 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1035 dnl This file is free software; the Free Software Foundation
1036 dnl gives unlimited permission to copy and/or distribute it,
1037 dnl with or without modifications, as long as this notice is preserved.
1038
1039 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1040   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1041   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1042     [ovs_save_CFLAGS="$CFLAGS"
1043      dnl Include -Werror in the compiler options, because without -Werror
1044      dnl clang's GCC-compatible compiler driver does not return a failure
1045      dnl exit status even though it complains about options it does not
1046      dnl understand.
1047      dnl
1048      dnl Also, check stderr as gcc exits with status 0 for options
1049      dnl rejected at getopt level.
1050      dnl    % touch /tmp/a.c
1051      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1052      dnl    gcc: unrecognized option '-Qunused-arguments'
1053      dnl    0
1054      dnl    %
1055      dnl
1056      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1057      dnl it does not understand, unless it has another error to report, so
1058      dnl instead of testing for -Wno-<foo>, test for the positive version.
1059      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1060      AC_COMPILE_IFELSE(
1061        [AC_LANG_SOURCE([int x;])],
1062        [if test -s conftest.err && grep "unrecognized option" conftest.err
1063         then
1064           ovs_cv_name[]=no
1065         else
1066           ovs_cv_name[]=yes
1067         fi],
1068        [ovs_cv_name[]=no])
1069      CFLAGS="$ovs_save_CFLAGS"])
1070   if test $ovs_cv_name = yes; then
1071     m4_if([$2], [], [:], [$2])
1072   else
1073     m4_if([$3], [], [:], [$3])
1074   fi
1075 ])
1076
1077 dnl OVS_CHECK_WERROR
1078 dnl
1079 dnl Check whether the C compiler accepts -Werror.
1080 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1081 AC_DEFUN([OVS_CHECK_WERROR],
1082   [WERROR=
1083    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1084
1085 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1086 dnl Check whether the given C compiler OPTION is accepted.
1087 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1088 AC_DEFUN([OVS_CHECK_CC_OPTION],
1089   [AC_REQUIRE([OVS_CHECK_WERROR])
1090    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1091
1092 dnl OVS_ENABLE_OPTION([OPTION])
1093 dnl Check whether the given C compiler OPTION is accepted.
1094 dnl If so, add it to WARNING_FLAGS.
1095 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1096 AC_DEFUN([OVS_ENABLE_OPTION],
1097   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1098    AC_SUBST([WARNING_FLAGS])])
1099
1100 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1101 dnl Check whether the given C compiler OPTION is accepted.
1102 dnl If so, enable the given Automake CONDITIONAL.
1103
1104 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1105 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1106   [OVS_CHECK_CC_OPTION(
1107     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1108    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1109 dnl ----------------------------------------------------------------------
1110
1111 dnl Check for too-old XenServer.
1112 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1113   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1114     [if test -e /etc/redhat-release; then
1115        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1116      fi
1117      if test -z "$ovs_cv_xsversion"; then
1118        ovs_cv_xsversion=none
1119      fi])
1120   case $ovs_cv_xsversion in
1121     none)
1122       ;;
1123
1124     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1125     [[6-9]]* |                           dnl XenServer 6 or later
1126     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1127     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1128     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1129     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1130       ;;
1131
1132     *)
1133       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1134       ;;
1135   esac])
1136
1137 dnl OVS_CHECK_SPARSE_TARGET
1138 dnl
1139 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1140 dnl target for which the code is being built.  This helps it out.
1141 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1142   [AC_CACHE_CHECK(
1143     [target hint for cgcc],
1144     [ac_cv_sparse_target],
1145     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1146        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1147        [x86_64-*], [ac_cv_sparse_target=x86_64],
1148        [ac_cv_sparse_target=other])])
1149    AS_CASE([$ac_cv_sparse_target],
1150      [x86], [SPARSEFLAGS= CGCCFLAGS="-target=i86 -target=host_os_specs"],
1151      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS="-target=x86_64 -target=host_os_specs"],
1152      [SPARSEFLAGS= CGCCFLAGS=])
1153
1154    dnl Get the the default defines for vector instructions from compiler to
1155    dnl allow "sparse" correctly check the same code that will be built.
1156    dnl Required for checking DPDK headers.
1157    AC_MSG_CHECKING([vector options for cgcc])
1158    VECTOR=$($CC -dM -E - < /dev/null | grep -E "MMX|SSE|AVX" | \
1159             cut -c 9- | sed 's/ /=/' | sed 's/^/-D/' | tr '\n' ' ')
1160    AC_MSG_RESULT([$VECTOR])
1161    CGCCFLAGS="$CGCCFLAGS $VECTOR"
1162
1163    AC_SUBST([SPARSEFLAGS])
1164    AC_SUBST([CGCCFLAGS])])
1165
1166 dnl OVS_SPARSE_EXTRA_INCLUDES
1167 dnl
1168 dnl The cgcc script from "sparse" does not search gcc's default
1169 dnl search path. Get the default search path from GCC and pass
1170 dnl them to sparse.
1171 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1172     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1173            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1174
1175 dnl OVS_ENABLE_SPARSE
1176 AC_DEFUN([OVS_ENABLE_SPARSE],
1177   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1178    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1179    : ${SPARSE=sparse}
1180    AC_SUBST([SPARSE])
1181    AC_CONFIG_COMMANDS_PRE(
1182      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1183
1184    AC_ARG_ENABLE(
1185      [sparse],
1186      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1187      [], [enable_sparse=no])
1188    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1189
1190 dnl OVS_CTAGS_IDENTIFIERS
1191 dnl
1192 dnl ctags ignores symbols with extras identifiers. This builds a list of
1193 dnl specially handled identifiers to be ignored.
1194 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1195     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1196            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1197
1198 dnl OVS_PTHREAD_SET_NAME
1199 dnl
1200 dnl This checks for three known variants of pthreads functions for setting
1201 dnl the name of the current thread:
1202 dnl
1203 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1204 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1205 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1206 dnl
1207 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1208 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1209 dnl provide to it.
1210 dnl
1211 dnl This macro defines:
1212 dnl
1213 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1214 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1215 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1216 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1217   [AC_CHECK_FUNCS([pthread_set_name_np])
1218    if test $ac_cv_func_pthread_set_name_np != yes; then
1219      AC_CACHE_CHECK(
1220        [for pthread_setname_np() variant],
1221        [ovs_cv_pthread_setname_np],
1222        [AC_LINK_IFELSE(
1223          [AC_LANG_PROGRAM([#include <pthread.h>
1224   ], [pthread_setname_np(pthread_self(), "name");])],
1225          [ovs_cv_pthread_setname_np=glibc],
1226          [AC_LINK_IFELSE(
1227            [AC_LANG_PROGRAM([#include <pthread.h>
1228 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1229            [ovs_cv_pthread_setname_np=netbsd],
1230            [ovs_cv_pthread_setname_np=none])])])
1231      case $ovs_cv_pthread_setname_np in # (
1232        glibc)
1233           AC_DEFINE(
1234             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1235             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1236           ;; # (
1237        netbsd)
1238           AC_DEFINE(
1239             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1240             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1241           ;;
1242      esac
1243    fi])
1244
1245 dnl OVS_CHECK_LINUX_HOST.
1246 dnl
1247 dnl Checks whether we're building for a Linux host, based on the presence of
1248 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1249 dnl LINUX based on the result.
1250 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1251   [AC_CACHE_CHECK(
1252      [whether __linux__ is defined],
1253      [ovs_cv_linux],
1254      [AC_COMPILE_IFELSE(
1255         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1256         [ovs_cv_linux=true],
1257         [ovs_cv_linux=false])])
1258    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])