acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 4; then
 137        if test "$version" = 4 && test "$patchlevel" -le 11; then
 138           : # Linux 4.x
 139        else
 140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.11.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 143        : # Linux 3.x
 144     else
 145        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 146     fi
 147     if (test ! -e "$KBUILD"/include/linux/version.h && \
 148         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 149        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 150         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 151         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 152     fi
 153     OVS_CHECK_LINUX_COMPAT
 154   fi
 155   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 156 ])
 157
 158 dnl OVS_CHECK_DPDK
 159 dnl
 160 dnl Configure DPDK source tree
 161 AC_DEFUN([OVS_CHECK_DPDK], [
 162   AC_ARG_WITH([dpdk],
 163               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 164                               [Specify the DPDK build directory])],
 165               [have_dpdk=true])
 166
 167   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 168   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 169     AC_MSG_RESULT([no])
 170     DPDKLIB_FOUND=false
 171   else
 172     AC_MSG_RESULT([yes])
 173     case "$with_dpdk" in
 174       yes)
 175         DPDK_AUTO_DISCOVER="true"
 176         DPDK_INCLUDE="/usr/local/include/dpdk -I/usr/include/dpdk"
 177         ;;
 178       *)
 179         DPDK_AUTO_DISCOVER="false"
 180         DPDK_INCLUDE="$with_dpdk/include"
 181         # If 'with_dpdk' is passed install directory, point to headers
 182         # installed in $DESTDIR/$prefix/include/dpdk
 183         AC_CHECK_FILE([$DPDK_INCLUDE/rte_config.h], [],
 184                       [AC_CHECK_FILE([$DPDK_INCLUDE/dpdk/rte_config.h],
 185                                      [DPDK_INCLUDE=$DPDK_INCLUDE/dpdk], [])])
 186         DPDK_LIB_DIR="$with_dpdk/lib"
 187         ;;
 188     esac
 189
 190     DPDK_LIB="-ldpdk"
 191     DPDK_EXTRA_LIB=""
 192
 193     ovs_save_CFLAGS="$CFLAGS"
 194     ovs_save_LDFLAGS="$LDFLAGS"
 195     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 196     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 197       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 198     fi
 199
 200     AC_COMPILE_IFELSE([
 201       AC_LANG_PROGRAM(
 202         [
 203           #include <rte_config.h>
 204 #if RTE_LIBRTE_VHOST_NUMA
 205 #error
 206 #endif
 207         ], [])
 208       ], [],
 209       [AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])])
 210        DPDK_EXTRA_LIB="-lnuma"
 211        AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])])
 212
 213     AC_COMPILE_IFELSE([
 214       AC_LANG_PROGRAM(
 215         [
 216           #include <rte_config.h>
 217 #if RTE_LIBRTE_PMD_PCAP
 218 #error
 219 #endif
 220         ], [])
 221       ], [],
 222       [AC_SEARCH_LIBS([pcap_dump],[pcap],[],[AC_MSG_ERROR([unable to find libpcap, install the dependency package])])
 223        DPDK_EXTRA_LIB="-lpcap"
 224        AC_COMPILE_IFELSE([
 225          AC_LANG_PROGRAM(
 226            [
 227              #include <rte_config.h>
 228 #if RTE_LIBRTE_PDUMP
 229 #error
 230 #endif
 231          ], [])
 232        ], [],
 233        [AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])])
 234      ])
 235
 236     # On some systems we have to add -ldl to link with dpdk
 237     #
 238     # This code, at first, tries to link without -ldl (""),
 239     # then adds it and tries again.
 240     # Before each attempt the search cache must be unset,
 241     # otherwise autoconf will stick with the old result
 242
 243     DPDKLIB_FOUND=false
 244     save_LIBS=$LIBS
 245     for extras in "" "-ldl"; do
 246         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 247         AC_LINK_IFELSE(
 248            [AC_LANG_PROGRAM([#include <rte_config.h>
 249                              #include <rte_eal.h>],
 250                             [int rte_argc; char ** rte_argv;
 251                              rte_eal_init(rte_argc, rte_argv);])],
 252            [DPDKLIB_FOUND=true])
 253         if $DPDKLIB_FOUND; then
 254             break
 255         fi
 256     done
 257
 258     # If linking unsuccessful
 259     if test "$DPDKLIB_FOUND" = "false" ; then
 260       if $DPDK_AUTO_DISCOVER; then
 261         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 262       else
 263         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 264       fi
 265     fi
 266     CFLAGS="$ovs_save_CFLAGS"
 267     LDFLAGS="$ovs_save_LDFLAGS"
 268     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 269       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 270     fi
 271     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE"
 272     OVS_ENABLE_OPTION([-mssse3])
 273
 274     # DPDK pmd drivers are not linked unless --whole-archive is used.
 275     #
 276     # This happens because the rest of the DPDK code doesn't use any symbol in
 277     # the pmd driver objects, and the drivers register themselves using an
 278     # __attribute__((constructor)) function.
 279     #
 280     # These options are specified inside a single -Wl directive to prevent
 281     # autotools from reordering them.
 282     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 283     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 284     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 285   fi
 286
 287   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 288 ])
 289
 290 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 291 dnl
 292 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 293 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 294 dnl <REGEX> translated to uppercase.
 295 AC_DEFUN([OVS_GREP_IFELSE], [
 296   AC_MSG_CHECKING([whether $2 matches in $1])
 297   if test -f $1; then
 298     grep '$2' $1 >/dev/null 2>&1
 299     status=$?
 300     case $status in
 301       0)
 302         AC_MSG_RESULT([yes])
 303         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 304         ;;
 305       1)
 306         AC_MSG_RESULT([no])
 307         $4
 308         ;;
 309       *)
 310         AC_MSG_ERROR([grep exited with status $status])
 311         ;;
 312     esac
 313   else
 314     AC_MSG_RESULT([file not found])
 315     $4
 316   fi
 317 ])
 318
 319 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 320 dnl
 321 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 322 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 323 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 324 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 325 dnl translated to uppercase.
 326 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 327   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 328   if test -f $1; then
 329     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 330     status=$?
 331     case $status in
 332       0)
 333         AC_MSG_RESULT([yes])
 334         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 335         ;;
 336       1)
 337         AC_MSG_RESULT([no])
 338         $5
 339         ;;
 340       *)
 341         AC_MSG_ERROR([grep exited with status $status])
 342         ;;
 343     esac
 344   else
 345     AC_MSG_RESULT([file not found])
 346     $5
 347   fi
 348 ])
 349
 350 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 351 dnl
 352 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 353 dnl the function signature starting from the line matching FUNCTION
 354 dnl and ending with the line containing the closing parenthesis.  If
 355 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 356 dnl IF-MATCH is empty then it defines to
 357 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 358 dnl <REGEX> translated to uppercase.
 359 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 360   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 361   if test -f $1; then
 362     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 363     status=$?
 364     case $status in
 365       0)
 366         AC_MSG_RESULT([yes])
 367         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 368         ;;
 369       1)
 370         AC_MSG_RESULT([no])
 371         $5
 372         ;;
 373       *)
 374         AC_MSG_ERROR([grep exited with status $status])
 375         ;;
 376     esac
 377   else
 378     AC_MSG_RESULT([file not found])
 379     $5
 380   fi
 381 ])
 382
 383 dnl OVS_DEFINE(NAME)
 384 dnl
 385 dnl Defines NAME to 1 in kcompat.h.
 386 AC_DEFUN([OVS_DEFINE], [
 387   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 388 ])
 389
 390 dnl OVS_CHECK_LINUX_COMPAT
 391 dnl
 392 dnl Runs various Autoconf checks on the Linux kernel source in
 393 dnl the directory in $KBUILD.
 394 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 395   rm -f datapath/linux/kcompat.h.new
 396   mkdir -p datapath/linux
 397   : > datapath/linux/kcompat.h.new
 398
 399   echo '#include <linux/version.h>
 400 #ifndef RHEL_RELEASE_CODE
 401 #define RHEL_RELEASE_CODE 0
 402 #define RHEL_RELEASE_VERSION(a, b) 0
 403 #endif' >> datapath/linux/kcompat.h.new
 404
 405   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 406                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 407
 408   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 409                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 410   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 411
 412   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 413   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 414   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 415
 416   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 417   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 418
 419   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 420   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 421   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 422   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 423   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 424
 425   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 426   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 427   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 428                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 429   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 430                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 431
 432   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 433                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 434   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 435                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 436   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 437                         [ip_do_fragment], [net],
 438                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 439   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 440                         [ip_local_out], [net],
 441                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 442
 443   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 444
 445   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 446                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 447   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 448   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 449                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 450   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 451                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 452   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 453   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 454   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 455                         [frags_work])
 456   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 457                         [rwlock])
 458   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 459                         [list_evictor])
 460   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 461   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 462                         [sub_frag_mem_limit], [struct.netns_frags],
 463                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 464   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 465                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 466   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 467                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 468
 469   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 470   dnl OVS does not really need ipv6 label field, but its presence signifies that
 471   dnl the stack has all required ipv6 support.
 472   dnl OVS also does not need dst_cache But this dependency allows us to write
 473   dnl much cleaner code.
 474
 475   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 476                         [label],
 477                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 478                                          [iptunnel_pull_offloads],
 479                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 480                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])
 481
 482   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 483                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 484   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 485   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 486   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 487   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 488   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 489   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 490   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 491   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 492   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 493                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 494   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 495   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 496   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 497   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 498   dnl So check type of tstats.
 499   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 500                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 501   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 502                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 503   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 504   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 505                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 506   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 507   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 508   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 509                         [extended])
 510   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 511                         [netdev_master_upper_dev_link], [upper_priv],
 512                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 513   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 514                         [max_mtu])
 515
 516   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 517   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 518   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 519                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 520   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 521                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 522   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 523                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 524
 525   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 526                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 527
 528   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 529                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 530                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 531   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 532                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 533
 534   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 535                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 536                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 537   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 538                   [nf_ct_get_tuplepr], [struct.net],
 539                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 540   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 541                   [nf_ct_set])
 542   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 543                   [nf_ct_zone_init])
 544   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 545                   [nf_connlabels_get])
 546   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 547                   [nf_connlabels_get], [int bit],
 548                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 549   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 550                         [nf_conn_labels], [words])
 551   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 552   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 553   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 554
 555   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 556   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 557
 558   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 559   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 560   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 561                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 562   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 563
 564   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 565                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 566                                    [rcu_read_lock_held])])
 567   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 568
 569   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 570   # is necessary because some versions of this header remove the
 571   # member but retain the kerneldoc comment that describes it (which
 572   # starts with @).  The brackets must be doubled because of m4
 573   # quoting rules.
 574   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 575                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 576   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 577   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 578   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 579   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 580   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 581   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 582   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 583                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 584   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 585                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 586   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 587                   [skb_copy_from_linear_data_offset])
 588   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 589                   [skb_reset_tail_pointer])
 590   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 591   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 592                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 593   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 594   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 595   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 596   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 597   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 598   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 599   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 600   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 601                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 602   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 603   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 604                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 605   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 606                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 607   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 608   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 609   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 610   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 611   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 612   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 613   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 614   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 615
 616   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 617                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 618   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 619                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 620   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 621                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 622
 623   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 624   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 625
 626   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 627   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 628
 629   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 630   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 631   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 632   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 633                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 634   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 635   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 636                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 637   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 638                         [genl_notify], [net],
 639                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 640
 641
 642   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 643                         [genl_multicast_group], [id])
 644   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 645
 646   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 647   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 648   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 649   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 650   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 651   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 652                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 653   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 654                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 655
 656   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 657   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 658   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 659   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 660   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 661   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 662   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 663   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 664   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 665                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 666   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 667                         [nla_parse], [netlink_ext_ack],
 668                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 669
 670   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 671
 672   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 673                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 674   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 675   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 676   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 677   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 678   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 679
 680   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 681
 682   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 683                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 684   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 685                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 686                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 687   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 688   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 689   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 690                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 691   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 692                         [gro_receive])
 693
 694   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 695                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 696   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 697                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 698
 699   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 700   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 701   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 702                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 703   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 704                         [udp_add_offload], [net],
 705                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 706
 707
 708   if cmp -s datapath/linux/kcompat.h.new \
 709             datapath/linux/kcompat.h >/dev/null 2>&1; then
 710     rm datapath/linux/kcompat.h.new
 711   else
 712     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 713   fi
 714 ])
 715
 716 dnl Checks for net/if_packet.h.
 717 AC_DEFUN([OVS_CHECK_IF_PACKET],
 718   [AC_CHECK_HEADER([net/if_packet.h],
 719                    [HAVE_IF_PACKET=yes],
 720                    [HAVE_IF_PACKET=no])
 721    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 722    if test "$HAVE_IF_PACKET" = yes; then
 723       AC_DEFINE([HAVE_IF_PACKET], [1],
 724                 [Define to 1 if net/if_packet.h is available.])
 725    fi])
 726
 727 dnl Checks for net/if_dl.h.
 728 dnl
 729 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 730 dnl or NetBSD.)
 731 AC_DEFUN([OVS_CHECK_IF_DL],
 732   [AC_CHECK_HEADER([net/if_dl.h],
 733                    [HAVE_IF_DL=yes],
 734                    [HAVE_IF_DL=no])
 735    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 736    if test "$HAVE_IF_DL" = yes; then
 737       AC_DEFINE([HAVE_IF_DL], [1],
 738                 [Define to 1 if net/if_dl.h is available.])
 739
 740       # On these platforms we use libpcap to access network devices.
 741       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 742    fi])
 743
 744 dnl Checks for buggy strtok_r.
 745 dnl
 746 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 747 dnl with optimization that can cause segfaults:
 748 dnl
 749 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 750 AC_DEFUN([OVS_CHECK_STRTOK_R],
 751   [AC_CACHE_CHECK(
 752      [whether strtok_r macro segfaults on some inputs],
 753      [ovs_cv_strtok_r_bug],
 754      [AC_RUN_IFELSE(
 755         [AC_LANG_PROGRAM([#include <stdio.h>
 756                           #include <string.h>
 757                          ],
 758                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 759                            /* Assume bug is present, because relatively minor
 760                               changes in compiler settings (e.g. optimization
 761                               level) can make it crop up. */
 762                            return 1;
 763                            #else
 764                            char string[] = ":::";
 765                            char *save_ptr = (char *) 0xc0ffee;
 766                            char *token1, *token2;
 767                            token1 = strtok_r(string, ":", &save_ptr);
 768                            token2 = strtok_r(NULL, ":", &save_ptr);
 769                            freopen ("/dev/null", "w", stdout);
 770                            printf ("%s %s\n", token1, token2);
 771                            return 0;
 772                            #endif
 773                           ]])],
 774         [ovs_cv_strtok_r_bug=no],
 775         [ovs_cv_strtok_r_bug=yes],
 776         [ovs_cv_strtok_r_bug=yes])])
 777    if test $ovs_cv_strtok_r_bug = yes; then
 778      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 779                [Define if strtok_r macro segfaults on some inputs])
 780    fi
 781 ])
 782
 783 dnl ----------------------------------------------------------------------
 784 dnl These macros are from GNU PSPP, with the following original license:
 785 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 786 dnl This file is free software; the Free Software Foundation
 787 dnl gives unlimited permission to copy and/or distribute it,
 788 dnl with or without modifications, as long as this notice is preserved.
 789
 790 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 791   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
 792   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 793     [ovs_save_CFLAGS="$CFLAGS"
 794      dnl Include -Werror in the compiler options, because without -Werror
 795      dnl clang's GCC-compatible compiler driver does not return a failure
 796      dnl exit status even though it complains about options it does not
 797      dnl understand.
 798      dnl
 799      dnl Also, check stderr as gcc exits with status 0 for options
 800      dnl rejected at getopt level.
 801      dnl    % touch /tmp/a.c
 802      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 803      dnl    gcc: unrecognized option '-Qunused-arguments'
 804      dnl    0
 805      dnl    %
 806      CFLAGS="$CFLAGS $WERROR $1"
 807      AC_COMPILE_IFELSE(
 808        [AC_LANG_SOURCE([int x;])],
 809        [if test -s conftest.err && grep "unrecognized option" conftest.err
 810         then
 811           ovs_cv_name[]=no
 812         else
 813           ovs_cv_name[]=yes
 814         fi],
 815        [ovs_cv_name[]=no])
 816      CFLAGS="$ovs_save_CFLAGS"])
 817   if test $ovs_cv_name = yes; then
 818     m4_if([$2], [], [:], [$2])
 819   else
 820     m4_if([$3], [], [:], [$3])
 821   fi
 822 ])
 823
 824 dnl OVS_CHECK_WERROR
 825 dnl
 826 dnl Check whether the C compiler accepts -Werror.
 827 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 828 AC_DEFUN([OVS_CHECK_WERROR],
 829   [WERROR=
 830    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 831
 832 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 833 dnl Check whether the given C compiler OPTION is accepted.
 834 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 835 AC_DEFUN([OVS_CHECK_CC_OPTION],
 836   [AC_REQUIRE([OVS_CHECK_WERROR])
 837    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 838
 839 dnl OVS_ENABLE_OPTION([OPTION])
 840 dnl Check whether the given C compiler OPTION is accepted.
 841 dnl If so, add it to WARNING_FLAGS.
 842 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 843 AC_DEFUN([OVS_ENABLE_OPTION],
 844   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 845    AC_SUBST([WARNING_FLAGS])])
 846
 847 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 848 dnl Check whether the given C compiler OPTION is accepted.
 849 dnl If so, enable the given Automake CONDITIONAL.
 850
 851 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 852 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 853   [OVS_CHECK_CC_OPTION(
 854     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 855    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 856 dnl ----------------------------------------------------------------------
 857
 858 dnl Check for too-old XenServer.
 859 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 860   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 861     [if test -e /etc/redhat-release; then
 862        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 863      fi
 864      if test -z "$ovs_cv_xsversion"; then
 865        ovs_cv_xsversion=none
 866      fi])
 867   case $ovs_cv_xsversion in
 868     none)
 869       ;;
 870
 871     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 872     [[6-9]]* |                           dnl XenServer 6 or later
 873     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 874     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 875     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 876     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 877       ;;
 878
 879     *)
 880       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 881       ;;
 882   esac])
 883
 884 dnl OVS_CHECK_SPARSE_TARGET
 885 dnl
 886 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 887 dnl target for which the code is being built.  This helps it out.
 888 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 889   [AC_CACHE_CHECK(
 890     [target hint for cgcc],
 891     [ac_cv_sparse_target],
 892     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 893        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 894        [x86_64-*], [ac_cv_sparse_target=x86_64],
 895        [ac_cv_sparse_target=other])])
 896    AS_CASE([$ac_cv_sparse_target],
 897      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 898      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 899      [SPARSEFLAGS= CGCCFLAGS=])
 900    AC_SUBST([SPARSEFLAGS])
 901    AC_SUBST([CGCCFLAGS])])
 902
 903 dnl OVS_SPARSE_EXTRA_INCLUDES
 904 dnl
 905 dnl The cgcc script from "sparse" does not search gcc's default
 906 dnl search path. Get the default search path from GCC and pass
 907 dnl them to sparse.
 908 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 909     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 910            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 911
 912 dnl OVS_ENABLE_SPARSE
 913 AC_DEFUN([OVS_ENABLE_SPARSE],
 914   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 915    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 916    : ${SPARSE=sparse}
 917    AC_SUBST([SPARSE])
 918    AC_CONFIG_COMMANDS_PRE(
 919      [CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])])
 920
 921 dnl OVS_PTHREAD_SET_NAME
 922 dnl
 923 dnl This checks for three known variants of pthreads functions for setting
 924 dnl the name of the current thread:
 925 dnl
 926 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 927 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 928 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 929 dnl
 930 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 931 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 932 dnl provide to it.
 933 dnl
 934 dnl This macro defines:
 935 dnl
 936 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 937 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 938 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 939 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 940   [AC_CHECK_FUNCS([pthread_set_name_np])
 941    if test $ac_cv_func_pthread_set_name_np != yes; then
 942      AC_CACHE_CHECK(
 943        [for pthread_setname_np() variant],
 944        [ovs_cv_pthread_setname_np],
 945        [AC_LINK_IFELSE(
 946          [AC_LANG_PROGRAM([#include <pthread.h>
 947   ], [pthread_setname_np(pthread_self(), "name");])],
 948          [ovs_cv_pthread_setname_np=glibc],
 949          [AC_LINK_IFELSE(
 950            [AC_LANG_PROGRAM([#include <pthread.h>
 951 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 952            [ovs_cv_pthread_setname_np=netbsd],
 953            [ovs_cv_pthread_setname_np=none])])])
 954      case $ovs_cv_pthread_setname_np in # (
 955        glibc)
 956           AC_DEFINE(
 957             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 958             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 959           ;; # (
 960        netbsd)
 961           AC_DEFINE(
 962             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 963             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 964           ;;
 965      esac
 966    fi])
 967
 968 dnl OVS_CHECK_LINUX_HOST.
 969 dnl
 970 dnl Checks whether we're building for a Linux host, based on the presence of
 971 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 972 dnl LINUX based on the result.
 973 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 974   [AC_CACHE_CHECK(
 975      [whether __linux__ is defined],
 976      [ovs_cv_linux],
 977      [AC_COMPILE_IFELSE(
 978         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 979         [ovs_cv_linux=true],
 980         [ovs_cv_linux=false])])
 981    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])