acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2019 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 5; then
 154        if test "$version" = 5 && test "$patchlevel" -le 0; then
 155           : # Linux 5.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 5.0.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 4; then
 160        : # Linux 4.x
 161     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 162        : # Linux 3.x
 163     else
 164        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 165     fi
 166     if (test ! -e "$KBUILD"/include/linux/version.h && \
 167         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 168        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 169         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 170         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 171     fi
 172     OVS_CHECK_LINUX_COMPAT
 173   fi
 174   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 175 ])
 176
 177 dnl OVS_CHECK_LINUX_TC
 178 dnl
 179 dnl Configure Linux tc compat.
 180 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 181   AC_COMPILE_IFELSE([
 182     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 183         int x = TCA_FLOWER_KEY_ENC_IP_TTL_MASK;
 184     ])],
 185     [AC_DEFINE([HAVE_TCA_FLOWER_KEY_ENC_IP_TTL_MASK], [1],
 186                [Define to 1 if TCA_FLOWER_KEY_ENC_IP_TTL_MASK is available.])])
 187
 188   AC_COMPILE_IFELSE([
 189     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 190         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 191     ])],
 192     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 193                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 194
 195   AC_COMPILE_IFELSE([
 196     AC_LANG_PROGRAM([#include <linux/tc_act/tc_mpls.h>], [
 197         int x = TCA_MPLS_TTL;
 198     ])],
 199     [AC_DEFINE([HAVE_TCA_MPLS_TTL], [1],
 200                [Define to 1 if HAVE_TCA_MPLS_TTL is available.])])
 201
 202   AC_COMPILE_IFELSE([
 203     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 204         int x = TCA_TUNNEL_KEY_ENC_TTL;
 205     ])],
 206     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 207                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 208
 209   AC_COMPILE_IFELSE([
 210     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 211         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 212     ])],
 213     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 214                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 215
 216   AC_COMPILE_IFELSE([
 217     AC_LANG_PROGRAM([#include <linux/tc_act/tc_skbedit.h>], [
 218         int x = TCA_SKBEDIT_FLAGS;
 219     ])],
 220     [AC_DEFINE([HAVE_TCA_SKBEDIT_FLAGS], [1],
 221                [Define to 1 if TCA_SKBEDIT_FLAGS is available.])])
 222 ])
 223
 224 dnl OVS_CHECK_LINUX_SCTP_CT
 225 dnl
 226 dnl Checks for kernels which need additional SCTP state
 227 AC_DEFUN([OVS_CHECK_LINUX_SCTP_CT], [
 228   AC_COMPILE_IFELSE([
 229     AC_LANG_PROGRAM([#include <linux/netfilter/nfnetlink.h>
 230 #include <linux/netfilter/nfnetlink_conntrack.h>
 231 #include <linux/netfilter/nf_conntrack_common.h>
 232 #include <linux/netfilter/nf_conntrack_sctp.h>], [
 233         int x = SCTP_CONNTRACK_HEARTBEAT_SENT;
 234     ])],
 235     [AC_DEFINE([HAVE_SCTP_CONNTRACK_HEARTBEATS], [1],
 236                [Define to 1 if SCTP_CONNTRACK_HEARTBEAT_SENT is available.])])
 237 ])
 238
 239 dnl OVS_FIND_DEPENDENCY(FUNCTION, SEARCH_LIBS, NAME_TO_PRINT)
 240 dnl
 241 dnl Check for a function in a library list.
 242 AC_DEFUN([OVS_FIND_DEPENDENCY], [
 243   AC_SEARCH_LIBS([$1], [$2], [], [
 244     AC_MSG_ERROR([unable to find $3, install the dependency package])
 245   ])
 246 ])
 247
 248 dnl OVS_CHECK_LINUX_AF_XDP
 249 dnl
 250 dnl Check both Linux kernel AF_XDP and libbpf support
 251 AC_DEFUN([OVS_CHECK_LINUX_AF_XDP], [
 252   AC_ARG_ENABLE([afxdp],
 253                 [AC_HELP_STRING([--enable-afxdp], [Enable AF-XDP support])],
 254                 [], [enable_afxdp=no])
 255   AC_MSG_CHECKING([whether AF_XDP is enabled])
 256   if test "$enable_afxdp" != yes; then
 257     AC_MSG_RESULT([no])
 258     AF_XDP_ENABLE=false
 259   else
 260     AC_MSG_RESULT([yes])
 261     AF_XDP_ENABLE=true
 262
 263     AC_CHECK_HEADER([bpf/libbpf.h], [],
 264       [AC_MSG_ERROR([unable to find bpf/libbpf.h for AF_XDP support])])
 265
 266     AC_CHECK_HEADER([linux/if_xdp.h], [],
 267       [AC_MSG_ERROR([unable to find linux/if_xdp.h for AF_XDP support])])
 268
 269     AC_CHECK_HEADER([bpf/xsk.h], [],
 270       [AC_MSG_ERROR([unable to find bpf/xsk.h for AF_XDP support])])
 271
 272     AC_CHECK_FUNCS([pthread_spin_lock], [],
 273       [AC_MSG_ERROR([unable to find pthread_spin_lock for AF_XDP support])])
 274
 275     AC_DEFINE([HAVE_AF_XDP], [1],
 276               [Define to 1 if AF_XDP support is available and enabled.])
 277     LIBBPF_LDADD=" -lbpf -lelf"
 278     AC_SUBST([LIBBPF_LDADD])
 279
 280     AC_CHECK_DECL([xsk_ring_prod__needs_wakeup], [
 281       AC_DEFINE([HAVE_XDP_NEED_WAKEUP], [1],
 282         [XDP need wakeup support detected in xsk.h.])
 283     ], [], [[#include <bpf/xsk.h>]])
 284   fi
 285   AM_CONDITIONAL([HAVE_AF_XDP], test "$AF_XDP_ENABLE" = true)
 286 ])
 287
 288 dnl OVS_CHECK_DPDK
 289 dnl
 290 dnl Configure DPDK source tree
 291 AC_DEFUN([OVS_CHECK_DPDK], [
 292   AC_ARG_WITH([dpdk],
 293               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 294                               [Specify the DPDK build directory])],
 295               [have_dpdk=true])
 296
 297   AC_MSG_CHECKING([whether dpdk is enabled])
 298   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 299     AC_MSG_RESULT([no])
 300     DPDKLIB_FOUND=false
 301   else
 302     AC_MSG_RESULT([yes])
 303     case "$with_dpdk" in
 304       yes)
 305         DPDK_AUTO_DISCOVER="true"
 306         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 307             DPDK_INCLUDE="$DPDK_CFLAGS"
 308             DPDK_LIB="$DPDK_LIBS"], [
 309             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 310             DPDK_LIB="-ldpdk"])
 311         ;;
 312       *)
 313         DPDK_AUTO_DISCOVER="false"
 314         DPDK_INCLUDE_PATH="$with_dpdk/include"
 315         # If 'with_dpdk' is passed install directory, point to headers
 316         # installed in $DESTDIR/$prefix/include/dpdk
 317         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 318            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 319         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 320            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 321         fi
 322         DPDK_LIB_DIR="$with_dpdk/lib"
 323         DPDK_LIB="-ldpdk"
 324         ;;
 325     esac
 326
 327     ovs_save_CFLAGS="$CFLAGS"
 328     ovs_save_LDFLAGS="$LDFLAGS"
 329     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 330     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 331       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 332     fi
 333
 334     AC_CHECK_HEADERS([rte_config.h], [], [
 335       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 336     ], [AC_INCLUDES_DEFAULT])
 337
 338     AC_CHECK_DECLS([RTE_LIBRTE_VHOST_NUMA, RTE_EAL_NUMA_AWARE_HUGEPAGES], [
 339       OVS_FIND_DEPENDENCY([get_mempolicy], [numa], [libnuma])
 340     ], [], [[#include <rte_config.h>]])
 341
 342     AC_CHECK_DECL([RTE_LIBRTE_VHOST_NUMA], [
 343       AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])
 344     ], [], [[#include <rte_config.h>]])
 345
 346     AC_CHECK_DECL([RTE_LIBRTE_PMD_PCAP], [
 347       OVS_FIND_DEPENDENCY([pcap_dump], [pcap], [libpcap])
 348       AC_CHECK_DECL([RTE_LIBRTE_PDUMP], [
 349         AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])
 350       ], [], [[#include <rte_config.h>]])
 351     ], [], [[#include <rte_config.h>]])
 352
 353     AC_CHECK_DECL([RTE_LIBRTE_MLX5_PMD], [dnl found
 354       OVS_FIND_DEPENDENCY([mnl_attr_put], [mnl], [libmnl])
 355       AC_CHECK_DECL([RTE_LIBRTE_MLX5_DLOPEN_DEPS], [], [dnl not found
 356         OVS_FIND_DEPENDENCY([mlx5dv_create_wq], [mlx5], [libmlx5])
 357         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 358       ], [[#include <rte_config.h>]])
 359     ], [], [[#include <rte_config.h>]])
 360
 361     AC_CHECK_DECL([RTE_LIBRTE_MLX4_PMD], [dnl found
 362       AC_CHECK_DECL([RTE_LIBRTE_MLX4_DLOPEN_DEPS], [], [dnl not found
 363         OVS_FIND_DEPENDENCY([mlx4dv_init_obj], [mlx4], [libmlx4])
 364         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 365       ], [[#include <rte_config.h>]])
 366     ], [], [[#include <rte_config.h>]])
 367
 368     # DPDK uses dlopen to load plugins.
 369     OVS_FIND_DEPENDENCY([dlopen], [dl], [libdl])
 370
 371     AC_MSG_CHECKING([whether linking with dpdk works])
 372     LIBS="$DPDK_LIB $LIBS"
 373     AC_LINK_IFELSE(
 374       [AC_LANG_PROGRAM([#include <rte_config.h>
 375                         #include <rte_eal.h>],
 376                        [int rte_argc; char ** rte_argv;
 377                         rte_eal_init(rte_argc, rte_argv);])],
 378       [AC_MSG_RESULT([yes])
 379        DPDKLIB_FOUND=true],
 380       [AC_MSG_RESULT([no])
 381        if test "$DPDK_AUTO_DISCOVER" = "true"; then
 382          AC_MSG_ERROR(m4_normalize([
 383             Could not find DPDK library in default search path, Use --with-dpdk
 384             to specify the DPDK library installed in non-standard location]))
 385        else
 386          AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 387        fi
 388       ])
 389
 390     CFLAGS="$ovs_save_CFLAGS"
 391     LDFLAGS="$ovs_save_LDFLAGS"
 392     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 393       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 394     fi
 395     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 396     OVS_ENABLE_OPTION([-mssse3])
 397
 398     # DPDK pmd drivers are not linked unless --whole-archive is used.
 399     #
 400     # This happens because the rest of the DPDK code doesn't use any symbol in
 401     # the pmd driver objects, and the drivers register themselves using an
 402     # __attribute__((constructor)) function.
 403     #
 404     # These options are specified inside a single -Wl directive to prevent
 405     # autotools from reordering them.
 406     #
 407     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 408     # will already have flagged just the right set of libs with
 409     # --whole-archive - in those cases do not wrap it once more.
 410     case "$DPDK_LIB" in
 411       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 412       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 413     esac
 414     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 415     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 416   fi
 417
 418   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 419 ])
 420
 421 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 422 dnl
 423 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 424 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 425 dnl <REGEX> translated to uppercase.
 426 AC_DEFUN([OVS_GREP_IFELSE], [
 427   AC_MSG_CHECKING([whether $2 matches in $1])
 428   if test -f $1; then
 429     grep '$2' $1 >/dev/null 2>&1
 430     status=$?
 431     case $status in
 432       0)
 433         AC_MSG_RESULT([yes])
 434         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 435         ;;
 436       1)
 437         AC_MSG_RESULT([no])
 438         $4
 439         ;;
 440       *)
 441         AC_MSG_ERROR([grep exited with status $status])
 442         ;;
 443     esac
 444   else
 445     AC_MSG_RESULT([file not found])
 446     $4
 447   fi
 448 ])
 449
 450 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 451 dnl
 452 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 453 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 454 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 455 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 456 dnl translated to uppercase.
 457 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 458   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 459   if test -f $1; then
 460     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 461     status=$?
 462     case $status in
 463       0)
 464         AC_MSG_RESULT([yes])
 465         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 466         ;;
 467       1)
 468         AC_MSG_RESULT([no])
 469         $5
 470         ;;
 471       *)
 472         AC_MSG_ERROR([grep exited with status $status])
 473         ;;
 474     esac
 475   else
 476     AC_MSG_RESULT([file not found])
 477     $5
 478   fi
 479 ])
 480
 481 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 482 dnl
 483 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 484 dnl the function signature starting from the line matching FUNCTION
 485 dnl and ending with the line containing the closing parenthesis.  If
 486 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 487 dnl IF-MATCH is empty then it defines to
 488 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 489 dnl <REGEX> translated to uppercase.
 490 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 491   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 492   if test -f $1; then
 493     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 494     status=$?
 495     case $status in
 496       0)
 497         AC_MSG_RESULT([yes])
 498         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 499         ;;
 500       1)
 501         AC_MSG_RESULT([no])
 502         $5
 503         ;;
 504       *)
 505         AC_MSG_ERROR([grep exited with status $status])
 506         ;;
 507     esac
 508   else
 509     AC_MSG_RESULT([file not found])
 510     $5
 511   fi
 512 ])
 513
 514 dnl OVS_DEFINE(NAME)
 515 dnl
 516 dnl Defines NAME to 1 in kcompat.h.
 517 AC_DEFUN([OVS_DEFINE], [
 518   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 519 ])
 520
 521 dnl OVS_CHECK_LINUX_COMPAT
 522 dnl
 523 dnl Runs various Autoconf checks on the Linux kernel source in
 524 dnl the directory in $KBUILD.
 525 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 526   rm -f datapath/linux/kcompat.h.new
 527   mkdir -p datapath/linux
 528   : > datapath/linux/kcompat.h.new
 529
 530   echo '#include <linux/version.h>
 531 #ifndef RHEL_RELEASE_CODE
 532 #define RHEL_RELEASE_CODE 0
 533 #define RHEL_RELEASE_VERSION(a, b) 0
 534 #endif' >> datapath/linux/kcompat.h.new
 535
 536   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 537                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 538
 539   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 540                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 541
 542   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 543                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 544   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 545
 546   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 547   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 548   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 549
 550   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 551                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 552   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 553                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 554
 555   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 556   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 557
 558   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 559   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 560   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 561   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 562   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 563   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_hwaccel_clear_tag])
 564
 565   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 566   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 567   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 568                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 569   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 570                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 571
 572   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 573                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 574   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 575                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 576   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 577                         [ip_do_fragment], [net],
 578                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 579   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 580                         [ip_local_out], [net],
 581                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 582
 583   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 584
 585   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 586                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 587   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 588   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 589                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 590   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 591                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 592   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 593   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 594   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 595                         [frags_work])
 596   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 597                         [rwlock])
 598   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 599                         [list_evictor])
 600   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 601   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 602                         [sub_frag_mem_limit], [struct.netns_frags],
 603                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 604   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 605                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 606   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 607                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 608
 609   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 610   dnl OVS does not really need ipv6 label field, but its presence signifies that
 611   dnl the stack has all required ipv6 support.
 612   dnl OVS also does not need dst_cache But this dependency allows us to write
 613   dnl much cleaner code.
 614
 615   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 616                         [label],
 617                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 618                                          [iptunnel_pull_offloads],
 619                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 620                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 621                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 622
 623   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 624                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 625   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 626                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 627   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 628                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 629   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 630   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 631   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 632   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 633   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 634   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 635   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 636   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 637   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 638   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 639                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 640   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 641   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 642   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 643   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 644   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 645   dnl So check type of tstats.
 646   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 647                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 648   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 649                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 650   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 651   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 652   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 653                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 654   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 655   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 656   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 657                         [extended])
 658   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 659                         [netdev_master_upper_dev_link], [upper_priv],
 660                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 661   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 662                   [netdev_master_upper_dev_link_rh],
 663                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 664
 665   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 666                         [max_mtu])
 667   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 668                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 669   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 670                         [dev_change_flags], [extack],
 671                         [OVS_DEFINE([HAVE_DEV_CHANGE_FLAGS_TAKES_EXTACK])])
 672
 673   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 674   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state],
 675                         [struct net ], [OVS_DEFINE([HAVE_NF_HOOK_STATE_NET])])
 676   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 677   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 678                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 679   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 680                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 681   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 682                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 683   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 684   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [CONFIG_NF_NAT_NEEDED])
 685
 686
 687   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 688                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 689
 690   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 691                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 692                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 693   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 694                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 695
 696   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 697                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 698                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 699   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 700                   [nf_ct_get_tuplepr], [struct.net],
 701                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 702   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 703                   [nf_ct_set])
 704   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 705                   [nf_ct_is_untracked])
 706   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 707                   [nf_ct_invert_tuplepr])
 708   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 709                   [nf_ct_zone_init])
 710   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 711                   [net_ns_get])
 712   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 713                   [nf_connlabels_get])
 714   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 715                   [nf_connlabels_get], [int bit],
 716                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 717   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 718                         [nf_conn_labels], [words])
 719   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 720   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 721   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 722   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_packet],
 723                   [OVS_DEFINE([HAVE_UPSTREAM_NF_NAT])])
 724   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 725   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 726                   [OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h],
 727                                    [int nf_conncount_add],
 728                                    [], [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])])
 729   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [nf_ct_set_timeout])
 730   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [struct nf_ct_timeout],
 731                   [OVS_DEFINE([HAVE_NF_CT_TIMEOUT])])
 732   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h],
 733                         [\(*nf_ct_timeout_find_get_hook\)], [net],
 734                         [OVS_DEFINE([HAVE_NF_CT_TIMEOUT_FIND_GET_HOOK_NET])])
 735
 736   OVS_GREP_IFELSE([$KSRC/include/linux/random.h],
 737                   [prandom_u32[[\(]]],
 738                   [OVS_DEFINE([HAVE_PRANDOM_U32])])
 739   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 740
 741   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 742   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 743   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 744                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 745   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 746
 747   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 748                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 749                                    [rcu_read_lock_held])])
 750   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 751   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 752   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
 753                         [rtnl_create_link], [extack],
 754                         [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_TAKES_EXTACK])])
 755   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [nf_reset_ct])
 756
 757   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 758   # is necessary because some versions of this header remove the
 759   # member but retain the kerneldoc comment that describes it (which
 760   # starts with @).  The brackets must be doubled because of m4
 761   # quoting rules.
 762   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 763                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 764   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 765   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 766   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 767   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 768   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 769   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 770   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 771                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 772   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 773                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 774   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 775                   [skb_copy_from_linear_data_offset])
 776   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 777                   [skb_reset_tail_pointer])
 778   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 779   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 780                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 781   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 782   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 783   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 784   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 785   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 786   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 787   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 788   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 789                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 790   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 791   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 792                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 793   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 794                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 795   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 796   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 797   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 798   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 799   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 800   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 801   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 802   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 803   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 804
 805   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 806                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 807   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 808                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 809   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 810                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 811
 812   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 813   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 814
 815   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 816   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 817
 818   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 819   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 820   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 821   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 822                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 823   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 824   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 825                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 826   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_validate_flags])
 827   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 828                         [genl_notify], [net],
 829                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 830
 831
 832   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 833                         [genl_multicast_group], [id])
 834   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 835
 836   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 837   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 838   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 839   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 840   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 841   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 842                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 843   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 844                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 845
 846   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 847   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 848   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 849   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 850   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 851   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 852   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 853   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 854   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_nest_start_noflag])
 855   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 856                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 857   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 858                         [nla_parse], [netlink_ext_ack],
 859                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 860
 861   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 862
 863   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 864   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 865   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 866   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 867   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 868
 869   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 870                         [metadata_dst_alloc], [metadata_type])
 871
 872   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 873
 874   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 875                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 876   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 877                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 878                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 879   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 880   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 881   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 882                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 883   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 884                         [gro_receive])
 885
 886   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 887                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 888   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 889                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 890
 891   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 892   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 893   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 894                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 895   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 896                         [udp_add_offload], [net],
 897                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 898   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 899                         [nf_defrag_ipv6_enable], [net],
 900                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 901   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 902                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 903   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 904                         [needs_free_netdev],
 905                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 906   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 907                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 908   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 909                   [nf_conntrack_helper_put],
 910                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 911   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 912                   [nf_nat_helper_try_module_get])
 913   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 914                   [nf_nat_helper_put])
 915   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 916                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 917   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 918                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 919   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 920                         [extack],
 921                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 922   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 923                         [list],
 924                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 925   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 926                   [IP_CT_UNTRACKED])
 927   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 928                         [netdev_master_upper_dev_link], [extack],
 929                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 930   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 931                   [__LINUX_COMPILER_TYPES_H],
 932                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 933   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 934                   [ktime_get_ts64],
 935                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 936   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 937                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 938                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 939   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 940                   [ktime_get_ns],
 941                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 942   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 943                   frag_percpu_counter_batch[],
 944                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 945   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 946                   [null_compute_pseudo],
 947                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 948   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 949                   [__skb_checksum_convert],
 950                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
 951   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 952                         [max_mtu],
 953                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
 954   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
 955                         [erspan_ver],
 956                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
 957   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 958                   [SKB_GSO_IPXIP6],
 959                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
 960   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
 961                         [ip6_make_flowlabel], [fl6],
 962                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
 963   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
 964                         [auto_flowlabels],
 965                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
 966   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 967                   [netif_keep_dst],
 968                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
 969   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 970                         [ndo_get_iflink],
 971                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
 972   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 973                   [skb_set_inner_ipproto],
 974                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
 975   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 976                   [tunnel_encap_types],
 977                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
 978   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 979                   [IFLA_IPTUN_ENCAP_TYPE],
 980                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
 981   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 982                   [IFLA_IPTUN_COLLECT_METADATA],
 983                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
 984   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 985                   [IFLA_GRE_ENCAP_DPORT])
 986   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 987                   [IFLA_GRE_COLLECT_METADATA])
 988   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 989                   [IFLA_GRE_IGNORE_DF])
 990   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 991                   [IFLA_GRE_FWMARK])
 992   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 993                   [IFLA_GRE_ERSPAN_INDEX])
 994   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 995                   [IFLA_GRE_ERSPAN_HWID])
 996   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 997                   [IFLA_IPTUN_FWMARK])
 998   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
 999                         [csum_valid],
