acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])])
  36
  37 dnl OVS_CHECK_LINUX
  38 dnl
  39 dnl Configure linux kernel source tree
  40 AC_DEFUN([OVS_CHECK_LINUX], [
  41   AC_ARG_WITH([linux],
  42               [AC_HELP_STRING([--with-linux=/path/to/linux],
  43                               [Specify the Linux kernel build directory])])
  44   AC_ARG_WITH([linux-source],
  45               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  46                               [Specify the Linux kernel source directory
  47                                (usually figured out automatically from build
  48                                directory)])])
  49
  50   # Deprecated equivalents to --with-linux, --with-linux-source.
  51   AC_ARG_WITH([l26])
  52   AC_ARG_WITH([l26-source])
  53
  54   if test X"$with_linux" != X; then
  55     KBUILD=$with_linux
  56   elif test X"$with_l26" != X; then
  57     KBUILD=$with_l26
  58     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  59   else
  60     KBUILD=
  61   fi
  62
  63   if test X"$KBUILD" != X; then
  64     if test X"$with_linux_source" != X; then
  65       KSRC=$with_linux_source
  66     elif test X"$with_l26_source" != X; then
  67       KSRC=$with_l26_source
  68       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  69     else
  70       KSRC=
  71     fi
  72   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  73     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  74   fi
  75
  76   if test -n "$KBUILD"; then
  77     KBUILD=`eval echo "$KBUILD"`
  78     case $KBUILD in
  79         /*) ;;
  80         *) KBUILD=`pwd`/$KBUILD ;;
  81     esac
  82
  83     # The build directory is what the user provided.
  84     # Make sure that it exists.
  85     AC_MSG_CHECKING([for Linux build directory])
  86     if test -d "$KBUILD"; then
  87         AC_MSG_RESULT([$KBUILD])
  88         AC_SUBST(KBUILD)
  89     else
  90         AC_MSG_RESULT([no])
  91         AC_ERROR([source dir $KBUILD doesn't exist])
  92     fi
  93
  94     # Debian breaks kernel headers into "source" header and "build" headers.
  95     # We want the source headers, but $KBUILD gives us the "build" headers.
  96     # Use heuristics to find the source headers.
  97     AC_MSG_CHECKING([for Linux source directory])
  98     if test -n "$KSRC"; then
  99       KSRC=`eval echo "$KSRC"`
 100       case $KSRC in
 101           /*) ;;
 102           *) KSRC=`pwd`/$KSRC ;;
 103       esac
 104       if test ! -e $KSRC/include/linux/kernel.h; then
 105         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 106       fi
 107     else
 108       KSRC=$KBUILD
 109       if test ! -e $KSRC/include/linux/kernel.h; then
 110         # Debian kernel build Makefiles tend to include a line of the form:
 111         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 112         # First try to extract the source directory from this line.
 113         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 114         if test ! -e "$KSRC"/include/linux/kernel.h; then
 115           # Didn't work.  Fall back to name-based heuristics that used to work.
 116           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 117             */build)
 118               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 119               ;; # (
 120             *)
 121               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 122               ;;
 123           esac
 124         fi
 125       fi
 126       if test ! -e "$KSRC"/include/linux/kernel.h; then
 127         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 128       fi
 129     fi
 130     AC_MSG_RESULT([$KSRC])
 131
 132     AC_MSG_CHECKING([for kernel version])
 133     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 134     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 135     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 136     if test X"$version" = X || test X"$patchlevel" = X; then
 137        AC_ERROR([cannot determine kernel version])
 138     elif test X"$sublevel" = X; then
 139        kversion=$version.$patchlevel
 140     else
 141        kversion=$version.$patchlevel.$sublevel
 142     fi
 143     AC_MSG_RESULT([$kversion])
 144
 145     if test "$version" -ge 4; then
 146        if test "$version" = 4 && test "$patchlevel" -le 12; then
 147           : # Linux 4.x
 148        else
 149           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.11.x is not supported (please refer to the FAQ for advice)])
 150        fi
 151     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 152        : # Linux 3.x
 153     else
 154        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 155     fi
 156     if (test ! -e "$KBUILD"/include/linux/version.h && \
 157         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 158        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 159         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 160         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 161     fi
 162     OVS_CHECK_LINUX_COMPAT
 163   fi
 164   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 165 ])
 166
 167 dnl OVS_CHECK_LINUX_TC
 168 dnl
 169 dnl Configure Linux tc compat.
 170 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 171   AC_COMPILE_IFELSE([
 172     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 173         int x = TCA_FLOWER_KEY_IP_TTL_MASK;
 174     ])],
 175     [AC_DEFINE([HAVE_TCA_FLOWER_KEY_IP_TTL_MASK], [1],
 176                [Define to 1 if TCA_FLOWER_KEY_IP_TTL_MASK is avaiable.])])
 177
 178   AC_COMPILE_IFELSE([
 179     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 180         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 181     ])],
 182     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 183                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is avaiable.])])
 184
 185   AC_COMPILE_IFELSE([
 186     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 187         int x = TCA_TUNNEL_KEY_ENC_DST_PORT;
 188     ])],
 189     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_DST_PORT], [1],
 190                [Define to 1 if TCA_TUNNEL_KEY_ENC_DST_PORT is avaiable.])])
 191 ])
 192
 193 dnl OVS_CHECK_DPDK
 194 dnl
 195 dnl Configure DPDK source tree
 196 AC_DEFUN([OVS_CHECK_DPDK], [
 197   AC_ARG_WITH([dpdk],
 198               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 199                               [Specify the DPDK build directory])],
 200               [have_dpdk=true])
 201
 202   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 203   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 204     AC_MSG_RESULT([no])
 205     DPDKLIB_FOUND=false
 206   else
 207     AC_MSG_RESULT([yes])
 208     case "$with_dpdk" in
 209       yes)
 210         DPDK_AUTO_DISCOVER="true"
 211         PKG_CHECK_MODULES([DPDK], [libdpdk],
 212                           [DPDK_INCLUDE="$DPDK_CFLAGS"],
 213                           [DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"])
 214         ;;
 215       *)
 216         DPDK_AUTO_DISCOVER="false"
 217         DPDK_INCLUDE_PATH="$with_dpdk/include"
 218         # If 'with_dpdk' is passed install directory, point to headers
 219         # installed in $DESTDIR/$prefix/include/dpdk
 220         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 221            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 222         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 223            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 224         fi
 225         DPDK_LIB_DIR="$with_dpdk/lib"
 226         ;;
 227     esac
 228
 229     DPDK_LIB="-ldpdk"
 230     DPDK_EXTRA_LIB=""
 231
 232     ovs_save_CFLAGS="$CFLAGS"
 233     ovs_save_LDFLAGS="$LDFLAGS"
 234     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 235     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 236       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 237     fi
 238
 239     AC_COMPILE_IFELSE([
 240       AC_LANG_PROGRAM(
 241         [
 242           #include <rte_config.h>
 243 #if RTE_LIBRTE_VHOST_NUMA
 244 #error
 245 #endif
 246         ], [])
 247       ], [],
 248       [AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])])
 249        DPDK_EXTRA_LIB="-lnuma"
 250        AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])])
 251
 252     AC_COMPILE_IFELSE([
 253       AC_LANG_PROGRAM(
 254         [
 255           #include <rte_config.h>
 256 #if RTE_LIBRTE_PMD_PCAP
 257 #error
 258 #endif
 259         ], [])
 260       ], [],
 261       [AC_SEARCH_LIBS([pcap_dump],[pcap],[],[AC_MSG_ERROR([unable to find libpcap, install the dependency package])])
 262        DPDK_EXTRA_LIB="-lpcap"
 263        AC_COMPILE_IFELSE([
 264          AC_LANG_PROGRAM(
 265            [
 266              #include <rte_config.h>
 267 #if RTE_LIBRTE_PDUMP
 268 #error
 269 #endif
 270          ], [])
 271        ], [],
 272        [AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])])
 273      ])
 274
 275     # On some systems we have to add -ldl to link with dpdk
 276     #
 277     # This code, at first, tries to link without -ldl (""),
 278     # then adds it and tries again.
 279     # Before each attempt the search cache must be unset,
 280     # otherwise autoconf will stick with the old result
 281
 282     DPDKLIB_FOUND=false
 283     save_LIBS=$LIBS
 284     for extras in "" "-ldl"; do
 285         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 286         AC_LINK_IFELSE(
 287            [AC_LANG_PROGRAM([#include <rte_config.h>
 288                              #include <rte_eal.h>],
 289                             [int rte_argc; char ** rte_argv;
 290                              rte_eal_init(rte_argc, rte_argv);])],
 291            [DPDKLIB_FOUND=true])
 292         if $DPDKLIB_FOUND; then
 293             break
 294         fi
 295     done
 296
 297     # If linking unsuccessful
 298     if test "$DPDKLIB_FOUND" = "false" ; then
 299       if $DPDK_AUTO_DISCOVER; then
 300         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 301       else
 302         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 303       fi
 304     fi
 305     CFLAGS="$ovs_save_CFLAGS"
 306     LDFLAGS="$ovs_save_LDFLAGS"
 307     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 308       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 309     fi
 310     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 311     OVS_ENABLE_OPTION([-mssse3])
 312
 313     # DPDK pmd drivers are not linked unless --whole-archive is used.
 314     #
 315     # This happens because the rest of the DPDK code doesn't use any symbol in
 316     # the pmd driver objects, and the drivers register themselves using an
 317     # __attribute__((constructor)) function.
 318     #
 319     # These options are specified inside a single -Wl directive to prevent
 320     # autotools from reordering them.
 321     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 322     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 323     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 324   fi
 325
 326   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 327 ])
 328
 329 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 330 dnl
 331 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 332 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 333 dnl <REGEX> translated to uppercase.
 334 AC_DEFUN([OVS_GREP_IFELSE], [
 335   AC_MSG_CHECKING([whether $2 matches in $1])
 336   if test -f $1; then
 337     grep '$2' $1 >/dev/null 2>&1
 338     status=$?
 339     case $status in
 340       0)
 341         AC_MSG_RESULT([yes])
 342         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 343         ;;
 344       1)
 345         AC_MSG_RESULT([no])
 346         $4
 347         ;;
 348       *)
 349         AC_MSG_ERROR([grep exited with status $status])
 350         ;;
 351     esac
 352   else
 353     AC_MSG_RESULT([file not found])
 354     $4
 355   fi
 356 ])
 357
 358 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 359 dnl
 360 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 361 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 362 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 363 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 364 dnl translated to uppercase.
 365 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 366   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 367   if test -f $1; then
 368     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 369     status=$?
 370     case $status in
 371       0)
 372         AC_MSG_RESULT([yes])
 373         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 374         ;;
 375       1)
 376         AC_MSG_RESULT([no])
 377         $5
 378         ;;
 379       *)
 380         AC_MSG_ERROR([grep exited with status $status])
 381         ;;
 382     esac
 383   else
 384     AC_MSG_RESULT([file not found])
 385     $5
 386   fi
 387 ])
 388
 389 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 390 dnl
 391 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 392 dnl the function signature starting from the line matching FUNCTION
 393 dnl and ending with the line containing the closing parenthesis.  If
 394 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 395 dnl IF-MATCH is empty then it defines to
 396 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 397 dnl <REGEX> translated to uppercase.
 398 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 399   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 400   if test -f $1; then
 401     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 402     status=$?
 403     case $status in
 404       0)
 405         AC_MSG_RESULT([yes])
 406         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 407         ;;
 408       1)
 409         AC_MSG_RESULT([no])
 410         $5
 411         ;;
 412       *)
 413         AC_MSG_ERROR([grep exited with status $status])
 414         ;;
 415     esac
 416   else
 417     AC_MSG_RESULT([file not found])
 418     $5
 419   fi
 420 ])
 421
 422 dnl OVS_DEFINE(NAME)
 423 dnl
 424 dnl Defines NAME to 1 in kcompat.h.
 425 AC_DEFUN([OVS_DEFINE], [
 426   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 427 ])
 428
 429 dnl OVS_CHECK_LINUX_COMPAT
 430 dnl
 431 dnl Runs various Autoconf checks on the Linux kernel source in
 432 dnl the directory in $KBUILD.
 433 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 434   rm -f datapath/linux/kcompat.h.new
 435   mkdir -p datapath/linux
 436   : > datapath/linux/kcompat.h.new
 437
 438   echo '#include <linux/version.h>
 439 #ifndef RHEL_RELEASE_CODE
 440 #define RHEL_RELEASE_CODE 0
 441 #define RHEL_RELEASE_VERSION(a, b) 0
 442 #endif' >> datapath/linux/kcompat.h.new
 443
 444   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 445                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 446
 447   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 448                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 449   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 450
 451   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 452   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 453   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 454
 455   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 456   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 457
 458   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 459   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 460   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 461   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 462   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 463
 464   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 465   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 466   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 467                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 468   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 469                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 470
 471   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 472                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 473   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 474                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 475   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 476                         [ip_do_fragment], [net],
 477                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 478   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 479                         [ip_local_out], [net],
 480                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 481
 482   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 483
 484   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 485                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 486   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 487   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 488                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 489   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 490                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 491   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 492   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 493   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 494                         [frags_work])
 495   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 496                         [rwlock])
 497   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 498                         [list_evictor])
 499   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 500   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 501                         [sub_frag_mem_limit], [struct.netns_frags],
 502                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 503   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 504                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 505   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 506                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 507
 508   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 509   dnl OVS does not really need ipv6 label field, but its presence signifies that
 510   dnl the stack has all required ipv6 support.
 511   dnl OVS also does not need dst_cache But this dependency allows us to write
 512   dnl much cleaner code.
 513
 514   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 515                         [label],
 516                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 517                                          [iptunnel_pull_offloads],
 518                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 519                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])
 520
 521   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 522                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 523   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 524                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 525   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 526   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 527   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 528   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 529   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 530   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 531   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 532   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 533   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 534                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 535   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 536   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 537   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 538   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 539   dnl So check type of tstats.
 540   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 541                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 542   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 543                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 544   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 545   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 546   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 547                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 548   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 549   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 550   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 551                         [extended])
 552   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 553                         [netdev_master_upper_dev_link], [upper_priv],
 554                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 555   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 556                   [netdev_master_upper_dev_link_rh],
 557                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 558
 559   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 560                         [max_mtu])
 561
 562   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 563   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 564   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 565                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 566   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 567                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 568   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 569                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 570
 571   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 572                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 573
 574   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 575                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 576                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 577   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 578                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 579
 580   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 581                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 582                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 583   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 584                   [nf_ct_get_tuplepr], [struct.net],
 585                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 586   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 587                   [nf_ct_set])
 588   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 589                   [nf_ct_is_untracked])
 590   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 591                   [nf_ct_zone_init])
 592   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 593                   [nf_connlabels_get])
 594   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 595                   [nf_connlabels_get], [int bit],
 596                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 597   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 598                         [nf_conn_labels], [words])
 599   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 600   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 601   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 602
 603   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 604   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 605
 606   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 607   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 608   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 609                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 610   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 611
 612   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 613                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 614                                    [rcu_read_lock_held])])
 615   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 616
 617   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 618   # is necessary because some versions of this header remove the
 619   # member but retain the kerneldoc comment that describes it (which
 620   # starts with @).  The brackets must be doubled because of m4
 621   # quoting rules.
 622   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 623                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 624   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 625   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 626   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 627   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 628   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 629   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 630   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 631                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 632   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 633                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 634   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 635                   [skb_copy_from_linear_data_offset])
 636   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 637                   [skb_reset_tail_pointer])
 638   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 639   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 640                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 641   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 642   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 643   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 644   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 645   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 646   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 647   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 648   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 649                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 650   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 651   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 652                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 653   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 654                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 655   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 656   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 657   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 658   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 659   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 660   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 661   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 662   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 663   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 664
 665   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 666                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 667   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 668                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 669   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 670                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 671
 672   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 673   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 674
 675   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 676   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 677
 678   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 679   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 680   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 681   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 682                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 683   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 684   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 685                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 686   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 687                         [genl_notify], [net],
 688                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 689
 690
 691   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 692                         [genl_multicast_group], [id])
 693   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 694
 695   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 696   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 697   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 698   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 699   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 700   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 701                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 702   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 703                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 704
 705   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 706   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 707   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 708   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 709   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 710   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 711   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 712   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 713   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 714                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 715   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 716                         [nla_parse], [netlink_ext_ack],
 717                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 718
 719   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 720
 721   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 722                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 723   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 724   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 725   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 726   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 727   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 728
 729   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 730                         [metadata_dst_alloc], [metadata_type])
 731
 732   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 733
 734   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 735                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 736   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 737                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 738                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 739   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 740   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 741   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 742                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 743   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 744                         [gro_receive])
 745
 746   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 747                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 748   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 749                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 750
 751   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 752   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 753   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 754                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 755   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 756                         [udp_add_offload], [net],
 757                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 758   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 759                         [nf_defrag_ipv6_enable], [net],
 760                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 761   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 762                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 763   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 764                         [needs_free_netdev],
 765                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 766   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 767                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 768   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 769                   [nf_conntrack_helper_put])
 770
 771   if cmp -s datapath/linux/kcompat.h.new \
 772             datapath/linux/kcompat.h >/dev/null 2>&1; then
 773     rm datapath/linux/kcompat.h.new
 774   else
 775     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 776   fi
 777 ])
 778
 779 dnl Checks for net/if_packet.h.
 780 AC_DEFUN([OVS_CHECK_IF_PACKET],
 781   [AC_CHECK_HEADER([net/if_packet.h],
 782                    [HAVE_IF_PACKET=yes],
 783                    [HAVE_IF_PACKET=no])
 784    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 785    if test "$HAVE_IF_PACKET" = yes; then
 786       AC_DEFINE([HAVE_IF_PACKET], [1],
 787                 [Define to 1 if net/if_packet.h is available.])
 788    fi])
 789
 790 dnl Checks for net/if_dl.h.
 791 dnl
 792 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 793 dnl or NetBSD.)
 794 AC_DEFUN([OVS_CHECK_IF_DL],
 795   [AC_CHECK_HEADER([net/if_dl.h],
 796                    [HAVE_IF_DL=yes],
 797                    [HAVE_IF_DL=no])
 798    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 799    if test "$HAVE_IF_DL" = yes; then
 800       AC_DEFINE([HAVE_IF_DL], [1],
 801                 [Define to 1 if net/if_dl.h is available.])
 802
 803       # On these platforms we use libpcap to access network devices.
 804       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 805    fi])
 806
 807 dnl Checks for buggy strtok_r.
 808 dnl
 809 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 810 dnl with optimization that can cause segfaults:
 811 dnl
 812 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 813 AC_DEFUN([OVS_CHECK_STRTOK_R],
 814   [AC_CACHE_CHECK(
 815      [whether strtok_r macro segfaults on some inputs],
 816      [ovs_cv_strtok_r_bug],
 817      [AC_RUN_IFELSE(
 818         [AC_LANG_PROGRAM([#include <stdio.h>
 819                           #include <string.h>
 820                          ],
 821                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 822                            /* Assume bug is present, because relatively minor
 823                               changes in compiler settings (e.g. optimization
 824                               level) can make it crop up. */
 825                            return 1;
 826                            #else
 827                            char string[] = ":::";
 828                            char *save_ptr = (char *) 0xc0ffee;
 829                            char *token1, *token2;
 830                            token1 = strtok_r(string, ":", &save_ptr);
 831                            token2 = strtok_r(NULL, ":", &save_ptr);
 832                            freopen ("/dev/null", "w", stdout);
 833                            printf ("%s %s\n", token1, token2);
 834                            return 0;
 835                            #endif
 836                           ]])],
 837         [ovs_cv_strtok_r_bug=no],
 838         [ovs_cv_strtok_r_bug=yes],
 839         [ovs_cv_strtok_r_bug=yes])])
 840    if test $ovs_cv_strtok_r_bug = yes; then
 841      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 842                [Define if strtok_r macro segfaults on some inputs])
 843    fi
 844 ])
 845
 846 dnl ----------------------------------------------------------------------
 847 dnl These macros are from GNU PSPP, with the following original license:
 848 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 849 dnl This file is free software; the Free Software Foundation
 850 dnl gives unlimited permission to copy and/or distribute it,
 851 dnl with or without modifications, as long as this notice is preserved.
 852
 853 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 854   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
 855   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 856     [ovs_save_CFLAGS="$CFLAGS"
 857      dnl Include -Werror in the compiler options, because without -Werror
 858      dnl clang's GCC-compatible compiler driver does not return a failure
 859      dnl exit status even though it complains about options it does not
 860      dnl understand.
 861      dnl
 862      dnl Also, check stderr as gcc exits with status 0 for options
 863      dnl rejected at getopt level.
 864      dnl    % touch /tmp/a.c
 865      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 866      dnl    gcc: unrecognized option '-Qunused-arguments'
 867      dnl    0
 868      dnl    %
 869      CFLAGS="$CFLAGS $WERROR $1"
 870      AC_COMPILE_IFELSE(
 871        [AC_LANG_SOURCE([int x;])],
 872        [if test -s conftest.err && grep "unrecognized option" conftest.err
 873         then
 874           ovs_cv_name[]=no
 875         else
 876           ovs_cv_name[]=yes
 877         fi],
 878        [ovs_cv_name[]=no])
 879      CFLAGS="$ovs_save_CFLAGS"])
 880   if test $ovs_cv_name = yes; then
 881     m4_if([$2], [], [:], [$2])
 882   else
 883     m4_if([$3], [], [:], [$3])
 884   fi
 885 ])
 886
 887 dnl OVS_CHECK_WERROR
 888 dnl
 889 dnl Check whether the C compiler accepts -Werror.
 890 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 891 AC_DEFUN([OVS_CHECK_WERROR],
 892   [WERROR=
 893    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 894
 895 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 896 dnl Check whether the given C compiler OPTION is accepted.
 897 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 898 AC_DEFUN([OVS_CHECK_CC_OPTION],
 899   [AC_REQUIRE([OVS_CHECK_WERROR])
 900    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 901
 902 dnl OVS_ENABLE_OPTION([OPTION])
 903 dnl Check whether the given C compiler OPTION is accepted.
 904 dnl If so, add it to WARNING_FLAGS.
 905 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 906 AC_DEFUN([OVS_ENABLE_OPTION],
 907   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 908    AC_SUBST([WARNING_FLAGS])])
 909
 910 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 911 dnl Check whether the given C compiler OPTION is accepted.
 912 dnl If so, enable the given Automake CONDITIONAL.
 913
 914 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 915 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 916   [OVS_CHECK_CC_OPTION(
 917     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 918    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 919 dnl ----------------------------------------------------------------------
 920
 921 dnl Check for too-old XenServer.
 922 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 923   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 924     [if test -e /etc/redhat-release; then
 925        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 926      fi
 927      if test -z "$ovs_cv_xsversion"; then
 928        ovs_cv_xsversion=none
 929      fi])
 930   case $ovs_cv_xsversion in
 931     none)
 932       ;;
 933
 934     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 935     [[6-9]]* |                           dnl XenServer 6 or later
 936     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 937     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 938     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 939     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 940       ;;
 941
 942     *)
 943       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 944       ;;
 945   esac])
 946
 947 dnl OVS_CHECK_SPARSE_TARGET
 948 dnl
 949 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 950 dnl target for which the code is being built.  This helps it out.
 951 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 952   [AC_CACHE_CHECK(
 953     [target hint for cgcc],
 954     [ac_cv_sparse_target],
 955     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 956        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 957        [x86_64-*], [ac_cv_sparse_target=x86_64],
 958        [ac_cv_sparse_target=other])])
 959    AS_CASE([$ac_cv_sparse_target],
 960      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 961      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 962      [SPARSEFLAGS= CGCCFLAGS=])
 963    AC_SUBST([SPARSEFLAGS])
 964    AC_SUBST([CGCCFLAGS])])
 965
 966 dnl OVS_SPARSE_EXTRA_INCLUDES
 967 dnl
 968 dnl The cgcc script from "sparse" does not search gcc's default
 969 dnl search path. Get the default search path from GCC and pass
 970 dnl them to sparse.
 971 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 972     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 973            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 974
 975 dnl OVS_ENABLE_SPARSE
 976 AC_DEFUN([OVS_ENABLE_SPARSE],
 977   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 978    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 979    : ${SPARSE=sparse}
 980    AC_SUBST([SPARSE])
 981    AC_CONFIG_COMMANDS_PRE(
 982      [CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])])
 983
 984 dnl OVS_CTAGS_IDENTIFIERS
 985 dnl
 986 dnl ctags ignores symbols with extras identifiers. This builds a list of
 987 dnl specially handled identifiers to be ignored.
 988 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
 989     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
 990            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
 991
 992 dnl OVS_PTHREAD_SET_NAME
 993 dnl
 994 dnl This checks for three known variants of pthreads functions for setting
 995 dnl the name of the current thread:
 996 dnl
 997 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 998 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 999 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1000 dnl
