arch/arm/boot/compressed/vmlinux.lds.in

   1 /*
   2  *  linux/arch/arm/boot/compressed/vmlinux.lds.in
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10 OUTPUT_ARCH(arm)
  11 ENTRY(_start)
  12 SECTIONS
  13 {
  14   . = TEXT_START;
  15   _text = .;
  16
  17   .text : {
  18     _start = .;
  19     *(.start)
  20     *(.text)
  21     *(.fixup)
  22     *(.gnu.warning)
  23     *(.rodata)
  24     *(.rodata.*)
  25     *(.glue_7)
  26     *(.glue_7t)
  27     *(.piggydata)
  28     . = ALIGN(4);
  29   }
  30
  31   _etext = .;
  32
  33   _got_start = .;
  34   .got                  : { *(.got) }
  35   _got_end = .;
  36   .got.plt              : { *(.got.plt) }
  37   .data                 : { *(.data) }
  38   _edata = .;
  39
  40   . = BSS_START;
  41   __bss_start = .;
  42   .bss                  : { *(.bss) }
  43   _end = .;
  44
  45   .stack (NOLOAD)       : { *(.stack) }
  46
  47   .stab 0               : { *(.stab) }
  48   .stabstr 0            : { *(.stabstr) }
  49   .stab.excl 0          : { *(.stab.excl) }
  50   .stab.exclstr 0       : { *(.stab.exclstr) }
  51   .stab.index 0         : { *(.stab.index) }
  52   .stab.indexstr 0      : { *(.stab.indexstr) }
  53   .comment 0            : { *(.comment) }
  54 }
  55