arch/alpha/kernel/vmlinux.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2
   3 OUTPUT_FORMAT("elf64-alpha")
   4 OUTPUT_ARCH(alpha)
   5 ENTRY(__start)
   6 PHDRS { kernel PT_LOAD ; }
   7 jiffies = jiffies_64;
   8 SECTIONS
   9 {
  10 #ifdef CONFIG_ALPHA_LEGACY_START_ADDRESS
  11   . = 0xfffffc0000310000;
  12 #else
  13   . = 0xfffffc0001010000;
  14 #endif
  15
  16   _text = .;                                    /* Text and read-only data */
  17   .text : {
  18         TEXT_TEXT
  19         SCHED_TEXT
  20         LOCK_TEXT
  21         *(.fixup)
  22         *(.gnu.warning)
  23   } :kernel
  24   _etext = .;                                   /* End of text section */
  25
  26   . = ALIGN(16);
  27   __start___ex_table = .;                       /* Exception table */
  28   __ex_table : { *(__ex_table) }
  29   __stop___ex_table = .;
  30
  31   RODATA
  32
  33   /* Will be freed after init */
  34   . = ALIGN(8192);                              /* Init code and data */
  35   __init_begin = .;
  36   .init.text : {
  37         _sinittext = .;
  38         *(.init.text)
  39         _einittext = .;
  40   }
  41   .init.data : { *(.init.data) }
  42
  43   . = ALIGN(16);
  44   __setup_start = .;
  45   .init.setup : { *(.init.setup) }
  46   __setup_end = .;
  47
  48   . = ALIGN(8);
  49   __initcall_start = .;
  50   .initcall.init : {
  51         INITCALLS
  52   }
  53   __initcall_end = .;
  54
  55 #ifdef CONFIG_BLK_DEV_INITRD
  56   . = ALIGN(8192);
  57   __initramfs_start = .;
  58   .init.ramfs : { *(.init.ramfs) }
  59   __initramfs_end = .;
  60 #endif
  61
  62   . = ALIGN(8);
  63   .con_initcall.init : {
  64         __con_initcall_start = .;
  65         *(.con_initcall.init)
  66         __con_initcall_end = .;
  67   }
  68
  69   . = ALIGN(8);
  70   SECURITY_INIT
  71
  72   . = ALIGN(8192);
  73   __per_cpu_start = .;
  74   .data.percpu : { *(.data.percpu) }
  75   __per_cpu_end = .;
  76
  77   . = ALIGN(2*8192);
  78   __init_end = .;
  79   /* Freed after init ends here */
  80
  81   /* Note 2 page alignment above.  */
  82   .data.init_thread : { *(.data.init_thread) }
  83
  84   . = ALIGN(8192);
  85   .data.page_aligned : { *(.data.page_aligned) }
  86
  87   . = ALIGN(64);
  88   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  89
  90   _data = .;
  91   .data : {                                     /* Data */
  92         DATA_DATA
  93         CONSTRUCTORS
  94   }
  95
  96   .got : { *(.got) }
  97   .sdata : { *(.sdata) }
  98
  99   _edata = .;                                   /* End of data section */
 100
 101   __bss_start = .;
 102   .sbss : { *(.sbss) *(.scommon) }
 103   .bss : { *(.bss) *(COMMON) }
 104   __bss_stop = .;
 105
 106   _end = .;
 107
 108   /* Sections to be discarded */
 109   /DISCARD/ : { *(.exit.text) *(.exit.data) *(.exitcall.exit) }
 110
 111   .mdebug 0 : { *(.mdebug) }
 112   .note 0 : { *(.note) }
 113   .comment 0 : { *(.comment) }
 114
 115   /* Stabs debugging sections */
 116   .stab 0 : { *(.stab) }
 117   .stabstr 0 : { *(.stabstr) }
 118   .stab.excl 0 : { *(.stab.excl) }
 119   .stab.exclstr 0 : { *(.stab.exclstr) }
 120   .stab.index 0 : { *(.stab.index) }
 121   .stab.indexstr 0 : { *(.stab.indexstr) }
 122   /* DWARF 1 */
 123   .debug          0 : { *(.debug) }
 124   .line           0 : { *(.line) }
 125   /* GNU DWARF 1 extensions */
 126   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 127   .debug_sfnames  0 : { *(.debug_sfnames) }
 128   /* DWARF 1.1 and DWARF 2 */
 129   .debug_aranges  0 : { *(.debug_aranges) }
 130   .debug_pubnames 0 : { *(.debug_pubnames) }
 131   /* DWARF 2 */
 132   .debug_info     0 : { *(.debug_info) }
 133   .debug_abbrev   0 : { *(.debug_abbrev) }
 134   .debug_line     0 : { *(.debug_line) }
 135   .debug_frame    0 : { *(.debug_frame) }
 136   .debug_str      0 : { *(.debug_str) }
 137   .debug_loc      0 : { *(.debug_loc) }
 138   .debug_macinfo  0 : { *(.debug_macinfo) }
 139   /* SGI/MIPS DWARF 2 extensions */
 140   .debug_weaknames 0 : { *(.debug_weaknames) }
 141   .debug_funcnames 0 : { *(.debug_funcnames) }
 142   .debug_typenames 0 : { *(.debug_typenames) }
 143   .debug_varnames  0 : { *(.debug_varnames) }
 144 }