acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2019 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 5; then
 154        if test "$version" = 5 && test "$patchlevel" -le 0; then
 155           : # Linux 5.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 5.0.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 4; then
 160        : # Linux 4.x
 161     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 162        : # Linux 3.x
 163     else
 164        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 165     fi
 166     if (test ! -e "$KBUILD"/include/linux/version.h && \
 167         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 168        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 169         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 170         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 171     fi
 172     OVS_CHECK_LINUX_COMPAT
 173   fi
 174   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 175 ])
 176
 177 dnl OVS_CHECK_LINUX_TC
 178 dnl
 179 dnl Configure Linux tc compat.
 180 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 181   AC_COMPILE_IFELSE([
 182     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 183         int x = TCA_FLOWER_KEY_ENC_IP_TTL_MASK;
 184     ])],
 185     [AC_DEFINE([HAVE_TCA_FLOWER_KEY_ENC_IP_TTL_MASK], [1],
 186                [Define to 1 if TCA_FLOWER_KEY_ENC_IP_TTL_MASK is available.])])
 187
 188   AC_COMPILE_IFELSE([
 189     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 190         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 191     ])],
 192     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 193                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 194
 195   AC_COMPILE_IFELSE([
 196     AC_LANG_PROGRAM([#include <linux/tc_act/tc_mpls.h>], [
 197         int x = TCA_MPLS_TTL;
 198     ])],
 199     [AC_DEFINE([HAVE_TCA_MPLS_TTL], [1],
 200                [Define to 1 if HAVE_TCA_MPLS_TTL is available.])])
 201
 202   AC_COMPILE_IFELSE([
 203     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 204         int x = TCA_TUNNEL_KEY_ENC_TTL;
 205     ])],
 206     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 207                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 208
 209   AC_COMPILE_IFELSE([
 210     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 211         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 212     ])],
 213     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 214                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 215
 216   AC_COMPILE_IFELSE([
 217     AC_LANG_PROGRAM([#include <linux/tc_act/tc_skbedit.h>], [
 218         int x = TCA_SKBEDIT_FLAGS;
 219     ])],
 220     [AC_DEFINE([HAVE_TCA_SKBEDIT_FLAGS], [1],
 221                [Define to 1 if TCA_SKBEDIT_FLAGS is available.])])
 222 ])
 223
 224 dnl OVS_CHECK_LINUX_SCTP_CT
 225 dnl
 226 dnl Checks for kernels which need additional SCTP state
 227 AC_DEFUN([OVS_CHECK_LINUX_SCTP_CT], [
 228   AC_COMPILE_IFELSE([
 229     AC_LANG_PROGRAM([#include <linux/netfilter/nfnetlink.h>
 230 #include <linux/netfilter/nfnetlink_conntrack.h>
 231 #include <linux/netfilter/nf_conntrack_common.h>
 232 #include <linux/netfilter/nf_conntrack_sctp.h>], [
 233         int x = SCTP_CONNTRACK_HEARTBEAT_SENT;
 234     ])],
 235     [AC_DEFINE([HAVE_SCTP_CONNTRACK_HEARTBEATS], [1],
 236                [Define to 1 if SCTP_CONNTRACK_HEARTBEAT_SENT is available.])])
 237 ])
 238
 239 dnl OVS_FIND_DEPENDENCY(FUNCTION, SEARCH_LIBS, NAME_TO_PRINT)
 240 dnl
 241 dnl Check for a function in a library list.
 242 AC_DEFUN([OVS_FIND_DEPENDENCY], [
 243   AC_SEARCH_LIBS([$1], [$2], [], [
 244     AC_MSG_ERROR([unable to find $3, install the dependency package])
 245   ])
 246 ])
 247
 248 dnl OVS_CHECK_LINUX_AF_XDP
 249 dnl
 250 dnl Check both Linux kernel AF_XDP and libbpf support
 251 AC_DEFUN([OVS_CHECK_LINUX_AF_XDP], [
 252   AC_ARG_ENABLE([afxdp],
 253                 [AC_HELP_STRING([--enable-afxdp], [Enable AF-XDP support])],
 254                 [], [enable_afxdp=no])
 255   AC_MSG_CHECKING([whether AF_XDP is enabled])
 256   if test "$enable_afxdp" != yes; then
 257     AC_MSG_RESULT([no])
 258     AF_XDP_ENABLE=false
 259   else
 260     AC_MSG_RESULT([yes])
 261     AF_XDP_ENABLE=true
 262
 263     AC_CHECK_HEADER([bpf/libbpf.h], [],
 264       [AC_MSG_ERROR([unable to find bpf/libbpf.h for AF_XDP support])])
 265
 266     AC_CHECK_HEADER([linux/if_xdp.h], [],
 267       [AC_MSG_ERROR([unable to find linux/if_xdp.h for AF_XDP support])])
 268
 269     AC_CHECK_HEADER([bpf/xsk.h], [],
 270       [AC_MSG_ERROR([unable to find bpf/xsk.h for AF_XDP support])])
 271
 272     AC_CHECK_FUNCS([pthread_spin_lock], [],
 273       [AC_MSG_ERROR([unable to find pthread_spin_lock for AF_XDP support])])
 274
 275     AC_DEFINE([HAVE_AF_XDP], [1],
 276               [Define to 1 if AF_XDP support is available and enabled.])
 277     LIBBPF_LDADD=" -lbpf -lelf"
 278     AC_SUBST([LIBBPF_LDADD])
 279   fi
 280   AM_CONDITIONAL([HAVE_AF_XDP], test "$AF_XDP_ENABLE" = true)
 281 ])
 282
 283 dnl OVS_CHECK_DPDK
 284 dnl
 285 dnl Configure DPDK source tree
 286 AC_DEFUN([OVS_CHECK_DPDK], [
 287   AC_ARG_WITH([dpdk],
 288               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 289                               [Specify the DPDK build directory])],
 290               [have_dpdk=true])
 291
 292   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 293   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 294     AC_MSG_RESULT([no])
 295     DPDKLIB_FOUND=false
 296   else
 297     AC_MSG_RESULT([yes])
 298     case "$with_dpdk" in
 299       yes)
 300         DPDK_AUTO_DISCOVER="true"
 301         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 302             DPDK_INCLUDE="$DPDK_CFLAGS"
 303             DPDK_LIB="$DPDK_LIBS"], [
 304             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 305             DPDK_LIB="-ldpdk"])
 306         ;;
 307       *)
 308         DPDK_AUTO_DISCOVER="false"
 309         DPDK_INCLUDE_PATH="$with_dpdk/include"
 310         # If 'with_dpdk' is passed install directory, point to headers
 311         # installed in $DESTDIR/$prefix/include/dpdk
 312         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 313            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 314         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 315            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 316         fi
 317         DPDK_LIB_DIR="$with_dpdk/lib"
 318         DPDK_LIB="-ldpdk"
 319         ;;
 320     esac
 321
 322     ovs_save_CFLAGS="$CFLAGS"
 323     ovs_save_LDFLAGS="$LDFLAGS"
 324     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 325     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 326       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 327     fi
 328
 329     AC_CHECK_HEADERS([rte_config.h], [], [
 330       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 331     ], [AC_INCLUDES_DEFAULT])
 332
 333     AC_CHECK_DECLS([RTE_LIBRTE_VHOST_NUMA, RTE_EAL_NUMA_AWARE_HUGEPAGES], [
 334       OVS_FIND_DEPENDENCY([get_mempolicy], [numa], [libnuma])
 335     ], [], [[#include <rte_config.h>]])
 336
 337     AC_CHECK_DECL([RTE_LIBRTE_VHOST_NUMA], [
 338       AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])
 339     ], [], [[#include <rte_config.h>]])
 340
 341     AC_CHECK_DECL([RTE_LIBRTE_PMD_PCAP], [
 342       OVS_FIND_DEPENDENCY([pcap_dump], [pcap], [libpcap])
 343       AC_CHECK_DECL([RTE_LIBRTE_PDUMP], [
 344         AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])
 345       ], [], [[#include <rte_config.h>]])
 346     ], [], [[#include <rte_config.h>]])
 347
 348     AC_CHECK_DECL([RTE_LIBRTE_MLX5_PMD], [dnl found
 349       OVS_FIND_DEPENDENCY([mnl_attr_put], [mnl], [libmnl])
 350       AC_CHECK_DECL([RTE_LIBRTE_MLX5_DLOPEN_DEPS], [], [dnl not found
 351         OVS_FIND_DEPENDENCY([mlx5dv_create_wq], [mlx5], [libmlx5])
 352         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 353       ], [[#include <rte_config.h>]])
 354     ], [], [[#include <rte_config.h>]])
 355
 356     AC_CHECK_DECL([RTE_LIBRTE_MLX4_PMD], [dnl found
 357       AC_CHECK_DECL([RTE_LIBRTE_MLX4_DLOPEN_DEPS], [], [dnl not found
 358         OVS_FIND_DEPENDENCY([mlx4dv_init_obj], [mlx4], [libmlx4])
 359         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 360       ], [[#include <rte_config.h>]])
 361     ], [], [[#include <rte_config.h>]])
 362
 363     # DPDK uses dlopen to load plugins.
 364     OVS_FIND_DEPENDENCY([dlopen], [dl], [libdl])
 365
 366     AC_MSG_CHECKING([whether linking with dpdk works])
 367     LIBS="$DPDK_LIB $LIBS"
 368     AC_LINK_IFELSE(
 369       [AC_LANG_PROGRAM([#include <rte_config.h>
 370                         #include <rte_eal.h>],
 371                        [int rte_argc; char ** rte_argv;
 372                         rte_eal_init(rte_argc, rte_argv);])],
 373       [AC_MSG_RESULT([yes])
 374        DPDKLIB_FOUND=true],
 375       [AC_MSG_RESULT([no])
 376        if test "$DPDK_AUTO_DISCOVER" = "true"; then
 377          AC_MSG_ERROR(m4_normalize([
 378             Could not find DPDK library in default search path, Use --with-dpdk
 379             to specify the DPDK library installed in non-standard location]))
 380        else
 381          AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 382        fi
 383       ])
 384
 385     CFLAGS="$ovs_save_CFLAGS"
 386     LDFLAGS="$ovs_save_LDFLAGS"
 387     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 388       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 389     fi
 390     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 391     OVS_ENABLE_OPTION([-mssse3])
 392
 393     # DPDK pmd drivers are not linked unless --whole-archive is used.
 394     #
 395     # This happens because the rest of the DPDK code doesn't use any symbol in
 396     # the pmd driver objects, and the drivers register themselves using an
 397     # __attribute__((constructor)) function.
 398     #
 399     # These options are specified inside a single -Wl directive to prevent
 400     # autotools from reordering them.
 401     #
 402     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 403     # will already have flagged just the right set of libs with
 404     # --whole-archive - in those cases do not wrap it once more.
 405     case "$DPDK_LIB" in
 406       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 407       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 408     esac
 409     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 410     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 411   fi
 412
 413   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 414 ])
 415
 416 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 417 dnl
 418 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 419 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 420 dnl <REGEX> translated to uppercase.
 421 AC_DEFUN([OVS_GREP_IFELSE], [
 422   AC_MSG_CHECKING([whether $2 matches in $1])
 423   if test -f $1; then
 424     grep '$2' $1 >/dev/null 2>&1
 425     status=$?
 426     case $status in
 427       0)
 428         AC_MSG_RESULT([yes])
 429         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 430         ;;
 431       1)
 432         AC_MSG_RESULT([no])
 433         $4
 434         ;;
 435       *)
 436         AC_MSG_ERROR([grep exited with status $status])
 437         ;;
 438     esac
 439   else
 440     AC_MSG_RESULT([file not found])
 441     $4
 442   fi
 443 ])
 444
 445 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 446 dnl
 447 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 448 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 449 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 450 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 451 dnl translated to uppercase.
 452 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 453   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 454   if test -f $1; then
 455     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 456     status=$?
 457     case $status in
 458       0)
 459         AC_MSG_RESULT([yes])
 460         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 461         ;;
 462       1)
 463         AC_MSG_RESULT([no])
 464         $5
 465         ;;
 466       *)
 467         AC_MSG_ERROR([grep exited with status $status])
 468         ;;
 469     esac
 470   else
 471     AC_MSG_RESULT([file not found])
 472     $5
 473   fi
 474 ])
 475
 476 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 477 dnl
 478 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 479 dnl the function signature starting from the line matching FUNCTION
 480 dnl and ending with the line containing the closing parenthesis.  If
 481 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 482 dnl IF-MATCH is empty then it defines to
 483 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 484 dnl <REGEX> translated to uppercase.
 485 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 486   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 487   if test -f $1; then
 488     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 489     status=$?
 490     case $status in
 491       0)
 492         AC_MSG_RESULT([yes])
 493         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 494         ;;
 495       1)
 496         AC_MSG_RESULT([no])
 497         $5
 498         ;;
 499       *)
 500         AC_MSG_ERROR([grep exited with status $status])
 501         ;;
 502     esac
 503   else
 504     AC_MSG_RESULT([file not found])
 505     $5
 506   fi
 507 ])
 508
 509 dnl OVS_DEFINE(NAME)
 510 dnl
 511 dnl Defines NAME to 1 in kcompat.h.
 512 AC_DEFUN([OVS_DEFINE], [
 513   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 514 ])
 515
 516 dnl OVS_CHECK_LINUX_COMPAT
 517 dnl
 518 dnl Runs various Autoconf checks on the Linux kernel source in
 519 dnl the directory in $KBUILD.
 520 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 521   rm -f datapath/linux/kcompat.h.new
 522   mkdir -p datapath/linux
 523   : > datapath/linux/kcompat.h.new
 524
 525   echo '#include <linux/version.h>
 526 #ifndef RHEL_RELEASE_CODE
 527 #define RHEL_RELEASE_CODE 0
 528 #define RHEL_RELEASE_VERSION(a, b) 0
 529 #endif' >> datapath/linux/kcompat.h.new
 530
 531   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 532                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 533
 534   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 535                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 536
 537   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 538                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 539   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 540
 541   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 542   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 543   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 544
 545   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 546                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 547   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 548                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 549
 550   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 551   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 552
 553   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 554   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 555   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 556   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 557   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 558   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_hwaccel_clear_tag])
 559
 560   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 561   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 562   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 563                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 564   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 565                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 566
 567   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 568                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 569   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 570                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 571   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 572                         [ip_do_fragment], [net],
 573                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 574   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 575                         [ip_local_out], [net],
 576                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 577
 578   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 579
 580   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 581                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 582   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 583   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 584                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 585   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 586                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 587   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 588   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 589   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 590                         [frags_work])
 591   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 592                         [rwlock])
 593   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 594                         [list_evictor])
 595   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 596   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 597                         [sub_frag_mem_limit], [struct.netns_frags],
 598                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 599   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 600                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 601   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 602                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 603
 604   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 605   dnl OVS does not really need ipv6 label field, but its presence signifies that
 606   dnl the stack has all required ipv6 support.
 607   dnl OVS also does not need dst_cache But this dependency allows us to write
 608   dnl much cleaner code.
 609
 610   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 611                         [label],
 612                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 613                                          [iptunnel_pull_offloads],
 614                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 615                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 616                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 617
 618   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 619                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 620   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 621                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 622   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 623                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 624   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 625   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 626   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 627   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 628   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 629   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 630   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 631   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 632   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 633   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 634                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 635   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 636   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 637   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 638   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 639   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 640   dnl So check type of tstats.
 641   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 642                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 643   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 644                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 645   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 646   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 647   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 648                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 649   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 650   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 651   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 652                         [extended])
 653   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 654                         [netdev_master_upper_dev_link], [upper_priv],
 655                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 656   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 657                   [netdev_master_upper_dev_link_rh],
 658                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 659
 660   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 661                         [max_mtu])
 662   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 663                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 664   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 665                         [dev_change_flags], [extack],
 666                         [OVS_DEFINE([HAVE_DEV_CHANGE_FLAGS_TAKES_EXTACK])])
 667
 668   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 669   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state],
 670                         [struct net ], [OVS_DEFINE([HAVE_NF_HOOK_STATE_NET])])
 671   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 672   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 673                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 674   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 675                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 676   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 677                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 678   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 679
 680
 681   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 682                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 683
 684   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 685                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 686                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 687   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 688                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 689
 690   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 691                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 692                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 693   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 694                   [nf_ct_get_tuplepr], [struct.net],
 695                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 696   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 697                   [nf_ct_set])
 698   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 699                   [nf_ct_is_untracked])
 700   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 701                   [nf_ct_invert_tuplepr])
 702   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 703                   [nf_ct_zone_init])
 704   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 705                   [net_ns_get])
 706   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 707                   [nf_connlabels_get])
 708   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 709                   [nf_connlabels_get], [int bit],
 710                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 711   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 712                         [nf_conn_labels], [words])
 713   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 714   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 715   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 716   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 717   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 718                   [OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h],
 719                                    [int nf_conncount_add],
 720                                    [], [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])])
 721   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [nf_ct_set_timeout])
 722   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [struct nf_ct_timeout],
 723                   [OVS_DEFINE([HAVE_NF_CT_TIMEOUT])])
 724   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h],
 725                         [\(*nf_ct_timeout_find_get_hook\)], [net],
 726                         [OVS_DEFINE([HAVE_NF_CT_TIMEOUT_FIND_GET_HOOK_NET])])
 727
 728   OVS_GREP_IFELSE([$KSRC/include/linux/random.h],
 729                   [prandom_u32[[\(]]],
 730                   [OVS_DEFINE([HAVE_PRANDOM_U32])])
 731   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 732
 733   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 734   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 735   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 736                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 737   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 738
 739   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 740                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 741                                    [rcu_read_lock_held])])
 742   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 743   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 744   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
 745                         [rtnl_create_link], [extack],
 746                         [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_TAKES_EXTACK])])
 747   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [nf_reset_ct])
 748
 749   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 750   # is necessary because some versions of this header remove the
 751   # member but retain the kerneldoc comment that describes it (which
 752   # starts with @).  The brackets must be doubled because of m4
 753   # quoting rules.
 754   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 755                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 756   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 757   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 758   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 759   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 760   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 761   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 762   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 763                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 764   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 765                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 766   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 767                   [skb_copy_from_linear_data_offset])
 768   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 769                   [skb_reset_tail_pointer])
 770   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 771   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 772                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 773   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 774   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 775   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 776   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 777   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 778   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 779   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 780   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 781                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 782   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 783   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 784                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 785   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 786                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 787   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 788   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 789   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 790   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 791   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 792   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 793   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 794   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 795   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 796
 797   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 798                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 799   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 800                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 801   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 802                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 803
 804   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 805   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 806
 807   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 808   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 809
 810   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 811   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 812   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 813   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 814                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 815   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 816   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 817                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 818   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 819                         [genl_notify], [net],
 820                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 821
 822
 823   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 824                         [genl_multicast_group], [id])
 825   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 826
 827   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 828   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 829   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 830   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 831   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 832   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 833                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 834   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 835                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 836
 837   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 838   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 839   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 840   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 841   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 842   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 843   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 844   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 845   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 846                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 847   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 848                         [nla_parse], [netlink_ext_ack],
 849                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 850
 851   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 852
 853   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 854   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 855   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 856   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 857   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 858
 859   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 860                         [metadata_dst_alloc], [metadata_type])
 861
 862   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 863
 864   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 865                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 866   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 867                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 868                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 869   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 870   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 871   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 872                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 873   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 874                         [gro_receive])
 875
 876   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 877                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 878   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 879                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 880
 881   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 882   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 883   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 884                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 885   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 886                         [udp_add_offload], [net],
 887                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 888   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 889                         [nf_defrag_ipv6_enable], [net],
 890                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 891   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 892                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 893   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 894                         [needs_free_netdev],
 895                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 896   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 897                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 898   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 899                   [nf_conntrack_helper_put],
 900                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 901   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 902                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 903   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 904                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 905   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 906                         [extack],
 907                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 908   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 909                         [list],
 910                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 911   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 912                   [IP_CT_UNTRACKED])
 913   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 914                         [netdev_master_upper_dev_link], [extack],
 915                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 916   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 917                   [__LINUX_COMPILER_TYPES_H],
 918                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 919   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 920                   [ktime_get_ts64],
 921                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 922   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 923                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 924                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 925   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 926                   [ktime_get_ns],
 927                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 928   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 929                   frag_percpu_counter_batch[],
 930                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 931   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 932                   [null_compute_pseudo],
 933                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 934   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 935                   [__skb_checksum_convert],
 936                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
 937   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 938                         [max_mtu],
 939                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
 940   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
 941                         [erspan_ver],
 942                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
 943   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 944                   [SKB_GSO_IPXIP6],
 945                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
 946   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
 947                         [ip6_make_flowlabel], [fl6],
 948                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
 949   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
 950                         [auto_flowlabels],
 951                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
 952   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 953                   [netif_keep_dst],
 954                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
 955   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 956                         [ndo_get_iflink],
 957                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
 958   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 959                   [skb_set_inner_ipproto],
 960                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
 961   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 962                   [tunnel_encap_types],
 963                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
 964   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 965                   [IFLA_IPTUN_ENCAP_TYPE],
 966                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
 967   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 968                   [IFLA_IPTUN_COLLECT_METADATA],
 969                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
 970   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 971                   [IFLA_GRE_ENCAP_DPORT])
 972   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 973                   [IFLA_GRE_COLLECT_METADATA])
 974   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 975                   [IFLA_GRE_IGNORE_DF])
 976   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 977                   [IFLA_GRE_FWMARK])
 978   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 979                   [IFLA_GRE_ERSPAN_INDEX])
 980   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 981                   [IFLA_GRE_ERSPAN_HWID])
 982   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 983                   [IFLA_IPTUN_FWMARK])
 984   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
 985                         [csum_valid],
 986                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
 987   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
 988                         [vlan_present],
 989                         [OVS_DEFINE([HAVE_SKBUFF_VLAN_PRESENT])])
 990   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 991                   [skb_checksum_simple_validate])
 992   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 993                   [void.*ndo_get_stats64],
 994                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
 995   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
 996                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
 997   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
 998                         [ip_tunnel_info_opts_set], [flags],
 999                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
