acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2019 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl Set OVS DPCLS Autovalidator as default subtable search at compile time?
  18 dnl This enables automatically running all unit tests with all DPCLS
  19 dnl implementations.
  20 AC_DEFUN([OVS_CHECK_DPCLS_AUTOVALIDATOR], [
  21   AC_ARG_ENABLE([autovalidator],
  22                 [AC_HELP_STRING([--enable-autovalidator], [Enable DPCLS autovalidator as default subtable search implementation.])],
  23                 [autovalidator=yes],[autovalidator=no])
  24   AC_MSG_CHECKING([whether DPCLS Autovalidator is default implementation])
  25   if test "$autovalidator" != yes; then
  26     AC_MSG_RESULT([no])
  27   else
  28     OVS_CFLAGS="$OVS_CFLAGS -DDPCLS_AUTOVALIDATOR_DEFAULT"
  29     AC_MSG_RESULT([yes])
  30   fi
  31 ])
  32
  33 dnl OVS_ENABLE_WERROR
  34 AC_DEFUN([OVS_ENABLE_WERROR],
  35   [AC_ARG_ENABLE(
  36      [Werror],
  37      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  38      [], [enable_Werror=no])
  39    AC_CONFIG_COMMANDS_PRE(
  40      [if test "X$enable_Werror" = Xyes; then
  41         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  42       fi])
  43
  44    # Unless --enable-Werror is specified, report but do not fail the build
  45    # for errors reported by flake8.
  46    if test "X$enable_Werror" = Xyes; then
  47      FLAKE8_WERROR=
  48    else
  49      FLAKE8_WERROR=-
  50    fi
  51    AC_SUBST([FLAKE8_WERROR])
  52
  53    # If --enable-Werror is specified, fail the build on sparse warnings.
  54    if test "X$enable_Werror" = Xyes; then
  55      SPARSE_WERROR=-Wsparse-error
  56    else
  57      SPARSE_WERROR=
  58    fi
  59    AC_SUBST([SPARSE_WERROR])])
  60
  61 dnl OVS_CHECK_LINUX
  62 dnl
  63 dnl Configure linux kernel source tree
  64 AC_DEFUN([OVS_CHECK_LINUX], [
  65   AC_ARG_WITH([linux],
  66               [AC_HELP_STRING([--with-linux=/path/to/linux],
  67                               [Specify the Linux kernel build directory])])
  68   AC_ARG_WITH([linux-source],
  69               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  70                               [Specify the Linux kernel source directory
  71                                (usually figured out automatically from build
  72                                directory)])])
  73
  74   # Deprecated equivalents to --with-linux, --with-linux-source.
  75   AC_ARG_WITH([l26])
  76   AC_ARG_WITH([l26-source])
  77
  78   if test X"$with_linux" != X; then
  79     KBUILD=$with_linux
  80   elif test X"$with_l26" != X; then
  81     KBUILD=$with_l26
  82     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  83   else
  84     KBUILD=
  85   fi
  86
  87   if test X"$KBUILD" != X; then
  88     if test X"$with_linux_source" != X; then
  89       KSRC=$with_linux_source
  90     elif test X"$with_l26_source" != X; then
  91       KSRC=$with_l26_source
  92       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  93     else
  94       KSRC=
  95     fi
  96   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  97     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  98   fi
  99
 100   if test -n "$KBUILD"; then
 101     KBUILD=`eval echo "$KBUILD"`
 102     case $KBUILD in
 103         /*) ;;
 104         *) KBUILD=`pwd`/$KBUILD ;;
 105     esac
 106
 107     # The build directory is what the user provided.
 108     # Make sure that it exists.
 109     AC_MSG_CHECKING([for Linux build directory])
 110     if test -d "$KBUILD"; then
 111         AC_MSG_RESULT([$KBUILD])
 112         AC_SUBST(KBUILD)
 113     else
 114         AC_MSG_RESULT([no])
 115         AC_ERROR([source dir $KBUILD doesn't exist])
 116     fi
 117
 118     # Debian breaks kernel headers into "source" header and "build" headers.
 119     # We want the source headers, but $KBUILD gives us the "build" headers.
 120     # Use heuristics to find the source headers.
 121     AC_MSG_CHECKING([for Linux source directory])
 122     if test -n "$KSRC"; then
 123       KSRC=`eval echo "$KSRC"`
 124       case $KSRC in
 125           /*) ;;
 126           *) KSRC=`pwd`/$KSRC ;;
 127       esac
 128       if test ! -e $KSRC/include/linux/kernel.h; then
 129         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 130       fi
 131     else
 132       KSRC=$KBUILD
 133       if test ! -e $KSRC/include/linux/kernel.h; then
 134         # Debian kernel build Makefiles tend to include a line of the form:
 135         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 136         # First try to extract the source directory from this line.
 137         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 138         if test ! -e "$KSRC"/include/linux/kernel.h; then
 139           # Didn't work.  Fall back to name-based heuristics that used to work.
 140           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 141             */build)
 142               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 143               ;; # (
 144             *)
 145               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 146               ;;
 147           esac
 148         fi
 149       fi
 150       if test ! -e "$KSRC"/include/linux/kernel.h; then
 151         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 152       fi
 153     fi
 154     AC_MSG_RESULT([$KSRC])
 155
 156     AC_MSG_CHECKING([for kernel version])
 157     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 158     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 159     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 160     if test X"$version" = X || test X"$patchlevel" = X; then
 161        AC_ERROR([cannot determine kernel version])
 162     elif test X"$sublevel" = X; then
 163        kversion=$version.$patchlevel
 164     else
 165        kversion=$version.$patchlevel.$sublevel
 166     fi
 167     AC_MSG_RESULT([$kversion])
 168
 169     if test "$version" -ge 5; then
 170        if test "$version" = 5 && test "$patchlevel" -le 5; then
 171           : # Linux 5.x
 172        else
 173           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 5.5.x is not supported (please refer to the FAQ for advice)])
 174        fi
 175     elif test "$version" = 4; then
 176        : # Linux 4.x
 177     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 178        : # Linux 3.x
 179     else
 180        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 181     fi
 182     if (test ! -e "$KBUILD"/include/linux/version.h && \
 183         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 184        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 185         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 186         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 187     fi
 188     OVS_CHECK_LINUX_COMPAT
 189   fi
 190   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 191 ])
 192
 193 dnl OVS_CHECK_LINUX_NETLINK
 194 dnl
 195 dnl Configure Linux netlink compat.
 196 AC_DEFUN([OVS_CHECK_LINUX_NETLINK], [
 197   AC_COMPILE_IFELSE([
 198     AC_LANG_PROGRAM([#include <linux/netlink.h>], [
 199         struct nla_bitfield32 x =  { 0 };
 200     ])],
 201     [AC_DEFINE([HAVE_NLA_BITFIELD32], [1],
 202     [Define to 1 if struct nla_bitfield32 is available.])])
 203 ])
 204
 205 dnl OVS_CHECK_LINUX_TC
 206 dnl
 207 dnl Configure Linux tc compat.
 208 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 209   AC_COMPILE_IFELSE([
 210     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 211         int x = TCA_ACT_FLAGS;
 212     ])],
 213     [AC_DEFINE([HAVE_TCA_ACT_FLAGS], [1],
 214                [Define to 1 if TCA_ACT_FLAGS is available.])])
 215
 216   AC_CHECK_MEMBERS([struct tcf_t.firstuse], [], [], [#include <linux/pkt_cls.h>])
 217
 218   AC_COMPILE_IFELSE([
 219     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 220         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 221     ])],
 222     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 223                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 224
 225   AC_COMPILE_IFELSE([
 226     AC_LANG_PROGRAM([#include <linux/tc_act/tc_mpls.h>], [
 227         int x = TCA_MPLS_TTL;
 228     ])],
 229     [AC_DEFINE([HAVE_TCA_MPLS_TTL], [1],
 230                [Define to 1 if HAVE_TCA_MPLS_TTL is available.])])
 231
 232   AC_COMPILE_IFELSE([
 233     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 234         int x = TCA_TUNNEL_KEY_ENC_TTL;
 235     ])],
 236     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 237                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 238
 239   AC_COMPILE_IFELSE([
 240     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 241         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 242     ])],
 243     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 244                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 245
 246   AC_COMPILE_IFELSE([
 247     AC_LANG_PROGRAM([#include <linux/tc_act/tc_skbedit.h>], [
 248         int x = TCA_SKBEDIT_FLAGS;
 249     ])],
 250     [AC_DEFINE([HAVE_TCA_SKBEDIT_FLAGS], [1],
 251                [Define to 1 if TCA_SKBEDIT_FLAGS is available.])])
 252 ])
 253
 254 dnl OVS_CHECK_LINUX_SCTP_CT
 255 dnl
 256 dnl Checks for kernels which need additional SCTP state
 257 AC_DEFUN([OVS_CHECK_LINUX_SCTP_CT], [
 258   AC_COMPILE_IFELSE([
 259     AC_LANG_PROGRAM([#include <linux/netfilter/nfnetlink.h>
 260 #include <linux/netfilter/nfnetlink_conntrack.h>
 261 #include <linux/netfilter/nf_conntrack_common.h>
 262 #include <linux/netfilter/nf_conntrack_sctp.h>], [
 263         int x = SCTP_CONNTRACK_HEARTBEAT_SENT;
 264     ])],
 265     [AC_DEFINE([HAVE_SCTP_CONNTRACK_HEARTBEATS], [1],
 266                [Define to 1 if SCTP_CONNTRACK_HEARTBEAT_SENT is available.])])
 267 ])
 268
 269 dnl OVS_CHECK_LINUX_VIRTIO_TYPES
 270 dnl
 271 dnl Checks for kernels that need virtio_types definition.
 272 AC_DEFUN([OVS_CHECK_LINUX_VIRTIO_TYPES], [
 273   AC_COMPILE_IFELSE([
 274     AC_LANG_PROGRAM([#include <linux/virtio_types.h>], [
 275         __virtio16 x =  0;
 276     ])],
 277     [AC_DEFINE([HAVE_VIRTIO_TYPES], [1],
 278     [Define to 1 if __virtio16 is available.])])
 279 ])
 280
 281 dnl OVS_FIND_DEPENDENCY(FUNCTION, SEARCH_LIBS, NAME_TO_PRINT)
 282 dnl
 283 dnl Check for a function in a library list.
 284 AC_DEFUN([OVS_FIND_DEPENDENCY], [
 285   AC_SEARCH_LIBS([$1], [$2], [], [
 286     AC_MSG_ERROR([unable to find $3, install the dependency package])
 287   ])
 288 ])
 289
 290 dnl OVS_CHECK_LINUX_AF_XDP
 291 dnl
 292 dnl Check both Linux kernel AF_XDP and libbpf support
 293 AC_DEFUN([OVS_CHECK_LINUX_AF_XDP], [
 294   AC_ARG_ENABLE([afxdp],
 295                 [AC_HELP_STRING([--enable-afxdp], [Enable AF-XDP support])],
 296                 [], [enable_afxdp=no])
 297   AC_MSG_CHECKING([whether AF_XDP is enabled])
 298   if test "$enable_afxdp" != yes; then
 299     AC_MSG_RESULT([no])
 300     AF_XDP_ENABLE=false
 301   else
 302     AC_MSG_RESULT([yes])
 303     AF_XDP_ENABLE=true
 304
 305     AC_CHECK_HEADER([bpf/libbpf.h], [],
 306       [AC_MSG_ERROR([unable to find bpf/libbpf.h for AF_XDP support])])
 307
 308     AC_CHECK_HEADER([linux/if_xdp.h], [],
 309       [AC_MSG_ERROR([unable to find linux/if_xdp.h for AF_XDP support])])
 310
 311     AC_CHECK_HEADER([bpf/xsk.h], [],
 312       [AC_MSG_ERROR([unable to find bpf/xsk.h for AF_XDP support])])
 313
 314     AC_CHECK_FUNCS([pthread_spin_lock], [],
 315       [AC_MSG_ERROR([unable to find pthread_spin_lock for AF_XDP support])])
 316
 317     OVS_FIND_DEPENDENCY([numa_alloc_onnode], [numa], [libnuma])
 318
 319     AC_DEFINE([HAVE_AF_XDP], [1],
 320               [Define to 1 if AF_XDP support is available and enabled.])
 321     LIBBPF_LDADD=" -lbpf -lelf"
 322     AC_SUBST([LIBBPF_LDADD])
 323
 324     AC_CHECK_DECL([xsk_ring_prod__needs_wakeup], [
 325       AC_DEFINE([HAVE_XDP_NEED_WAKEUP], [1],
 326         [XDP need wakeup support detected in xsk.h.])
 327     ], [], [[#include <bpf/xsk.h>]])
 328   fi
 329   AM_CONDITIONAL([HAVE_AF_XDP], test "$AF_XDP_ENABLE" = true)
 330 ])
 331
 332 dnl OVS_CHECK_DPDK
 333 dnl
 334 dnl Configure DPDK source tree
 335 AC_DEFUN([OVS_CHECK_DPDK], [
 336   AC_ARG_WITH([dpdk],
 337               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 338                               [Specify the DPDK build directory])],
 339               [have_dpdk=true])
 340
 341   AC_MSG_CHECKING([whether dpdk is enabled])
 342   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 343     AC_MSG_RESULT([no])
 344     DPDKLIB_FOUND=false
 345   else
 346     AC_MSG_RESULT([yes])
 347     case "$with_dpdk" in
 348       yes)
 349         DPDK_AUTO_DISCOVER="true"
 350         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 351             DPDK_INCLUDE="$DPDK_CFLAGS"
 352             DPDK_LIB="$DPDK_LIBS"], [
 353             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 354             DPDK_LIB="-ldpdk"])
 355         ;;
 356       *)
 357         DPDK_AUTO_DISCOVER="false"
 358         DPDK_INCLUDE_PATH="$with_dpdk/include"
 359         # If 'with_dpdk' is passed install directory, point to headers
 360         # installed in $DESTDIR/$prefix/include/dpdk
 361         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 362            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 363         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 364            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 365         fi
 366         DPDK_LIB_DIR="$with_dpdk/lib"
 367         DPDK_LIB="-ldpdk"
 368         ;;
 369     esac
 370
 371     ovs_save_CFLAGS="$CFLAGS"
 372     ovs_save_LDFLAGS="$LDFLAGS"
 373     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 374     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 375       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 376     fi
 377
 378     AC_CHECK_HEADERS([rte_config.h], [], [
 379       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 380     ], [AC_INCLUDES_DEFAULT])
 381
 382     AC_CHECK_DECLS([RTE_LIBRTE_VHOST_NUMA, RTE_EAL_NUMA_AWARE_HUGEPAGES], [
 383       OVS_FIND_DEPENDENCY([get_mempolicy], [numa], [libnuma])
 384     ], [], [[#include <rte_config.h>]])
 385
 386     AC_CHECK_DECL([RTE_LIBRTE_PMD_PCAP], [
 387       OVS_FIND_DEPENDENCY([pcap_dump_close], [pcap], [libpcap])
 388     ], [], [[#include <rte_config.h>]])
 389
 390     AC_CHECK_DECL([RTE_LIBRTE_PMD_AF_XDP], [
 391       LIBBPF_LDADD="-lbpf"
 392     ], [], [[#include <rte_config.h>]])
 393
 394     AC_CHECK_DECL([RTE_LIBRTE_VHOST_NUMA], [
 395       AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])
 396     ], [], [[#include <rte_config.h>]])
 397
 398     AC_CHECK_DECL([RTE_LIBRTE_MLX5_PMD], [dnl found
 399       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 400         OVS_FIND_DEPENDENCY([mlx5dv_create_wq], [mlx5], [libmlx5])
 401         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 402       ], [[#include <rte_config.h>]])
 403     ], [], [[#include <rte_config.h>]])
 404
 405     AC_CHECK_DECL([RTE_LIBRTE_MLX4_PMD], [dnl found
 406       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 407         OVS_FIND_DEPENDENCY([mlx4dv_init_obj], [mlx4], [libmlx4])
 408         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 409       ], [[#include <rte_config.h>]])
 410     ], [], [[#include <rte_config.h>]])
 411
 412     # DPDK uses dlopen to load plugins.
 413     OVS_FIND_DEPENDENCY([dlopen], [dl], [libdl])
 414
 415     AC_MSG_CHECKING([whether linking with dpdk works])
 416     LIBS="$DPDK_LIB $LIBS"
 417     AC_LINK_IFELSE(
 418       [AC_LANG_PROGRAM([#include <rte_config.h>
 419                         #include <rte_eal.h>],
 420                        [int rte_argc; char ** rte_argv;
 421                         rte_eal_init(rte_argc, rte_argv);])],
 422       [AC_MSG_RESULT([yes])
 423        DPDKLIB_FOUND=true],
 424       [AC_MSG_RESULT([no])
 425        if test "$DPDK_AUTO_DISCOVER" = "true"; then
 426          AC_MSG_ERROR(m4_normalize([
 427             Could not find DPDK library in default search path, Use --with-dpdk
 428             to specify the DPDK library installed in non-standard location]))
 429        else
 430          AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 431        fi
 432       ])
 433
 434     CFLAGS="$ovs_save_CFLAGS"
 435     LDFLAGS="$ovs_save_LDFLAGS"
 436     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 437       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 438     fi
 439     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 440     OVS_ENABLE_OPTION([-mssse3])
 441
 442     # DPDK pmd drivers are not linked unless --whole-archive is used.
 443     #
 444     # This happens because the rest of the DPDK code doesn't use any symbol in
 445     # the pmd driver objects, and the drivers register themselves using an
 446     # __attribute__((constructor)) function.
 447     #
 448     # These options are specified inside a single -Wl directive to prevent
 449     # autotools from reordering them.
 450     #
 451     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 452     # will already have flagged just the right set of libs with
 453     # --whole-archive - in those cases do not wrap it once more.
 454     case "$DPDK_LIB" in
 455       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 456       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 457     esac
 458     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 459     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 460   fi
 461
 462   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 463 ])
 464
 465 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 466 dnl
 467 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 468 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 469 dnl <REGEX> translated to uppercase.
 470 AC_DEFUN([OVS_GREP_IFELSE], [
 471   AC_MSG_CHECKING([whether $2 matches in $1])
 472   if test -f $1; then
 473     grep '$2' $1 >/dev/null 2>&1
 474     status=$?
 475     case $status in
 476       0)
 477         AC_MSG_RESULT([yes])
 478         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 479         ;;
 480       1)
 481         AC_MSG_RESULT([no])
 482         $4
 483         ;;
 484       *)
 485         AC_MSG_ERROR([grep exited with status $status])
 486         ;;
 487     esac
 488   else
 489     AC_MSG_RESULT([file not found])
 490     $4
 491   fi
 492 ])
 493
 494 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 495 dnl
 496 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 497 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 498 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 499 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 500 dnl translated to uppercase.
 501 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 502   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 503   if test -f $1; then
 504     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 505     status=$?
 506     case $status in
 507       0)
 508         AC_MSG_RESULT([yes])
 509         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 510         ;;
 511       1)
 512         AC_MSG_RESULT([no])
 513         $5
 514         ;;
 515       *)
 516         AC_MSG_ERROR([grep exited with status $status])
 517         ;;
 518     esac
 519   else
 520     AC_MSG_RESULT([file not found])
 521     $5
 522   fi
 523 ])
 524
 525 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 526 dnl
 527 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 528 dnl the function signature starting from the line matching FUNCTION
 529 dnl and ending with the line containing the closing parenthesis.  If
 530 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 531 dnl IF-MATCH is empty then it defines to
 532 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 533 dnl <REGEX> translated to uppercase.
 534 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 535   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 536   if test -f $1; then
 537     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 538     status=$?
 539     case $status in
 540       0)
 541         AC_MSG_RESULT([yes])
 542         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 543         ;;
 544       1)
 545         AC_MSG_RESULT([no])
 546         $5
 547         ;;
 548       *)
 549         AC_MSG_ERROR([grep exited with status $status])
 550         ;;
 551     esac
 552   else
 553     AC_MSG_RESULT([file not found])
 554     $5
 555   fi
 556 ])
 557
 558 dnl OVS_FIND_OP_PARAM_IFELSE(FILE, OP, REGEX, [IF-MATCH], [IF-NO-MATCH])
 559 dnl
 560 dnl Looks for OP in FILE. If it is found, greps for REGEX within the
 561 dnl OP definition. If this is successful, runs IF-MATCH, otherwise
 562 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 563 dnl OVS_DEFINE(HAVE_<OP>_WITH_<REGEX>), with <OP> and <REGEX>
 564 dnl translated to uppercase.
 565 AC_DEFUN([OVS_FIND_OP_PARAM_IFELSE], [
 566   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 567   if test -f $1; then
 568     awk '/$2[[ \t\n]]*\)\(/,/;/' $1 2>/dev/null | grep '$3' >/dev/null
 569     status=$?
 570     case $status in
 571       0)
 572         AC_MSG_RESULT([yes])
 573         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 574         ;;
 575       1)
 576         AC_MSG_RESULT([no])
 577         $5
 578         ;;
 579       *)
 580         AC_MSG_ERROR([grep exited with status $status])
 581         ;;
 582     esac
 583   else
 584     AC_MSG_RESULT([file not found])
 585     $5
 586   fi
 587 ])
 588
 589 dnl OVS_DEFINE(NAME)
 590 dnl
 591 dnl Defines NAME to 1 in kcompat.h.
 592 AC_DEFUN([OVS_DEFINE], [
 593   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 594 ])
 595
 596 dnl OVS_CHECK_LINUX_COMPAT
 597 dnl
 598 dnl Runs various Autoconf checks on the Linux kernel source in
 599 dnl the directory in $KBUILD.
 600 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 601   rm -f datapath/linux/kcompat.h.new
 602   mkdir -p datapath/linux
 603   : > datapath/linux/kcompat.h.new
 604
 605   echo '#include <linux/version.h>
 606 #ifndef RHEL_RELEASE_CODE
 607 #define RHEL_RELEASE_CODE 0
 608 #define RHEL_RELEASE_VERSION(a, b) 0
 609 #endif' >> datapath/linux/kcompat.h.new
 610
 611   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 612                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 613
 614   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 615                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 616
 617   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub],
 618                         [dst_entry])
 619   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 620                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 621   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup_flow.*net],
 622                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_FLOW_NET])])
 623   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 624   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup_flow])
 625
 626   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 627   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 628   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 629
 630   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 631                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 632   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 633                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 634
 635   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 636   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 637
 638   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 639   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 640   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 641   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 642   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 643   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_hwaccel_clear_tag])
 644
 645   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 646   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 647   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 648                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 649   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 650                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 651
 652   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 653                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 654   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 655                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 656   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 657                         [ip_do_fragment], [net],
 658                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 659   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 660                         [ip_local_out], [net],
 661                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 662
 663   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 664
 665   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 666                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 667   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 668   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 669                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 670   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 671                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 672   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 673   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 674   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 675                         [frags_work])
 676   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 677                         [rwlock])
 678   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 679                         [list_evictor])
 680   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 681   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 682                         [sub_frag_mem_limit], [struct.netns_frags],
 683                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 684   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 685                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 686   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 687                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 688
 689   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 690   dnl OVS does not really need ipv6 label field, but its presence signifies that
 691   dnl the stack has all required ipv6 support.
 692   dnl OVS also does not need dst_cache But this dependency allows us to write
 693   dnl much cleaner code.
 694
 695   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 696                         [label],
 697                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 698                                          [iptunnel_pull_offloads],
 699                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 700                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 701                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 702
 703   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 704                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 705   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 706                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 707   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 708                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 709   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 710   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 711   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 712   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 713   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 714   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 715   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 716   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 717   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 718   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 719                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 720   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 721   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 722   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 723   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 724   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 725   dnl So check type of tstats.
 726   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 727                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 728   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 729                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 730   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 731   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 732   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 733                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 734   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 735   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 736   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 737                         [extended])
 738   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 739                         [netdev_master_upper_dev_link], [upper_priv],
 740                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 741   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 742                   [netdev_master_upper_dev_link_rh],
 743                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 744
 745   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 746                         [max_mtu])
 747   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 748                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 749   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 750                         [dev_change_flags], [extack],
 751                         [OVS_DEFINE([HAVE_DEV_CHANGE_FLAGS_TAKES_EXTACK])])
 752
 753   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 754   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state],
 755                         [struct net ], [OVS_DEFINE([HAVE_NF_HOOK_STATE_NET])])
 756   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 757   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 758                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 759   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 760                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 761   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 762                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 763   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 764   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [CONFIG_NF_NAT_NEEDED])
 765
 766
 767   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 768                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 769
 770   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 771                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 772                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 773   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 774                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 775
 776   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 777                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 778                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 779   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 780                   [nf_ct_get_tuplepr], [struct.net],
 781                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 782   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 783                   [nf_ct_set])
 784   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 785                   [nf_ct_is_untracked])
 786   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 787                   [nf_ct_invert_tuplepr])
 788   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 789                   [nf_ct_zone_init])
 790   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 791                   [net_ns_get])
 792   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 793                   [nf_connlabels_get])
 794   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 795                   [nf_connlabels_get], [int bit],
 796                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 797   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 798                         [nf_conn_labels], [words])
 799   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 800   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 801   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 802   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_packet],
 803                   [OVS_DEFINE([HAVE_UPSTREAM_NF_NAT])])
 804   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 805   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 806                   [OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h],
 807                                    [int nf_conncount_add],
 808                                    [], [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])])
 809   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [nf_ct_set_timeout])
 810   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [struct nf_ct_timeout],
 811                   [OVS_DEFINE([HAVE_NF_CT_TIMEOUT])])
 812   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h],
 813                         [\(*nf_ct_timeout_find_get_hook\)], [net],
 814                         [OVS_DEFINE([HAVE_NF_CT_TIMEOUT_FIND_GET_HOOK_NET])])
 815
 816   OVS_GREP_IFELSE([$KSRC/include/linux/random.h],
 817                   [prandom_u32[[\(]]],
 818                   [OVS_DEFINE([HAVE_PRANDOM_U32])])
 819   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 820
 821   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 822   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 823   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 824                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 825   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 826
 827   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 828                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 829                                    [rcu_read_lock_held])])
 830   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 831   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 832   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
 833                         [rtnl_create_link], [extack],
 834                         [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_TAKES_EXTACK])])
 835   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [nf_reset_ct])
 836
 837   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 838   # is necessary because some versions of this header remove the
 839   # member but retain the kerneldoc comment that describes it (which
 840   # starts with @).  The brackets must be doubled because of m4
 841   # quoting rules.
 842   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 843                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 844   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 845   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 846   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 847   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 848   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 849   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 850   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 851                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 852   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 853                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 854   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 855                   [skb_copy_from_linear_data_offset])
 856   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 857                   [skb_reset_tail_pointer])
 858   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 859   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 860                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 861   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 862   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 863   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 864   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 865   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 866   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 867   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 868   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 869                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 870   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 871   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 872                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 873   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 874                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 875   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 876   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 877   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 878   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 879   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 880   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 881   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 882   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 883   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 884
 885   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 886                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 887   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 888                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 889
 890   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 891   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 892
 893   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 894   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 895
 896   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 897   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 898   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 899   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 900                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 901   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 902   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 903                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 904   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_validate_flags])
 905   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 906                         [genl_notify], [net],
 907                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 908
 909
 910   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 911                         [genl_multicast_group], [id])
 912   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 913
 914   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 915   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 916   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 917   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 918   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 919   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 920                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 921   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 922                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 923
 924   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 925   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 926   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 927   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 928   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 929   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 930   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 931   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 932   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_nest_start_noflag])
 933   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 934                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 935   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 936                         [nla_parse], [netlink_ext_ack],
 937                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 938
 939   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 940
 941   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 942   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 943   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 944   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 945   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 946
 947   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 948                         [metadata_dst_alloc], [metadata_type])
 949
 950   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 951
 952   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 953                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 954   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 955                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 956                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 957   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 958   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 959   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 960                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 961   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 962                         [gro_receive])
 963
 964   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 965                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 966   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 967                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 968
 969   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 970   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 971   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 972                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 973   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 974                         [udp_add_offload], [net],
 975                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 976   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 977                         [nf_defrag_ipv6_enable], [net],
 978                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 979   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 980                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 981   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 982                         [needs_free_netdev],
 983                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 984   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 985                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 986   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 987                   [nf_conntrack_helper_put],
 988                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 989   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 990                   [nf_nat_helper_try_module_get])
 991   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 992                   [nf_nat_helper_put])
 993   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 994                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 995   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 996                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 997   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 998                         [extack],
 999                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