1000                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
1001   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1002                         [vlan_present],
1003                         [OVS_DEFINE([HAVE_SKBUFF_VLAN_PRESENT])])
1004   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1005                   [skb_checksum_simple_validate])
1006   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
1007                   [void.*ndo_get_stats64],
1008                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
1009   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
1010                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
1011   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
1012                         [ip_tunnel_info_opts_set], [flags],
1013                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
1014   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
1015                         [rnd],
1016                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
1017   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [__LINUX_OVERFLOW_H],
1018                   [OVS_DEFINE([HAVE_OVERFLOW_H])])
1019   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [struct_size],
1020                   [OVS_DEFINE([HAVE_STRUCT_SIZE])])
1021   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_array],
1022                   [OVS_DEFINE([HAVE_KVMALLOC_ARRAY])])
1023   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_node],
1024                   [OVS_DEFINE([HAVE_KVMALLOC_NODE])])
1025   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
1026                   [nf_conntrack_l3proto],
1027                   [OVS_DEFINE([HAVE_NF_CONNTRACK_L3PROATO_H])])
1028   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_core.h],
1029                         [nf_conntrack_in], [nf_hook_state],
1030                         [OVS_DEFINE([HAVE_NF_CONNTRACK_IN_TAKES_NF_HOOK_STATE])])
1031   OVS_GREP_IFELSE([$KSRC/include/net/ipv6_frag.h], [IP6_DEFRAG_CONNTRACK_IN],
1032                   [OVS_DEFINE([HAVE_IPV6_FRAG_H])])
1033   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
1034                         [nf_ct_helper_ext_add], [nf_conntrack_helper],
1035                         [OVS_DEFINE([HAVE_NF_CT_HELPER_EXT_ADD_TAKES_HELPER])])
1036   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_calc_hlen],
1037                   [OVS_DEFINE([HAVE_GRE_CALC_HLEN])])
1038   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [ip_gre_calc_hlen],
1039                   [OVS_DEFINE([HAVE_IP_GRE_CALC_HLEN])])
1040   OVS_GREP_IFELSE([$KSRC/include/linux/rbtree.h], [rb_link_node_rcu],
1041                   [OVS_DEFINE([HAVE_RBTREE_RB_LINK_NODE_RCU])])
1042
1043   if cmp -s datapath/linux/kcompat.h.new \
1044             datapath/linux/kcompat.h >/dev/null 2>&1; then
1045     rm datapath/linux/kcompat.h.new
1046   else
1047     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
1048   fi
1049 ])
1050
1051 dnl Checks for net/if_dl.h.
1052 dnl
1053 dnl (We use this as a proxy for checking whether we're building on FreeBSD
1054 dnl or NetBSD.)
1055 AC_DEFUN([OVS_CHECK_IF_DL],
1056   [AC_CHECK_HEADER([net/if_dl.h],
1057                    [HAVE_IF_DL=yes],
1058                    [HAVE_IF_DL=no])
1059    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
1060    if test "$HAVE_IF_DL" = yes; then
1061       AC_DEFINE([HAVE_IF_DL], [1],
1062                 [Define to 1 if net/if_dl.h is available.])
1063
1064       # On these platforms we use libpcap to access network devices.
1065       AC_SEARCH_LIBS([pcap_open_live], [pcap])
1066    fi])
1067
1068 dnl Checks for buggy strtok_r.
1069 dnl
1070 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
1071 dnl with optimization that can cause segfaults:
1072 dnl
1073 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
1074 AC_DEFUN([OVS_CHECK_STRTOK_R],
1075   [AC_CACHE_CHECK(
1076      [whether strtok_r macro segfaults on some inputs],
1077      [ovs_cv_strtok_r_bug],
1078      [AC_RUN_IFELSE(
1079         [AC_LANG_PROGRAM([#include <stdio.h>
1080                           #include <string.h>
1081                          ],
1082                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
1083                            /* Assume bug is present, because relatively minor
1084                               changes in compiler settings (e.g. optimization
1085                               level) can make it crop up. */
1086                            return 1;
1087                            #else
1088                            char string[] = ":::";
1089                            char *save_ptr = (char *) 0xc0ffee;
1090                            char *token1, *token2;
1091                            token1 = strtok_r(string, ":", &save_ptr);
1092                            token2 = strtok_r(NULL, ":", &save_ptr);
1093                            freopen ("/dev/null", "w", stdout);
1094                            printf ("%s %s\n", token1, token2);
1095                            return 0;
1096                            #endif
1097                           ]])],
1098         [ovs_cv_strtok_r_bug=no],
1099         [ovs_cv_strtok_r_bug=yes],
1100         [ovs_cv_strtok_r_bug=yes])])
1101    if test $ovs_cv_strtok_r_bug = yes; then
1102      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1103                [Define if strtok_r macro segfaults on some inputs])
1104    fi
1105 ])
1106
1107 dnl ----------------------------------------------------------------------
1108 dnl These macros are from GNU PSPP, with the following original license:
1109 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1110 dnl This file is free software; the Free Software Foundation
1111 dnl gives unlimited permission to copy and/or distribute it,
1112 dnl with or without modifications, as long as this notice is preserved.
1113
1114 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1115   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1116   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1117     [ovs_save_CFLAGS="$CFLAGS"
1118      dnl Include -Werror in the compiler options, because without -Werror
1119      dnl clang's GCC-compatible compiler driver does not return a failure
1120      dnl exit status even though it complains about options it does not
1121      dnl understand.
1122      dnl
1123      dnl Also, check stderr as gcc exits with status 0 for options
1124      dnl rejected at getopt level.
1125      dnl    % touch /tmp/a.c
1126      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1127      dnl    gcc: unrecognized option '-Qunused-arguments'
1128      dnl    0
1129      dnl    %
1130      dnl
1131      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1132      dnl it does not understand, unless it has another error to report, so
1133      dnl instead of testing for -Wno-<foo>, test for the positive version.
1134      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1135      AC_COMPILE_IFELSE(
1136        [AC_LANG_SOURCE([int x;])],
1137        [if test -s conftest.err && grep "unrecognized option" conftest.err
1138         then
1139           ovs_cv_name[]=no
1140         else
1141           ovs_cv_name[]=yes
1142         fi],
1143        [ovs_cv_name[]=no])
1144      CFLAGS="$ovs_save_CFLAGS"])
1145   if test $ovs_cv_name = yes; then
1146     m4_if([$2], [], [:], [$2])
1147   else
1148     m4_if([$3], [], [:], [$3])
1149   fi
1150 ])
1151
1152 dnl OVS_CHECK_WERROR
1153 dnl
1154 dnl Check whether the C compiler accepts -Werror.
1155 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1156 AC_DEFUN([OVS_CHECK_WERROR],
1157   [WERROR=
1158    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1159
1160 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1161 dnl Check whether the given C compiler OPTION is accepted.
1162 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1163 AC_DEFUN([OVS_CHECK_CC_OPTION],
1164   [AC_REQUIRE([OVS_CHECK_WERROR])
1165    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1166
1167 dnl OVS_ENABLE_OPTION([OPTION])
1168 dnl Check whether the given C compiler OPTION is accepted.
1169 dnl If so, add it to WARNING_FLAGS.
1170 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1171 AC_DEFUN([OVS_ENABLE_OPTION],
1172   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1173    AC_SUBST([WARNING_FLAGS])])
1174
1175 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1176 dnl Check whether the given C compiler OPTION is accepted.
1177 dnl If so, enable the given Automake CONDITIONAL.
1178
1179 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1180 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1181   [OVS_CHECK_CC_OPTION(
1182     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1183    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1184 dnl ----------------------------------------------------------------------
1185
1186 dnl Check for too-old XenServer.
1187 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1188   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1189     [if test -e /etc/redhat-release; then
1190        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1191      fi
1192      if test -z "$ovs_cv_xsversion"; then
1193        ovs_cv_xsversion=none
1194      fi])
1195   case $ovs_cv_xsversion in
1196     none)
1197       ;;
1198
1199     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1200     [[6-9]]* |                           dnl XenServer 6 or later
1201     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1202     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1203     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1204     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1205       ;;
1206
1207     *)
1208       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1209       ;;
1210   esac])
1211
1212 dnl OVS_CHECK_SPARSE_TARGET
1213 dnl
1214 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1215 dnl target for which the code is being built.  This helps it out.
1216 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1217   [AC_CACHE_CHECK(
1218     [target hint for cgcc],
1219     [ac_cv_sparse_target],
1220     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1221        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1222        [x86_64-*], [ac_cv_sparse_target=x86_64],
1223        [ac_cv_sparse_target=other])])
1224    AS_CASE([$ac_cv_sparse_target],
1225      [x86], [SPARSEFLAGS= CGCCFLAGS="-target=i86 -target=host_os_specs"],
1226      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS="-target=x86_64 -target=host_os_specs"],
1227      [SPARSEFLAGS= CGCCFLAGS=])
1228
1229    dnl Get the default defines for vector instructions from compiler to
1230    dnl allow "sparse" correctly check the same code that will be built.
1231    dnl Required for checking DPDK headers.
1232    AC_MSG_CHECKING([vector options for cgcc])
1233    VECTOR=$($CC -dM -E - < /dev/null | grep -E "MMX|SSE|AVX" | \
1234             cut -c 9- | sed 's/ /=/' | sed 's/^/-D/' | tr '\n' ' ')
1235    AC_MSG_RESULT([$VECTOR])
1236    CGCCFLAGS="$CGCCFLAGS $VECTOR"
1237
1238    AC_SUBST([SPARSEFLAGS])
1239    AC_SUBST([CGCCFLAGS])])
1240
1241 dnl OVS_SPARSE_EXTRA_INCLUDES
1242 dnl
1243 dnl The cgcc script from "sparse" does not search gcc's default
1244 dnl search path. Get the default search path from GCC and pass
1245 dnl them to sparse.
1246 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1247     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1248            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1249
1250 dnl OVS_ENABLE_SPARSE
1251 AC_DEFUN([OVS_ENABLE_SPARSE],
1252   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1253    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1254    : ${SPARSE=sparse}
1255    AC_SUBST([SPARSE])
1256    AC_CONFIG_COMMANDS_PRE(
1257      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1258
1259    AC_ARG_ENABLE(
1260      [sparse],
1261      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1262      [], [enable_sparse=no])
1263    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1264
1265 dnl OVS_CTAGS_IDENTIFIERS
1266 dnl
1267 dnl ctags ignores symbols with extras identifiers. This builds a list of
1268 dnl specially handled identifiers to be ignored.
1269 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1270     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1271            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1272
1273 dnl OVS_PTHREAD_SET_NAME
1274 dnl
1275 dnl This checks for three known variants of pthreads functions for setting
1276 dnl the name of the current thread:
1277 dnl
1278 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1279 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1280 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1281 dnl
1282 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1283 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1284 dnl provide to it.
1285 dnl
1286 dnl This macro defines:
1287 dnl
1288 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1289 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1290 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1291 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1292   [AC_CHECK_FUNCS([pthread_set_name_np])
1293    if test $ac_cv_func_pthread_set_name_np != yes; then
1294      AC_CACHE_CHECK(
1295        [for pthread_setname_np() variant],
1296        [ovs_cv_pthread_setname_np],
1297        [AC_LINK_IFELSE(
1298          [AC_LANG_PROGRAM([#include <pthread.h>
1299   ], [pthread_setname_np(pthread_self(), "name");])],
1300          [ovs_cv_pthread_setname_np=glibc],
1301          [AC_LINK_IFELSE(
1302            [AC_LANG_PROGRAM([#include <pthread.h>
1303 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1304            [ovs_cv_pthread_setname_np=netbsd],
1305            [ovs_cv_pthread_setname_np=none])])])
1306      case $ovs_cv_pthread_setname_np in # (
1307        glibc)
1308           AC_DEFINE(
1309             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1310             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1311           ;; # (
1312        netbsd)
1313           AC_DEFINE(
1314             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1315             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1316           ;;
1317      esac
1318    fi])
1319
1320 dnl OVS_CHECK_LINUX_HOST.
1321 dnl
1322 dnl Checks whether we're building for a Linux host, based on the presence of
1323 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1324 dnl LINUX based on the result.
1325 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1326   [AC_CACHE_CHECK(
1327      [whether __linux__ is defined],
1328      [ovs_cv_linux],
1329      [AC_COMPILE_IFELSE(
1330         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1331         [ovs_cv_linux=true],
1332         [ovs_cv_linux=false])])
1333    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])