acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 4; then
 154        if test "$version" = 4 && test "$patchlevel" -le 18; then
 155           : # Linux 4.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.18.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 160        : # Linux 3.x
 161     else
 162        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 163     fi
 164     if (test ! -e "$KBUILD"/include/linux/version.h && \
 165         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 166        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 167         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 168         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 169     fi
 170     OVS_CHECK_LINUX_COMPAT
 171   fi
 172   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 173 ])
 174
 175 dnl OVS_CHECK_LINUX_TC
 176 dnl
 177 dnl Configure Linux tc compat.
 178 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 179   AC_COMPILE_IFELSE([
 180     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 181         int x = TCA_FLOWER_KEY_ENC_IP_TTL_MASK;
 182     ])],
 183     [AC_DEFINE([HAVE_TCA_FLOWER_KEY_ENC_IP_TTL_MASK], [1],
 184                [Define to 1 if TCA_FLOWER_KEY_ENC_IP_TTL_MASK is available.])])
 185
 186   AC_COMPILE_IFELSE([
 187     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 188         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 189     ])],
 190     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 191                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 192
 193   AC_COMPILE_IFELSE([
 194     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 195         int x = TCA_TUNNEL_KEY_ENC_TTL;
 196     ])],
 197     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 198                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 199
 200   AC_COMPILE_IFELSE([
 201     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 202         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 203     ])],
 204     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 205                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 206
 207   AC_COMPILE_IFELSE([
 208     AC_LANG_PROGRAM([#include <linux/tc_act/tc_skbedit.h>], [
 209         int x = TCA_SKBEDIT_FLAGS;
 210     ])],
 211     [AC_DEFINE([HAVE_TCA_SKBEDIT_FLAGS], [1],
 212                [Define to 1 if TCA_SKBEDIT_FLAGS is available.])])
 213 ])
 214
 215 dnl OVS_CHECK_DPDK
 216 dnl
 217 dnl Configure DPDK source tree
 218 AC_DEFUN([OVS_CHECK_DPDK], [
 219   AC_ARG_WITH([dpdk],
 220               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 221                               [Specify the DPDK build directory])],
 222               [have_dpdk=true])
 223
 224   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 225   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 226     AC_MSG_RESULT([no])
 227     DPDKLIB_FOUND=false
 228   else
 229     AC_MSG_RESULT([yes])
 230     case "$with_dpdk" in
 231       yes)
 232         DPDK_AUTO_DISCOVER="true"
 233         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 234             DPDK_INCLUDE="$DPDK_CFLAGS"
 235             DPDK_LIB="$DPDK_LIBS"], [
 236             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 237             DPDK_LIB="-ldpdk"])
 238         ;;
 239       *)
 240         DPDK_AUTO_DISCOVER="false"
 241         DPDK_INCLUDE_PATH="$with_dpdk/include"
 242         # If 'with_dpdk' is passed install directory, point to headers
 243         # installed in $DESTDIR/$prefix/include/dpdk
 244         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 245            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 246         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 247            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 248         fi
 249         DPDK_LIB_DIR="$with_dpdk/lib"
 250         DPDK_LIB="-ldpdk"
 251         ;;
 252     esac
 253
 254     ovs_save_CFLAGS="$CFLAGS"
 255     ovs_save_LDFLAGS="$LDFLAGS"
 256     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 257     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 258       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 259     fi
 260
 261     AC_CHECK_HEADERS([rte_config.h], [], [
 262       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 263     ], [AC_INCLUDES_DEFAULT])
 264
 265     AC_COMPILE_IFELSE([
 266       AC_LANG_PROGRAM(
 267         [
 268           #include <rte_config.h>
 269 #if defined(RTE_LIBRTE_VHOST_NUMA) || defined(RTE_EAL_NUMA_AWARE_HUGEPAGES)
 270 #error
 271 #endif
 272         ], [])
 273       ], [],
 274       [AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])])
 275        AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])])
 276
 277     AC_COMPILE_IFELSE([
 278       AC_LANG_PROGRAM(
 279         [
 280           #include <rte_config.h>
 281 #if RTE_LIBRTE_PMD_PCAP
 282 #error
 283 #endif
 284         ], [])
 285       ], [],
 286       [AC_SEARCH_LIBS([pcap_dump],[pcap],[],[AC_MSG_ERROR([unable to find libpcap, install the dependency package])])
 287        AC_COMPILE_IFELSE([
 288          AC_LANG_PROGRAM(
 289            [
 290              #include <rte_config.h>
 291 #if RTE_LIBRTE_PDUMP
 292 #error
 293 #endif
 294          ], [])
 295        ], [],
 296        [AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])])
 297      ])
 298
 299     AC_COMPILE_IFELSE([
 300       AC_LANG_PROGRAM(
 301         [
 302           #include <rte_config.h>
 303 #if RTE_LIBRTE_MLX5_PMD
 304 #error
 305 #endif
 306         ], [])
 307       ], [],
 308       [AC_SEARCH_LIBS([mnl_attr_put],[mnl],[],[AC_MSG_ERROR([unable to find libmnl, install the dependency package])])])
 309
 310     AC_COMPILE_IFELSE([
 311       AC_LANG_PROGRAM(
 312         [
 313           #include <rte_config.h>
 314 #if defined(RTE_LIBRTE_MLX5_PMD) && !defined(RTE_LIBRTE_MLX5_DLOPEN_DEPS)
 315 #error
 316 #endif
 317         ], [])
 318       ], [],
 319       [AC_SEARCH_LIBS([mlx5dv_create_wq],[mlx5],[],[AC_MSG_ERROR([unable to find libmlx5, install the dependency package])])])
 320
 321     AC_COMPILE_IFELSE([
 322       AC_LANG_PROGRAM(
 323         [
 324           #include <rte_config.h>
 325 #if defined(RTE_LIBRTE_MLX4_PMD) && !defined(RTE_LIBRTE_MLX4_DLOPEN_DEPS)
 326 #error
 327 #endif
 328         ], [])
 329       ], [],
 330       [AC_SEARCH_LIBS([mlx4dv_init_obj],[mlx4],[],[AC_MSG_ERROR([unable to find libmlx4, install the dependency package])])])
 331
 332     AC_COMPILE_IFELSE([
 333       AC_LANG_PROGRAM(
 334         [
 335           #include <rte_config.h>
 336 #if defined(RTE_LIBRTE_MLX5_PMD) && !defined(RTE_LIBRTE_MLX5_DLOPEN_DEPS)
 337 #error
 338 #endif
 339 #if defined(RTE_LIBRTE_MLX4_PMD) && !defined(RTE_LIBRTE_MLX4_DLOPEN_DEPS)
 340 #error
 341 #endif
 342         ], [])
 343       ], [],
 344       [AC_SEARCH_LIBS([verbs_init_cq],[ibverbs],[],[AC_MSG_ERROR([unable to find libibverbs, install the dependency package])])])
 345
 346     # On some systems we have to add -ldl to link with dpdk
 347     #
 348     # This code, at first, tries to link without -ldl (""),
 349     # then adds it and tries again.
 350     # Before each attempt the search cache must be unset,
 351     # otherwise autoconf will stick with the old result
 352
 353     DPDKLIB_FOUND=false
 354     save_LIBS=$LIBS
 355     for extras in "" "-ldl"; do
 356         LIBS="$DPDK_LIB $extras $save_LIBS"
 357         AC_LINK_IFELSE(
 358            [AC_LANG_PROGRAM([#include <rte_config.h>
 359                              #include <rte_eal.h>],
 360                             [int rte_argc; char ** rte_argv;
 361                              rte_eal_init(rte_argc, rte_argv);])],
 362            [DPDKLIB_FOUND=true])
 363         if $DPDKLIB_FOUND; then
 364             break
 365         fi
 366     done
 367
 368     # If linking unsuccessful
 369     if test "$DPDKLIB_FOUND" = "false" ; then
 370       if $DPDK_AUTO_DISCOVER; then
 371         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 372       else
 373         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 374       fi
 375     fi
 376     CFLAGS="$ovs_save_CFLAGS"
 377     LDFLAGS="$ovs_save_LDFLAGS"
 378     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 379       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 380     fi
 381     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 382     OVS_ENABLE_OPTION([-mssse3])
 383
 384     # DPDK pmd drivers are not linked unless --whole-archive is used.
 385     #
 386     # This happens because the rest of the DPDK code doesn't use any symbol in
 387     # the pmd driver objects, and the drivers register themselves using an
 388     # __attribute__((constructor)) function.
 389     #
 390     # These options are specified inside a single -Wl directive to prevent
 391     # autotools from reordering them.
 392     #
 393     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 394     # will already have flagged just the right set of libs with
 395     # --whole-archive - in those cases do not wrap it once more.
 396     case "$DPDK_LIB" in
 397       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 398       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 399     esac
 400     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 401     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 402   fi
 403
 404   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 405 ])
 406
 407 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 408 dnl
 409 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 410 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 411 dnl <REGEX> translated to uppercase.
 412 AC_DEFUN([OVS_GREP_IFELSE], [
 413   AC_MSG_CHECKING([whether $2 matches in $1])
 414   if test -f $1; then
 415     grep '$2' $1 >/dev/null 2>&1
 416     status=$?
 417     case $status in
 418       0)
 419         AC_MSG_RESULT([yes])
 420         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 421         ;;
 422       1)
 423         AC_MSG_RESULT([no])
 424         $4
 425         ;;
 426       *)
 427         AC_MSG_ERROR([grep exited with status $status])
 428         ;;
 429     esac
 430   else
 431     AC_MSG_RESULT([file not found])
 432     $4
 433   fi
 434 ])
 435
 436 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 437 dnl
 438 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 439 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 440 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 441 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 442 dnl translated to uppercase.
 443 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 444   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 445   if test -f $1; then
 446     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 447     status=$?
 448     case $status in
 449       0)
 450         AC_MSG_RESULT([yes])
 451         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 452         ;;
 453       1)
 454         AC_MSG_RESULT([no])
 455         $5
 456         ;;
 457       *)
 458         AC_MSG_ERROR([grep exited with status $status])
 459         ;;
 460     esac
 461   else
 462     AC_MSG_RESULT([file not found])
 463     $5
 464   fi
 465 ])
 466
 467 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 468 dnl
 469 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 470 dnl the function signature starting from the line matching FUNCTION
 471 dnl and ending with the line containing the closing parenthesis.  If
 472 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 473 dnl IF-MATCH is empty then it defines to
 474 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 475 dnl <REGEX> translated to uppercase.
 476 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 477   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 478   if test -f $1; then
 479     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 480     status=$?
 481     case $status in
 482       0)
 483         AC_MSG_RESULT([yes])
 484         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 485         ;;
 486       1)
 487         AC_MSG_RESULT([no])
 488         $5
 489         ;;
 490       *)
 491         AC_MSG_ERROR([grep exited with status $status])
 492         ;;
 493     esac
 494   else
 495     AC_MSG_RESULT([file not found])
 496     $5
 497   fi
 498 ])
 499
 500 dnl OVS_DEFINE(NAME)
 501 dnl
 502 dnl Defines NAME to 1 in kcompat.h.
 503 AC_DEFUN([OVS_DEFINE], [
 504   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 505 ])
 506
 507 dnl OVS_CHECK_LINUX_COMPAT
 508 dnl
 509 dnl Runs various Autoconf checks on the Linux kernel source in
 510 dnl the directory in $KBUILD.
 511 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 512   rm -f datapath/linux/kcompat.h.new
 513   mkdir -p datapath/linux
 514   : > datapath/linux/kcompat.h.new
 515
 516   echo '#include <linux/version.h>
 517 #ifndef RHEL_RELEASE_CODE
 518 #define RHEL_RELEASE_CODE 0
 519 #define RHEL_RELEASE_VERSION(a, b) 0
 520 #endif' >> datapath/linux/kcompat.h.new
 521
 522   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 523                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 524
 525   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 526                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 527
 528   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 529                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 530   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 531
 532   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 533   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 534   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 535
 536   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 537                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 538   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 539                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 540
 541   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 542   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 543
 544   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 545   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 546   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 547   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 548   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 549
 550   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 551   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 552   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 553                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 554   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 555                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 556
 557   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 558                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 559   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 560                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 561   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 562                         [ip_do_fragment], [net],
 563                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 564   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 565                         [ip_local_out], [net],
 566                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 567
 568   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 569
 570   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 571                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 572   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 573   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 574                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 575   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 576                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 577   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 578   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 579   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 580                         [frags_work])
 581   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 582                         [rwlock])
 583   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 584                         [list_evictor])
 585   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 586   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 587                         [sub_frag_mem_limit], [struct.netns_frags],
 588                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 589   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 590                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 591   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 592                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 593
 594   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 595   dnl OVS does not really need ipv6 label field, but its presence signifies that
 596   dnl the stack has all required ipv6 support.
 597   dnl OVS also does not need dst_cache But this dependency allows us to write
 598   dnl much cleaner code.
 599
 600   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 601                         [label],
 602                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 603                                          [iptunnel_pull_offloads],
 604                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 605                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 606                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 607
 608   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 609                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 610   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 611                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 612   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 613                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 614   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 615   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 616   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 617   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 618   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 619   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 620   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 621   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 622   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 623   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 624                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 625   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 626   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 627   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 628   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 629   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 630   dnl So check type of tstats.
 631   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 632                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 633   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 634                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 635   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 636   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 637   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 638                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 639   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 640   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 641   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 642                         [extended])
 643   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 644                         [netdev_master_upper_dev_link], [upper_priv],
 645                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 646   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 647                   [netdev_master_upper_dev_link_rh],
 648                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 649
 650   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 651                         [max_mtu])
 652   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 653                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 654
 655   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 656   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 657   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 658                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 659   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 660                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 661   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 662                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 663   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 664
 665
 666   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 667                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 668
 669   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 670                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 671                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 672   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 673                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 674
 675   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 676                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 677                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 678   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 679                   [nf_ct_get_tuplepr], [struct.net],
 680                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 681   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 682                   [nf_ct_set])
 683   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 684                   [nf_ct_is_untracked])
 685   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 686                   [nf_ct_zone_init])
 687   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 688                   [net_ns_get])
 689   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 690                   [nf_connlabels_get])
 691   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 692                   [nf_connlabels_get], [int bit],
 693                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 694   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 695                         [nf_conn_labels], [words])
 696   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 697   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 698   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 699   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 700   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 701                   [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])
 702
 703   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 704   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 705
 706   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 707   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 708   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 709                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 710   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 711
 712   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 713                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 714                                    [rcu_read_lock_held])])
 715   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 716   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 717
 718   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 719   # is necessary because some versions of this header remove the
 720   # member but retain the kerneldoc comment that describes it (which
 721   # starts with @).  The brackets must be doubled because of m4
 722   # quoting rules.
 723   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 724                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 725   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 726   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 727   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 728   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 729   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 730   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 731   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 732                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 733   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 734                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 735   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 736                   [skb_copy_from_linear_data_offset])
 737   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 738                   [skb_reset_tail_pointer])
 739   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 740   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 741                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 742   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 743   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 744   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 745   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 746   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 747   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 748   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 749   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 750                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 751   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 752   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 753                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 754   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 755                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 756   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 757   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 758   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 759   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 760   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 761   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 762   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 763   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 764   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 765
 766   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 767                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 768   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 769                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 770   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 771                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 772
 773   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 774   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 775
 776   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 777   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 778
 779   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 780   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 781   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 782   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 783                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 784   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 785   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 786                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 787   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 788                         [genl_notify], [net],
 789                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 790
 791
 792   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 793                         [genl_multicast_group], [id])
 794   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 795
 796   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 797   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 798   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 799   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 800   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 801   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 802                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 803   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 804                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 805
 806   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 807   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 808   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 809   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 810   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 811   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 812   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 813   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 814   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 815                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 816   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 817                         [nla_parse], [netlink_ext_ack],
 818                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 819
 820   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 821
 822   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 823                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 824   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 825   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 826   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 827   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 828   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 829
 830   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 831                         [metadata_dst_alloc], [metadata_type])
 832
 833   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 834
 835   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 836                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 837   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 838                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 839                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 840   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 841   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 842   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 843                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 844   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 845                         [gro_receive])
 846
 847   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 848                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 849   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 850                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 851
 852   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 853   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 854   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 855                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 856   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 857                         [udp_add_offload], [net],
 858                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 859   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 860                         [nf_defrag_ipv6_enable], [net],
 861                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 862   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 863                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 864   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 865                         [needs_free_netdev],
 866                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 867   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 868                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 869   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 870                   [nf_conntrack_helper_put],
 871                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 872   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 873                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 874   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 875                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 876   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 877                         [extack],
 878                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 879   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 880                         [list],
 881                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 882   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 883                   [IP_CT_UNTRACKED])
 884   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 885                         [netdev_master_upper_dev_link], [extack],
 886                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 887   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 888                   [__LINUX_COMPILER_TYPES_H],
 889                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 890   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 891                   [ktime_get_ts64],
 892                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 893   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 894                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 895                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 896   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 897                   [ktime_get_ns],
 898                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 899   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 900                   frag_percpu_counter_batch[],
 901                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 902   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 903                   [null_compute_pseudo],
 904                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 905   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 906                   [__skb_checksum_convert],
 907                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
 908   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 909                         [max_mtu],
 910                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
 911   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
 912                         [erspan_ver],
 913                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
 914   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 915                   [SKB_GSO_IPXIP6],
 916                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
 917   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
 918                         [ip6_make_flowlabel], [fl6],
 919                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
 920   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
 921                         [auto_flowlabels],
 922                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
 923   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 924                   [netif_keep_dst],
 925                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
 926   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 927                         [ndo_get_iflink],
 928                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
 929   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 930                   [skb_set_inner_ipproto],
 931                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
 932   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 933                   [tunnel_encap_types],
 934                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
 935   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 936                   [IFLA_IPTUN_ENCAP_TYPE],
 937                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
 938   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 939                   [IFLA_IPTUN_COLLECT_METADATA],
 940                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
 941   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 942                   [IFLA_GRE_ENCAP_DPORT])
 943   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 944                   [IFLA_GRE_COLLECT_METADATA])
 945   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 946                   [IFLA_GRE_IGNORE_DF])
 947   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 948                   [IFLA_GRE_FWMARK])
 949   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 950                   [IFLA_GRE_ERSPAN_INDEX])
 951   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 952                   [IFLA_GRE_ERSPAN_HWID])
 953   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 954                   [IFLA_IPTUN_FWMARK])
 955   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
 956                         [csum_valid],
 957                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
 958   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 959                   [skb_checksum_simple_validate])
 960   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 961                   [void.*ndo_get_stats64],
 962                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
 963   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
 964                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
 965   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
 966                         [ip_tunnel_info_opts_set], [flags],
 967                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
 968   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 969                         [rnd],
 970                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
 971
 972   if cmp -s datapath/linux/kcompat.h.new \
 973             datapath/linux/kcompat.h >/dev/null 2>&1; then
 974     rm datapath/linux/kcompat.h.new
 975   else
 976     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 977   fi
 978 ])
 979
 980 dnl Checks for net/if_dl.h.
 981 dnl
 982 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 983 dnl or NetBSD.)
 984 AC_DEFUN([OVS_CHECK_IF_DL],
 985   [AC_CHECK_HEADER([net/if_dl.h],
 986                    [HAVE_IF_DL=yes],
 987                    [HAVE_IF_DL=no])
 988    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 989    if test "$HAVE_IF_DL" = yes; then
 990       AC_DEFINE([HAVE_IF_DL], [1],
 991                 [Define to 1 if net/if_dl.h is available.])
 992
 993       # On these platforms we use libpcap to access network devices.
 994       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 995    fi])
 996
 997 dnl Checks for buggy strtok_r.
 998 dnl
 999 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