1000   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
1001                         [list],
1002                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
1003   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
1004                   [IP_CT_UNTRACKED])
1005   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
1006                         [netdev_master_upper_dev_link], [extack],
1007                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
1008   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
1009                   [__LINUX_COMPILER_TYPES_H],
1010                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
1011   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
1012                   [ktime_get_ts64],
1013                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
1014   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
1015                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
1016                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
1017   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
1018                   [ktime_get_ns],
1019                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
1020   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
1021                   frag_percpu_counter_batch[],
1022                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
1023   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1024                   [null_compute_pseudo],
1025                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
1026   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1027                   [__skb_checksum_convert],
1028                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
1029   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
1030                         [max_mtu],
1031                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
1032   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
1033                         [erspan_ver],
1034                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
1035   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1036                   [SKB_GSO_IPXIP6],
1037                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
1038   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
1039                         [ip6_make_flowlabel], [fl6],
1040                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
1041   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
1042                         [auto_flowlabels],
1043                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
1044   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
1045                   [netif_keep_dst],
1046                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
1047   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
1048                         [ndo_get_iflink],
1049                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
1050   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1051                   [skb_set_inner_ipproto],
1052                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
1053   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1054                   [tunnel_encap_types],
1055                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
1056   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1057                   [IFLA_IPTUN_ENCAP_TYPE],
1058                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
1059   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1060                   [IFLA_IPTUN_COLLECT_METADATA],
1061                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
1062   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1063                   [IFLA_GRE_ENCAP_DPORT])
1064   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1065                   [IFLA_GRE_COLLECT_METADATA])
1066   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1067                   [IFLA_GRE_IGNORE_DF])
1068   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1069                   [IFLA_GRE_FWMARK])
1070   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1071                   [IFLA_GRE_ERSPAN_INDEX])
1072   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1073                   [IFLA_GRE_ERSPAN_HWID])
1074   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1075                   [IFLA_IPTUN_FWMARK])
1076   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1077                         [csum_valid],
1078                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
1079   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1080                         [vlan_present],
1081                         [OVS_DEFINE([HAVE_SKBUFF_VLAN_PRESENT])])
1082   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1083                   [skb_checksum_simple_validate])
1084   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
1085                   [void.*ndo_get_stats64],
1086                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
1087   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
1088                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
1089   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
1090                         [ip_tunnel_info_opts_set], [flags],
1091                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
1092   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
1093                         [rnd],
1094                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
1095   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [__LINUX_OVERFLOW_H],
1096                   [OVS_DEFINE([HAVE_OVERFLOW_H])])
1097   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [struct_size],
1098                   [OVS_DEFINE([HAVE_STRUCT_SIZE])])
1099   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_array],
1100                   [OVS_DEFINE([HAVE_KVMALLOC_ARRAY])])
1101   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_node],
1102                   [OVS_DEFINE([HAVE_KVMALLOC_NODE])])
1103   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
1104                   [nf_conntrack_l3proto],
1105                   [OVS_DEFINE([HAVE_NF_CONNTRACK_L3PROATO_H])])
1106   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_core.h],
1107                         [nf_conntrack_in], [nf_hook_state],
1108                         [OVS_DEFINE([HAVE_NF_CONNTRACK_IN_TAKES_NF_HOOK_STATE])])
1109   OVS_GREP_IFELSE([$KSRC/include/net/ipv6_frag.h], [IP6_DEFRAG_CONNTRACK_IN],
1110                   [OVS_DEFINE([HAVE_IPV6_FRAG_H])])
1111   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
1112                         [nf_ct_helper_ext_add], [nf_conntrack_helper],
1113                         [OVS_DEFINE([HAVE_NF_CT_HELPER_EXT_ADD_TAKES_HELPER])])
1114   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_calc_hlen],
1115                   [OVS_DEFINE([HAVE_GRE_CALC_HLEN])])
1116   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [ip_gre_calc_hlen],
1117                   [OVS_DEFINE([HAVE_IP_GRE_CALC_HLEN])])
1118   OVS_GREP_IFELSE([$KSRC/include/linux/rbtree.h], [rb_link_node_rcu],
1119                   [OVS_DEFINE([HAVE_RBTREE_RB_LINK_NODE_RCU])])
1120   OVS_GREP_IFELSE([$KSRC/include/net/dst_ops.h], [bool confirm_neigh],
1121                   [OVS_DEFINE([HAVE_DST_OPS_CONFIRM_NEIGH])])
1122   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [fqdir],
1123                   [OVS_DEFINE([HAVE_INET_FRAG_FQDIR])])
1124   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h], [genl_ops],
1125                         [policy],
1126                         [OVS_DEFINE([HAVE_GENL_OPS_POLICY])])
1127   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h],
1128                   [nla_parse_deprecated_strict],
1129                   [OVS_DEFINE([HAVE_NLA_PARSE_DEPRECATED_STRICT])])
1130   OVS_FIND_OP_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
1131                            [validate], [extack],
1132                            [OVS_DEFINE([HAVE_RTNLOP_VALIDATE_WITH_EXTACK])])
1133   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1134                   [__skb_set_hash])
1135   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [sw_hash])
1136   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash_raw])
1137
1138   if cmp -s datapath/linux/kcompat.h.new \
1139             datapath/linux/kcompat.h >/dev/null 2>&1; then
1140     rm datapath/linux/kcompat.h.new
1141   else
1142     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
1143   fi
1144 ])
1145
1146 dnl Checks for net/if_dl.h.
1147 dnl
1148 dnl (We use this as a proxy for checking whether we're building on FreeBSD
1149 dnl or NetBSD.)
1150 AC_DEFUN([OVS_CHECK_IF_DL],
1151   [AC_CHECK_HEADER([net/if_dl.h],
1152                    [HAVE_IF_DL=yes],
1153                    [HAVE_IF_DL=no])
1154    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
1155    if test "$HAVE_IF_DL" = yes; then
1156       AC_DEFINE([HAVE_IF_DL], [1],
1157                 [Define to 1 if net/if_dl.h is available.])
1158
1159       # On these platforms we use libpcap to access network devices.
1160       AC_SEARCH_LIBS([pcap_open_live], [pcap])
1161    fi])
1162
1163 dnl Checks for buggy strtok_r.
1164 dnl
1165 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
1166 dnl with optimization that can cause segfaults:
1167 dnl
1168 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
1169 AC_DEFUN([OVS_CHECK_STRTOK_R],
1170   [AC_CACHE_CHECK(
1171      [whether strtok_r macro segfaults on some inputs],
1172      [ovs_cv_strtok_r_bug],
1173      [AC_RUN_IFELSE(
1174         [AC_LANG_PROGRAM([#include <stdio.h>
1175                           #include <string.h>
1176                          ],
1177                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
1178                            /* Assume bug is present, because relatively minor
1179                               changes in compiler settings (e.g. optimization
1180                               level) can make it crop up. */
1181                            return 1;
1182                            #else
1183                            char string[] = ":::";
1184                            char *save_ptr = (char *) 0xc0ffee;
1185                            char *token1, *token2;
1186                            token1 = strtok_r(string, ":", &save_ptr);
1187                            token2 = strtok_r(NULL, ":", &save_ptr);
1188                            freopen ("/dev/null", "w", stdout);
1189                            printf ("%s %s\n", token1, token2);
1190                            return 0;
1191                            #endif
1192                           ]])],
1193         [ovs_cv_strtok_r_bug=no],
1194         [ovs_cv_strtok_r_bug=yes],
1195         [ovs_cv_strtok_r_bug=yes])])
1196    if test $ovs_cv_strtok_r_bug = yes; then
1197      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1198                [Define if strtok_r macro segfaults on some inputs])
1199    fi
1200 ])
1201
1202 dnl ----------------------------------------------------------------------
1203 dnl These macros are from GNU PSPP, with the following original license:
1204 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1205 dnl This file is free software; the Free Software Foundation
1206 dnl gives unlimited permission to copy and/or distribute it,
1207 dnl with or without modifications, as long as this notice is preserved.
1208
1209 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1210   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1211   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1212     [ovs_save_CFLAGS="$CFLAGS"
1213      dnl Include -Werror in the compiler options, because without -Werror
1214      dnl clang's GCC-compatible compiler driver does not return a failure
1215      dnl exit status even though it complains about options it does not
1216      dnl understand.
1217      dnl
1218      dnl Also, check stderr as gcc exits with status 0 for options
1219      dnl rejected at getopt level.
1220      dnl    % touch /tmp/a.c
1221      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1222      dnl    gcc: unrecognized option '-Qunused-arguments'
1223      dnl    0
1224      dnl    %
1225      dnl
1226      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1227      dnl it does not understand, unless it has another error to report, so
1228      dnl instead of testing for -Wno-<foo>, test for the positive version.
1229      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1230      AC_COMPILE_IFELSE(
1231        [AC_LANG_SOURCE([int x;])],
1232        [if test -s conftest.err && grep "unrecognized option" conftest.err
1233         then
1234           ovs_cv_name[]=no
1235         else
1236           ovs_cv_name[]=yes
1237         fi],
1238        [ovs_cv_name[]=no])
1239      CFLAGS="$ovs_save_CFLAGS"])
1240   if test $ovs_cv_name = yes; then
1241     m4_if([$2], [], [:], [$2])
1242   else
1243     m4_if([$3], [], [:], [$3])
1244   fi
1245 ])
1246
1247 dnl OVS_CHECK_WERROR
1248 dnl
1249 dnl Check whether the C compiler accepts -Werror.
1250 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1251 AC_DEFUN([OVS_CHECK_WERROR],
1252   [WERROR=
1253    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1254
1255 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1256 dnl Check whether the given C compiler OPTION is accepted.
1257 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1258 AC_DEFUN([OVS_CHECK_CC_OPTION],
1259   [AC_REQUIRE([OVS_CHECK_WERROR])
1260    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1261
1262 dnl OVS_ENABLE_OPTION([OPTION])
1263 dnl Check whether the given C compiler OPTION is accepted.
1264 dnl If so, add it to WARNING_FLAGS.
1265 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1266 AC_DEFUN([OVS_ENABLE_OPTION],
1267   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1268    AC_SUBST([WARNING_FLAGS])])
1269
1270 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1271 dnl Check whether the given C compiler OPTION is accepted.
1272 dnl If so, enable the given Automake CONDITIONAL.
1273
1274 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1275 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1276   [OVS_CHECK_CC_OPTION(
1277     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1278    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1279 dnl ----------------------------------------------------------------------
1280
1281 dnl Check for too-old XenServer.
1282 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1283   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1284     [if test -e /etc/redhat-release; then
1285        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1286      fi
1287      if test -z "$ovs_cv_xsversion"; then
1288        ovs_cv_xsversion=none
1289      fi])
1290   case $ovs_cv_xsversion in
1291     none)
1292       ;;
1293
1294     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1295     [[6-9]]* |                           dnl XenServer 6 or later
1296     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1297     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1298     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1299     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1300       ;;
1301
1302     *)
1303       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1304       ;;
1305   esac])
1306
1307 dnl OVS_CHECK_SPARSE_TARGET
1308 dnl
1309 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1310 dnl target for which the code is being built.  This helps it out.
1311 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1312   [AC_CACHE_CHECK(
1313     [target hint for cgcc],
1314     [ac_cv_sparse_target],
1315     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1316        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1317        [x86_64-*], [ac_cv_sparse_target=x86_64],
1318        [ac_cv_sparse_target=other])])
1319    AS_CASE([$ac_cv_sparse_target],
1320      [x86], [SPARSEFLAGS= CGCCFLAGS="-target=i86 -target=host_os_specs"],
1321      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS="-target=x86_64 -target=host_os_specs"],
1322      [SPARSEFLAGS= CGCCFLAGS=])
1323
1324    dnl Get the default defines for vector instructions from compiler to
1325    dnl allow "sparse" correctly check the same code that will be built.
1326    dnl Required for checking DPDK headers.
1327    AC_MSG_CHECKING([vector options for cgcc])
1328    VECTOR=$($CC -dM -E - < /dev/null | grep -E "MMX|SSE|AVX" | \
1329             cut -c 9- | sed 's/ /=/' | sed 's/^/-D/' | tr '\n' ' ')
1330    AC_MSG_RESULT([$VECTOR])
1331    CGCCFLAGS="$CGCCFLAGS $VECTOR"
1332
1333    AC_SUBST([SPARSEFLAGS])
1334    AC_SUBST([CGCCFLAGS])])
1335
1336 dnl OVS_SPARSE_EXTRA_INCLUDES
1337 dnl
1338 dnl The cgcc script from "sparse" does not search gcc's default
1339 dnl search path. Get the default search path from GCC and pass
1340 dnl them to sparse.
1341 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1342     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1343            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1344
1345 dnl OVS_ENABLE_SPARSE
1346 AC_DEFUN([OVS_ENABLE_SPARSE],
1347   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1348    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1349    : ${SPARSE=sparse}
1350    AC_SUBST([SPARSE])
1351    AC_CONFIG_COMMANDS_PRE(
1352      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1353
1354    AC_ARG_ENABLE(
1355      [sparse],
1356      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1357      [], [enable_sparse=no])
1358    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1359
1360 dnl OVS_CTAGS_IDENTIFIERS
1361 dnl
1362 dnl ctags ignores symbols with extras identifiers. This is a list of
1363 dnl specially handled identifiers to be ignored. [ctags(1) -I <list>].
1364 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1365     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1366            ["OVS_LOCKABLE OVS_NO_THREAD_SAFETY_ANALYSIS OVS_REQ_RDLOCK+ OVS_ACQ_RDLOCK+ OVS_REQ_WRLOCK+ OVS_ACQ_WRLOCK+ OVS_REQUIRES+ OVS_ACQUIRES+ OVS_TRY_WRLOCK+ OVS_TRY_RDLOCK+ OVS_TRY_LOCK+ OVS_GUARDED_BY+ OVS_EXCLUDED+ OVS_RELEASES+ OVS_ACQ_BEFORE+ OVS_ACQ_AFTER+"]))
1367
1368 dnl OVS_PTHREAD_SET_NAME
1369 dnl
1370 dnl This checks for three known variants of pthreads functions for setting
1371 dnl the name of the current thread:
1372 dnl
1373 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1374 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1375 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1376 dnl
1377 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1378 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1379 dnl provide to it.
1380 dnl
1381 dnl This macro defines:
1382 dnl
1383 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1384 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1385 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1386 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1387   [AC_CHECK_FUNCS([pthread_set_name_np])
1388    if test $ac_cv_func_pthread_set_name_np != yes; then
1389      AC_CACHE_CHECK(
1390        [for pthread_setname_np() variant],
1391        [ovs_cv_pthread_setname_np],
1392        [AC_LINK_IFELSE(
1393          [AC_LANG_PROGRAM([#include <pthread.h>
1394   ], [pthread_setname_np(pthread_self(), "name");])],
1395          [ovs_cv_pthread_setname_np=glibc],
1396          [AC_LINK_IFELSE(
1397            [AC_LANG_PROGRAM([#include <pthread.h>
1398 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1399            [ovs_cv_pthread_setname_np=netbsd],
1400            [ovs_cv_pthread_setname_np=none])])])
1401      case $ovs_cv_pthread_setname_np in # (
1402        glibc)
1403           AC_DEFINE(
1404             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1405             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1406           ;; # (
1407        netbsd)
1408           AC_DEFINE(
1409             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1410             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1411           ;;
1412      esac
1413    fi])
1414
1415 dnl OVS_CHECK_LINUX_HOST.
1416 dnl
1417 dnl Checks whether we're building for a Linux host, based on the presence of
1418 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1419 dnl LINUX based on the result.
1420 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1421   [AC_CACHE_CHECK(
1422      [whether __linux__ is defined],
1423      [ovs_cv_linux],
1424      [AC_COMPILE_IFELSE(
1425         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1426         [ovs_cv_linux=true],
1427         [ovs_cv_linux=false])])
1428    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])