1000   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
1001                         [rnd],
1002                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
1003   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [__LINUX_OVERFLOW_H],
1004                   [OVS_DEFINE([HAVE_OVERFLOW_H])])
1005   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [struct_size],
1006                   [OVS_DEFINE([HAVE_STRUCT_SIZE])])
1007   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_array],
1008                   [OVS_DEFINE([HAVE_KVMALLOC_ARRAY])])
1009   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_node],
1010                   [OVS_DEFINE([HAVE_KVMALLOC_NODE])])
1011   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
1012                   [nf_conntrack_l3proto],
1013                   [OVS_DEFINE([HAVE_NF_CONNTRACK_L3PROATO_H])])
1014   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_core.h],
1015                         [nf_conntrack_in], [nf_hook_state],
1016                         [OVS_DEFINE([HAVE_NF_CONNTRACK_IN_TAKES_NF_HOOK_STATE])])
1017   OVS_GREP_IFELSE([$KSRC/include/net/ipv6_frag.h], [IP6_DEFRAG_CONNTRACK_IN],
1018                   [OVS_DEFINE([HAVE_IPV6_FRAG_H])])
1019   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
1020                         [nf_ct_helper_ext_add], [nf_conntrack_helper],
1021                         [OVS_DEFINE([HAVE_NF_CT_HELPER_EXT_ADD_TAKES_HELPER])])
1022   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_calc_hlen],
1023                   [OVS_DEFINE([HAVE_GRE_CALC_HLEN])])
1024   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [ip_gre_calc_hlen],
1025                   [OVS_DEFINE([HAVE_IP_GRE_CALC_HLEN])])
1026   OVS_GREP_IFELSE([$KSRC/include/linux/rbtree.h], [rb_link_node_rcu],
1027                   [OVS_DEFINE([HAVE_RBTREE_RB_LINK_NODE_RCU])])
1028
1029   if cmp -s datapath/linux/kcompat.h.new \
1030             datapath/linux/kcompat.h >/dev/null 2>&1; then
1031     rm datapath/linux/kcompat.h.new
1032   else
1033     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
1034   fi
1035 ])
1036
1037 dnl Checks for net/if_dl.h.
1038 dnl
1039 dnl (We use this as a proxy for checking whether we're building on FreeBSD
1040 dnl or NetBSD.)
1041 AC_DEFUN([OVS_CHECK_IF_DL],
1042   [AC_CHECK_HEADER([net/if_dl.h],
1043                    [HAVE_IF_DL=yes],
1044                    [HAVE_IF_DL=no])
1045    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
1046    if test "$HAVE_IF_DL" = yes; then
1047       AC_DEFINE([HAVE_IF_DL], [1],
1048                 [Define to 1 if net/if_dl.h is available.])
1049
1050       # On these platforms we use libpcap to access network devices.
1051       AC_SEARCH_LIBS([pcap_open_live], [pcap])
1052    fi])
1053
1054 dnl Checks for buggy strtok_r.
1055 dnl
1056 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
1057 dnl with optimization that can cause segfaults:
1058 dnl
1059 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
1060 AC_DEFUN([OVS_CHECK_STRTOK_R],
1061   [AC_CACHE_CHECK(
1062      [whether strtok_r macro segfaults on some inputs],
1063      [ovs_cv_strtok_r_bug],
1064      [AC_RUN_IFELSE(
1065         [AC_LANG_PROGRAM([#include <stdio.h>
1066                           #include <string.h>
1067                          ],
1068                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
1069                            /* Assume bug is present, because relatively minor
1070                               changes in compiler settings (e.g. optimization
1071                               level) can make it crop up. */
1072                            return 1;
1073                            #else
1074                            char string[] = ":::";
1075                            char *save_ptr = (char *) 0xc0ffee;
1076                            char *token1, *token2;
1077                            token1 = strtok_r(string, ":", &save_ptr);
1078                            token2 = strtok_r(NULL, ":", &save_ptr);
1079                            freopen ("/dev/null", "w", stdout);
1080                            printf ("%s %s\n", token1, token2);
1081                            return 0;
1082                            #endif
1083                           ]])],
1084         [ovs_cv_strtok_r_bug=no],
1085         [ovs_cv_strtok_r_bug=yes],
1086         [ovs_cv_strtok_r_bug=yes])])
1087    if test $ovs_cv_strtok_r_bug = yes; then
1088      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1089                [Define if strtok_r macro segfaults on some inputs])
1090    fi
1091 ])
1092
1093 dnl ----------------------------------------------------------------------
1094 dnl These macros are from GNU PSPP, with the following original license:
1095 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1096 dnl This file is free software; the Free Software Foundation
1097 dnl gives unlimited permission to copy and/or distribute it,
1098 dnl with or without modifications, as long as this notice is preserved.
1099
1100 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1101   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1102   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1103     [ovs_save_CFLAGS="$CFLAGS"
1104      dnl Include -Werror in the compiler options, because without -Werror
1105      dnl clang's GCC-compatible compiler driver does not return a failure
1106      dnl exit status even though it complains about options it does not
1107      dnl understand.
1108      dnl
1109      dnl Also, check stderr as gcc exits with status 0 for options
1110      dnl rejected at getopt level.
1111      dnl    % touch /tmp/a.c
1112      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1113      dnl    gcc: unrecognized option '-Qunused-arguments'
1114      dnl    0
1115      dnl    %
1116      dnl
1117      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1118      dnl it does not understand, unless it has another error to report, so
1119      dnl instead of testing for -Wno-<foo>, test for the positive version.
1120      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1121      AC_COMPILE_IFELSE(
1122        [AC_LANG_SOURCE([int x;])],
1123        [if test -s conftest.err && grep "unrecognized option" conftest.err
1124         then
1125           ovs_cv_name[]=no
1126         else
1127           ovs_cv_name[]=yes
1128         fi],
1129        [ovs_cv_name[]=no])
1130      CFLAGS="$ovs_save_CFLAGS"])
1131   if test $ovs_cv_name = yes; then
1132     m4_if([$2], [], [:], [$2])
1133   else
1134     m4_if([$3], [], [:], [$3])
1135   fi
1136 ])
1137
1138 dnl OVS_CHECK_WERROR
1139 dnl
1140 dnl Check whether the C compiler accepts -Werror.
1141 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1142 AC_DEFUN([OVS_CHECK_WERROR],
1143   [WERROR=
1144    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1145
1146 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1147 dnl Check whether the given C compiler OPTION is accepted.
1148 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1149 AC_DEFUN([OVS_CHECK_CC_OPTION],
1150   [AC_REQUIRE([OVS_CHECK_WERROR])
1151    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1152
1153 dnl OVS_ENABLE_OPTION([OPTION])
1154 dnl Check whether the given C compiler OPTION is accepted.
1155 dnl If so, add it to WARNING_FLAGS.
1156 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1157 AC_DEFUN([OVS_ENABLE_OPTION],
1158   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1159    AC_SUBST([WARNING_FLAGS])])
1160
1161 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1162 dnl Check whether the given C compiler OPTION is accepted.
1163 dnl If so, enable the given Automake CONDITIONAL.
1164
1165 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1166 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1167   [OVS_CHECK_CC_OPTION(
1168     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1169    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1170 dnl ----------------------------------------------------------------------
1171
1172 dnl Check for too-old XenServer.
1173 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1174   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1175     [if test -e /etc/redhat-release; then
1176        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1177      fi
1178      if test -z "$ovs_cv_xsversion"; then
1179        ovs_cv_xsversion=none
1180      fi])
1181   case $ovs_cv_xsversion in
1182     none)
1183       ;;
1184
1185     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1186     [[6-9]]* |                           dnl XenServer 6 or later
1187     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1188     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1189     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1190     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1191       ;;
1192
1193     *)
1194       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1195       ;;
1196   esac])
1197
1198 dnl OVS_CHECK_SPARSE_TARGET
1199 dnl
1200 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1201 dnl target for which the code is being built.  This helps it out.
1202 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1203   [AC_CACHE_CHECK(
1204     [target hint for cgcc],
1205     [ac_cv_sparse_target],
1206     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1207        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1208        [x86_64-*], [ac_cv_sparse_target=x86_64],
1209        [ac_cv_sparse_target=other])])
1210    AS_CASE([$ac_cv_sparse_target],
1211      [x86], [SPARSEFLAGS= CGCCFLAGS="-target=i86 -target=host_os_specs"],
1212      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS="-target=x86_64 -target=host_os_specs"],
1213      [SPARSEFLAGS= CGCCFLAGS=])
1214
1215    dnl Get the default defines for vector instructions from compiler to
1216    dnl allow "sparse" correctly check the same code that will be built.
1217    dnl Required for checking DPDK headers.
1218    AC_MSG_CHECKING([vector options for cgcc])
1219    VECTOR=$($CC -dM -E - < /dev/null | grep -E "MMX|SSE|AVX" | \
1220             cut -c 9- | sed 's/ /=/' | sed 's/^/-D/' | tr '\n' ' ')
1221    AC_MSG_RESULT([$VECTOR])
1222    CGCCFLAGS="$CGCCFLAGS $VECTOR"
1223
1224    AC_SUBST([SPARSEFLAGS])
1225    AC_SUBST([CGCCFLAGS])])
1226
1227 dnl OVS_SPARSE_EXTRA_INCLUDES
1228 dnl
1229 dnl The cgcc script from "sparse" does not search gcc's default
1230 dnl search path. Get the default search path from GCC and pass
1231 dnl them to sparse.
1232 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1233     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1234            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1235
1236 dnl OVS_ENABLE_SPARSE
1237 AC_DEFUN([OVS_ENABLE_SPARSE],
1238   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1239    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1240    : ${SPARSE=sparse}
1241    AC_SUBST([SPARSE])
1242    AC_CONFIG_COMMANDS_PRE(
1243      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1244
1245    AC_ARG_ENABLE(
1246      [sparse],
1247      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1248      [], [enable_sparse=no])
1249    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1250
1251 dnl OVS_CTAGS_IDENTIFIERS
1252 dnl
1253 dnl ctags ignores symbols with extras identifiers. This builds a list of
1254 dnl specially handled identifiers to be ignored.
1255 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1256     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1257            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1258
1259 dnl OVS_PTHREAD_SET_NAME
1260 dnl
1261 dnl This checks for three known variants of pthreads functions for setting
1262 dnl the name of the current thread:
1263 dnl
1264 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1265 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1266 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1267 dnl
1268 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1269 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1270 dnl provide to it.
1271 dnl
1272 dnl This macro defines:
1273 dnl
1274 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1275 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1276 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1277 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1278   [AC_CHECK_FUNCS([pthread_set_name_np])
1279    if test $ac_cv_func_pthread_set_name_np != yes; then
1280      AC_CACHE_CHECK(
1281        [for pthread_setname_np() variant],
1282        [ovs_cv_pthread_setname_np],
1283        [AC_LINK_IFELSE(
1284          [AC_LANG_PROGRAM([#include <pthread.h>
1285   ], [pthread_setname_np(pthread_self(), "name");])],
1286          [ovs_cv_pthread_setname_np=glibc],
1287          [AC_LINK_IFELSE(
1288            [AC_LANG_PROGRAM([#include <pthread.h>
1289 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1290            [ovs_cv_pthread_setname_np=netbsd],
1291            [ovs_cv_pthread_setname_np=none])])])
1292      case $ovs_cv_pthread_setname_np in # (
1293        glibc)
1294           AC_DEFINE(
1295             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1296             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1297           ;; # (
1298        netbsd)
1299           AC_DEFINE(
1300             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1301             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1302           ;;
1303      esac
1304    fi])
1305
1306 dnl OVS_CHECK_LINUX_HOST.
1307 dnl
1308 dnl Checks whether we're building for a Linux host, based on the presence of
1309 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1310 dnl LINUX based on the result.
1311 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1312   [AC_CACHE_CHECK(
1313      [whether __linux__ is defined],
1314      [ovs_cv_linux],
1315      [AC_COMPILE_IFELSE(
1316         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1317         [ovs_cv_linux=true],
1318         [ovs_cv_linux=false])])
1319    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])