arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/assembler.h>
  12 #include <asm/unistd.h>
  13 #include <asm/ftrace.h>
  14 #include <asm/unwind.h>
  15 #include <asm/memory.h>
  16 #ifdef CONFIG_AEABI
  17 #include <asm/unistd-oabi.h>
  18 #endif
  19
  20         .equ    NR_syscalls, __NR_syscalls
  21
  22 #ifdef CONFIG_NEED_RET_TO_USER
  23 #include <mach/entry-macro.S>
  24 #else
  25         .macro  arch_ret_to_user, tmp1, tmp2
  26         .endm
  27 #endif
  28
  29 #include "entry-header.S"
  30
  31 saved_psr       .req    r8
  32 #if defined(CONFIG_TRACE_IRQFLAGS) || defined(CONFIG_CONTEXT_TRACKING)
  33 saved_pc        .req    r9
  34 #define TRACE(x...) x
  35 #else
  36 saved_pc        .req    lr
  37 #define TRACE(x...)
  38 #endif
  39
  40         .align  5
  41 #if !(IS_ENABLED(CONFIG_TRACE_IRQFLAGS) || IS_ENABLED(CONFIG_CONTEXT_TRACKING))
  42 /*
  43  * This is the fast syscall return path.  We do as little as possible here,
  44  * such as avoiding writing r0 to the stack.  We only use this path if we
  45  * have tracing and context tracking disabled - the overheads from those
  46  * features make this path too inefficient.
  47  */
  48 ret_fast_syscall:
  49  UNWIND(.fnstart        )
  50  UNWIND(.cantunwind     )
  51         disable_irq_notrace                     @ disable interrupts
  52         ldr     r2, [tsk, #TI_ADDR_LIMIT]
  53         cmp     r2, #TASK_SIZE
  54         blne    addr_limit_check_failed
  55         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  56         tst     r1, #_TIF_SYSCALL_WORK | _TIF_WORK_MASK
  57         bne     fast_work_pending
  58
  59
  60         /* perform architecture specific actions before user return */
  61         arch_ret_to_user r1, lr
  62
  63         restore_user_regs fast = 1, offset = S_OFF
  64  UNWIND(.fnend          )
  65 ENDPROC(ret_fast_syscall)
  66
  67         /* Ok, we need to do extra processing, enter the slow path. */
  68 fast_work_pending:
  69         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  70         /* fall through to work_pending */
  71 #else
  72 /*
  73  * The "replacement" ret_fast_syscall for when tracing or context tracking
  74  * is enabled.  As we will need to call out to some C functions, we save
  75  * r0 first to avoid needing to save registers around each C function call.
  76  */
  77 ret_fast_syscall:
  78  UNWIND(.fnstart        )
  79  UNWIND(.cantunwind     )
  80         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
  81         disable_irq_notrace                     @ disable interrupts
  82         ldr     r2, [tsk, #TI_ADDR_LIMIT]
  83         cmp     r2, #TASK_SIZE
  84         blne    addr_limit_check_failed
  85         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  86         tst     r1, #_TIF_SYSCALL_WORK | _TIF_WORK_MASK
  87         beq     no_work_pending
  88  UNWIND(.fnend          )
  89 ENDPROC(ret_fast_syscall)
  90
  91         /* Slower path - fall through to work_pending */
  92 #endif
  93
  94         tst     r1, #_TIF_SYSCALL_WORK
  95         bne     __sys_trace_return_nosave
  96 slow_work_pending:
  97         mov     r0, sp                          @ 'regs'
  98         mov     r2, why                         @ 'syscall'
  99         bl      do_work_pending
 100         cmp     r0, #0
 101         beq     no_work_pending
 102         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
 103         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
 104         b       local_restart                   @ ... and off we go
 105 ENDPROC(ret_fast_syscall)
 106
 107 /*
 108  * "slow" syscall return path.  "why" tells us if this was a real syscall.
 109  * IRQs may be enabled here, so always disable them.  Note that we use the
 110  * "notrace" version to avoid calling into the tracing code unnecessarily.
 111  * do_work_pending() will update this state if necessary.
 112  */
 113 ENTRY(ret_to_user)
 114 ret_slow_syscall:
 115         disable_irq_notrace                     @ disable interrupts
 116 ENTRY(ret_to_user_from_irq)
 117         ldr     r2, [tsk, #TI_ADDR_LIMIT]
 118         cmp     r2, #TASK_SIZE
 119         blne    addr_limit_check_failed
 120         ldr     r1, [tsk, #TI_FLAGS]
 121         tst     r1, #_TIF_WORK_MASK
 122         bne     slow_work_pending
 123 no_work_pending:
 124         asm_trace_hardirqs_on save = 0
 125
 126         /* perform architecture specific actions before user return */
 127         arch_ret_to_user r1, lr
 128         ct_user_enter save = 0
 129
 130         restore_user_regs fast = 0, offset = 0
 131 ENDPROC(ret_to_user_from_irq)
 132 ENDPROC(ret_to_user)
 133
 134 /*
 135  * This is how we return from a fork.
 136  */
 137 ENTRY(ret_from_fork)
 138         bl      schedule_tail
 139         cmp     r5, #0
 140         movne   r0, r4
 141         badrne  lr, 1f
 142         retne   r5
 143 1:      get_thread_info tsk
 144         b       ret_slow_syscall
 145 ENDPROC(ret_from_fork)
 146
 147 /*=============================================================================
 148  * SWI handler
 149  *-----------------------------------------------------------------------------
 150  */
 151
 152         .align  5
 153 ENTRY(vector_swi)
 154 #ifdef CONFIG_CPU_V7M
 155         v7m_exception_entry
 156 #else
 157         sub     sp, sp, #PT_REGS_SIZE
 158         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 159  ARM(   add     r8, sp, #S_PC           )
 160  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 161  THUMB( mov     r8, sp                  )
 162  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 163         mrs     saved_psr, spsr                 @ called from non-FIQ mode, so ok.
 164  TRACE( mov     saved_pc, lr            )
 165         str     saved_pc, [sp, #S_PC]           @ Save calling PC
 166         str     saved_psr, [sp, #S_PSR]         @ Save CPSR
 167         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 168 #endif
 169         zero_fp
 170         alignment_trap r10, ip, __cr_alignment
 171         asm_trace_hardirqs_on save=0
 172         enable_irq_notrace
 173         ct_user_exit save=0
 174
 175         /*
 176          * Get the system call number.
 177          */
 178
 179 #if defined(CONFIG_OABI_COMPAT)
 180
 181         /*
 182          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 183          * value to determine if it is an EABI or an old ABI call.
 184          */
 185 #ifdef CONFIG_ARM_THUMB
 186         tst     saved_psr, #PSR_T_BIT
 187         movne   r10, #0                         @ no thumb OABI emulation
 188  USER(  ldreq   r10, [saved_pc, #-4]    )       @ get SWI instruction
 189 #else
 190  USER(  ldr     r10, [saved_pc, #-4]    )       @ get SWI instruction
 191 #endif
 192  ARM_BE8(rev    r10, r10)                       @ little endian instruction
 193
 194 #elif defined(CONFIG_AEABI)
 195
 196         /*
 197          * Pure EABI user space always put syscall number into scno (r7).
 198          */
 199 #elif defined(CONFIG_ARM_THUMB)
 200         /* Legacy ABI only, possibly thumb mode. */
 201         tst     saved_psr, #PSR_T_BIT           @ this is SPSR from save_user_regs
 202         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 203  USER(  ldreq   scno, [saved_pc, #-4]   )
 204
 205 #else
 206         /* Legacy ABI only. */
 207  USER(  ldr     scno, [saved_pc, #-4]   )       @ get SWI instruction
 208 #endif
 209
 210         /* saved_psr and saved_pc are now dead */
 211
 212         uaccess_disable tbl
 213
 214         adr     tbl, sys_call_table             @ load syscall table pointer
 215
 216 #if defined(CONFIG_OABI_COMPAT)
 217         /*
 218          * If the swi argument is zero, this is an EABI call and we do nothing.
 219          *
 220          * If this is an old ABI call, get the syscall number into scno and
 221          * get the old ABI syscall table address.
 222          */
 223         bics    r10, r10, #0xff000000
 224         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 225         ldrne   tbl, =sys_oabi_call_table
 226 #elif !defined(CONFIG_AEABI)
 227         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 228         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 229 #endif
 230         get_thread_info tsk
 231         /*
 232          * Reload the registers that may have been corrupted on entry to
 233          * the syscall assembly (by tracing or context tracking.)
 234          */
 235  TRACE( ldmia   sp, {r0 - r3}           )
 236
 237 local_restart:
 238         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 239         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 240
 241         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 242         bne     __sys_trace
 243
 244         cmp     scno, #NR_syscalls              @ check upper syscall limit
 245         badr    lr, ret_fast_syscall            @ return address
 246         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 247
 248         add     r1, sp, #S_OFF
 249 2:      cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 250         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 251         bcs     arm_syscall
 252         mov     why, #0                         @ no longer a real syscall
 253         b       sys_ni_syscall                  @ not private func
 254
 255 #if defined(CONFIG_OABI_COMPAT) || !defined(CONFIG_AEABI)
 256         /*
 257          * We failed to handle a fault trying to access the page
 258          * containing the swi instruction, but we're not really in a
 259          * position to return -EFAULT. Instead, return back to the
 260          * instruction and re-enter the user fault handling path trying
 261          * to page it in. This will likely result in sending SEGV to the
 262          * current task.
 263          */
 264 9001:
 265         sub     lr, saved_pc, #4
 266         str     lr, [sp, #S_PC]
 267         get_thread_info tsk
 268         b       ret_fast_syscall
 269 #endif
 270 ENDPROC(vector_swi)
 271
 272         /*
 273          * This is the really slow path.  We're going to be doing
 274          * context switches, and waiting for our parent to respond.
 275          */
 276 __sys_trace:
 277         mov     r1, scno
 278         add     r0, sp, #S_OFF
 279         bl      syscall_trace_enter
 280
 281         badr    lr, __sys_trace_return          @ return address
 282         mov     scno, r0                        @ syscall number (possibly new)
 283         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 284         cmp     scno, #NR_syscalls              @ check upper syscall limit
 285         ldmccia r1, {r0 - r6}                   @ have to reload r0 - r6
 286         stmccia sp, {r4, r5}                    @ and update the stack args
 287         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 288         cmp     scno, #-1                       @ skip the syscall?
 289         bne     2b
 290         add     sp, sp, #S_OFF                  @ restore stack
 291         b       ret_slow_syscall
 292
 293 __sys_trace_return:
 294         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 295         mov     r0, sp
 296         bl      syscall_trace_exit
 297         b       ret_slow_syscall
 298
 299 __sys_trace_return_nosave:
 300         enable_irq_notrace
 301         mov     r0, sp
 302         bl      syscall_trace_exit
 303         b       ret_slow_syscall
 304
 305         .align  5
 306 #ifdef CONFIG_ALIGNMENT_TRAP
 307         .type   __cr_alignment, #object
 308 __cr_alignment:
 309         .word   cr_alignment
 310 #endif
 311         .ltorg
 312
 313         .macro  syscall_table_start, sym
 314         .equ    __sys_nr, 0
 315         .type   \sym, #object
 316 ENTRY(\sym)
 317         .endm
 318
 319         .macro  syscall, nr, func
 320         .ifgt   __sys_nr - \nr
 321         .error  "Duplicated/unorded system call entry"
 322         .endif
 323         .rept   \nr - __sys_nr
 324         .long   sys_ni_syscall
 325         .endr
 326         .long   \func
 327         .equ    __sys_nr, \nr + 1
 328         .endm
 329
 330         .macro  syscall_table_end, sym
 331         .ifgt   __sys_nr - __NR_syscalls
 332         .error  "System call table too big"
 333         .endif
 334         .rept   __NR_syscalls - __sys_nr
 335         .long   sys_ni_syscall
 336         .endr
 337         .size   \sym, . - \sym
 338         .endm
 339
 340 #define NATIVE(nr, func) syscall nr, func
 341
 342 /*
 343  * This is the syscall table declaration for native ABI syscalls.
 344  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 345  */
 346         syscall_table_start sys_call_table
 347 #define COMPAT(nr, native, compat) syscall nr, native
 348 #ifdef CONFIG_AEABI
 349 #include <calls-eabi.S>
 350 #else
 351 #include <calls-oabi.S>
 352 #endif
 353 #undef COMPAT
 354         syscall_table_end sys_call_table
 355
 356 /*============================================================================
 357  * Special system call wrappers
 358  */
 359 @ r0 = syscall number
 360 @ r8 = syscall table
 361 sys_syscall:
 362                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 363                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 364                 cmpne   scno, #NR_syscalls      @ check range
 365                 stmloia sp, {r5, r6}            @ shuffle args
 366                 movlo   r0, r1
 367                 movlo   r1, r2
 368                 movlo   r2, r3
 369                 movlo   r3, r4
 370                 ldrlo   pc, [tbl, scno, lsl #2]
 371                 b       sys_ni_syscall
 372 ENDPROC(sys_syscall)
 373
 374 sys_sigreturn_wrapper:
 375                 add     r0, sp, #S_OFF
 376                 mov     why, #0         @ prevent syscall restart handling
 377                 b       sys_sigreturn
 378 ENDPROC(sys_sigreturn_wrapper)
 379
 380 sys_rt_sigreturn_wrapper:
 381                 add     r0, sp, #S_OFF
 382                 mov     why, #0         @ prevent syscall restart handling
 383                 b       sys_rt_sigreturn
 384 ENDPROC(sys_rt_sigreturn_wrapper)
 385
 386 sys_statfs64_wrapper:
 387                 teq     r1, #88
 388                 moveq   r1, #84
 389                 b       sys_statfs64
 390 ENDPROC(sys_statfs64_wrapper)
 391
 392 sys_fstatfs64_wrapper:
 393                 teq     r1, #88
 394                 moveq   r1, #84
 395                 b       sys_fstatfs64
 396 ENDPROC(sys_fstatfs64_wrapper)
 397
 398 /*
 399  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 400  * offset, we return EINVAL.
 401  */
 402 sys_mmap2:
 403 #if PAGE_SHIFT > 12
 404                 tst     r5, #PGOFF_MASK
 405                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 406                 streq   r5, [sp, #4]
 407                 beq     sys_mmap_pgoff
 408                 mov     r0, #-EINVAL
 409                 ret     lr
 410 #else
 411                 str     r5, [sp, #4]
 412                 b       sys_mmap_pgoff
 413 #endif
 414 ENDPROC(sys_mmap2)
 415
 416 #ifdef CONFIG_OABI_COMPAT
 417
 418 /*
 419  * These are syscalls with argument register differences
 420  */
 421
 422 sys_oabi_pread64:
 423                 stmia   sp, {r3, r4}
 424                 b       sys_pread64
 425 ENDPROC(sys_oabi_pread64)
 426
 427 sys_oabi_pwrite64:
 428                 stmia   sp, {r3, r4}
 429                 b       sys_pwrite64
 430 ENDPROC(sys_oabi_pwrite64)
 431
 432 sys_oabi_truncate64:
 433                 mov     r3, r2
 434                 mov     r2, r1
 435                 b       sys_truncate64
 436 ENDPROC(sys_oabi_truncate64)
 437
 438 sys_oabi_ftruncate64:
 439                 mov     r3, r2
 440                 mov     r2, r1
 441                 b       sys_ftruncate64
 442 ENDPROC(sys_oabi_ftruncate64)
 443
 444 sys_oabi_readahead:
 445                 str     r3, [sp]
 446                 mov     r3, r2
 447                 mov     r2, r1
 448                 b       sys_readahead
 449 ENDPROC(sys_oabi_readahead)
 450
 451 /*
 452  * Let's declare a second syscall table for old ABI binaries
 453  * using the compatibility syscall entries.
 454  */
 455         syscall_table_start sys_oabi_call_table
 456 #define COMPAT(nr, native, compat) syscall nr, compat
 457 #include <calls-oabi.S>
 458         syscall_table_end sys_oabi_call_table
 459
 460 #endif
 461