acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2019 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])
  27
  28    # Unless --enable-Werror is specified, report but do not fail the build
  29    # for errors reported by flake8.
  30    if test "X$enable_Werror" = Xyes; then
  31      FLAKE8_WERROR=
  32    else
  33      FLAKE8_WERROR=-
  34    fi
  35    AC_SUBST([FLAKE8_WERROR])
  36
  37    # If --enable-Werror is specified, fail the build on sparse warnings.
  38    if test "X$enable_Werror" = Xyes; then
  39      SPARSE_WERROR=-Wsparse-error
  40    else
  41      SPARSE_WERROR=
  42    fi
  43    AC_SUBST([SPARSE_WERROR])])
  44
  45 dnl OVS_CHECK_LINUX
  46 dnl
  47 dnl Configure linux kernel source tree
  48 AC_DEFUN([OVS_CHECK_LINUX], [
  49   AC_ARG_WITH([linux],
  50               [AC_HELP_STRING([--with-linux=/path/to/linux],
  51                               [Specify the Linux kernel build directory])])
  52   AC_ARG_WITH([linux-source],
  53               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  54                               [Specify the Linux kernel source directory
  55                                (usually figured out automatically from build
  56                                directory)])])
  57
  58   # Deprecated equivalents to --with-linux, --with-linux-source.
  59   AC_ARG_WITH([l26])
  60   AC_ARG_WITH([l26-source])
  61
  62   if test X"$with_linux" != X; then
  63     KBUILD=$with_linux
  64   elif test X"$with_l26" != X; then
  65     KBUILD=$with_l26
  66     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  67   else
  68     KBUILD=
  69   fi
  70
  71   if test X"$KBUILD" != X; then
  72     if test X"$with_linux_source" != X; then
  73       KSRC=$with_linux_source
  74     elif test X"$with_l26_source" != X; then
  75       KSRC=$with_l26_source
  76       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  77     else
  78       KSRC=
  79     fi
  80   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  81     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  82   fi
  83
  84   if test -n "$KBUILD"; then
  85     KBUILD=`eval echo "$KBUILD"`
  86     case $KBUILD in
  87         /*) ;;
  88         *) KBUILD=`pwd`/$KBUILD ;;
  89     esac
  90
  91     # The build directory is what the user provided.
  92     # Make sure that it exists.
  93     AC_MSG_CHECKING([for Linux build directory])
  94     if test -d "$KBUILD"; then
  95         AC_MSG_RESULT([$KBUILD])
  96         AC_SUBST(KBUILD)
  97     else
  98         AC_MSG_RESULT([no])
  99         AC_ERROR([source dir $KBUILD doesn't exist])
 100     fi
 101
 102     # Debian breaks kernel headers into "source" header and "build" headers.
 103     # We want the source headers, but $KBUILD gives us the "build" headers.
 104     # Use heuristics to find the source headers.
 105     AC_MSG_CHECKING([for Linux source directory])
 106     if test -n "$KSRC"; then
 107       KSRC=`eval echo "$KSRC"`
 108       case $KSRC in
 109           /*) ;;
 110           *) KSRC=`pwd`/$KSRC ;;
 111       esac
 112       if test ! -e $KSRC/include/linux/kernel.h; then
 113         AC_MSG_ERROR([$KSRC is not a kernel source directory])
 114       fi
 115     else
 116       KSRC=$KBUILD
 117       if test ! -e $KSRC/include/linux/kernel.h; then
 118         # Debian kernel build Makefiles tend to include a line of the form:
 119         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 120         # First try to extract the source directory from this line.
 121         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 122         if test ! -e "$KSRC"/include/linux/kernel.h; then
 123           # Didn't work.  Fall back to name-based heuristics that used to work.
 124           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 125             */build)
 126               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 127               ;; # (
 128             *)
 129               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 130               ;;
 131           esac
 132         fi
 133       fi
 134       if test ! -e "$KSRC"/include/linux/kernel.h; then
 135         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 136       fi
 137     fi
 138     AC_MSG_RESULT([$KSRC])
 139
 140     AC_MSG_CHECKING([for kernel version])
 141     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 142     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 143     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 144     if test X"$version" = X || test X"$patchlevel" = X; then
 145        AC_ERROR([cannot determine kernel version])
 146     elif test X"$sublevel" = X; then
 147        kversion=$version.$patchlevel
 148     else
 149        kversion=$version.$patchlevel.$sublevel
 150     fi
 151     AC_MSG_RESULT([$kversion])
 152
 153     if test "$version" -ge 5; then
 154        if test "$version" = 5 && test "$patchlevel" -le 5; then
 155           : # Linux 5.x
 156        else
 157           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 5.5.x is not supported (please refer to the FAQ for advice)])
 158        fi
 159     elif test "$version" = 4; then
 160        : # Linux 4.x
 161     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 162        : # Linux 3.x
 163     else
 164        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 165     fi
 166     if (test ! -e "$KBUILD"/include/linux/version.h && \
 167         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 168        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 169         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 170         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 171     fi
 172     OVS_CHECK_LINUX_COMPAT
 173   fi
 174   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 175 ])
 176
 177 dnl OVS_CHECK_LINUX_NETLINK
 178 dnl
 179 dnl Configure Linux netlink compat.
 180 AC_DEFUN([OVS_CHECK_LINUX_NETLINK], [
 181   AC_COMPILE_IFELSE([
 182     AC_LANG_PROGRAM([#include <linux/netlink.h>], [
 183         struct nla_bitfield32 x =  { 0 };
 184     ])],
 185     [AC_DEFINE([HAVE_NLA_BITFIELD32], [1],
 186     [Define to 1 if struct nla_bitfield32 is available.])])
 187 ])
 188
 189 dnl OVS_CHECK_LINUX_TC
 190 dnl
 191 dnl Configure Linux tc compat.
 192 AC_DEFUN([OVS_CHECK_LINUX_TC], [
 193   AC_COMPILE_IFELSE([
 194     AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
 195         int x = TCA_ACT_FLAGS;
 196     ])],
 197     [AC_DEFINE([HAVE_TCA_ACT_FLAGS], [1],
 198                [Define to 1 if TCA_ACT_FLAGS is available.])])
 199
 200   AC_CHECK_MEMBERS([struct tcf_t.firstuse], [], [], [#include <linux/pkt_cls.h>])
 201
 202   AC_COMPILE_IFELSE([
 203     AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
 204         int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
 205     ])],
 206     [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
 207                [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is available.])])
 208
 209   AC_COMPILE_IFELSE([
 210     AC_LANG_PROGRAM([#include <linux/tc_act/tc_mpls.h>], [
 211         int x = TCA_MPLS_TTL;
 212     ])],
 213     [AC_DEFINE([HAVE_TCA_MPLS_TTL], [1],
 214                [Define to 1 if HAVE_TCA_MPLS_TTL is available.])])
 215
 216   AC_COMPILE_IFELSE([
 217     AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
 218         int x = TCA_TUNNEL_KEY_ENC_TTL;
 219     ])],
 220     [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_TTL], [1],
 221                [Define to 1 if TCA_TUNNEL_KEY_ENC_TTL is available.])])
 222
 223   AC_COMPILE_IFELSE([
 224     AC_LANG_PROGRAM([#include <linux/tc_act/tc_pedit.h>], [
 225         int x = TCA_PEDIT_KEY_EX_HDR_TYPE_UDP;
 226     ])],
 227     [AC_DEFINE([HAVE_TCA_PEDIT_KEY_EX_HDR_TYPE_UDP], [1],
 228                [Define to 1 if TCA_PEDIT_KEY_EX_HDR_TYPE_UDP is available.])])
 229
 230   AC_COMPILE_IFELSE([
 231     AC_LANG_PROGRAM([#include <linux/tc_act/tc_skbedit.h>], [
 232         int x = TCA_SKBEDIT_FLAGS;
 233     ])],
 234     [AC_DEFINE([HAVE_TCA_SKBEDIT_FLAGS], [1],
 235                [Define to 1 if TCA_SKBEDIT_FLAGS is available.])])
 236 ])
 237
 238 dnl OVS_CHECK_LINUX_SCTP_CT
 239 dnl
 240 dnl Checks for kernels which need additional SCTP state
 241 AC_DEFUN([OVS_CHECK_LINUX_SCTP_CT], [
 242   AC_COMPILE_IFELSE([
 243     AC_LANG_PROGRAM([#include <linux/netfilter/nfnetlink.h>
 244 #include <linux/netfilter/nfnetlink_conntrack.h>
 245 #include <linux/netfilter/nf_conntrack_common.h>
 246 #include <linux/netfilter/nf_conntrack_sctp.h>], [
 247         int x = SCTP_CONNTRACK_HEARTBEAT_SENT;
 248     ])],
 249     [AC_DEFINE([HAVE_SCTP_CONNTRACK_HEARTBEATS], [1],
 250                [Define to 1 if SCTP_CONNTRACK_HEARTBEAT_SENT is available.])])
 251 ])
 252
 253 dnl OVS_FIND_DEPENDENCY(FUNCTION, SEARCH_LIBS, NAME_TO_PRINT)
 254 dnl
 255 dnl Check for a function in a library list.
 256 AC_DEFUN([OVS_FIND_DEPENDENCY], [
 257   AC_SEARCH_LIBS([$1], [$2], [], [
 258     AC_MSG_ERROR([unable to find $3, install the dependency package])
 259   ])
 260 ])
 261
 262 dnl OVS_CHECK_LINUX_AF_XDP
 263 dnl
 264 dnl Check both Linux kernel AF_XDP and libbpf support
 265 AC_DEFUN([OVS_CHECK_LINUX_AF_XDP], [
 266   AC_ARG_ENABLE([afxdp],
 267                 [AC_HELP_STRING([--enable-afxdp], [Enable AF-XDP support])],
 268                 [], [enable_afxdp=no])
 269   AC_MSG_CHECKING([whether AF_XDP is enabled])
 270   if test "$enable_afxdp" != yes; then
 271     AC_MSG_RESULT([no])
 272     AF_XDP_ENABLE=false
 273   else
 274     AC_MSG_RESULT([yes])
 275     AF_XDP_ENABLE=true
 276
 277     AC_CHECK_HEADER([bpf/libbpf.h], [],
 278       [AC_MSG_ERROR([unable to find bpf/libbpf.h for AF_XDP support])])
 279
 280     AC_CHECK_HEADER([linux/if_xdp.h], [],
 281       [AC_MSG_ERROR([unable to find linux/if_xdp.h for AF_XDP support])])
 282
 283     AC_CHECK_HEADER([bpf/xsk.h], [],
 284       [AC_MSG_ERROR([unable to find bpf/xsk.h for AF_XDP support])])
 285
 286     AC_CHECK_FUNCS([pthread_spin_lock], [],
 287       [AC_MSG_ERROR([unable to find pthread_spin_lock for AF_XDP support])])
 288
 289     OVS_FIND_DEPENDENCY([numa_alloc_onnode], [numa], [libnuma])
 290
 291     AC_DEFINE([HAVE_AF_XDP], [1],
 292               [Define to 1 if AF_XDP support is available and enabled.])
 293     LIBBPF_LDADD=" -lbpf -lelf"
 294     AC_SUBST([LIBBPF_LDADD])
 295
 296     AC_CHECK_DECL([xsk_ring_prod__needs_wakeup], [
 297       AC_DEFINE([HAVE_XDP_NEED_WAKEUP], [1],
 298         [XDP need wakeup support detected in xsk.h.])
 299     ], [], [[#include <bpf/xsk.h>]])
 300   fi
 301   AM_CONDITIONAL([HAVE_AF_XDP], test "$AF_XDP_ENABLE" = true)
 302 ])
 303
 304 dnl OVS_CHECK_DPDK
 305 dnl
 306 dnl Configure DPDK source tree
 307 AC_DEFUN([OVS_CHECK_DPDK], [
 308   AC_ARG_WITH([dpdk],
 309               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 310                               [Specify the DPDK build directory])],
 311               [have_dpdk=true])
 312
 313   AC_MSG_CHECKING([whether dpdk is enabled])
 314   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 315     AC_MSG_RESULT([no])
 316     DPDKLIB_FOUND=false
 317   else
 318     AC_MSG_RESULT([yes])
 319     case "$with_dpdk" in
 320       yes)
 321         DPDK_AUTO_DISCOVER="true"
 322         PKG_CHECK_MODULES_STATIC([DPDK], [libdpdk], [
 323             DPDK_INCLUDE="$DPDK_CFLAGS"
 324             DPDK_LIB="$DPDK_LIBS"], [
 325             DPDK_INCLUDE="-I/usr/local/include/dpdk -I/usr/include/dpdk"
 326             DPDK_LIB="-ldpdk"])
 327         ;;
 328       *)
 329         DPDK_AUTO_DISCOVER="false"
 330         DPDK_INCLUDE_PATH="$with_dpdk/include"
 331         # If 'with_dpdk' is passed install directory, point to headers
 332         # installed in $DESTDIR/$prefix/include/dpdk
 333         if test -e "$DPDK_INCLUDE_PATH/rte_config.h"; then
 334            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH"
 335         elif test -e "$DPDK_INCLUDE_PATH/dpdk/rte_config.h"; then
 336            DPDK_INCLUDE="-I$DPDK_INCLUDE_PATH/dpdk"
 337         fi
 338         DPDK_LIB_DIR="$with_dpdk/lib"
 339         DPDK_LIB="-ldpdk"
 340         ;;
 341     esac
 342
 343     ovs_save_CFLAGS="$CFLAGS"
 344     ovs_save_LDFLAGS="$LDFLAGS"
 345     CFLAGS="$CFLAGS $DPDK_INCLUDE"
 346     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 347       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 348     fi
 349
 350     AC_CHECK_HEADERS([rte_config.h], [], [
 351       AC_MSG_ERROR([unable to find rte_config.h in $with_dpdk])
 352     ], [AC_INCLUDES_DEFAULT])
 353
 354     AC_CHECK_DECLS([RTE_LIBRTE_VHOST_NUMA, RTE_EAL_NUMA_AWARE_HUGEPAGES], [
 355       OVS_FIND_DEPENDENCY([get_mempolicy], [numa], [libnuma])
 356     ], [], [[#include <rte_config.h>]])
 357
 358     AC_CHECK_DECL([RTE_LIBRTE_PMD_PCAP], [
 359       OVS_FIND_DEPENDENCY([pcap_dump_close], [pcap], [libpcap])
 360     ], [], [[#include <rte_config.h>]])
 361
 362     AC_CHECK_DECL([RTE_LIBRTE_VHOST_NUMA], [
 363       AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])
 364     ], [], [[#include <rte_config.h>]])
 365
 366     AC_CHECK_DECL([RTE_LIBRTE_MLX5_PMD], [dnl found
 367       OVS_FIND_DEPENDENCY([mnl_attr_put], [mnl], [libmnl])
 368       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 369         OVS_FIND_DEPENDENCY([mlx5dv_create_wq], [mlx5], [libmlx5])
 370         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 371       ], [[#include <rte_config.h>]])
 372     ], [], [[#include <rte_config.h>]])
 373
 374     AC_CHECK_DECL([RTE_LIBRTE_MLX4_PMD], [dnl found
 375       AC_CHECK_DECL([RTE_IBVERBS_LINK_DLOPEN], [], [dnl not found
 376         OVS_FIND_DEPENDENCY([mlx4dv_init_obj], [mlx4], [libmlx4])
 377         OVS_FIND_DEPENDENCY([verbs_init_cq], [ibverbs], [libibverbs])
 378       ], [[#include <rte_config.h>]])
 379     ], [], [[#include <rte_config.h>]])
 380
 381     # DPDK uses dlopen to load plugins.
 382     OVS_FIND_DEPENDENCY([dlopen], [dl], [libdl])
 383
 384     AC_MSG_CHECKING([whether linking with dpdk works])
 385     LIBS="$DPDK_LIB $LIBS"
 386     AC_LINK_IFELSE(
 387       [AC_LANG_PROGRAM([#include <rte_config.h>
 388                         #include <rte_eal.h>],
 389                        [int rte_argc; char ** rte_argv;
 390                         rte_eal_init(rte_argc, rte_argv);])],
 391       [AC_MSG_RESULT([yes])
 392        DPDKLIB_FOUND=true],
 393       [AC_MSG_RESULT([no])
 394        if test "$DPDK_AUTO_DISCOVER" = "true"; then
 395          AC_MSG_ERROR(m4_normalize([
 396             Could not find DPDK library in default search path, Use --with-dpdk
 397             to specify the DPDK library installed in non-standard location]))
 398        else
 399          AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 400        fi
 401       ])
 402
 403     CFLAGS="$ovs_save_CFLAGS"
 404     LDFLAGS="$ovs_save_LDFLAGS"
 405     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 406       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 407     fi
 408     OVS_CFLAGS="$OVS_CFLAGS $DPDK_INCLUDE"
 409     OVS_ENABLE_OPTION([-mssse3])
 410
 411     # DPDK pmd drivers are not linked unless --whole-archive is used.
 412     #
 413     # This happens because the rest of the DPDK code doesn't use any symbol in
 414     # the pmd driver objects, and the drivers register themselves using an
 415     # __attribute__((constructor)) function.
 416     #
 417     # These options are specified inside a single -Wl directive to prevent
 418     # autotools from reordering them.
 419     #
 420     # OTOH newer versions of dpdk pkg-config (generated with Meson)
 421     # will already have flagged just the right set of libs with
 422     # --whole-archive - in those cases do not wrap it once more.
 423     case "$DPDK_LIB" in
 424       *whole-archive*) DPDK_vswitchd_LDFLAGS=$DPDK_LIB;;
 425       *) DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 426     esac
 427     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 428     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 429   fi
 430
 431   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 432 ])
 433
 434 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 435 dnl
 436 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 437 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 438 dnl <REGEX> translated to uppercase.
 439 AC_DEFUN([OVS_GREP_IFELSE], [
 440   AC_MSG_CHECKING([whether $2 matches in $1])
 441   if test -f $1; then
 442     grep '$2' $1 >/dev/null 2>&1
 443     status=$?
 444     case $status in
 445       0)
 446         AC_MSG_RESULT([yes])
 447         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 448         ;;
 449       1)
 450         AC_MSG_RESULT([no])
 451         $4
 452         ;;
 453       *)
 454         AC_MSG_ERROR([grep exited with status $status])
 455         ;;
 456     esac
 457   else
 458     AC_MSG_RESULT([file not found])
 459     $4
 460   fi
 461 ])
 462
 463 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 464 dnl
 465 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 466 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 467 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 468 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 469 dnl translated to uppercase.
 470 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 471   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 472   if test -f $1; then
 473     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 474     status=$?
 475     case $status in
 476       0)
 477         AC_MSG_RESULT([yes])
 478         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 479         ;;
 480       1)
 481         AC_MSG_RESULT([no])
 482         $5
 483         ;;
 484       *)
 485         AC_MSG_ERROR([grep exited with status $status])
 486         ;;
 487     esac
 488   else
 489     AC_MSG_RESULT([file not found])
 490     $5
 491   fi
 492 ])
 493
 494 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 495 dnl
 496 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 497 dnl the function signature starting from the line matching FUNCTION
 498 dnl and ending with the line containing the closing parenthesis.  If
 499 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 500 dnl IF-MATCH is empty then it defines to
 501 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 502 dnl <REGEX> translated to uppercase.
 503 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 504   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 505   if test -f $1; then
 506     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 507     status=$?
 508     case $status in
 509       0)
 510         AC_MSG_RESULT([yes])
 511         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 512         ;;
 513       1)
 514         AC_MSG_RESULT([no])
 515         $5
 516         ;;
 517       *)
 518         AC_MSG_ERROR([grep exited with status $status])
 519         ;;
 520     esac
 521   else
 522     AC_MSG_RESULT([file not found])
 523     $5
 524   fi
 525 ])
 526
 527 dnl OVS_FIND_OP_PARAM_IFELSE(FILE, OP, REGEX, [IF-MATCH], [IF-NO-MATCH])
 528 dnl
 529 dnl Looks for OP in FILE. If it is found, greps for REGEX within the
 530 dnl OP definition. If this is successful, runs IF-MATCH, otherwise
 531 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 532 dnl OVS_DEFINE(HAVE_<OP>_WITH_<REGEX>), with <OP> and <REGEX>
 533 dnl translated to uppercase.
 534 AC_DEFUN([OVS_FIND_OP_PARAM_IFELSE], [
 535   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 536   if test -f $1; then
 537     awk '/$2[[ \t\n]]*\)\(/,/;/' $1 2>/dev/null | grep '$3' >/dev/null
 538     status=$?
 539     case $status in
 540       0)
 541         AC_MSG_RESULT([yes])
 542         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 543         ;;
 544       1)
 545         AC_MSG_RESULT([no])
 546         $5
 547         ;;
 548       *)
 549         AC_MSG_ERROR([grep exited with status $status])
 550         ;;
 551     esac
 552   else
 553     AC_MSG_RESULT([file not found])
 554     $5
 555   fi
 556 ])
 557
 558 dnl OVS_DEFINE(NAME)
 559 dnl
 560 dnl Defines NAME to 1 in kcompat.h.
 561 AC_DEFUN([OVS_DEFINE], [
 562   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 563 ])
 564
 565 dnl OVS_CHECK_LINUX_COMPAT
 566 dnl
 567 dnl Runs various Autoconf checks on the Linux kernel source in
 568 dnl the directory in $KBUILD.
 569 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 570   rm -f datapath/linux/kcompat.h.new
 571   mkdir -p datapath/linux
 572   : > datapath/linux/kcompat.h.new
 573
 574   echo '#include <linux/version.h>
 575 #ifndef RHEL_RELEASE_CODE
 576 #define RHEL_RELEASE_CODE 0
 577 #define RHEL_RELEASE_VERSION(a, b) 0
 578 #endif' >> datapath/linux/kcompat.h.new
 579
 580   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 581                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 582
 583   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6_get_cookie],
 584                   [OVS_DEFINE([HAVE_RT6_GET_COOKIE])])
 585
 586   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 587                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 588   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 589
 590   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 591   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 592   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 593
 594   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [static_branch_unlikely(],
 595                   [OVS_DEFINE([HAVE_UPSTREAM_STATIC_KEY])])
 596   OVS_GREP_IFELSE([$KSRC/include/linux/jump_label.h], [DEFINE_STATIC_KEY_FALSE],
 597                   [OVS_DEFINE([HAVE_DEFINE_STATIC_KEY])])
 598
 599   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 600   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 601
 602   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 603   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 604   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 605   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 606   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 607   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_hwaccel_clear_tag])
 608
 609   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 610   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 611   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 612                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 613   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 614                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 615
 616   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 617                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 618   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 619                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 620   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 621                         [ip_do_fragment], [net],
 622                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 623   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 624                         [ip_local_out], [net],
 625                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 626
 627   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 628
 629   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 630                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 631   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 632   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 633                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 634   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 635                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 636   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 637   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
 638   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 639                         [frags_work])
 640   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 641                         [rwlock])
 642   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 643                         [list_evictor])
 644   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
 645   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
 646                         [sub_frag_mem_limit], [struct.netns_frags],
 647                         [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
 648   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
 649                   [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
 650   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 651                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 652
 653   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 654   dnl OVS does not really need ipv6 label field, but its presence signifies that
 655   dnl the stack has all required ipv6 support.
 656   dnl OVS also does not need dst_cache But this dependency allows us to write
 657   dnl much cleaner code.
 658
 659   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 660                         [label],
 661                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 662                                          [iptunnel_pull_offloads],
 663                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 664                         [OVS_GREP_IFELSE([$KSRC/include/net/erspan.h], [erspan_md2],
 665                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])])
 666
 667   OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 668                   [OVS_DEFINE([USE_BUILTIN_DST_CACHE])])
 669   OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
 670                   [OVS_DEFINE([MPLS_HEADER_IS_L3])])
 671   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 672                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 673   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 674   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 675   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 676   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 677   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 678   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 679   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_gso_error_unwind])
 680   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 681   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 682   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
 683                   [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
 684   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 685   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 686   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_udp_tunnel_add])
 687   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 688   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 689   dnl So check type of tstats.
 690   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 691                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 692   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 693                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 694   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [skb_csum_hwoffload_help])
 695   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 696   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 697                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 698   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 699   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 700   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
 701                         [extended])
 702   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 703                         [netdev_master_upper_dev_link], [upper_priv],
 704                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 705   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
 706                   [netdev_master_upper_dev_link_rh],
 707                   [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_RH])])
 708
 709   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 710                         [max_mtu])
 711   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops_extended],
 712                         [ndo_change_mtu], [OVS_DEFINE([HAVE_RHEL7_MAX_MTU])])
 713   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 714                         [dev_change_flags], [extack],
 715                         [OVS_DEFINE([HAVE_DEV_CHANGE_FLAGS_TAKES_EXTACK])])
 716
 717   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 718   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state],
 719                         [struct net ], [OVS_DEFINE([HAVE_NF_HOOK_STATE_NET])])
 720   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 721   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 722                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 723   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 724                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 725   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 726                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 727   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [NFPROTO_INET])
 728   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [CONFIG_NF_NAT_NEEDED])
 729
 730
 731   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 732                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 733
 734   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 735                         [nf_conn], [struct timer_list[[ \t]]*timeout],
 736                         [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
 737   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 738                   [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
 739
 740   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 741                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 742                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 743   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 744                   [nf_ct_get_tuplepr], [struct.net],
 745                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 746   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 747                   [nf_ct_set])
 748   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 749                   [nf_ct_is_untracked])
 750   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 751                   [nf_ct_invert_tuplepr])
 752   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 753                   [nf_ct_zone_init])
 754   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
 755                   [net_ns_get])
 756   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 757                   [nf_connlabels_get])
 758   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 759                   [nf_connlabels_get], [int bit],
 760                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 761   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 762                         [nf_conn_labels], [words])
 763   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 764   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 765   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_range2])
 766   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_packet],
 767                   [OVS_DEFINE([HAVE_UPSTREAM_NF_NAT])])
 768   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 769   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h], [nf_conncount_gc_list],
 770                   [OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_count.h],
 771                                    [int nf_conncount_add],
 772                                    [], [OVS_DEFINE([HAVE_UPSTREAM_NF_CONNCOUNT])])])
 773   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [nf_ct_set_timeout])
 774   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h], [struct nf_ct_timeout],
 775                   [OVS_DEFINE([HAVE_NF_CT_TIMEOUT])])
 776   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_timeout.h],
 777                         [\(*nf_ct_timeout_find_get_hook\)], [net],
 778                         [OVS_DEFINE([HAVE_NF_CT_TIMEOUT_FIND_GET_HOOK_NET])])
 779
 780   OVS_GREP_IFELSE([$KSRC/include/linux/random.h],
 781                   [prandom_u32[[\(]]],
 782                   [OVS_DEFINE([HAVE_PRANDOM_U32])])
 783   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 784
 785   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 786   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 787   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 788                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 789   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 790
 791   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 792                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 793                                    [rcu_read_lock_held])])
 794   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 795   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [net_rwsem])
 796   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
 797                         [rtnl_create_link], [extack],
 798                         [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_TAKES_EXTACK])])
 799   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [nf_reset_ct])
 800
 801   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 802   # is necessary because some versions of this header remove the
 803   # member but retain the kerneldoc comment that describes it (which
 804   # starts with @).  The brackets must be doubled because of m4
 805   # quoting rules.
 806   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 807                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 808   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 809   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 810   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 811   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 812   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 813   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 814   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 815                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 816   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 817                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 818   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 819                   [skb_copy_from_linear_data_offset])
 820   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 821                   [skb_reset_tail_pointer])
 822   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 823   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 824                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 825   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 826   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 827   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 828   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 829   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 830   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 831   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 832   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 833                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 834   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 835   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 836                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 837   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 838                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 839   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 840   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 841   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
 842   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 843   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 844   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 845   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
 846   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
 847   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_put_zero])
 848
 849   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 850                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 851   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 852                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 853
 854   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 855   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 856
 857   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 858   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 859
 860   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 861   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 862   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 863   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 864                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 865   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 866   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 867                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 868   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_validate_flags])
 869   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 870                         [genl_notify], [net],
 871                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 872
 873
 874   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 875                         [genl_multicast_group], [id])
 876   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 877
 878   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 879   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 880   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 881   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 882   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 883   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 884                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 885   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 886                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 887
 888   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 889   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 890   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 891   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 892   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 893   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 894   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 895   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 896   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_nest_start_noflag])
 897   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 898                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 899   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
 900                         [nla_parse], [netlink_ext_ack],
 901                         [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
 902
 903   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 904
 905   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 906   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 907   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 908   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
 909   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
 910
 911   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/dst_metadata.h],
 912                         [metadata_dst_alloc], [metadata_type])
 913
 914   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 915
 916   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 917                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 918   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 919                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 920                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 921   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 922   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 923   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 924                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 925   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 926                         [gro_receive])
 927
 928   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 929                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 930   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 931                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 932
 933   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 934   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 935   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 936                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 937   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
 938                         [udp_add_offload], [net],
 939                         [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
 940   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 941                         [nf_defrag_ipv6_enable], [net],
 942                         [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
 943   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
 944                         [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
 945   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 946                         [needs_free_netdev],
 947                         [OVS_DEFINE([HAVE_NEEDS_FREE_NETDEV])])
 948   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_dev], [cfg],
 949                         [OVS_DEFINE([HAVE_VXLAN_DEV_CFG])])
 950   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 951                   [nf_conntrack_helper_put],
 952                   [OVS_DEFINE(HAVE_NF_CONNTRACK_HELPER_PUT)])
 953   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 954                   [nf_nat_helper_try_module_get])
 955   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
 956                   [nf_nat_helper_put])
 957   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],[[[[:space:]]]SKB_GSO_UDP[[[:space:]]]],
 958                   [OVS_DEFINE([HAVE_SKB_GSO_UDP])])
 959   OVS_GREP_IFELSE([$KSRC/include/net/dst.h],[DST_NOCACHE],
 960                   [OVS_DEFINE([HAVE_DST_NOCACHE])])
 961   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_link_ops],
 962                         [extack],
 963                   [OVS_DEFINE([HAVE_EXT_ACK_IN_RTNL_LINKOPS])])
 964   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 965                         [list],
 966                         [OVS_DEFINE([HAVE_LIST_IN_NF_HOOK_OPS])])
 967   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netfilter/nf_conntrack_common.h],
 968                   [IP_CT_UNTRACKED])
 969   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 970                         [netdev_master_upper_dev_link], [extack],
 971                         [OVS_DEFINE([HAVE_UPPER_DEV_LINK_EXTACK])])
 972   OVS_GREP_IFELSE([$KSRC/include/linux/compiler_types.h],
 973                   [__LINUX_COMPILER_TYPES_H],
 974                   [OVS_DEFINE([HAVE_LINUX_COMPILER_TYPES_H])])
 975   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 976                   [ktime_get_ts64],
 977                   [OVS_DEFINE([HAVE_KTIME_GET_TS64])])
 978   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h],
 979                   [EXPORT_SYMBOL_GPL(peernet2id_alloc)],
 980                   [OVS_DEFINE([HAVE_PEERNET2ID_ALLOC])])
 981   OVS_GREP_IFELSE([$KSRC/include/linux/timekeeping.h],
 982                   [ktime_get_ns],
 983                   [OVS_DEFINE([HAVE_KTIME_GET_NS])])
 984   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h],
 985                   frag_percpu_counter_batch[],
 986                   [OVS_DEFINE([HAVE_FRAG_PERCPU_COUNTER_BATCH])])
 987   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 988                   [null_compute_pseudo],
 989                   [OVS_DEFINE([HAVE_NULL_COMPUTE_PSEUDO])])
 990   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 991                   [__skb_checksum_convert],
 992                   [OVS_DEFINE([HAVE_SKB_CHECKSUM_CONVERT])])
 993   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
 994                         [max_mtu],
 995                         [OVS_DEFINE([HAVE_NET_DEVICE_MAX_MTU])])
 996   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip6_tunnel.h], [__ip6_tnl_parm],
 997                         [erspan_ver],
 998                         [OVS_DEFINE([HAVE_IP6_TNL_PARM_ERSPAN_VER])])
 999   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1000                   [SKB_GSO_IPXIP6],
