arch/arm/kernel/entry-common.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  *  linux/arch/arm/kernel/entry-common.S
   4  *
   5  *  Copyright (C) 2000 Russell King
   6  */
   7
   8 #include <asm/assembler.h>
   9 #include <asm/unistd.h>
  10 #include <asm/ftrace.h>
  11 #include <asm/unwind.h>
  12 #include <asm/memory.h>
  13 #ifdef CONFIG_AEABI
  14 #include <asm/unistd-oabi.h>
  15 #endif
  16
  17         .equ    NR_syscalls, __NR_syscalls
  18
  19 #ifdef CONFIG_NEED_RET_TO_USER
  20 #include <mach/entry-macro.S>
  21 #else
  22         .macro  arch_ret_to_user, tmp1, tmp2
  23         .endm
  24 #endif
  25
  26 #include "entry-header.S"
  27
  28 saved_psr       .req    r8
  29 #if defined(CONFIG_TRACE_IRQFLAGS) || defined(CONFIG_CONTEXT_TRACKING)
  30 saved_pc        .req    r9
  31 #define TRACE(x...) x
  32 #else
  33 saved_pc        .req    lr
  34 #define TRACE(x...)
  35 #endif
  36
  37         .section .entry.text,"ax",%progbits
  38         .align  5
  39 #if !(IS_ENABLED(CONFIG_TRACE_IRQFLAGS) || IS_ENABLED(CONFIG_CONTEXT_TRACKING) || \
  40         IS_ENABLED(CONFIG_DEBUG_RSEQ))
  41 /*
  42  * This is the fast syscall return path.  We do as little as possible here,
  43  * such as avoiding writing r0 to the stack.  We only use this path if we
  44  * have tracing, context tracking and rseq debug disabled - the overheads
  45  * from those features make this path too inefficient.
  46  */
  47 ret_fast_syscall:
  48 __ret_fast_syscall:
  49  UNWIND(.fnstart        )
  50  UNWIND(.cantunwind     )
  51         disable_irq_notrace                     @ disable interrupts
  52         ldr     r2, [tsk, #TI_ADDR_LIMIT]
  53         cmp     r2, #TASK_SIZE
  54         blne    addr_limit_check_failed
  55         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  56         tst     r1, #_TIF_SYSCALL_WORK | _TIF_WORK_MASK
  57         bne     fast_work_pending
  58
  59
  60         /* perform architecture specific actions before user return */
  61         arch_ret_to_user r1, lr
  62
  63         restore_user_regs fast = 1, offset = S_OFF
  64  UNWIND(.fnend          )
  65 ENDPROC(ret_fast_syscall)
  66
  67         /* Ok, we need to do extra processing, enter the slow path. */
  68 fast_work_pending:
  69         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  70         /* fall through to work_pending */
  71 #else
  72 /*
  73  * The "replacement" ret_fast_syscall for when tracing, context tracking,
  74  * or rseq debug is enabled.  As we will need to call out to some C functions,
  75  * we save r0 first to avoid needing to save registers around each C function
  76  * call.
  77  */
  78 ret_fast_syscall:
  79 __ret_fast_syscall:
  80  UNWIND(.fnstart        )
  81  UNWIND(.cantunwind     )
  82         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
  83 #if IS_ENABLED(CONFIG_DEBUG_RSEQ)
  84         /* do_rseq_syscall needs interrupts enabled. */
  85         mov     r0, sp                          @ 'regs'
  86         bl      do_rseq_syscall
  87 #endif
  88         disable_irq_notrace                     @ disable interrupts
  89         ldr     r2, [tsk, #TI_ADDR_LIMIT]
  90         cmp     r2, #TASK_SIZE
  91         blne    addr_limit_check_failed
  92         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  93         tst     r1, #_TIF_SYSCALL_WORK | _TIF_WORK_MASK
  94         beq     no_work_pending
  95  UNWIND(.fnend          )
  96 ENDPROC(ret_fast_syscall)
  97
  98         /* Slower path - fall through to work_pending */
  99 #endif
 100
 101         tst     r1, #_TIF_SYSCALL_WORK
 102         bne     __sys_trace_return_nosave
 103 slow_work_pending:
 104         mov     r0, sp                          @ 'regs'
 105         mov     r2, why                         @ 'syscall'
 106         bl      do_work_pending
 107         cmp     r0, #0
 108         beq     no_work_pending
 109         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
 110         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
 111         b       local_restart                   @ ... and off we go
 112 ENDPROC(ret_fast_syscall)
 113
 114 /*
 115  * "slow" syscall return path.  "why" tells us if this was a real syscall.
 116  * IRQs may be enabled here, so always disable them.  Note that we use the
 117  * "notrace" version to avoid calling into the tracing code unnecessarily.
 118  * do_work_pending() will update this state if necessary.
 119  */
 120 ENTRY(ret_to_user)
 121 ret_slow_syscall:
 122 #if IS_ENABLED(CONFIG_DEBUG_RSEQ)
 123         /* do_rseq_syscall needs interrupts enabled. */
 124         enable_irq_notrace                      @ enable interrupts
 125         mov     r0, sp                          @ 'regs'
 126         bl      do_rseq_syscall
 127 #endif
 128         disable_irq_notrace                     @ disable interrupts
 129 ENTRY(ret_to_user_from_irq)
 130         ldr     r2, [tsk, #TI_ADDR_LIMIT]
 131         cmp     r2, #TASK_SIZE
 132         blne    addr_limit_check_failed
 133         ldr     r1, [tsk, #TI_FLAGS]
 134         tst     r1, #_TIF_WORK_MASK
 135         bne     slow_work_pending
 136 no_work_pending:
 137         asm_trace_hardirqs_on save = 0
 138
 139         /* perform architecture specific actions before user return */
 140         arch_ret_to_user r1, lr
 141         ct_user_enter save = 0
 142
 143         restore_user_regs fast = 0, offset = 0
 144 ENDPROC(ret_to_user_from_irq)
 145 ENDPROC(ret_to_user)
 146
 147 /*
 148  * This is how we return from a fork.
 149  */
 150 ENTRY(ret_from_fork)
 151         bl      schedule_tail
 152         cmp     r5, #0
 153         movne   r0, r4
 154         badrne  lr, 1f
 155         retne   r5
 156 1:      get_thread_info tsk
 157         b       ret_slow_syscall
 158 ENDPROC(ret_from_fork)
 159
 160 /*=============================================================================
 161  * SWI handler
 162  *-----------------------------------------------------------------------------
 163  */
 164
 165         .align  5
 166 #ifdef CONFIG_HARDEN_BRANCH_HISTORY
 167 ENTRY(vector_bhb_loop8_swi)
 168         sub     sp, sp, #PT_REGS_SIZE
 169         stmia   sp, {r0 - r12}
 170         mov     r8, #8
 171 1:      b       2f
 172 2:      subs    r8, r8, #1
 173         bne     1b
 174         dsb
 175         isb
 176         b       3f
 177 ENDPROC(vector_bhb_loop8_swi)
 178
 179         .align  5
 180 ENTRY(vector_bhb_bpiall_swi)
 181         sub     sp, sp, #PT_REGS_SIZE
 182         stmia   sp, {r0 - r12}
 183         mcr     p15, 0, r8, c7, c5, 6   @ BPIALL
 184         isb
 185         b       3f
 186 ENDPROC(vector_bhb_bpiall_swi)
 187 #endif
 188         .align  5
 189 ENTRY(vector_swi)
 190 #ifdef CONFIG_CPU_V7M
 191         v7m_exception_entry
 192 #else
 193         sub     sp, sp, #PT_REGS_SIZE
 194         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 195 3:
 196  ARM(   add     r8, sp, #S_PC           )
 197  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 198  THUMB( mov     r8, sp                  )
 199  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 200         mrs     saved_psr, spsr                 @ called from non-FIQ mode, so ok.
 201  TRACE( mov     saved_pc, lr            )
 202         str     saved_pc, [sp, #S_PC]           @ Save calling PC
 203         str     saved_psr, [sp, #S_PSR]         @ Save CPSR
 204         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 205 #endif
 206         zero_fp
 207         alignment_trap r10, ip, __cr_alignment
 208         asm_trace_hardirqs_on save=0
 209         enable_irq_notrace
 210         ct_user_exit save=0
 211
 212         /*
 213          * Get the system call number.
 214          */
 215
 216 #if defined(CONFIG_OABI_COMPAT)
 217
 218         /*
 219          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 220          * value to determine if it is an EABI or an old ABI call.
 221          */
 222 #ifdef CONFIG_ARM_THUMB
 223         tst     saved_psr, #PSR_T_BIT
 224         movne   r10, #0                         @ no thumb OABI emulation
 225  USER(  ldreq   r10, [saved_pc, #-4]    )       @ get SWI instruction
 226 #else
 227  USER(  ldr     r10, [saved_pc, #-4]    )       @ get SWI instruction
 228 #endif
 229  ARM_BE8(rev    r10, r10)                       @ little endian instruction
 230
 231 #elif defined(CONFIG_AEABI)
 232
 233         /*
 234          * Pure EABI user space always put syscall number into scno (r7).
 235          */
 236 #elif defined(CONFIG_ARM_THUMB)
 237         /* Legacy ABI only, possibly thumb mode. */
 238         tst     saved_psr, #PSR_T_BIT           @ this is SPSR from save_user_regs
 239         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 240  USER(  ldreq   scno, [saved_pc, #-4]   )
 241
 242 #else
 243         /* Legacy ABI only. */
 244  USER(  ldr     scno, [saved_pc, #-4]   )       @ get SWI instruction
 245 #endif
 246
 247         /* saved_psr and saved_pc are now dead */
 248
 249         uaccess_disable tbl
 250
 251         adr     tbl, sys_call_table             @ load syscall table pointer
 252
 253 #if defined(CONFIG_OABI_COMPAT)
 254         /*
 255          * If the swi argument is zero, this is an EABI call and we do nothing.
 256          *
 257          * If this is an old ABI call, get the syscall number into scno and
 258          * get the old ABI syscall table address.
 259          */
 260         bics    r10, r10, #0xff000000
 261         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 262         ldrne   tbl, =sys_oabi_call_table
 263 #elif !defined(CONFIG_AEABI)
 264         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 265         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 266 #endif
 267         get_thread_info tsk
 268         /*
 269          * Reload the registers that may have been corrupted on entry to
 270          * the syscall assembly (by tracing or context tracking.)
 271          */
 272  TRACE( ldmia   sp, {r0 - r3}           )
 273
 274 local_restart:
 275         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 276         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 277
 278         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 279         bne     __sys_trace
 280
 281         invoke_syscall tbl, scno, r10, __ret_fast_syscall
 282
 283         add     r1, sp, #S_OFF
 284 2:      cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 285         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 286         bcs     arm_syscall
 287         mov     why, #0                         @ no longer a real syscall
 288         b       sys_ni_syscall                  @ not private func
 289
 290 #if defined(CONFIG_OABI_COMPAT) || !defined(CONFIG_AEABI)
 291         /*
 292          * We failed to handle a fault trying to access the page
 293          * containing the swi instruction, but we're not really in a
 294          * position to return -EFAULT. Instead, return back to the
 295          * instruction and re-enter the user fault handling path trying
 296          * to page it in. This will likely result in sending SEGV to the
 297          * current task.
 298          */
 299 9001:
 300         sub     lr, saved_pc, #4
 301         str     lr, [sp, #S_PC]
 302         get_thread_info tsk
 303         b       ret_fast_syscall
 304 #endif
 305 ENDPROC(vector_swi)
 306
 307         /*
 308          * This is the really slow path.  We're going to be doing
 309          * context switches, and waiting for our parent to respond.
 310          */
 311 __sys_trace:
 312         mov     r1, scno
 313         add     r0, sp, #S_OFF
 314         bl      syscall_trace_enter
 315         mov     scno, r0
 316         invoke_syscall tbl, scno, r10, __sys_trace_return, reload=1
 317         cmp     scno, #-1                       @ skip the syscall?
 318         bne     2b
 319         add     sp, sp, #S_OFF                  @ restore stack
 320
 321 __sys_trace_return_nosave:
 322         enable_irq_notrace
 323         mov     r0, sp
 324         bl      syscall_trace_exit
 325         b       ret_slow_syscall
 326
 327 __sys_trace_return:
 328         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 329         mov     r0, sp
 330         bl      syscall_trace_exit
 331         b       ret_slow_syscall
 332
 333         .align  5
 334 #ifdef CONFIG_ALIGNMENT_TRAP
 335         .type   __cr_alignment, #object
 336 __cr_alignment:
 337         .word   cr_alignment
 338 #endif
 339         .ltorg
 340
 341         .macro  syscall_table_start, sym
 342         .equ    __sys_nr, 0
 343         .type   \sym, #object
 344 ENTRY(\sym)
 345         .endm
 346
 347         .macro  syscall, nr, func
 348         .ifgt   __sys_nr - \nr
 349         .error  "Duplicated/unorded system call entry"
 350         .endif
 351         .rept   \nr - __sys_nr
 352         .long   sys_ni_syscall
 353         .endr
 354         .long   \func
 355         .equ    __sys_nr, \nr + 1
 356         .endm
 357
 358         .macro  syscall_table_end, sym
 359         .ifgt   __sys_nr - __NR_syscalls
 360         .error  "System call table too big"
 361         .endif
 362         .rept   __NR_syscalls - __sys_nr
 363         .long   sys_ni_syscall
 364         .endr
 365         .size   \sym, . - \sym
 366         .endm
 367
 368 #define NATIVE(nr, func) syscall nr, func
 369
 370 /*
 371  * This is the syscall table declaration for native ABI syscalls.
 372  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 373  */
 374         syscall_table_start sys_call_table
 375 #define COMPAT(nr, native, compat) syscall nr, native
 376 #ifdef CONFIG_AEABI
 377 #include <calls-eabi.S>
 378 #else
 379 #include <calls-oabi.S>
 380 #endif
 381 #undef COMPAT
 382         syscall_table_end sys_call_table
 383
 384 /*============================================================================
 385  * Special system call wrappers
 386  */
 387 @ r0 = syscall number
 388 @ r8 = syscall table
 389 sys_syscall:
 390                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 391                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 392                 cmpne   scno, #NR_syscalls      @ check range
 393 #ifdef CONFIG_CPU_SPECTRE
 394                 movhs   scno, #0
 395                 csdb
 396 #endif
 397                 stmialo sp, {r5, r6}            @ shuffle args
 398                 movlo   r0, r1
 399                 movlo   r1, r2
 400                 movlo   r2, r3
 401                 movlo   r3, r4
 402                 ldrlo   pc, [tbl, scno, lsl #2]
 403                 b       sys_ni_syscall
 404 ENDPROC(sys_syscall)
 405
 406 sys_sigreturn_wrapper:
 407                 add     r0, sp, #S_OFF
 408                 mov     why, #0         @ prevent syscall restart handling
 409                 b       sys_sigreturn
 410 ENDPROC(sys_sigreturn_wrapper)
 411
 412 sys_rt_sigreturn_wrapper:
 413                 add     r0, sp, #S_OFF
 414                 mov     why, #0         @ prevent syscall restart handling
 415                 b       sys_rt_sigreturn
 416 ENDPROC(sys_rt_sigreturn_wrapper)
 417
 418 sys_statfs64_wrapper:
 419                 teq     r1, #88
 420                 moveq   r1, #84
 421                 b       sys_statfs64
 422 ENDPROC(sys_statfs64_wrapper)
 423
 424 sys_fstatfs64_wrapper:
 425                 teq     r1, #88
 426                 moveq   r1, #84
 427                 b       sys_fstatfs64
 428 ENDPROC(sys_fstatfs64_wrapper)
 429
 430 /*
 431  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 432  * offset, we return EINVAL.
 433  */
 434 sys_mmap2:
 435                 str     r5, [sp, #4]
 436                 b       sys_mmap_pgoff
 437 ENDPROC(sys_mmap2)
 438
 439 #ifdef CONFIG_OABI_COMPAT
 440
 441 /*
 442  * These are syscalls with argument register differences
 443  */
 444
 445 sys_oabi_pread64:
 446                 stmia   sp, {r3, r4}
 447                 b       sys_pread64
 448 ENDPROC(sys_oabi_pread64)
 449
 450 sys_oabi_pwrite64:
 451                 stmia   sp, {r3, r4}
 452                 b       sys_pwrite64
 453 ENDPROC(sys_oabi_pwrite64)
 454
 455 sys_oabi_truncate64:
 456                 mov     r3, r2
 457                 mov     r2, r1
 458                 b       sys_truncate64
 459 ENDPROC(sys_oabi_truncate64)
 460
 461 sys_oabi_ftruncate64:
 462                 mov     r3, r2
 463                 mov     r2, r1
 464                 b       sys_ftruncate64
 465 ENDPROC(sys_oabi_ftruncate64)
 466
 467 sys_oabi_readahead:
 468                 str     r3, [sp]
 469                 mov     r3, r2
 470                 mov     r2, r1
 471                 b       sys_readahead
 472 ENDPROC(sys_oabi_readahead)
 473
 474 /*
 475  * Let's declare a second syscall table for old ABI binaries
 476  * using the compatibility syscall entries.
 477  */
 478         syscall_table_start sys_oabi_call_table
 479 #define COMPAT(nr, native, compat) syscall nr, compat
 480 #include <calls-oabi.S>
 481         syscall_table_end sys_oabi_call_table
 482
 483 #endif
 484