arch/alpha/kernel/vmlinux.lds.S

   1 #include <linux/config.h>
   2 #include <asm-generic/vmlinux.lds.h>
   3
   4 OUTPUT_FORMAT("elf64-alpha")
   5 OUTPUT_ARCH(alpha)
   6 ENTRY(__start)
   7 PHDRS { kernel PT_LOAD ; }
   8 jiffies = jiffies_64;
   9 SECTIONS
  10 {
  11 #ifdef CONFIG_ALPHA_LEGACY_START_ADDRESS
  12   . = 0xfffffc0000310000;
  13 #else
  14   . = 0xfffffc0001010000;
  15 #endif
  16
  17   _text = .;                                    /* Text and read-only data */
  18   .text : {
  19         *(.text)
  20         SCHED_TEXT
  21         LOCK_TEXT
  22         *(.fixup)
  23         *(.gnu.warning)
  24   } :kernel
  25   _etext = .;                                   /* End of text section */
  26
  27   . = ALIGN(16);
  28   __start___ex_table = .;                       /* Exception table */
  29   __ex_table : { *(__ex_table) }
  30   __stop___ex_table = .;
  31
  32   RODATA
  33
  34   /* Will be freed after init */
  35   . = ALIGN(8192);                              /* Init code and data */
  36   __init_begin = .;
  37   .init.text : {
  38         _sinittext = .;
  39         *(.init.text)
  40         _einittext = .;
  41   }
  42   .init.data : { *(.init.data) }
  43
  44   . = ALIGN(16);
  45   __setup_start = .;
  46   .init.setup : { *(.init.setup) }
  47   __setup_end = .;
  48
  49   . = ALIGN(8);
  50   __initcall_start = .;
  51   .initcall.init : {
  52         *(.initcall1.init)
  53         *(.initcall2.init)
  54         *(.initcall3.init)
  55         *(.initcall4.init)
  56         *(.initcall5.init)
  57         *(.initcall6.init)
  58         *(.initcall7.init)
  59   }
  60   __initcall_end = .;
  61
  62   . = ALIGN(8192);
  63   __initramfs_start = .;
  64   .init.ramfs : { *(.init.ramfs) }
  65   __initramfs_end = .;
  66
  67   . = ALIGN(8);
  68   .con_initcall.init : {
  69         __con_initcall_start = .;
  70         *(.con_initcall.init)
  71         __con_initcall_end = .;
  72   }
  73
  74   . = ALIGN(8);
  75   SECURITY_INIT
  76
  77   . = ALIGN(64);
  78   __per_cpu_start = .;
  79   .data.percpu : { *(.data.percpu) }
  80   __per_cpu_end = .;
  81
  82   . = ALIGN(2*8192);
  83   __init_end = .;
  84   /* Freed after init ends here */
  85
  86   /* Note 2 page alignment above.  */
  87   .data.init_thread : { *(.data.init_thread) }
  88
  89   . = ALIGN(8192);
  90   .data.page_aligned : { *(.data.page_aligned) }
  91
  92   . = ALIGN(64);
  93   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  94
  95   _data = .;
  96   .data : {                                     /* Data */
  97         *(.data)
  98         CONSTRUCTORS
  99   }
 100
 101   .got : { *(.got) }
 102   .sdata : { *(.sdata) }
 103
 104   _edata = .;                                   /* End of data section */
 105
 106   __bss_start = .;
 107   .sbss : { *(.sbss) *(.scommon) }
 108   .bss : { *(.bss) *(COMMON) }
 109   __bss_stop = .;
 110
 111   _end = .;
 112
 113   /* Sections to be discarded */
 114   /DISCARD/ : { *(.exit.text) *(.exit.data) *(.exitcall.exit) }
 115
 116   .mdebug 0 : { *(.mdebug) }
 117   .note 0 : { *(.note) }
 118   .comment 0 : { *(.comment) }
 119
 120   /* Stabs debugging sections */
 121   .stab 0 : { *(.stab) }
 122   .stabstr 0 : { *(.stabstr) }
 123   .stab.excl 0 : { *(.stab.excl) }
 124   .stab.exclstr 0 : { *(.stab.exclstr) }
 125   .stab.index 0 : { *(.stab.index) }
 126   .stab.indexstr 0 : { *(.stab.indexstr) }
 127   /* DWARF 1 */
 128   .debug          0 : { *(.debug) }
 129   .line           0 : { *(.line) }
 130   /* GNU DWARF 1 extensions */
 131   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 132   .debug_sfnames  0 : { *(.debug_sfnames) }
 133   /* DWARF 1.1 and DWARF 2 */
 134   .debug_aranges  0 : { *(.debug_aranges) }
 135   .debug_pubnames 0 : { *(.debug_pubnames) }
 136   /* DWARF 2 */
 137   .debug_info     0 : { *(.debug_info) }
 138   .debug_abbrev   0 : { *(.debug_abbrev) }
 139   .debug_line     0 : { *(.debug_line) }
 140   .debug_frame    0 : { *(.debug_frame) }
 141   .debug_str      0 : { *(.debug_str) }
 142   .debug_loc      0 : { *(.debug_loc) }
 143   .debug_macinfo  0 : { *(.debug_macinfo) }
 144   /* SGI/MIPS DWARF 2 extensions */
 145   .debug_weaknames 0 : { *(.debug_weaknames) }
 146   .debug_funcnames 0 : { *(.debug_funcnames) }
 147   .debug_typenames 0 : { *(.debug_typenames) }
 148   .debug_varnames  0 : { *(.debug_varnames) }
 149 }