1001 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1002 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1003 dnl provide to it.
1004 dnl
1005 dnl This macro defines:
1006 dnl
1007 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1008 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1009 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1010 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1011   [AC_CHECK_FUNCS([pthread_set_name_np])
1012    if test $ac_cv_func_pthread_set_name_np != yes; then
1013      AC_CACHE_CHECK(
1014        [for pthread_setname_np() variant],
1015        [ovs_cv_pthread_setname_np],
1016        [AC_LINK_IFELSE(
1017          [AC_LANG_PROGRAM([#include <pthread.h>
1018   ], [pthread_setname_np(pthread_self(), "name");])],
1019          [ovs_cv_pthread_setname_np=glibc],
1020          [AC_LINK_IFELSE(
1021            [AC_LANG_PROGRAM([#include <pthread.h>
1022 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1023            [ovs_cv_pthread_setname_np=netbsd],
1024            [ovs_cv_pthread_setname_np=none])])])
1025      case $ovs_cv_pthread_setname_np in # (
1026        glibc)
1027           AC_DEFINE(
1028             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1029             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1030           ;; # (
1031        netbsd)
1032           AC_DEFINE(
1033             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1034             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1035           ;;
1036      esac
1037    fi])
1038
1039 dnl OVS_CHECK_LINUX_HOST.
1040 dnl
1041 dnl Checks whether we're building for a Linux host, based on the presence of
1042 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1043 dnl LINUX based on the result.
1044 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1045   [AC_CACHE_CHECK(
1046      [whether __linux__ is defined],
1047      [ovs_cv_linux],
1048      [AC_COMPILE_IFELSE(
1049         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1050         [ovs_cv_linux=true],
1051         [ovs_cv_linux=false])])
1052    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])