1000 dnl with optimization that can cause segfaults:
1001 dnl
1002 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
1003 AC_DEFUN([OVS_CHECK_STRTOK_R],
1004   [AC_CACHE_CHECK(
1005      [whether strtok_r macro segfaults on some inputs],
1006      [ovs_cv_strtok_r_bug],
1007      [AC_RUN_IFELSE(
1008         [AC_LANG_PROGRAM([#include <stdio.h>
1009                           #include <string.h>
1010                          ],
1011                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
1012                            /* Assume bug is present, because relatively minor
1013                               changes in compiler settings (e.g. optimization
1014                               level) can make it crop up. */
1015                            return 1;
1016                            #else
1017                            char string[] = ":::";
1018                            char *save_ptr = (char *) 0xc0ffee;
1019                            char *token1, *token2;
1020                            token1 = strtok_r(string, ":", &save_ptr);
1021                            token2 = strtok_r(NULL, ":", &save_ptr);
1022                            freopen ("/dev/null", "w", stdout);
1023                            printf ("%s %s\n", token1, token2);
1024                            return 0;
1025                            #endif
1026                           ]])],
1027         [ovs_cv_strtok_r_bug=no],
1028         [ovs_cv_strtok_r_bug=yes],
1029         [ovs_cv_strtok_r_bug=yes])])
1030    if test $ovs_cv_strtok_r_bug = yes; then
1031      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1032                [Define if strtok_r macro segfaults on some inputs])
1033    fi
1034 ])
1035
1036 dnl ----------------------------------------------------------------------
1037 dnl These macros are from GNU PSPP, with the following original license:
1038 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1039 dnl This file is free software; the Free Software Foundation
1040 dnl gives unlimited permission to copy and/or distribute it,
1041 dnl with or without modifications, as long as this notice is preserved.
1042
1043 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1044   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1045   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1046     [ovs_save_CFLAGS="$CFLAGS"
1047      dnl Include -Werror in the compiler options, because without -Werror
1048      dnl clang's GCC-compatible compiler driver does not return a failure
1049      dnl exit status even though it complains about options it does not
1050      dnl understand.
1051      dnl
1052      dnl Also, check stderr as gcc exits with status 0 for options
1053      dnl rejected at getopt level.
1054      dnl    % touch /tmp/a.c
1055      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1056      dnl    gcc: unrecognized option '-Qunused-arguments'
1057      dnl    0
1058      dnl    %
1059      dnl
1060      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1061      dnl it does not understand, unless it has another error to report, so
1062      dnl instead of testing for -Wno-<foo>, test for the positive version.
1063      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1064      AC_COMPILE_IFELSE(
1065        [AC_LANG_SOURCE([int x;])],
1066        [if test -s conftest.err && grep "unrecognized option" conftest.err
1067         then
1068           ovs_cv_name[]=no
1069         else
1070           ovs_cv_name[]=yes
1071         fi],
1072        [ovs_cv_name[]=no])
1073      CFLAGS="$ovs_save_CFLAGS"])
1074   if test $ovs_cv_name = yes; then
1075     m4_if([$2], [], [:], [$2])
1076   else
1077     m4_if([$3], [], [:], [$3])
1078   fi
1079 ])
1080
1081 dnl OVS_CHECK_WERROR
1082 dnl
1083 dnl Check whether the C compiler accepts -Werror.
1084 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1085 AC_DEFUN([OVS_CHECK_WERROR],
1086   [WERROR=
1087    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1088
1089 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1090 dnl Check whether the given C compiler OPTION is accepted.
1091 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1092 AC_DEFUN([OVS_CHECK_CC_OPTION],
1093   [AC_REQUIRE([OVS_CHECK_WERROR])
1094    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1095
1096 dnl OVS_ENABLE_OPTION([OPTION])
1097 dnl Check whether the given C compiler OPTION is accepted.
1098 dnl If so, add it to WARNING_FLAGS.
1099 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1100 AC_DEFUN([OVS_ENABLE_OPTION],
1101   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1102    AC_SUBST([WARNING_FLAGS])])
1103
1104 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1105 dnl Check whether the given C compiler OPTION is accepted.
1106 dnl If so, enable the given Automake CONDITIONAL.
1107
1108 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1109 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1110   [OVS_CHECK_CC_OPTION(
1111     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1112    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1113 dnl ----------------------------------------------------------------------
1114
1115 dnl Check for too-old XenServer.
1116 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1117   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1118     [if test -e /etc/redhat-release; then
1119        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1120      fi
1121      if test -z "$ovs_cv_xsversion"; then
1122        ovs_cv_xsversion=none
1123      fi])
1124   case $ovs_cv_xsversion in
1125     none)
1126       ;;
1127
1128     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1129     [[6-9]]* |                           dnl XenServer 6 or later
1130     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1131     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1132     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1133     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1134       ;;
1135
1136     *)
1137       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1138       ;;
1139   esac])
1140
1141 dnl OVS_CHECK_SPARSE_TARGET
1142 dnl
1143 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1144 dnl target for which the code is being built.  This helps it out.
1145 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1146   [AC_CACHE_CHECK(
1147     [target hint for cgcc],
1148     [ac_cv_sparse_target],
1149     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1150        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1151        [x86_64-*], [ac_cv_sparse_target=x86_64],
1152        [ac_cv_sparse_target=other])])
1153    AS_CASE([$ac_cv_sparse_target],
1154      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
1155      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
1156      [SPARSEFLAGS= CGCCFLAGS=])
1157    AC_SUBST([SPARSEFLAGS])
1158    AC_SUBST([CGCCFLAGS])])
1159
1160 dnl OVS_SPARSE_EXTRA_INCLUDES
1161 dnl
1162 dnl The cgcc script from "sparse" does not search gcc's default
1163 dnl search path. Get the default search path from GCC and pass
1164 dnl them to sparse.
1165 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1166     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1167            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1168
1169 dnl OVS_ENABLE_SPARSE
1170 AC_DEFUN([OVS_ENABLE_SPARSE],
1171   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1172    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1173    : ${SPARSE=sparse}
1174    AC_SUBST([SPARSE])
1175    AC_CONFIG_COMMANDS_PRE(
1176      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1177
1178    AC_ARG_ENABLE(
1179      [sparse],
1180      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1181      [], [enable_sparse=no])
1182    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1183
1184 dnl OVS_CTAGS_IDENTIFIERS
1185 dnl
1186 dnl ctags ignores symbols with extras identifiers. This builds a list of
1187 dnl specially handled identifiers to be ignored.
1188 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1189     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1190            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1191
1192 dnl OVS_PTHREAD_SET_NAME
1193 dnl
1194 dnl This checks for three known variants of pthreads functions for setting
1195 dnl the name of the current thread:
1196 dnl
1197 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1198 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1199 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1200 dnl
1201 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1202 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1203 dnl provide to it.
1204 dnl
1205 dnl This macro defines:
1206 dnl
1207 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1208 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1209 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1210 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1211   [AC_CHECK_FUNCS([pthread_set_name_np])
1212    if test $ac_cv_func_pthread_set_name_np != yes; then
1213      AC_CACHE_CHECK(
1214        [for pthread_setname_np() variant],
1215        [ovs_cv_pthread_setname_np],
1216        [AC_LINK_IFELSE(
1217          [AC_LANG_PROGRAM([#include <pthread.h>
1218   ], [pthread_setname_np(pthread_self(), "name");])],
1219          [ovs_cv_pthread_setname_np=glibc],
1220          [AC_LINK_IFELSE(
1221            [AC_LANG_PROGRAM([#include <pthread.h>
1222 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1223            [ovs_cv_pthread_setname_np=netbsd],
1224            [ovs_cv_pthread_setname_np=none])])])
1225      case $ovs_cv_pthread_setname_np in # (
1226        glibc)
1227           AC_DEFINE(
1228             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1229             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1230           ;; # (
1231        netbsd)
1232           AC_DEFINE(
1233             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1234             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1235           ;;
1236      esac
1237    fi])
1238
1239 dnl OVS_CHECK_LINUX_HOST.
1240 dnl
1241 dnl Checks whether we're building for a Linux host, based on the presence of
1242 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1243 dnl LINUX based on the result.
1244 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1245   [AC_CACHE_CHECK(
1246      [whether __linux__ is defined],
1247      [ovs_cv_linux],
1248      [AC_COMPILE_IFELSE(
1249         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1250         [ovs_cv_linux=true],
1251         [ovs_cv_linux=false])])
1252    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])