1001                   [OVS_DEFINE([HAVE_SKB_GSO_IPXIP6])])
1002   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ipv6.h],
1003                         [ip6_make_flowlabel], [fl6],
1004                         [OVS_DEFINE([HAVE_IP6_MAKE_FLOWLABEL_FL6])])
1005   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ipv6.h], [netns_sysctl_ipv6],
1006                         [auto_flowlabels],
1007                         [OVS_DEFINE([HAVE_NETNS_SYSCTL_IPV6_AUTO_FLOWLABELS])])
1008   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
1009                   [netif_keep_dst],
1010                   [OVS_DEFINE([HAVE_NETIF_KEEP_DST])])
1011   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
1012                         [ndo_get_iflink],
1013                         [OVS_DEFINE([HAVE_NDO_GET_IFLINK])])
1014   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1015                   [skb_set_inner_ipproto],
1016                   [OVS_DEFINE([HAVE_SKB_SET_INNER_IPPROTO])])
1017   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1018                   [tunnel_encap_types],
1019                   [OVS_DEFINE([HAVE_TUNNEL_ENCAP_TYPES])])
1020   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1021                   [IFLA_IPTUN_ENCAP_TYPE],
1022                   [OVS_DEFINE([HAVE_IFLA_IPTUN_ENCAP_TYPE])])
1023   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1024                   [IFLA_IPTUN_COLLECT_METADATA],
1025                   [OVS_DEFINE([HAVE_IFLA_IPTUN_COLLECT_METADATA])])
1026   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1027                   [IFLA_GRE_ENCAP_DPORT])
1028   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1029                   [IFLA_GRE_COLLECT_METADATA])
1030   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1031                   [IFLA_GRE_IGNORE_DF])
1032   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1033                   [IFLA_GRE_FWMARK])
1034   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1035                   [IFLA_GRE_ERSPAN_INDEX])
1036   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1037                   [IFLA_GRE_ERSPAN_HWID])
1038   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_tunnel.h],
1039                   [IFLA_IPTUN_FWMARK])
1040   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1041                         [csum_valid],
1042                         [OVS_DEFINE([HAVE_SKBUFF_CSUM_VALID])])
1043   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/skbuff.h], [sk_buff],
1044                         [vlan_present],
1045                         [OVS_DEFINE([HAVE_SKBUFF_VLAN_PRESENT])])
1046   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
1047                   [skb_checksum_simple_validate])
1048   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h],
1049                   [void.*ndo_get_stats64],
1050                   [OVS_DEFINE([HAVE_VOID_NDO_GET_STATS64])])
1051   OVS_GREP_IFELSE([$KSRC/include/linux/timer.h], [init_timer_deferrable],
1052                   [OVS_DEFINE([HAVE_INIT_TIMER_DEFERRABLE])])
1053   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip_tunnels.h],
1054                         [ip_tunnel_info_opts_set], [flags],
1055                         [OVS_DEFINE([HAVE_IP_TUNNEL_INFO_OPTS_SET_FLAGS])])
1056   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
1057                         [rnd],
1058                         [OVS_DEFINE([HAVE_INET_FRAGS_RND])])
1059   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [__LINUX_OVERFLOW_H],
1060                   [OVS_DEFINE([HAVE_OVERFLOW_H])])
1061   OVS_GREP_IFELSE([$KSRC/include/linux/overflow.h], [struct_size],
1062                   [OVS_DEFINE([HAVE_STRUCT_SIZE])])
1063   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_array],
1064                   [OVS_DEFINE([HAVE_KVMALLOC_ARRAY])])
1065   OVS_GREP_IFELSE([$KSRC/include/linux/mm.h], [kvmalloc_node],
1066                   [OVS_DEFINE([HAVE_KVMALLOC_NODE])])
1067   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_l3proto.h],
1068                   [nf_conntrack_l3proto],
1069                   [OVS_DEFINE([HAVE_NF_CONNTRACK_L3PROATO_H])])
1070   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_core.h],
1071                         [nf_conntrack_in], [nf_hook_state],
1072                         [OVS_DEFINE([HAVE_NF_CONNTRACK_IN_TAKES_NF_HOOK_STATE])])
1073   OVS_GREP_IFELSE([$KSRC/include/net/ipv6_frag.h], [IP6_DEFRAG_CONNTRACK_IN],
1074                   [OVS_DEFINE([HAVE_IPV6_FRAG_H])])
1075   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
1076                         [nf_ct_helper_ext_add], [nf_conntrack_helper],
1077                         [OVS_DEFINE([HAVE_NF_CT_HELPER_EXT_ADD_TAKES_HELPER])])
1078   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_calc_hlen],
1079                   [OVS_DEFINE([HAVE_GRE_CALC_HLEN])])
1080   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [ip_gre_calc_hlen],
1081                   [OVS_DEFINE([HAVE_IP_GRE_CALC_HLEN])])
1082   OVS_GREP_IFELSE([$KSRC/include/linux/rbtree.h], [rb_link_node_rcu],
1083                   [OVS_DEFINE([HAVE_RBTREE_RB_LINK_NODE_RCU])])
1084   OVS_GREP_IFELSE([$KSRC/include/net/dst_ops.h], [bool confirm_neigh],
1085                   [OVS_DEFINE([HAVE_DST_OPS_CONFIRM_NEIGH])])
1086   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [fqdir],
1087                   [OVS_DEFINE([HAVE_INET_FRAG_FQDIR])])
1088   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h], [genl_ops],
1089                         [policy],
1090                         [OVS_DEFINE([HAVE_GENL_OPS_POLICY])])
1091   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h],
1092                   [nla_parse_deprecated_strict],
1093                   [OVS_DEFINE([HAVE_NLA_PARSE_DEPRECATED_STRICT])])
1094   OVS_FIND_OP_PARAM_IFELSE([$KSRC/include/net/rtnetlink.h],
1095                            [validate], [extack],
1096                            [OVS_DEFINE([HAVE_RTNLOP_VALIDATE_WITH_EXTACK])])
1097
1098   if cmp -s datapath/linux/kcompat.h.new \
1099             datapath/linux/kcompat.h >/dev/null 2>&1; then
1100     rm datapath/linux/kcompat.h.new
1101   else
1102     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
1103   fi
1104 ])
1105
1106 dnl Checks for net/if_dl.h.
1107 dnl
1108 dnl (We use this as a proxy for checking whether we're building on FreeBSD
1109 dnl or NetBSD.)
1110 AC_DEFUN([OVS_CHECK_IF_DL],
1111   [AC_CHECK_HEADER([net/if_dl.h],
1112                    [HAVE_IF_DL=yes],
1113                    [HAVE_IF_DL=no])
1114    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
1115    if test "$HAVE_IF_DL" = yes; then
1116       AC_DEFINE([HAVE_IF_DL], [1],
1117                 [Define to 1 if net/if_dl.h is available.])
1118
1119       # On these platforms we use libpcap to access network devices.
1120       AC_SEARCH_LIBS([pcap_open_live], [pcap])
1121    fi])
1122
1123 dnl Checks for buggy strtok_r.
1124 dnl
1125 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
1126 dnl with optimization that can cause segfaults:
1127 dnl
1128 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
1129 AC_DEFUN([OVS_CHECK_STRTOK_R],
1130   [AC_CACHE_CHECK(
1131      [whether strtok_r macro segfaults on some inputs],
1132      [ovs_cv_strtok_r_bug],
1133      [AC_RUN_IFELSE(
1134         [AC_LANG_PROGRAM([#include <stdio.h>
1135                           #include <string.h>
1136                          ],
1137                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
1138                            /* Assume bug is present, because relatively minor
1139                               changes in compiler settings (e.g. optimization
1140                               level) can make it crop up. */
1141                            return 1;
1142                            #else
1143                            char string[] = ":::";
1144                            char *save_ptr = (char *) 0xc0ffee;
1145                            char *token1, *token2;
1146                            token1 = strtok_r(string, ":", &save_ptr);
1147                            token2 = strtok_r(NULL, ":", &save_ptr);
1148                            freopen ("/dev/null", "w", stdout);
1149                            printf ("%s %s\n", token1, token2);
1150                            return 0;
1151                            #endif
1152                           ]])],
1153         [ovs_cv_strtok_r_bug=no],
1154         [ovs_cv_strtok_r_bug=yes],
1155         [ovs_cv_strtok_r_bug=yes])])
1156    if test $ovs_cv_strtok_r_bug = yes; then
1157      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
1158                [Define if strtok_r macro segfaults on some inputs])
1159    fi
1160 ])
1161
1162 dnl ----------------------------------------------------------------------
1163 dnl These macros are from GNU PSPP, with the following original license:
1164 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
1165 dnl This file is free software; the Free Software Foundation
1166 dnl gives unlimited permission to copy and/or distribute it,
1167 dnl with or without modifications, as long as this notice is preserved.
1168
1169 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
1170   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
1171   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
1172     [ovs_save_CFLAGS="$CFLAGS"
1173      dnl Include -Werror in the compiler options, because without -Werror
1174      dnl clang's GCC-compatible compiler driver does not return a failure
1175      dnl exit status even though it complains about options it does not
1176      dnl understand.
1177      dnl
1178      dnl Also, check stderr as gcc exits with status 0 for options
1179      dnl rejected at getopt level.
1180      dnl    % touch /tmp/a.c
1181      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
1182      dnl    gcc: unrecognized option '-Qunused-arguments'
1183      dnl    0
1184      dnl    %
1185      dnl
1186      dnl In addition, GCC does not complain about a -Wno-<foo> option that
1187      dnl it does not understand, unless it has another error to report, so
1188      dnl instead of testing for -Wno-<foo>, test for the positive version.
1189      CFLAGS="$CFLAGS $WERROR m4_bpatsubst([$1], [-Wno-], [-W])"
1190      AC_COMPILE_IFELSE(
1191        [AC_LANG_SOURCE([int x;])],
1192        [if test -s conftest.err && grep "unrecognized option" conftest.err
1193         then
1194           ovs_cv_name[]=no
1195         else
1196           ovs_cv_name[]=yes
1197         fi],
1198        [ovs_cv_name[]=no])
1199      CFLAGS="$ovs_save_CFLAGS"])
1200   if test $ovs_cv_name = yes; then
1201     m4_if([$2], [], [:], [$2])
1202   else
1203     m4_if([$3], [], [:], [$3])
1204   fi
1205 ])
1206
1207 dnl OVS_CHECK_WERROR
1208 dnl
1209 dnl Check whether the C compiler accepts -Werror.
1210 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
1211 AC_DEFUN([OVS_CHECK_WERROR],
1212   [WERROR=
1213    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
1214
1215 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
1216 dnl Check whether the given C compiler OPTION is accepted.
1217 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
1218 AC_DEFUN([OVS_CHECK_CC_OPTION],
1219   [AC_REQUIRE([OVS_CHECK_WERROR])
1220    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
1221
1222 dnl OVS_ENABLE_OPTION([OPTION])
1223 dnl Check whether the given C compiler OPTION is accepted.
1224 dnl If so, add it to WARNING_FLAGS.
1225 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
1226 AC_DEFUN([OVS_ENABLE_OPTION],
1227   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
1228    AC_SUBST([WARNING_FLAGS])])
1229
1230 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
1231 dnl Check whether the given C compiler OPTION is accepted.
1232 dnl If so, enable the given Automake CONDITIONAL.
1233
1234 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
1235 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
1236   [OVS_CHECK_CC_OPTION(
1237     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
1238    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
1239 dnl ----------------------------------------------------------------------
1240
1241 dnl Check for too-old XenServer.
1242 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
1243   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
1244     [if test -e /etc/redhat-release; then
1245        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
1246      fi
1247      if test -z "$ovs_cv_xsversion"; then
1248        ovs_cv_xsversion=none
1249      fi])
1250   case $ovs_cv_xsversion in
1251     none)
1252       ;;
1253
1254     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
1255     [[6-9]]* |                           dnl XenServer 6 or later
1256     5.[[7-9]]* |                         dnl XenServer 5.7 or later
1257     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
1258     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
1259     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
1260       ;;
1261
1262     *)
1263       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
1264       ;;
1265   esac])
1266
1267 dnl OVS_CHECK_SPARSE_TARGET
1268 dnl
1269 dnl The "cgcc" script from "sparse" isn't very good at detecting the
1270 dnl target for which the code is being built.  This helps it out.
1271 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
1272   [AC_CACHE_CHECK(
1273     [target hint for cgcc],
1274     [ac_cv_sparse_target],
1275     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
1276        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
1277        [x86_64-*], [ac_cv_sparse_target=x86_64],
1278        [ac_cv_sparse_target=other])])
1279    AS_CASE([$ac_cv_sparse_target],
1280      [x86], [SPARSEFLAGS= CGCCFLAGS="-target=i86 -target=host_os_specs"],
1281      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS="-target=x86_64 -target=host_os_specs"],
1282      [SPARSEFLAGS= CGCCFLAGS=])
1283
1284    dnl Get the default defines for vector instructions from compiler to
1285    dnl allow "sparse" correctly check the same code that will be built.
1286    dnl Required for checking DPDK headers.
1287    AC_MSG_CHECKING([vector options for cgcc])
1288    VECTOR=$($CC -dM -E - < /dev/null | grep -E "MMX|SSE|AVX" | \
1289             cut -c 9- | sed 's/ /=/' | sed 's/^/-D/' | tr '\n' ' ')
1290    AC_MSG_RESULT([$VECTOR])
1291    CGCCFLAGS="$CGCCFLAGS $VECTOR"
1292
1293    AC_SUBST([SPARSEFLAGS])
1294    AC_SUBST([CGCCFLAGS])])
1295
1296 dnl OVS_SPARSE_EXTRA_INCLUDES
1297 dnl
1298 dnl The cgcc script from "sparse" does not search gcc's default
1299 dnl search path. Get the default search path from GCC and pass
1300 dnl them to sparse.
1301 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
1302     AC_SUBST([SPARSE_EXTRA_INCLUDES],
1303            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
1304
1305 dnl OVS_ENABLE_SPARSE
1306 AC_DEFUN([OVS_ENABLE_SPARSE],
1307   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
1308    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
1309    : ${SPARSE=sparse}
1310    AC_SUBST([SPARSE])
1311    AC_CONFIG_COMMANDS_PRE(
1312      [CC='$(if $(C:0=),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) $(SPARSE_WERROR) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])
1313
1314    AC_ARG_ENABLE(
1315      [sparse],
1316      [AC_HELP_STRING([--enable-sparse], [Run "sparse" by default])],
1317      [], [enable_sparse=no])
1318    AM_CONDITIONAL([ENABLE_SPARSE_BY_DEFAULT], [test $enable_sparse = yes])])
1319
1320 dnl OVS_CTAGS_IDENTIFIERS
1321 dnl
1322 dnl ctags ignores symbols with extras identifiers. This builds a list of
1323 dnl specially handled identifiers to be ignored.
1324 AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
1325     AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
1326            [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h  | tr \\\n ' ' ; printf '"'`] ))
1327
1328 dnl OVS_PTHREAD_SET_NAME
1329 dnl
1330 dnl This checks for three known variants of pthreads functions for setting
1331 dnl the name of the current thread:
1332 dnl
1333 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
1334 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
1335 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
1336 dnl
1337 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
1338 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
1339 dnl provide to it.
1340 dnl
1341 dnl This macro defines:
1342 dnl
1343 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
1344 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
1345 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
1346 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
1347   [AC_CHECK_FUNCS([pthread_set_name_np])
1348    if test $ac_cv_func_pthread_set_name_np != yes; then
1349      AC_CACHE_CHECK(
1350        [for pthread_setname_np() variant],
1351        [ovs_cv_pthread_setname_np],
1352        [AC_LINK_IFELSE(
1353          [AC_LANG_PROGRAM([#include <pthread.h>
1354   ], [pthread_setname_np(pthread_self(), "name");])],
1355          [ovs_cv_pthread_setname_np=glibc],
1356          [AC_LINK_IFELSE(
1357            [AC_LANG_PROGRAM([#include <pthread.h>
1358 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
1359            [ovs_cv_pthread_setname_np=netbsd],
1360            [ovs_cv_pthread_setname_np=none])])])
1361      case $ovs_cv_pthread_setname_np in # (
1362        glibc)
1363           AC_DEFINE(
1364             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1365             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1366           ;; # (
1367        netbsd)
1368           AC_DEFINE(
1369             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1370             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1371           ;;
1372      esac
1373    fi])
1374
1375 dnl OVS_CHECK_LINUX_HOST.
1376 dnl
1377 dnl Checks whether we're building for a Linux host, based on the presence of
1378 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1379 dnl LINUX based on the result.
1380 AC_DEFUN([OVS_CHECK_LINUX_HOST],
1381   [AC_CACHE_CHECK(
1382      [whether __linux__ is defined],
1383      [ovs_cv_linux],
1384      [AC_COMPILE_IFELSE(
1385         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1386         [ovs_cv_linux=true],
1387         [ovs_cv_linux=false])])
1388    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])