acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 4; then
 154        if test "$version" = 4 && test "$patchlevel" -le 18; then
 155           : # Linux 4.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.18.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 160        : # Linux 3.x
 161     else
 162        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 163     fi
 164     if (test ! -e "$KBUILD"/include/linux/version.h && \
 165         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 166        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 167         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 168         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 169     fi
 170     OVS_CHECK_LINUX_COMPAT
 171   fi
 172   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 173 ])
 174
 175 dnl OVS_CHECK_LINUX_TC
 176 dnl
 177 dnl Configure Linux tc compat.
 178 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 179   AC_COMPILE_IFELSE([
 180     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 181         int x = TCA_FLOWER_KEY_ENC_IP_TTL_MASK;
 182     ])],
 183     [AC_DEFINE([HAVE_TCA_FLOWER_KEY_ENC_IP_TTL_MASK], [1],
 184                [Define to 1 if TCA_FLOWER_KEY_ENC_IP_TTL_MASK is available.])])
 185
 186   AC_COMPILE_IFELSE([
 187     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 188         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 189     ])],
 190     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 191                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 192
 193   AC_COMPILE_IFELSE([
 194     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 195         int x = TCA_TUNNEL_KEY_ENC_TTL;
 196     ])],
 197     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 198                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 199
 200   AC_COMPILE_IFELSE([
 201     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 202         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 203     ])],
 204     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 205                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 206 ])
 207
 208 dnl OVS_CHECK_DPDK
 209 dnl
 210 dnl Configure DPDK source tree
 211 AC_DEFUN([OVS_CHECK_DPDK], [
 212   AC_ARG_WITH([dpdk],
 213               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 214                               [Specify the DPDK build directory])],
 215               [have_dpdk=true])
 216
 217   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 218   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 219     AC_MSG_RESULT([no])
 220     DPDKLIB_FOUND=false
 221   else
 222     AC_MSG_RESULT([yes])
 223     case "$with_dpdk" in
 224       yes)
 225         DPDK_AUTO_DISCOVER="true"
 226         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 227             DPDK_INCLUDE="$DPDK_CFLAGS"
 228             DPDK_LIB="$DPDK_LIBS"], [
 229             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 230             DPDK_LIB="-ldpdk"])
 231         ;;
 232       *)
 233         DPDK_AUTO_DISCOVER="false"
 234         DPDK_INCLUDE_PATH="$with_dpdk/include"
 235         # If 'with_dpdk' is passed install directory, point to headers
 236         # installed in $DESTDIR/$prefix/include/dpdk
 237         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 238            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 239         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 240            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 241         fi
 242         DPDK_LIB_DIR="$with_dpdk/lib"
 243         DPDK_LIB="-ldpdk"
 244         ;;
 245     esac
 246
 247     ovs_save_CFLAGS="$CFLAGS"
 248     ovs_save_LDFLAGS="$LDFLAGS"
 249     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 250     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 251       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 252     fi
 253
 254     AC_CHECK_HEADERS([rte_config.h], [], [
 255       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 256     ], [AC_INCLUDES_DEFAULT])
 257
 258     AC_COMPILE_IFELSE([
 259       AC_LANG_PROGRAM(
 260         [
 261           #include <rte_config.h>
 262 #if defined(RTE_LIBRTE_VHOST_NUMA) || defined(RTE_EAL_NUMA_AWARE_HUGEPAGES)
 263 #error
 264 #endif
 265         ], [])
 266       ], [],
 267       [AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])])
 268        AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])])
 269
 270     AC_COMPILE_IFELSE([
 271       AC_LANG_PROGRAM(
 272         [
 273           #include <rte_config.h>
 274 #if RTE_LIBRTE_PMD_PCAP
 275 #error
 276 #endif
 277         ], [])
 278       ], [],
 279       [AC_SEARCH_LIBS([pcap_dump],[pcap],[],[AC_MSG_ERROR([unable to find libpcap, install the dependency package])])
 280        AC_COMPILE_IFELSE([
 281          AC_LANG_PROGRAM(
 282            [
 283              #include <rte_config.h>
 284 #if RTE_LIBRTE_PDUMP
 285 #error
 286 #endif
 287          ], [])
 288        ], [],
 289        [AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])])
 290      ])
 291
 292     AC_COMPILE_IFELSE([
 293       AC_LANG_PROGRAM(
 294         [
 295           #include <rte_config.h>
 296 #if RTE_LIBRTE_MLX5_PMD
 297 #error
 298 #endif
 299         ], [])
 300       ], [],
 301       [AC_SEARCH_LIBS([mnl_attr_put],[mnl],[],[AC_MSG_ERROR([unable to find libmnl, install the dependency package])])
 302        AC_DEFINE([DPDK_MNL], [1], [MLX5 PMD detected in DPDK.])])
 303
 304     AC_COMPILE_IFELSE([
 305       AC_LANG_PROGRAM(
 306         [
 307           #include <rte_config.h>
 308 #if defined(RTE_LIBRTE_MLX5_PMD) && !defined(RTE_LIBRTE_MLX5_DLOPEN_DEPS)
 309 #error
 310 #endif
 311         ], [])
 312       ], [],
 313       [AC_SEARCH_LIBS([mlx5dv_create_wq],[mlx5],[],[AC_MSG_ERROR([unable to find libmlx5, install the dependency package])])])
 314
 315     AC_COMPILE_IFELSE([
 316       AC_LANG_PROGRAM(
 317         [
 318           #include <rte_config.h>
 319 #if defined(RTE_LIBRTE_MLX5_PMD) && !defined(RTE_LIBRTE_MLX5_DLOPEN_DEPS)
 320 #error
 321 #endif
 322         ], [])
 323       ], [],
 324       [AC_SEARCH_LIBS([verbs_init_cq],[ibverbs],[],[AC_MSG_ERROR([unable to find libibverbs, install the dependency package])])])
 325
 326     # On some systems we have to add -ldl to link with dpdk
 327     #
 328     # This code, at first, tries to link without -ldl (""),
 329     # then adds it and tries again.
 330     # Before each attempt the search cache must be unset,
 331     # otherwise autoconf will stick with the old result
 332
 333     DPDKLIB_FOUND=false
 334     save_LIBS=$LIBS
 335     for extras in "" "-ldl"; do
 336         LIBS="$DPDK_LIB $extras $save_LIBS"
 337         AC_LINK_IFELSE(
 338            [AC_LANG_PROGRAM([#include <rte_config.h>
 339                              #include <rte_eal.h>],
 340                             [int rte_argc; char ** rte_argv;
 341                              rte_eal_init(rte_argc, rte_argv);])],
 342            [DPDKLIB_FOUND=true])
 343         if $DPDKLIB_FOUND; then
 344             break
 345         fi
 346     done
 347
 348     # If linking unsuccessful
 349     if test "$DPDKLIB_FOUND" = "false" ; then
 350       if $DPDK_AUTO_DISCOVER; then
 351         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 352       else
 353         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 354       fi
 355     fi
 356     CFLAGS="$ovs_save_CFLAGS"
 357     LDFLAGS="$ovs_save_LDFLAGS"
 358     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 359       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 360     fi
 361     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 362     OVS_ENABLE_OPTION([-mssse3])
 363
 364     # DPDK pmd drivers are not linked unless --whole-archive is used.
 365     #
 366     # This happens because the rest of the DPDK code doesn't use any symbol in
 367     # the pmd driver objects, and the drivers register themselves using an
 368     # __attribute__((constructor)) function.
 369     #
 370     # These options are specified inside a single -Wl directive to prevent
 371     # autotools from reordering them.
 372     #
 373     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 374     # will already have flagged just the right set of libs with
 375     # --whole-archive - in those cases do not wrap it once more.
 376     case "$DPDK_LIB" in
 377       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 378       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 379     esac
 380     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 381     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 382   fi
 383
 384   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 385 ])
 386
 387 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 388 dnl
 389 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 390 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 391 dnl <REGEX> translated to uppercase.
 392 AC_DEFUN([OVS_GREP_IFELSE], [
 393   AC_MSG_CHECKING([whether $2 matches in $1])
 394   if test -f $1; then
 395     grep '$2' $1 >/dev/null 2>&1
 396     status=$?
 397     case $status in
 398       0)
 399         AC_MSG_RESULT([yes])
 400         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 401         ;;
 402       1)
 403         AC_MSG_RESULT([no])
 404         $4
 405         ;;
 406       *)
 407         AC_MSG_ERROR([grep exited with status $status])
 408         ;;
 409     esac
 410   else
 411     AC_MSG_RESULT([file not found])
 412     $4
 413   fi
 414 ])
 415
 416 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 417 dnl
 418 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 419 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 420 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 421 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 422 dnl translated to uppercase.
 423 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 424   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 425   if test -f $1; then
 426     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 427     status=$?
 428     case $status in
 429       0)
 430         AC_MSG_RESULT([yes])
 431         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 432         ;;
 433       1)
 434         AC_MSG_RESULT([no])
 435         $5
 436         ;;
 437       *)
 438         AC_MSG_ERROR([grep exited with status $status])
 439         ;;
 440     esac
 441   else
 442     AC_MSG_RESULT([file not found])
 443     $5
 444   fi
 445 ])
 446
 447 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 448 dnl
 449 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 450 dnl the function signature starting from the line matching FUNCTION
 451 dnl and ending with the line containing the closing parenthesis.  If
 452 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 453 dnl IF-MATCH is empty then it defines to
 454 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 455 dnl <REGEX> translated to uppercase.
 456 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 457   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 458   if test -f $1; then
 459     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 460     status=$?
 461     case $status in
 462       0)
 463         AC_MSG_RESULT([yes])
 464         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 465         ;;
 466       1)
 467         AC_MSG_RESULT([no])
 468         $5
 469         ;;
 470       *)
 471         AC_MSG_ERROR([grep exited with status $status])
 472         ;;
 473     esac
 474   else
 475     AC_MSG_RESULT([file not found])
 476     $5
 477   fi
 478 ])
 479
 480 dnl OVS_DEFINE(NAME)
 481 dnl
 482 dnl Defines NAME to 1 in kcompat.h.
 483 AC_DEFUN([OVS_DEFINE], [
 484   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 485 ])
 486
 487 dnl OVS_CHECK_LINUX_COMPAT
 488 dnl
 489 dnl Runs various Autoconf checks on the Linux kernel source in
 490 dnl the directory in $KBUILD.
 491 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 492   rm -f datapath/linux/kcompat.h.new
 493   mkdir -p datapath/linux
 494   : > datapath/linux/kcompat.h.new
 495
 496   echo '#include <linux/version.h>
 497 #ifndef RHEL_RELEASE_CODE
 498 #define RHEL_RELEASE_CODE 0
 499 #define RHEL_RELEASE_VERSION(a, b) 0
 500 #endif' >> datapath/linux/kcompat.h.new
 501
 502   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 503                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 504
 505   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 506                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 507
 508   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 509                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 510   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 511
 512   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 513   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 514   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 515
 516   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 517                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 518   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 519                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 520
 521   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 522   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 523
 524   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 525   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 526   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 527   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 528   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 529
 530   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 531   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 532   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 533                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 534   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 535                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 536
 537   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 538                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 539   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 540                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 541   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 542                         [ip_do_fragment], [net],
 543                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 544   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 545                         [ip_local_out], [net],
 546                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 547
 548   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 549
 550   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 551                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 552   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 553   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 554                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 555   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 556                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 557   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 558   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 559   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 560                         [frags_work])
 561   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 562                         [rwlock])
 563   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 564                         [list_evictor])
 565   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 566   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 567                         [sub_frag_mem_limit], [struct.netns_frags],
 568                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 569   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 570                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 571   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 572                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 573
 574   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 575   dnl OVS does not really need ipv6 label field, but its presence signifies that
 576   dnl the stack has all required ipv6 support.
 577   dnl OVS also does not need dst_cache But this dependency allows us to write
 578   dnl much cleaner code.
 579
 580   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 581                         [label],
 582                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 583                                          [iptunnel_pull_offloads],
 584                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 585                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 586                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 587
 588   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 589                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 590   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 591                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 592   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 593                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 594   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 595   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 596   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 597   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 598   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 599   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 600   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 601   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 602   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 603   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 604                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 605   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 606   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 607   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 608   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 609   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 610   dnl So check type of tstats.
 611   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 612                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 613   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 614                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 615   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 616   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 617   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 618                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 619   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 620   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 621   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 622                         [extended])
 623   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 624                         [netdev_master_upper_dev_link], [upper_priv],
 625                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 626   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 627                   [netdev_master_upper_dev_link_rh],
 628                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 629
 630   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 631                         [max_mtu])
 632   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 633                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 634
 635   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 636   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 637   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 638                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 639   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 640                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 641   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 642                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 643   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 644
 645
 646   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 647                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 648
 649   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 650                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 651                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 652   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 653                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 654
 655   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 656                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 657                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 658   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 659                   [nf_ct_get_tuplepr], [struct.net],
 660                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 661   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 662                   [nf_ct_set])
 663   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 664                   [nf_ct_is_untracked])
 665   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 666                   [nf_ct_zone_init])
 667   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 668                   [net_ns_get])
 669   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 670                   [nf_connlabels_get])
 671   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 672                   [nf_connlabels_get], [int bit],
 673                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 674   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 675                         [nf_conn_labels], [words])
 676   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 677   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 678   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 679   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 680   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 681                   [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])
 682
 683   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 684   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 685
 686   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 687   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 688   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 689                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 690   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 691
 692   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 693                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 694                                    [rcu_read_lock_held])])
 695   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 696   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 697
 698   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 699   # is necessary because some versions of this header remove the
 700   # member but retain the kerneldoc comment that describes it (which
 701   # starts with @).  The brackets must be doubled because of m4
 702   # quoting rules.
 703   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 704                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 705   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 706   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 707   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 708   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 709   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 710   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 711   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 712                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 713   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 714                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 715   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 716                   [skb_copy_from_linear_data_offset])
 717   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 718                   [skb_reset_tail_pointer])
 719   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 720   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 721                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 722   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 723   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 724   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 725   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 726   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 727   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 728   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 729   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 730                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 731   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 732   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 733                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 734   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 735                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 736   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 737   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 738   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 739   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 740   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 741   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 742   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 743   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 744   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 745
 746   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 747                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 748   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 749                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 750   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 751                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 752
 753   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 754   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 755
 756   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 757   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 758
 759   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 760   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 761   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 762   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 763                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 764   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 765   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 766                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 767   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 768                         [genl_notify], [net],
 769                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 770
 771
 772   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 773                         [genl_multicast_group], [id])
 774   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 775
 776   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 777   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 778   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 779   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 780   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 781   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 782                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 783   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 784                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 785
 786   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 787   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 788   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 789   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 790   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 791   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 792   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 793   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 794   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 795                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 796   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 797                         [nla_parse], [netlink_ext_ack],
 798                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 799
 800   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 801
 802   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 803                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 804   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 805   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 806   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 807   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 808   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 809
 810   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 811                         [metadata_dst_alloc], [metadata_type])
 812
 813   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 814
 815   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 816                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 817   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 818                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 819                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 820   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 821   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 822   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 823                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 824   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 825                         [gro_receive])
 826
 827   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 828                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 829   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 830                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 831
 832   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 833   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 834   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 835                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 836   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 837                         [udp_add_offload], [net],
 838                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 839   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 840                         [nf_defrag_ipv6_enable], [net],
 841                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 842   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 843                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 844   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 845                         [needs_free_netdev],
 846                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 847   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 848                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 849   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 850                   [nf_conntrack_helper_put],
 851                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 852   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 853                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 854   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 855                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 856   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 857                         [extack],
 858                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 859   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 860                         [list],
 861                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 862   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 863                   [IP_CT_UNTRACKED])
 864   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 865                         [netdev_master_upper_dev_link], [extack],
 866                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 867   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 868                   [__LINUX_COMPILER_TYPES_H],
 869                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 870   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 871                   [ktime_get_ts64],
 872                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 873   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 874                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 875                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 876   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 877                   [ktime_get_ns],
 878                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 879   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 880                   frag_percpu_counter_batch[],
 881                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 882   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 883                   [null_compute_pseudo],
 884                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 885   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 886                   [__skb_checksum_convert],
 887                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
 888   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 889                         [max_mtu],
 890                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
 891   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
 892                         [erspan_ver],
 893                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
 894   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 895                   [SKB_GSO_IPXIP6],
 896                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
 897   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
 898                         [ip6_make_flowlabel], [fl6],
 899                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
 900   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
 901                         [auto_flowlabels],
 902                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
 903   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 904                   [netif_keep_dst],
 905                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
 906   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 907                         [ndo_get_iflink],
 908                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
 909   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 910                   [skb_set_inner_ipproto],
 911                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
 912   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 913                   [tunnel_encap_types],
 914                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
 915   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 916                   [IFLA_IPTUN_ENCAP_TYPE],
 917                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
 918   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 919                   [IFLA_IPTUN_COLLECT_METADATA],
 920                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
 921   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 922                   [IFLA_GRE_ENCAP_DPORT])
 923   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 924                   [IFLA_GRE_COLLECT_METADATA])
 925   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 926                   [IFLA_GRE_IGNORE_DF])
 927   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 928                   [IFLA_GRE_FWMARK])
 929   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 930                   [IFLA_GRE_ERSPAN_INDEX])
 931   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 932                   [IFLA_GRE_ERSPAN_HWID])
 933   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
 934                   [IFLA_IPTUN_FWMARK])
 935   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
 936                         [csum_valid],
 937                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
 938   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 939                   [skb_checksum_simple_validate])
 940   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 941                   [void.*ndo_get_stats64],
 942                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
 943   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
 944                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
 945   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
 946                         [ip_tunnel_info_opts_set], [flags],
 947                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
 948   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 949                         [rnd],
 950                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
 951
 952   if cmp -s datapath/linux/kcompat.h.new \
 953             datapath/linux/kcompat.h >/dev/null 2>&1; then
 954     rm datapath/linux/kcompat.h.new
 955   else
 956     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 957   fi
 958 ])
 959
 960 dnl Checks for net/if_dl.h.
 961 dnl
 962 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 963 dnl or NetBSD.)
 964 AC_DEFUN([OVS_CHECK_IF_DL],
 965   [AC_CHECK_HEADER([net/if_dl.h],
 966                    [HAVE_IF_DL=yes],
 967                    [HAVE_IF_DL=no])
 968    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 969    if test "$HAVE_IF_DL" = yes; then
 970       AC_DEFINE([HAVE_IF_DL], [1],
 971                 [Define to 1 if net/if_dl.h is available.])
 972
 973       # On these platforms we use libpcap to access network devices.
 974       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 975    fi])
 976
 977 dnl Checks for buggy strtok_r.
 978 dnl
 979 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 980 dnl with optimization that can cause segfaults:
 981 dnl
 982 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 983 AC_DEFUN([OVS_CHECK_STRTOK_R],
 984   [AC_CACHE_CHECK(
 985      [whether strtok_r macro segfaults on some inputs],
 986      [ovs_cv_strtok_r_bug],
 987      [AC_RUN_IFELSE(
 988         [AC_LANG_PROGRAM([#include <stdio.h>
 989                           #include <string.h>
 990                          ],
 991                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 992                            /* Assume bug is present, because relatively minor
 993                               changes in compiler settings (e.g. optimization
 994                               level) can make it crop up. */
 995                            return 1;
 996                            #else
 997                            char string[] = ":::";
 998                            char *save_ptr = (char *) 0xc0ffee;
 999                            char *token1, *token2;
1000                            token1 = strtok_r(string, ":", &save_ptr);
1001                            token2 = strtok_r(NULL, ":", &save_ptr);
1002                            freopen ("/dev/null", "w", stdout);
1003                            printf ("%s %s\n", token1, token2);
1004                            return 0;
1005                            #endif
1006                           ]])],
1007         [ovs_cv_strtok_r_bug=no],
1008         [ovs_cv_strtok_r_bug=yes],
1009         [ovs_cv_strtok_r_bug=yes])])
1010    if test $ovs_cv_strtok_r_bug = yes; then
1011      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1012                [Define if strtok_r macro segfaults on some inputs])
1013    fi
1014 ])
1015
1016 dnl ----------------------------------------------------------------------
1017 dnl These macros are from GNU PSPP, with the following original license:
1018 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1019 dnl This file is free software; the Free Software Foundation
1020 dnl gives unlimited permission to copy and/or distribute it,
1021 dnl with or without modifications, as long as this notice is preserved.
1022
1023 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1024   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1025   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1026     [ovs_save_CFLAGS="$CFLAGS"
1027      dnl Include -Werror in the compiler options, because without -Werror
1028      dnl clang's GCC-compatible compiler driver does not return a failure
1029      dnl exit status even though it complains about options it does not
1030      dnl understand.
1031      dnl
1032      dnl Also, check stderr as gcc exits with status 0 for options
1033      dnl rejected at getopt level.
1034      dnl    % touch /tmp/a.c
1035      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1036      dnl    gcc: unrecognized option '-Qunused-arguments'
1037      dnl    0
1038      dnl    %
1039      dnl
1040      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1041      dnl it does not understand, unless it has another error to report, so
1042      dnl instead of testing for -Wno-<foo>, test for the positive version.
1043      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1044      AC_COMPILE_IFELSE(
1045        [AC_LANG_SOURCE([int x;])],
1046        [if test -s conftest.err && grep "unrecognized option" conftest.err
1047         then
1048           ovs_cv_name[]=no
1049         else
1050           ovs_cv_name[]=yes
1051         fi],
1052        [ovs_cv_name[]=no])
1053      CFLAGS="$ovs_save_CFLAGS"])
1054   if test $ovs_cv_name = yes; then
1055     m4_if([$2], [], [:], [$2])
1056   else
1057     m4_if([$3], [], [:], [$3])
1058   fi
1059 ])
1060
1061 dnl OVS_CHECK_WERROR
1062 dnl
1063 dnl Check whether the C compiler accepts -Werror.
1064 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1065 AC_DEFUN([OVS_CHECK_WERROR],
1066   [WERROR=
1067    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1068
1069 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1070 dnl Check whether the given C compiler OPTION is accepted.
1071 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1072 AC_DEFUN([OVS_CHECK_CC_OPTION],
1073   [AC_REQUIRE([OVS_CHECK_WERROR])
1074    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1075
1076 dnl OVS_ENABLE_OPTION([OPTION])
1077 dnl Check whether the given C compiler OPTION is accepted.
1078 dnl If so, add it to WARNING_FLAGS.
1079 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1080 AC_DEFUN([OVS_ENABLE_OPTION],
1081   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1082    AC_SUBST([WARNING_FLAGS])])
1083
1084 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1085 dnl Check whether the given C compiler OPTION is accepted.
1086 dnl If so, enable the given Automake CONDITIONAL.
1087
1088 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1089 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1090   [OVS_CHECK_CC_OPTION(
1091     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1092    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1093 dnl ----------------------------------------------------------------------
1094
1095 dnl Check for too-old XenServer.
1096 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1097   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1098     [if test -e /etc/redhat-release; then
1099        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1100      fi
1101      if test -z "$ovs_cv_xsversion"; then
1102        ovs_cv_xsversion=none
1103      fi])
1104   case $ovs_cv_xsversion in
1105     none)
1106       ;;
1107
1108     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1109     [[6-9]]* |                           dnl XenServer 6 or later
1110     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1111     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1112     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1113     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1114       ;;
1115
1116     *)
1117       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1118       ;;
1119   esac])
1120
1121 dnl OVS_CHECK_SPARSE_TARGET
1122 dnl
1123 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1124 dnl target for which the code is being built.  This helps it out.
1125 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1126   [AC_CACHE_CHECK(
1127     [target hint for cgcc],
1128     [ac_cv_sparse_target],
1129     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1130        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1131        [x86_64-*], [ac_cv_sparse_target=x86_64],
1132        [ac_cv_sparse_target=other])])
1133    AS_CASE([$ac_cv_sparse_target],
1134      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
1135      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
1136      [SPARSEFLAGS= CGCCFLAGS=])
1137    AC_SUBST([SPARSEFLAGS])
1138    AC_SUBST([CGCCFLAGS])])
1139
1140 dnl OVS_SPARSE_EXTRA_INCLUDES
1141 dnl
1142 dnl The cgcc script from "sparse" does not search gcc's default
1143 dnl search path. Get the default search path from GCC and pass
1144 dnl them to sparse.
1145 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1146     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1147            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1148
1149 dnl OVS_ENABLE_SPARSE
1150 AC_DEFUN([OVS_ENABLE_SPARSE],
1151   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1152    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1153    : ${SPARSE=sparse}
1154    AC_SUBST([SPARSE])
1155    AC_CONFIG_COMMANDS_PRE(
1156      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1157
1158    AC_ARG_ENABLE(
1159      [sparse],
1160      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1161      [], [enable_sparse=no])
1162    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1163
1164 dnl OVS_CTAGS_IDENTIFIERS
1165 dnl
1166 dnl ctags ignores symbols with extras identifiers. This builds a list of
1167 dnl specially handled identifiers to be ignored.
1168 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1169     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1170            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1171
1172 dnl OVS_PTHREAD_SET_NAME
1173 dnl
1174 dnl This checks for three known variants of pthreads functions for setting
1175 dnl the name of the current thread:
1176 dnl
1177 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1178 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1179 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1180 dnl
1181 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1182 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1183 dnl provide to it.
1184 dnl
1185 dnl This macro defines:
1186 dnl
1187 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1188 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1189 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1190 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1191   [AC_CHECK_FUNCS([pthread_set_name_np])
1192    if test $ac_cv_func_pthread_set_name_np != yes; then
1193      AC_CACHE_CHECK(
1194        [for pthread_setname_np() variant],
1195        [ovs_cv_pthread_setname_np],
1196        [AC_LINK_IFELSE(
1197          [AC_LANG_PROGRAM([#include <pthread.h>
1198   ], [pthread_setname_np(pthread_self(), "name");])],
1199          [ovs_cv_pthread_setname_np=glibc],
1200          [AC_LINK_IFELSE(
1201            [AC_LANG_PROGRAM([#include <pthread.h>
1202 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1203            [ovs_cv_pthread_setname_np=netbsd],
1204            [ovs_cv_pthread_setname_np=none])])])
1205      case $ovs_cv_pthread_setname_np in # (
1206        glibc)
1207           AC_DEFINE(
1208             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1209             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1210           ;; # (
1211        netbsd)
1212           AC_DEFINE(
1213             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1214             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1215           ;;
1216      esac
1217    fi])
1218
1219 dnl OVS_CHECK_LINUX_HOST.
1220 dnl
1221 dnl Checks whether we're building for a Linux host, based on the presence of
1222 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1223 dnl LINUX based on the result.
1224 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1225   [AC_CACHE_CHECK(
1226      [whether __linux__ is defined],
1227      [ovs_cv_linux],
1228      [AC_COMPILE_IFELSE(
1229         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1230         [ovs_cv_linux=true],
1231         [ovs_cv_linux=false])])
1232    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])