]> git.proxmox.com Git - mirror_ubuntu-bionic-kernel.git/blob - arch/ia64/kernel/entry.S
projects / mirror_ubuntu-bionic-kernel.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
Merge branches 'no-rebases', 'arch-avr32', 'arch-blackfin', 'arch-cris', 'arch-h8300...
[mirror_ubuntu-bionic-kernel.git] / arch / ia64 / kernel / entry.S
1 /*
2 * arch/ia64/kernel/entry.S
3 *
4 * Kernel entry points.
5 *
6 * Copyright (C) 1998-2003, 2005 Hewlett-Packard Co
7 * David Mosberger-Tang <davidm@hpl.hp.com>
8 * Copyright (C) 1999, 2002-2003
9 * Asit Mallick <Asit.K.Mallick@intel.com>
10 * Don Dugger <Don.Dugger@intel.com>
11 * Suresh Siddha <suresh.b.siddha@intel.com>
12 * Fenghua Yu <fenghua.yu@intel.com>
13 * Copyright (C) 1999 VA Linux Systems
14 * Copyright (C) 1999 Walt Drummond <drummond@valinux.com>
15 */
16 /*
17 * ia64_switch_to now places correct virtual mapping in in TR2 for
18 * kernel stack. This allows us to handle interrupts without changing
19 * to physical mode.
20 *
21 * Jonathan Nicklin <nicklin@missioncriticallinux.com>
22 * Patrick O'Rourke <orourke@missioncriticallinux.com>
23 * 11/07/2000
24 */
25 /*
26 * Copyright (c) 2008 Isaku Yamahata <yamahata at valinux co jp>
27 * VA Linux Systems Japan K.K.
28 * pv_ops.
29 */
30 /*
31 * Global (preserved) predicate usage on syscall entry/exit path:
32 *
33 * pKStk: See entry.h.
34 * pUStk: See entry.h.
35 * pSys: See entry.h.
36 * pNonSys: !pSys
37 */
38
39
40 #include <asm/asmmacro.h>
41 #include <asm/cache.h>
42 #include <asm/errno.h>
43 #include <asm/kregs.h>
44 #include <asm/asm-offsets.h>
45 #include <asm/pgtable.h>
46 #include <asm/percpu.h>
47 #include <asm/processor.h>
48 #include <asm/thread_info.h>
49 #include <asm/unistd.h>
50 #include <asm/ftrace.h>
51
52 #include "minstate.h"
53
54 #ifdef __IA64_ASM_PARAVIRTUALIZED_NATIVE
55 /*
56 * execve() is special because in case of success, we need to
57 * setup a null register window frame.
58 */
59 ENTRY(ia64_execve)
60 /*
61 * Allocate 8 input registers since ptrace() may clobber them
62 */
63 .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
64 alloc loc1=ar.pfs,8,2,3,0
65 mov loc0=rp
66 .body
67 mov out0=in0 // filename
68 ;; // stop bit between alloc and call
69 mov out1=in1 // argv
70 mov out2=in2 // envp
71 br.call.sptk.many rp=sys_execve
72 .ret0:
73 cmp4.ge p6,p7=r8,r0
74 mov ar.pfs=loc1 // restore ar.pfs
75 sxt4 r8=r8 // return 64-bit result
76 ;;
77 stf.spill [sp]=f0
78 mov rp=loc0
79 (p6) mov ar.pfs=r0 // clear ar.pfs on success
80 (p7) br.ret.sptk.many rp
81
82 /*
83 * In theory, we'd have to zap this state only to prevent leaking of
84 * security sensitive state (e.g., if current->mm->dumpable is zero). However,
85 * this executes in less than 20 cycles even on Itanium, so it's not worth
86 * optimizing for...).
87 */
88 mov ar.unat=0; mov ar.lc=0
89 mov r4=0; mov f2=f0; mov b1=r0
90 mov r5=0; mov f3=f0; mov b2=r0
91 mov r6=0; mov f4=f0; mov b3=r0
92 mov r7=0; mov f5=f0; mov b4=r0
93 ldf.fill f12=[sp]; mov f13=f0; mov b5=r0
94 ldf.fill f14=[sp]; ldf.fill f15=[sp]; mov f16=f0
95 ldf.fill f17=[sp]; ldf.fill f18=[sp]; mov f19=f0
96 ldf.fill f20=[sp]; ldf.fill f21=[sp]; mov f22=f0
97 ldf.fill f23=[sp]; ldf.fill f24=[sp]; mov f25=f0
98 ldf.fill f26=[sp]; ldf.fill f27=[sp]; mov f28=f0
99 ldf.fill f29=[sp]; ldf.fill f30=[sp]; mov f31=f0
100 br.ret.sptk.many rp
101 END(ia64_execve)
102
103 /*
104 * sys_clone2(u64 flags, u64 ustack_base, u64 ustack_size, u64 parent_tidptr, u64 child_tidptr,
105 * u64 tls)
106 */
107 GLOBAL_ENTRY(sys_clone2)
108 /*
109 * Allocate 8 input registers since ptrace() may clobber them
110 */
111 .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
112 alloc r16=ar.pfs,8,2,6,0
113 DO_SAVE_SWITCH_STACK
114 adds r2=PT(R16)+IA64_SWITCH_STACK_SIZE+16,sp
115 mov loc0=rp
116 mov loc1=r16 // save ar.pfs across do_fork
117 .body
118 mov out1=in1
119 mov out3=in2
120 tbit.nz p6,p0=in0,CLONE_SETTLS_BIT
121 mov out4=in3 // parent_tidptr: valid only w/CLONE_PARENT_SETTID
122 ;;
123 (p6) st8 [r2]=in5 // store TLS in r16 for copy_thread()
124 mov out5=in4 // child_tidptr: valid only w/CLONE_CHILD_SETTID or CLONE_CHILD_CLEARTID
125 adds out2=IA64_SWITCH_STACK_SIZE+16,sp // out2 = &regs
126 mov out0=in0 // out0 = clone_flags
127 br.call.sptk.many rp=do_fork
128 .ret1: .restore sp
129 adds sp=IA64_SWITCH_STACK_SIZE,sp // pop the switch stack
130 mov ar.pfs=loc1
131 mov rp=loc0
132 br.ret.sptk.many rp
133 END(sys_clone2)
134
135 /*
136 * sys_clone(u64 flags, u64 ustack_base, u64 parent_tidptr, u64 child_tidptr, u64 tls)
137 * Deprecated. Use sys_clone2() instead.
138 */
139 GLOBAL_ENTRY(sys_clone)
140 /*
141 * Allocate 8 input registers since ptrace() may clobber them
142 */
143 .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
144 alloc r16=ar.pfs,8,2,6,0
145 DO_SAVE_SWITCH_STACK
146 adds r2=PT(R16)+IA64_SWITCH_STACK_SIZE+16,sp
147 mov loc0=rp
148 mov loc1=r16 // save ar.pfs across do_fork
149 .body
150 mov out1=in1
151 mov out3=16 // stacksize (compensates for 16-byte scratch area)
152 tbit.nz p6,p0=in0,CLONE_SETTLS_BIT
153 mov out4=in2 // parent_tidptr: valid only w/CLONE_PARENT_SETTID
154 ;;
155 (p6) st8 [r2]=in4 // store TLS in r13 (tp)
156 mov out5=in3 // child_tidptr: valid only w/CLONE_CHILD_SETTID or CLONE_CHILD_CLEARTID
157 adds out2=IA64_SWITCH_STACK_SIZE+16,sp // out2 = &regs
158 mov out0=in0 // out0 = clone_flags
159 br.call.sptk.many rp=do_fork
160 .ret2: .restore sp
161 adds sp=IA64_SWITCH_STACK_SIZE,sp // pop the switch stack
162 mov ar.pfs=loc1
163 mov rp=loc0
164 br.ret.sptk.many rp
165 END(sys_clone)
166 #endif /* __IA64_ASM_PARAVIRTUALIZED_NATIVE */
167
168 /*
169 * prev_task <- ia64_switch_to(struct task_struct *next)
170 * With Ingo's new scheduler, interrupts are disabled when this routine gets
171 * called. The code starting at .map relies on this. The rest of the code
172 * doesn't care about the interrupt masking status.
173 */
174 GLOBAL_ENTRY(__paravirt_switch_to)
175 .prologue
176 alloc r16=ar.pfs,1,0,0,0
177 DO_SAVE_SWITCH_STACK
178 .body
179
180 adds r22=IA64_TASK_THREAD_KSP_OFFSET,r13
181 movl r25=init_task
182 mov r27=IA64_KR(CURRENT_STACK)
183 adds r21=IA64_TASK_THREAD_KSP_OFFSET,in0
184 dep r20=0,in0,61,3 // physical address of "next"
185 ;;
186 st8 [r22]=sp // save kernel stack pointer of old task
187 shr.u r26=r20,IA64_GRANULE_SHIFT
188 cmp.eq p7,p6=r25,in0
189 ;;
190 /*
191 * If we've already mapped this task's page, we can skip doing it again.
192 */
193 (p6) cmp.eq p7,p6=r26,r27
194 (p6) br.cond.dpnt .map
195 ;;
196 .done:
197 ld8 sp=[r21] // load kernel stack pointer of new task
198 MOV_TO_KR(CURRENT, in0, r8, r9) // update "current" application register
199 mov r8=r13 // return pointer to previously running task
200 mov r13=in0 // set "current" pointer
201 ;;
202 DO_LOAD_SWITCH_STACK
203
204 #ifdef CONFIG_SMP
205 sync.i // ensure "fc"s done by this CPU are visible on other CPUs
206 #endif
207 br.ret.sptk.many rp // boogie on out in new context
208
209 .map:
210 RSM_PSR_IC(r25) // interrupts (psr.i) are already disabled here
211 movl r25=PAGE_KERNEL
212 ;;
213 srlz.d
214 or r23=r25,r20 // construct PA | page properties
215 mov r25=IA64_GRANULE_SHIFT<<2
216 ;;
217 MOV_TO_ITIR(p0, r25, r8)
218 MOV_TO_IFA(in0, r8) // VA of next task...
219 ;;
220 mov r25=IA64_TR_CURRENT_STACK
221 MOV_TO_KR(CURRENT_STACK, r26, r8, r9) // remember last page we mapped...
222 ;;
223 itr.d dtr[r25]=r23 // wire in new mapping...
224 SSM_PSR_IC_AND_SRLZ_D(r8, r9) // reenable the psr.ic bit
225 br.cond.sptk .done
226 END(__paravirt_switch_to)
227
228 #ifdef __IA64_ASM_PARAVIRTUALIZED_NATIVE
229 /*
230 * Note that interrupts are enabled during save_switch_stack and load_switch_stack. This
231 * means that we may get an interrupt with "sp" pointing to the new kernel stack while
232 * ar.bspstore is still pointing to the old kernel backing store area. Since ar.rsc,
233 * ar.rnat, ar.bsp, and ar.bspstore are all preserved by interrupts, this is not a
234 * problem. Also, we don't need to specify unwind information for preserved registers
235 * that are not modified in save_switch_stack as the right unwind information is already
236 * specified at the call-site of save_switch_stack.
237 */
238
239 /*
240 * save_switch_stack:
241 * - r16 holds ar.pfs
242 * - b7 holds address to return to
243 * - rp (b0) holds return address to save
244 */
245 GLOBAL_ENTRY(save_switch_stack)
246 .prologue
247 .altrp b7
248 flushrs // flush dirty regs to backing store (must be first in insn group)
249 .save @priunat,r17
250 mov r17=ar.unat // preserve caller's
251 .body
252 #ifdef CONFIG_ITANIUM
253 adds r2=16+128,sp
254 adds r3=16+64,sp
255 adds r14=SW(R4)+16,sp
256 ;;
257 st8.spill [r14]=r4,16 // spill r4
258 lfetch.fault.excl.nt1 [r3],128
259 ;;
260 lfetch.fault.excl.nt1 [r2],128
261 lfetch.fault.excl.nt1 [r3],128
262 ;;
263 lfetch.fault.excl [r2]
264 lfetch.fault.excl [r3]
265 adds r15=SW(R5)+16,sp
266 #else
267 add r2=16+3*128,sp
268 add r3=16,sp
269 add r14=SW(R4)+16,sp
270 ;;
271 st8.spill [r14]=r4,SW(R6)-SW(R4) // spill r4 and prefetch offset 0x1c0
272 lfetch.fault.excl.nt1 [r3],128 // prefetch offset 0x010
273 ;;
274 lfetch.fault.excl.nt1 [r3],128 // prefetch offset 0x090
275 lfetch.fault.excl.nt1 [r2],128 // prefetch offset 0x190
276 ;;
277 lfetch.fault.excl.nt1 [r3] // prefetch offset 0x110
278 lfetch.fault.excl.nt1 [r2] // prefetch offset 0x210
279 adds r15=SW(R5)+16,sp
280 #endif
281 ;;
282 st8.spill [r15]=r5,SW(R7)-SW(R5) // spill r5
283 mov.m ar.rsc=0 // put RSE in mode: enforced lazy, little endian, pl 0
284 add r2=SW(F2)+16,sp // r2 = &sw->f2
285 ;;
286 st8.spill [r14]=r6,SW(B0)-SW(R6) // spill r6
287 mov.m r18=ar.fpsr // preserve fpsr
288 add r3=SW(F3)+16,sp // r3 = &sw->f3
289 ;;
290 stf.spill [r2]=f2,32
291 mov.m r19=ar.rnat
292 mov r21=b0
293
294 stf.spill [r3]=f3,32
295 st8.spill [r15]=r7,SW(B2)-SW(R7) // spill r7
296 mov r22=b1
297 ;;
298 // since we're done with the spills, read and save ar.unat:
299 mov.m r29=ar.unat
300 mov.m r20=ar.bspstore
301 mov r23=b2
302 stf.spill [r2]=f4,32
303 stf.spill [r3]=f5,32
304 mov r24=b3
305 ;;
306 st8 [r14]=r21,SW(B1)-SW(B0) // save b0
307 st8 [r15]=r23,SW(B3)-SW(B2) // save b2
308 mov r25=b4
309 mov r26=b5
310 ;;
311 st8 [r14]=r22,SW(B4)-SW(B1) // save b1
312 st8 [r15]=r24,SW(AR_PFS)-SW(B3) // save b3
313 mov r21=ar.lc // I-unit
314 stf.spill [r2]=f12,32
315 stf.spill [r3]=f13,32
316 ;;
317 st8 [r14]=r25,SW(B5)-SW(B4) // save b4
318 st8 [r15]=r16,SW(AR_LC)-SW(AR_PFS) // save ar.pfs
319 stf.spill [r2]=f14,32
320 stf.spill [r3]=f15,32
321 ;;
322 st8 [r14]=r26 // save b5
323 st8 [r15]=r21 // save ar.lc
324 stf.spill [r2]=f16,32
325 stf.spill [r3]=f17,32
326 ;;
327 stf.spill [r2]=f18,32
328 stf.spill [r3]=f19,32
329 ;;
330 stf.spill [r2]=f20,32
331 stf.spill [r3]=f21,32
332 ;;
333 stf.spill [r2]=f22,32
334 stf.spill [r3]=f23,32
335 ;;
336 stf.spill [r2]=f24,32
337 stf.spill [r3]=f25,32
338 ;;
339 stf.spill [r2]=f26,32
340 stf.spill [r3]=f27,32
341 ;;
342 stf.spill [r2]=f28,32
343 stf.spill [r3]=f29,32
344 ;;
345 stf.spill [r2]=f30,SW(AR_UNAT)-SW(F30)
346 stf.spill [r3]=f31,SW(PR)-SW(F31)
347 add r14=SW(CALLER_UNAT)+16,sp
348 ;;
349 st8 [r2]=r29,SW(AR_RNAT)-SW(AR_UNAT) // save ar.unat
350 st8 [r14]=r17,SW(AR_FPSR)-SW(CALLER_UNAT) // save caller_unat
351 mov r21=pr
352 ;;
353 st8 [r2]=r19,SW(AR_BSPSTORE)-SW(AR_RNAT) // save ar.rnat
354 st8 [r3]=r21 // save predicate registers
355 ;;
356 st8 [r2]=r20 // save ar.bspstore
357 st8 [r14]=r18 // save fpsr
358 mov ar.rsc=3 // put RSE back into eager mode, pl 0
359 br.cond.sptk.many b7
360 END(save_switch_stack)
361
362 /*
363 * load_switch_stack:
364 * - "invala" MUST be done at call site (normally in DO_LOAD_SWITCH_STACK)
365 * - b7 holds address to return to
366 * - must not touch r8-r11
367 */
368 GLOBAL_ENTRY(load_switch_stack)
369 .prologue
370 .altrp b7
371
372 .body
373 lfetch.fault.nt1 [sp]
374 adds r2=SW(AR_BSPSTORE)+16,sp
375 adds r3=SW(AR_UNAT)+16,sp
376 mov ar.rsc=0 // put RSE into enforced lazy mode
377 adds r14=SW(CALLER_UNAT)+16,sp
378 adds r15=SW(AR_FPSR)+16,sp
379 ;;
380 ld8 r27=[r2],(SW(B0)-SW(AR_BSPSTORE)) // bspstore
381 ld8 r29=[r3],(SW(B1)-SW(AR_UNAT)) // unat
382 ;;
383 ld8 r21=[r2],16 // restore b0
384 ld8 r22=[r3],16 // restore b1
385 ;;
386 ld8 r23=[r2],16 // restore b2
387 ld8 r24=[r3],16 // restore b3
388 ;;
389 ld8 r25=[r2],16 // restore b4
390 ld8 r26=[r3],16 // restore b5
391 ;;
392 ld8 r16=[r2],(SW(PR)-SW(AR_PFS)) // ar.pfs
393 ld8 r17=[r3],(SW(AR_RNAT)-SW(AR_LC)) // ar.lc
394 ;;
395 ld8 r28=[r2] // restore pr
396 ld8 r30=[r3] // restore rnat
397 ;;
398 ld8 r18=[r14],16 // restore caller's unat
399 ld8 r19=[r15],24 // restore fpsr
400 ;;
401 ldf.fill f2=[r14],32
402 ldf.fill f3=[r15],32
403 ;;
404 ldf.fill f4=[r14],32
405 ldf.fill f5=[r15],32
406 ;;
407 ldf.fill f12=[r14],32
408 ldf.fill f13=[r15],32
409 ;;
410 ldf.fill f14=[r14],32
411 ldf.fill f15=[r15],32
412 ;;
413 ldf.fill f16=[r14],32
414 ldf.fill f17=[r15],32
415 ;;
416 ldf.fill f18=[r14],32
417 ldf.fill f19=[r15],32
418 mov b0=r21
419 ;;
420 ldf.fill f20=[r14],32
421 ldf.fill f21=[r15],32
422 mov b1=r22
423 ;;
424 ldf.fill f22=[r14],32
425 ldf.fill f23=[r15],32
426 mov b2=r23
427 ;;
428 mov ar.bspstore=r27
429 mov ar.unat=r29 // establish unat holding the NaT bits for r4-r7
430 mov b3=r24
431 ;;
432 ldf.fill f24=[r14],32
433 ldf.fill f25=[r15],32
434 mov b4=r25
435 ;;
436 ldf.fill f26=[r14],32
437 ldf.fill f27=[r15],32
438 mov b5=r26
439 ;;
440 ldf.fill f28=[r14],32
441 ldf.fill f29=[r15],32
442 mov ar.pfs=r16
443 ;;
444 ldf.fill f30=[r14],32
445 ldf.fill f31=[r15],24
446 mov ar.lc=r17
447 ;;
448 ld8.fill r4=[r14],16
449 ld8.fill r5=[r15],16
450 mov pr=r28,-1
451 ;;
452 ld8.fill r6=[r14],16
453 ld8.fill r7=[r15],16
454
455 mov ar.unat=r18 // restore caller's unat
456 mov ar.rnat=r30 // must restore after bspstore but before rsc!
457 mov ar.fpsr=r19 // restore fpsr
458 mov ar.rsc=3 // put RSE back into eager mode, pl 0
459 br.cond.sptk.many b7
460 END(load_switch_stack)
461
462 GLOBAL_ENTRY(prefetch_stack)
463 add r14 = -IA64_SWITCH_STACK_SIZE, sp
464 add r15 = IA64_TASK_THREAD_KSP_OFFSET, in0
465 ;;
466 ld8 r16 = [r15] // load next's stack pointer
467 lfetch.fault.excl [r14], 128
468 ;;
469 lfetch.fault.excl [r14], 128
470 lfetch.fault [r16], 128
471 ;;
472 lfetch.fault.excl [r14], 128
473 lfetch.fault [r16], 128
474 ;;
475 lfetch.fault.excl [r14], 128
476 lfetch.fault [r16], 128
477 ;;
478 lfetch.fault.excl [r14], 128
479 lfetch.fault [r16], 128
480 ;;
481 lfetch.fault [r16], 128
482 br.ret.sptk.many rp
483 END(prefetch_stack)
484
485 /*
486 * Invoke a system call, but do some tracing before and after the call.
487 * We MUST preserve the current register frame throughout this routine
488 * because some system calls (such as ia64_execve) directly
489 * manipulate ar.pfs.
490 */
491 GLOBAL_ENTRY(ia64_trace_syscall)
492 PT_REGS_UNWIND_INFO(0)
493 /*
494 * We need to preserve the scratch registers f6-f11 in case the system
495 * call is sigreturn.
496 */
497 adds r16=PT(F6)+16,sp
498 adds r17=PT(F7)+16,sp
499 ;;
500 stf.spill [r16]=f6,32
501 stf.spill [r17]=f7,32
502 ;;
503 stf.spill [r16]=f8,32
504 stf.spill [r17]=f9,32
505 ;;
506 stf.spill [r16]=f10
507 stf.spill [r17]=f11
508 br.call.sptk.many rp=syscall_trace_enter // give parent a chance to catch syscall args
509 cmp.lt p6,p0=r8,r0 // check tracehook
510 adds r2=PT(R8)+16,sp // r2 = &pt_regs.r8
511 adds r3=PT(R10)+16,sp // r3 = &pt_regs.r10
512 mov r10=0
513 (p6) br.cond.sptk strace_error // syscall failed ->
514 adds r16=PT(F6)+16,sp
515 adds r17=PT(F7)+16,sp
516 ;;
517 ldf.fill f6=[r16],32
518 ldf.fill f7=[r17],32
519 ;;
520 ldf.fill f8=[r16],32
521 ldf.fill f9=[r17],32
522 ;;
523 ldf.fill f10=[r16]
524 ldf.fill f11=[r17]
525 // the syscall number may have changed, so re-load it and re-calculate the
526 // syscall entry-point:
527 adds r15=PT(R15)+16,sp // r15 = &pt_regs.r15 (syscall #)
528 ;;
529 ld8 r15=[r15]
530 mov r3=NR_syscalls - 1
531 ;;
532 adds r15=-1024,r15
533 movl r16=sys_call_table
534 ;;
535 shladd r20=r15,3,r16 // r20 = sys_call_table + 8*(syscall-1024)
536 cmp.leu p6,p7=r15,r3
537 ;;
538 (p6) ld8 r20=[r20] // load address of syscall entry point
539 (p7) movl r20=sys_ni_syscall
540 ;;
541 mov b6=r20
542 br.call.sptk.many rp=b6 // do the syscall
543 .strace_check_retval:
544 cmp.lt p6,p0=r8,r0 // syscall failed?
545 adds r2=PT(R8)+16,sp // r2 = &pt_regs.r8
546 adds r3=PT(R10)+16,sp // r3 = &pt_regs.r10
547 mov r10=0
548 (p6) br.cond.sptk strace_error // syscall failed ->
549 ;; // avoid RAW on r10
550 .strace_save_retval:
551 .mem.offset 0,0; st8.spill [r2]=r8 // store return value in slot for r8
552 .mem.offset 8,0; st8.spill [r3]=r10 // clear error indication in slot for r10
553 br.call.sptk.many rp=syscall_trace_leave // give parent a chance to catch return value
554 .ret3:
555 (pUStk) cmp.eq.unc p6,p0=r0,r0 // p6 <- pUStk
556 (pUStk) rsm psr.i // disable interrupts
557 br.cond.sptk ia64_work_pending_syscall_end
558
559 strace_error:
560 ld8 r3=[r2] // load pt_regs.r8
561 sub r9=0,r8 // negate return value to get errno value
562 ;;
563 cmp.ne p6,p0=r3,r0 // is pt_regs.r8!=0?
564 adds r3=16,r2 // r3=&pt_regs.r10
565 ;;
566 (p6) mov r10=-1
567 (p6) mov r8=r9
568 br.cond.sptk .strace_save_retval
569 END(ia64_trace_syscall)
570
571 /*
572 * When traced and returning from sigreturn, we invoke syscall_trace but then
573 * go straight to ia64_leave_kernel rather than ia64_leave_syscall.
574 */
575 GLOBAL_ENTRY(ia64_strace_leave_kernel)
576 PT_REGS_UNWIND_INFO(0)
577 { /*
578 * Some versions of gas generate bad unwind info if the first instruction of a
579 * procedure doesn't go into the first slot of a bundle. This is a workaround.
580 */
581 nop.m 0
582 nop.i 0
583 br.call.sptk.many rp=syscall_trace_leave // give parent a chance to catch return value
584 }
585 .ret4: br.cond.sptk ia64_leave_kernel
586 END(ia64_strace_leave_kernel)
587
588 ENTRY(call_payload)
589 .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(0)
590 /* call the kernel_thread payload; fn is in r4, arg - in r5 */
591 alloc loc1=ar.pfs,0,3,1,0
592 mov loc0=rp
593 mov loc2=gp
594 mov out0=r5 // arg
595 ld8 r14 = [r4], 8 // fn.address
596 ;;
597 mov b6 = r14
598 ld8 gp = [r4] // fn.gp
599 ;;
600 br.call.sptk.many rp=b6 // fn(arg)
601 .ret12: mov gp=loc2
602 mov rp=loc0
603 mov ar.pfs=loc1
604 /* ... and if it has returned, we are going to userland */
605 cmp.ne pKStk,pUStk=r0,r0
606 br.ret.sptk.many rp
607 END(call_payload)
608
609 GLOBAL_ENTRY(ia64_ret_from_clone)
610 PT_REGS_UNWIND_INFO(0)
611 { /*
612 * Some versions of gas generate bad unwind info if the first instruction of a
613 * procedure doesn't go into the first slot of a bundle. This is a workaround.
614 */
615 nop.m 0
616 nop.i 0
617 /*
618 * We need to call schedule_tail() to complete the scheduling process.
619 * Called by ia64_switch_to() after do_fork()->copy_thread(). r8 contains the
620 * address of the previously executing task.
621 */
622 br.call.sptk.many rp=ia64_invoke_schedule_tail
623 }
624 .ret8:
625 (pKStk) br.call.sptk.many rp=call_payload
626 adds r2=TI_FLAGS+IA64_TASK_SIZE,r13
627 ;;
628 ld4 r2=[r2]
629 ;;
630 mov r8=0
631 and r2=_TIF_SYSCALL_TRACEAUDIT,r2
632 ;;
633 cmp.ne p6,p0=r2,r0
634 (p6) br.cond.spnt .strace_check_retval
635 ;; // added stop bits to prevent r8 dependency
636 END(ia64_ret_from_clone)
637 // fall through
638 GLOBAL_ENTRY(ia64_ret_from_syscall)
639 PT_REGS_UNWIND_INFO(0)
640 cmp.ge p6,p7=r8,r0 // syscall executed successfully?
641 adds r2=PT(R8)+16,sp // r2 = &pt_regs.r8
642 mov r10=r0 // clear error indication in r10
643 (p7) br.cond.spnt handle_syscall_error // handle potential syscall failure
644 #ifdef CONFIG_PARAVIRT
645 ;;
646 br.cond.sptk.few ia64_leave_syscall
647 ;;
648 #endif /* CONFIG_PARAVIRT */
649 END(ia64_ret_from_syscall)
650 #ifndef CONFIG_PARAVIRT
651 // fall through
652 #endif
653 #endif /* __IA64_ASM_PARAVIRTUALIZED_NATIVE */
654
655 /*
656 * ia64_leave_syscall(): Same as ia64_leave_kernel, except that it doesn't
657 * need to switch to bank 0 and doesn't restore the scratch registers.
658 * To avoid leaking kernel bits, the scratch registers are set to
659 * the following known-to-be-safe values:
660 *
661 * r1: restored (global pointer)
662 * r2: cleared
663 * r3: 1 (when returning to user-level)
664 * r8-r11: restored (syscall return value(s))
665 * r12: restored (user-level stack pointer)
666 * r13: restored (user-level thread pointer)
667 * r14: set to __kernel_syscall_via_epc
668 * r15: restored (syscall #)
669 * r16-r17: cleared
670 * r18: user-level b6
671 * r19: cleared
672 * r20: user-level ar.fpsr
673 * r21: user-level b0
674 * r22: cleared
675 * r23: user-level ar.bspstore
676 * r24: user-level ar.rnat
677 * r25: user-level ar.unat
678 * r26: user-level ar.pfs
679 * r27: user-level ar.rsc
680 * r28: user-level ip
681 * r29: user-level psr
682 * r30: user-level cfm
683 * r31: user-level pr
684 * f6-f11: cleared
685 * pr: restored (user-level pr)
686 * b0: restored (user-level rp)
687 * b6: restored
688 * b7: set to __kernel_syscall_via_epc
689 * ar.unat: restored (user-level ar.unat)
690 * ar.pfs: restored (user-level ar.pfs)
691 * ar.rsc: restored (user-level ar.rsc)
692 * ar.rnat: restored (user-level ar.rnat)
693 * ar.bspstore: restored (user-level ar.bspstore)
694 * ar.fpsr: restored (user-level ar.fpsr)
695 * ar.ccv: cleared
696 * ar.csd: cleared
697 * ar.ssd: cleared
698 */
699 GLOBAL_ENTRY(__paravirt_leave_syscall)
700 PT_REGS_UNWIND_INFO(0)
701 /*
702 * work.need_resched etc. mustn't get changed by this CPU before it returns to
703 * user- or fsys-mode, hence we disable interrupts early on.
704 *
705 * p6 controls whether current_thread_info()->flags needs to be check for
706 * extra work. We always check for extra work when returning to user-level.
707 * With CONFIG_PREEMPT, we also check for extra work when the preempt_count
708 * is 0. After extra work processing has been completed, execution
709 * resumes at ia64_work_processed_syscall with p6 set to 1 if the extra-work-check
710 * needs to be redone.
711 */
712 #ifdef CONFIG_PREEMPT
713 RSM_PSR_I(p0, r2, r18) // disable interrupts
714 cmp.eq pLvSys,p0=r0,r0 // pLvSys=1: leave from syscall
715 (pKStk) adds r20=TI_PRE_COUNT+IA64_TASK_SIZE,r13
716 ;;
717 .pred.rel.mutex pUStk,pKStk
718 (pKStk) ld4 r21=[r20] // r21 <- preempt_count
719 (pUStk) mov r21=0 // r21 <- 0
720 ;;
721 cmp.eq p6,p0=r21,r0 // p6 <- pUStk || (preempt_count == 0)
722 #else /* !CONFIG_PREEMPT */
723 RSM_PSR_I(pUStk, r2, r18)
724 cmp.eq pLvSys,p0=r0,r0 // pLvSys=1: leave from syscall
725 (pUStk) cmp.eq.unc p6,p0=r0,r0 // p6 <- pUStk
726 #endif
727 .global __paravirt_work_processed_syscall;
728 __paravirt_work_processed_syscall:
729 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
730 adds r2=PT(LOADRS)+16,r12
731 MOV_FROM_ITC(pUStk, p9, r22, r19) // fetch time at leave
732 adds r18=TI_FLAGS+IA64_TASK_SIZE,r13
733 ;;
734 (p6) ld4 r31=[r18] // load current_thread_info()->flags
735 ld8 r19=[r2],PT(B6)-PT(LOADRS) // load ar.rsc value for "loadrs"
736 adds r3=PT(AR_BSPSTORE)+16,r12 // deferred
737 ;;
738 #else
739 adds r2=PT(LOADRS)+16,r12
740 adds r3=PT(AR_BSPSTORE)+16,r12
741 adds r18=TI_FLAGS+IA64_TASK_SIZE,r13
742 ;;
743 (p6) ld4 r31=[r18] // load current_thread_info()->flags
744 ld8 r19=[r2],PT(B6)-PT(LOADRS) // load ar.rsc value for "loadrs"
745 nop.i 0
746 ;;
747 #endif
748 mov r16=ar.bsp // M2 get existing backing store pointer
749 ld8 r18=[r2],PT(R9)-PT(B6) // load b6
750 (p6) and r15=TIF_WORK_MASK,r31 // any work other than TIF_SYSCALL_TRACE?
751 ;;
752 ld8 r23=[r3],PT(R11)-PT(AR_BSPSTORE) // load ar.bspstore (may be garbage)
753 (p6) cmp4.ne.unc p6,p0=r15, r0 // any special work pending?
754 (p6) br.cond.spnt .work_pending_syscall
755 ;;
756 // start restoring the state saved on the kernel stack (struct pt_regs):
757 ld8 r9=[r2],PT(CR_IPSR)-PT(R9)
758 ld8 r11=[r3],PT(CR_IIP)-PT(R11)
759 (pNonSys) break 0 // bug check: we shouldn't be here if pNonSys is TRUE!
760 ;;
761 invala // M0|1 invalidate ALAT
762 RSM_PSR_I_IC(r28, r29, r30) // M2 turn off interrupts and interruption collection
763 cmp.eq p9,p0=r0,r0 // A set p9 to indicate that we should restore cr.ifs
764
765 ld8 r29=[r2],16 // M0|1 load cr.ipsr
766 ld8 r28=[r3],16 // M0|1 load cr.iip
767 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
768 (pUStk) add r14=TI_AC_LEAVE+IA64_TASK_SIZE,r13
769 ;;
770 ld8 r30=[r2],16 // M0|1 load cr.ifs
771 ld8 r25=[r3],16 // M0|1 load ar.unat
772 (pUStk) add r15=IA64_TASK_THREAD_ON_USTACK_OFFSET,r13
773 ;;
774 #else
775 mov r22=r0 // A clear r22
776 ;;
777 ld8 r30=[r2],16 // M0|1 load cr.ifs
778 ld8 r25=[r3],16 // M0|1 load ar.unat
779 (pUStk) add r14=IA64_TASK_THREAD_ON_USTACK_OFFSET,r13
780 ;;
781 #endif
782 ld8 r26=[r2],PT(B0)-PT(AR_PFS) // M0|1 load ar.pfs
783 MOV_FROM_PSR(pKStk, r22, r21) // M2 read PSR now that interrupts are disabled
784 nop 0
785 ;;
786 ld8 r21=[r2],PT(AR_RNAT)-PT(B0) // M0|1 load b0
787 ld8 r27=[r3],PT(PR)-PT(AR_RSC) // M0|1 load ar.rsc
788 mov f6=f0 // F clear f6
789 ;;
790 ld8 r24=[r2],PT(AR_FPSR)-PT(AR_RNAT) // M0|1 load ar.rnat (may be garbage)
791 ld8 r31=[r3],PT(R1)-PT(PR) // M0|1 load predicates
792 mov f7=f0 // F clear f7
793 ;;
794 ld8 r20=[r2],PT(R12)-PT(AR_FPSR) // M0|1 load ar.fpsr
795 ld8.fill r1=[r3],16 // M0|1 load r1
796 (pUStk) mov r17=1 // A
797 ;;
798 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
799 (pUStk) st1 [r15]=r17 // M2|3
800 #else
801 (pUStk) st1 [r14]=r17 // M2|3
802 #endif
803 ld8.fill r13=[r3],16 // M0|1
804 mov f8=f0 // F clear f8
805 ;;
806 ld8.fill r12=[r2] // M0|1 restore r12 (sp)
807 ld8.fill r15=[r3] // M0|1 restore r15
808 mov b6=r18 // I0 restore b6
809
810 LOAD_PHYS_STACK_REG_SIZE(r17)
811 mov f9=f0 // F clear f9
812 (pKStk) br.cond.dpnt.many skip_rbs_switch // B
813
814 srlz.d // M0 ensure interruption collection is off (for cover)
815 shr.u r18=r19,16 // I0|1 get byte size of existing "dirty" partition
816 COVER // B add current frame into dirty partition & set cr.ifs
817 ;;
818 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
819 mov r19=ar.bsp // M2 get new backing store pointer
820 st8 [r14]=r22 // M save time at leave
821 mov f10=f0 // F clear f10
822
823 mov r22=r0 // A clear r22
824 movl r14=__kernel_syscall_via_epc // X
825 ;;
826 #else
827 mov r19=ar.bsp // M2 get new backing store pointer
828 mov f10=f0 // F clear f10
829
830 nop.m 0
831 movl r14=__kernel_syscall_via_epc // X
832 ;;
833 #endif
834 mov.m ar.csd=r0 // M2 clear ar.csd
835 mov.m ar.ccv=r0 // M2 clear ar.ccv
836 mov b7=r14 // I0 clear b7 (hint with __kernel_syscall_via_epc)
837
838 mov.m ar.ssd=r0 // M2 clear ar.ssd
839 mov f11=f0 // F clear f11
840 br.cond.sptk.many rbs_switch // B
841 END(__paravirt_leave_syscall)
842
843 GLOBAL_ENTRY(__paravirt_leave_kernel)
844 PT_REGS_UNWIND_INFO(0)
845 /*
846 * work.need_resched etc. mustn't get changed by this CPU before it returns to
847 * user- or fsys-mode, hence we disable interrupts early on.
848 *
849 * p6 controls whether current_thread_info()->flags needs to be check for
850 * extra work. We always check for extra work when returning to user-level.
851 * With CONFIG_PREEMPT, we also check for extra work when the preempt_count
852 * is 0. After extra work processing has been completed, execution
853 * resumes at .work_processed_syscall with p6 set to 1 if the extra-work-check
854 * needs to be redone.
855 */
856 #ifdef CONFIG_PREEMPT
857 RSM_PSR_I(p0, r17, r31) // disable interrupts
858 cmp.eq p0,pLvSys=r0,r0 // pLvSys=0: leave from kernel
859 (pKStk) adds r20=TI_PRE_COUNT+IA64_TASK_SIZE,r13
860 ;;
861 .pred.rel.mutex pUStk,pKStk
862 (pKStk) ld4 r21=[r20] // r21 <- preempt_count
863 (pUStk) mov r21=0 // r21 <- 0
864 ;;
865 cmp.eq p6,p0=r21,r0 // p6 <- pUStk || (preempt_count == 0)
866 #else
867 RSM_PSR_I(pUStk, r17, r31)
868 cmp.eq p0,pLvSys=r0,r0 // pLvSys=0: leave from kernel
869 (pUStk) cmp.eq.unc p6,p0=r0,r0 // p6 <- pUStk
870 #endif
871 .work_processed_kernel:
872 adds r17=TI_FLAGS+IA64_TASK_SIZE,r13
873 ;;
874 (p6) ld4 r31=[r17] // load current_thread_info()->flags
875 adds r21=PT(PR)+16,r12
876 ;;
877
878 lfetch [r21],PT(CR_IPSR)-PT(PR)
879 adds r2=PT(B6)+16,r12
880 adds r3=PT(R16)+16,r12
881 ;;
882 lfetch [r21]
883 ld8 r28=[r2],8 // load b6
884 adds r29=PT(R24)+16,r12
885
886 ld8.fill r16=[r3],PT(AR_CSD)-PT(R16)
887 adds r30=PT(AR_CCV)+16,r12
888 (p6) and r19=TIF_WORK_MASK,r31 // any work other than TIF_SYSCALL_TRACE?
889 ;;
890 ld8.fill r24=[r29]
891 ld8 r15=[r30] // load ar.ccv
892 (p6) cmp4.ne.unc p6,p0=r19, r0 // any special work pending?
893 ;;
894 ld8 r29=[r2],16 // load b7
895 ld8 r30=[r3],16 // load ar.csd
896 (p6) br.cond.spnt .work_pending
897 ;;
898 ld8 r31=[r2],16 // load ar.ssd
899 ld8.fill r8=[r3],16
900 ;;
901 ld8.fill r9=[r2],16
902 ld8.fill r10=[r3],PT(R17)-PT(R10)
903 ;;
904 ld8.fill r11=[r2],PT(R18)-PT(R11)
905 ld8.fill r17=[r3],16
906 ;;
907 ld8.fill r18=[r2],16
908 ld8.fill r19=[r3],16
909 ;;
910 ld8.fill r20=[r2],16
911 ld8.fill r21=[r3],16
912 mov ar.csd=r30
913 mov ar.ssd=r31
914 ;;
915 RSM_PSR_I_IC(r23, r22, r25) // initiate turning off of interrupt and interruption collection
916 invala // invalidate ALAT
917 ;;
918 ld8.fill r22=[r2],24
919 ld8.fill r23=[r3],24
920 mov b6=r28
921 ;;
922 ld8.fill r25=[r2],16
923 ld8.fill r26=[r3],16
924 mov b7=r29
925 ;;
926 ld8.fill r27=[r2],16
927 ld8.fill r28=[r3],16
928 ;;
929 ld8.fill r29=[r2],16
930 ld8.fill r30=[r3],24
931 ;;
932 ld8.fill r31=[r2],PT(F9)-PT(R31)
933 adds r3=PT(F10)-PT(F6),r3
934 ;;
935 ldf.fill f9=[r2],PT(F6)-PT(F9)
936 ldf.fill f10=[r3],PT(F8)-PT(F10)
937 ;;
938 ldf.fill f6=[r2],PT(F7)-PT(F6)
939 ;;
940 ldf.fill f7=[r2],PT(F11)-PT(F7)
941 ldf.fill f8=[r3],32
942 ;;
943 srlz.d // ensure that inter. collection is off (VHPT is don't care, since text is pinned)
944 mov ar.ccv=r15
945 ;;
946 ldf.fill f11=[r2]
947 BSW_0(r2, r3, r15) // switch back to bank 0 (no stop bit required beforehand...)
948 ;;
949 (pUStk) mov r18=IA64_KR(CURRENT)// M2 (12 cycle read latency)
950 adds r16=PT(CR_IPSR)+16,r12
951 adds r17=PT(CR_IIP)+16,r12
952
953 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
954 .pred.rel.mutex pUStk,pKStk
955 MOV_FROM_PSR(pKStk, r22, r29) // M2 read PSR now that interrupts are disabled
956 MOV_FROM_ITC(pUStk, p9, r22, r29) // M fetch time at leave
957 nop.i 0
958 ;;
959 #else
960 MOV_FROM_PSR(pKStk, r22, r29) // M2 read PSR now that interrupts are disabled
961 nop.i 0
962 nop.i 0
963 ;;
964 #endif
965 ld8 r29=[r16],16 // load cr.ipsr
966 ld8 r28=[r17],16 // load cr.iip
967 ;;
968 ld8 r30=[r16],16 // load cr.ifs
969 ld8 r25=[r17],16 // load ar.unat
970 ;;
971 ld8 r26=[r16],16 // load ar.pfs
972 ld8 r27=[r17],16 // load ar.rsc
973 cmp.eq p9,p0=r0,r0 // set p9 to indicate that we should restore cr.ifs
974 ;;
975 ld8 r24=[r16],16 // load ar.rnat (may be garbage)
976 ld8 r23=[r17],16 // load ar.bspstore (may be garbage)
977 ;;
978 ld8 r31=[r16],16 // load predicates
979 ld8 r21=[r17],16 // load b0
980 ;;
981 ld8 r19=[r16],16 // load ar.rsc value for "loadrs"
982 ld8.fill r1=[r17],16 // load r1
983 ;;
984 ld8.fill r12=[r16],16
985 ld8.fill r13=[r17],16
986 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
987 (pUStk) adds r3=TI_AC_LEAVE+IA64_TASK_SIZE,r18
988 #else
989 (pUStk) adds r18=IA64_TASK_THREAD_ON_USTACK_OFFSET,r18
990 #endif
991 ;;
992 ld8 r20=[r16],16 // ar.fpsr
993 ld8.fill r15=[r17],16
994 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
995 (pUStk) adds r18=IA64_TASK_THREAD_ON_USTACK_OFFSET,r18 // deferred
996 #endif
997 ;;
998 ld8.fill r14=[r16],16
999 ld8.fill r2=[r17]
1000 (pUStk) mov r17=1
1001 ;;
1002 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
1003 // mmi_ : ld8 st1 shr;; mmi_ : st8 st1 shr;;
1004 // mib : mov add br -> mib : ld8 add br
1005 // bbb_ : br nop cover;; mbb_ : mov br cover;;
1006 //
1007 // no one require bsp in r16 if (pKStk) branch is selected.
1008 (pUStk) st8 [r3]=r22 // save time at leave
1009 (pUStk) st1 [r18]=r17 // restore current->thread.on_ustack
1010 shr.u r18=r19,16 // get byte size of existing "dirty" partition
1011 ;;
1012 ld8.fill r3=[r16] // deferred
1013 LOAD_PHYS_STACK_REG_SIZE(r17)
1014 (pKStk) br.cond.dpnt skip_rbs_switch
1015 mov r16=ar.bsp // get existing backing store pointer
1016 #else
1017 ld8.fill r3=[r16]
1018 (pUStk) st1 [r18]=r17 // restore current->thread.on_ustack
1019 shr.u r18=r19,16 // get byte size of existing "dirty" partition
1020 ;;
1021 mov r16=ar.bsp // get existing backing store pointer
1022 LOAD_PHYS_STACK_REG_SIZE(r17)
1023 (pKStk) br.cond.dpnt skip_rbs_switch
1024 #endif
1025
1026 /*
1027 * Restore user backing store.
1028 *
1029 * NOTE: alloc, loadrs, and cover can't be predicated.
1030 */
1031 (pNonSys) br.cond.dpnt dont_preserve_current_frame
1032 COVER // add current frame into dirty partition and set cr.ifs
1033 ;;
1034 mov r19=ar.bsp // get new backing store pointer
1035 rbs_switch:
1036 sub r16=r16,r18 // krbs = old bsp - size of dirty partition
1037 cmp.ne p9,p0=r0,r0 // clear p9 to skip restore of cr.ifs
1038 ;;
1039 sub r19=r19,r16 // calculate total byte size of dirty partition
1040 add r18=64,r18 // don't force in0-in7 into memory...
1041 ;;
1042 shl r19=r19,16 // shift size of dirty partition into loadrs position
1043 ;;
1044 dont_preserve_current_frame:
1045 /*
1046 * To prevent leaking bits between the kernel and user-space,
1047 * we must clear the stacked registers in the "invalid" partition here.
1048 * Not pretty, but at least it's fast (3.34 registers/cycle on Itanium,
1049 * 5 registers/cycle on McKinley).
1050 */
1051 # define pRecurse p6
1052 # define pReturn p7
1053 #ifdef CONFIG_ITANIUM
1054 # define Nregs 10
1055 #else
1056 # define Nregs 14
1057 #endif
1058 alloc loc0=ar.pfs,2,Nregs-2,2,0
1059 shr.u loc1=r18,9 // RNaTslots <= floor(dirtySize / (64*8))
1060 sub r17=r17,r18 // r17 = (physStackedSize + 8) - dirtySize
1061 ;;
1062 mov ar.rsc=r19 // load ar.rsc to be used for "loadrs"
1063 shladd in0=loc1,3,r17
1064 mov in1=0
1065 ;;
1066 TEXT_ALIGN(32)
1067 rse_clear_invalid:
1068 #ifdef CONFIG_ITANIUM
1069 // cycle 0
1070 { .mii
1071 alloc loc0=ar.pfs,2,Nregs-2,2,0
1072 cmp.lt pRecurse,p0=Nregs*8,in0 // if more than Nregs regs left to clear, (re)curse
1073 add out0=-Nregs*8,in0
1074 }{ .mfb
1075 add out1=1,in1 // increment recursion count
1076 nop.f 0
1077 nop.b 0 // can't do br.call here because of alloc (WAW on CFM)
1078 ;;
1079 }{ .mfi // cycle 1
1080 mov loc1=0
1081 nop.f 0
1082 mov loc2=0
1083 }{ .mib
1084 mov loc3=0
1085 mov loc4=0
1086 (pRecurse) br.call.sptk.many b0=rse_clear_invalid
1087
1088 }{ .mfi // cycle 2
1089 mov loc5=0
1090 nop.f 0
1091 cmp.ne pReturn,p0=r0,in1 // if recursion count != 0, we need to do a br.ret
1092 }{ .mib
1093 mov loc6=0
1094 mov loc7=0
1095 (pReturn) br.ret.sptk.many b0
1096 }
1097 #else /* !CONFIG_ITANIUM */
1098 alloc loc0=ar.pfs,2,Nregs-2,2,0
1099 cmp.lt pRecurse,p0=Nregs*8,in0 // if more than Nregs regs left to clear, (re)curse
1100 add out0=-Nregs*8,in0
1101 add out1=1,in1 // increment recursion count
1102 mov loc1=0
1103 mov loc2=0
1104 ;;
1105 mov loc3=0
1106 mov loc4=0
1107 mov loc5=0
1108 mov loc6=0
1109 mov loc7=0
1110 (pRecurse) br.call.dptk.few b0=rse_clear_invalid
1111 ;;
1112 mov loc8=0
1113 mov loc9=0
1114 cmp.ne pReturn,p0=r0,in1 // if recursion count != 0, we need to do a br.ret
1115 mov loc10=0
1116 mov loc11=0
1117 (pReturn) br.ret.dptk.many b0
1118 #endif /* !CONFIG_ITANIUM */
1119 # undef pRecurse
1120 # undef pReturn
1121 ;;
1122 alloc r17=ar.pfs,0,0,0,0 // drop current register frame
1123 ;;
1124 loadrs
1125 ;;
1126 skip_rbs_switch:
1127 mov ar.unat=r25 // M2
1128 (pKStk) extr.u r22=r22,21,1 // I0 extract current value of psr.pp from r22
1129 (pLvSys)mov r19=r0 // A clear r19 for leave_syscall, no-op otherwise
1130 ;;
1131 (pUStk) mov ar.bspstore=r23 // M2
1132 (pKStk) dep r29=r22,r29,21,1 // I0 update ipsr.pp with psr.pp
1133 (pLvSys)mov r16=r0 // A clear r16 for leave_syscall, no-op otherwise
1134 ;;
1135 MOV_TO_IPSR(p0, r29, r25) // M2
1136 mov ar.pfs=r26 // I0
1137 (pLvSys)mov r17=r0 // A clear r17 for leave_syscall, no-op otherwise
1138
1139 MOV_TO_IFS(p9, r30, r25)// M2
1140 mov b0=r21 // I0
1141 (pLvSys)mov r18=r0 // A clear r18 for leave_syscall, no-op otherwise
1142
1143 mov ar.fpsr=r20 // M2
1144 MOV_TO_IIP(r28, r25) // M2
1145 nop 0
1146 ;;
1147 (pUStk) mov ar.rnat=r24 // M2 must happen with RSE in lazy mode
1148 nop 0
1149 (pLvSys)mov r2=r0
1150
1151 mov ar.rsc=r27 // M2
1152 mov pr=r31,-1 // I0
1153 RFI // B
1154
1155 /*
1156 * On entry:
1157 * r20 = &current->thread_info->pre_count (if CONFIG_PREEMPT)
1158 * r31 = current->thread_info->flags
1159 * On exit:
1160 * p6 = TRUE if work-pending-check needs to be redone
1161 *
1162 * Interrupts are disabled on entry, reenabled depend on work, and
1163 * disabled on exit.
1164 */
1165 .work_pending_syscall:
1166 add r2=-8,r2
1167 add r3=-8,r3
1168 ;;
1169 st8 [r2]=r8
1170 st8 [r3]=r10
1171 .work_pending:
1172 tbit.z p6,p0=r31,TIF_NEED_RESCHED // is resched not needed?
1173 (p6) br.cond.sptk.few .notify
1174 #ifdef CONFIG_PREEMPT
1175 (pKStk) dep r21=-1,r0,PREEMPT_ACTIVE_BIT,1
1176 ;;
1177 (pKStk) st4 [r20]=r21
1178 #endif
1179 SSM_PSR_I(p0, p6, r2) // enable interrupts
1180 br.call.spnt.many rp=schedule
1181 .ret9: cmp.eq p6,p0=r0,r0 // p6 <- 1 (re-check)
1182 RSM_PSR_I(p0, r2, r20) // disable interrupts
1183 ;;
1184 #ifdef CONFIG_PREEMPT
1185 (pKStk) adds r20=TI_PRE_COUNT+IA64_TASK_SIZE,r13
1186 ;;
1187 (pKStk) st4 [r20]=r0 // preempt_count() <- 0
1188 #endif
1189 (pLvSys)br.cond.sptk.few __paravirt_pending_syscall_end
1190 br.cond.sptk.many .work_processed_kernel
1191
1192 .notify:
1193 (pUStk) br.call.spnt.many rp=notify_resume_user
1194 .ret10: cmp.ne p6,p0=r0,r0 // p6 <- 0 (don't re-check)
1195 (pLvSys)br.cond.sptk.few __paravirt_pending_syscall_end
1196 br.cond.sptk.many .work_processed_kernel
1197
1198 .global __paravirt_pending_syscall_end;
1199 __paravirt_pending_syscall_end:
1200 adds r2=PT(R8)+16,r12
1201 adds r3=PT(R10)+16,r12
1202 ;;
1203 ld8 r8=[r2]
1204 ld8 r10=[r3]
1205 br.cond.sptk.many __paravirt_work_processed_syscall_target
1206 END(__paravirt_leave_kernel)
1207
1208 #ifdef __IA64_ASM_PARAVIRTUALIZED_NATIVE
1209 ENTRY(handle_syscall_error)
1210 /*
1211 * Some system calls (e.g., ptrace, mmap) can return arbitrary values which could
1212 * lead us to mistake a negative return value as a failed syscall. Those syscall
1213 * must deposit a non-zero value in pt_regs.r8 to indicate an error. If
1214 * pt_regs.r8 is zero, we assume that the call completed successfully.
1215 */
1216 PT_REGS_UNWIND_INFO(0)
1217 ld8 r3=[r2] // load pt_regs.r8
1218 ;;
1219 cmp.eq p6,p7=r3,r0 // is pt_regs.r8==0?
1220 ;;
1221 (p7) mov r10=-1
1222 (p7) sub r8=0,r8 // negate return value to get errno
1223 br.cond.sptk ia64_leave_syscall
1224 END(handle_syscall_error)
1225
1226 /*
1227 * Invoke schedule_tail(task) while preserving in0-in7, which may be needed
1228 * in case a system call gets restarted.
1229 */
1230 GLOBAL_ENTRY(ia64_invoke_schedule_tail)
1231 .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
1232 alloc loc1=ar.pfs,8,2,1,0
1233 mov loc0=rp
1234 mov out0=r8 // Address of previous task
1235 ;;
1236 br.call.sptk.many rp=schedule_tail
1237 .ret11: mov ar.pfs=loc1
1238 mov rp=loc0
1239 br.ret.sptk.many rp
1240 END(ia64_invoke_schedule_tail)
1241
1242 /*
1243 * Setup stack and call do_notify_resume_user(), keeping interrupts
1244 * disabled.
1245 *
1246 * Note that pSys and pNonSys need to be set up by the caller.
1247 * We declare 8 input registers so the system call args get preserved,
1248 * in case we need to restart a system call.
1249 */
1250 GLOBAL_ENTRY(notify_resume_user)
1251 .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
1252 alloc loc1=ar.pfs,8,2,3,0 // preserve all eight input regs in case of syscall restart!
1253 mov r9=ar.unat
1254 mov loc0=rp // save return address
1255 mov out0=0 // there is no "oldset"
1256 adds out1=8,sp // out1=&sigscratch->ar_pfs
1257 (pSys) mov out2=1 // out2==1 => we're in a syscall
1258 ;;
1259 (pNonSys) mov out2=0 // out2==0 => not a syscall
1260 .fframe 16
1261 .spillsp ar.unat, 16
1262 st8 [sp]=r9,-16 // allocate space for ar.unat and save it
1263 st8 [out1]=loc1,-8 // save ar.pfs, out1=&sigscratch
1264 .body
1265 br.call.sptk.many rp=do_notify_resume_user
1266 .ret15: .restore sp
1267 adds sp=16,sp // pop scratch stack space
1268 ;;
1269 ld8 r9=[sp] // load new unat from sigscratch->scratch_unat
1270 mov rp=loc0
1271 ;;
1272 mov ar.unat=r9
1273 mov ar.pfs=loc1
1274 br.ret.sptk.many rp
1275 END(notify_resume_user)
1276
1277 ENTRY(sys_rt_sigreturn)
1278 PT_REGS_UNWIND_INFO(0)
1279 /*
1280 * Allocate 8 input registers since ptrace() may clobber them
1281 */
1282 alloc r2=ar.pfs,8,0,1,0
1283 .prologue
1284 PT_REGS_SAVES(16)
1285 adds sp=-16,sp
1286 .body
1287 cmp.eq pNonSys,pSys=r0,r0 // sigreturn isn't a normal syscall...
1288 ;;
1289 /*
1290 * leave_kernel() restores f6-f11 from pt_regs, but since the streamlined
1291 * syscall-entry path does not save them we save them here instead. Note: we
1292 * don't need to save any other registers that are not saved by the stream-lined
1293 * syscall path, because restore_sigcontext() restores them.
1294 */
1295 adds r16=PT(F6)+32,sp
1296 adds r17=PT(F7)+32,sp
1297 ;;
1298 stf.spill [r16]=f6,32
1299 stf.spill [r17]=f7,32
1300 ;;
1301 stf.spill [r16]=f8,32
1302 stf.spill [r17]=f9,32
1303 ;;
1304 stf.spill [r16]=f10
1305 stf.spill [r17]=f11
1306 adds out0=16,sp // out0 = &sigscratch
1307 br.call.sptk.many rp=ia64_rt_sigreturn
1308 .ret19: .restore sp,0
1309 adds sp=16,sp
1310 ;;
1311 ld8 r9=[sp] // load new ar.unat
1312 mov.sptk b7=r8,ia64_native_leave_kernel
1313 ;;
1314 mov ar.unat=r9
1315 br.many b7
1316 END(sys_rt_sigreturn)
1317
1318 GLOBAL_ENTRY(ia64_prepare_handle_unaligned)
1319 .prologue
1320 /*
1321 * r16 = fake ar.pfs, we simply need to make sure privilege is still 0
1322 */
1323 mov r16=r0
1324 DO_SAVE_SWITCH_STACK
1325 br.call.sptk.many rp=ia64_handle_unaligned // stack frame setup in ivt
1326 .ret21: .body
1327 DO_LOAD_SWITCH_STACK
1328 br.cond.sptk.many rp // goes to ia64_leave_kernel
1329 END(ia64_prepare_handle_unaligned)
1330
1331 //
1332 // unw_init_running(void (*callback)(info, arg), void *arg)
1333 //
1334 # define EXTRA_FRAME_SIZE ((UNW_FRAME_INFO_SIZE+15)&~15)
1335
1336 GLOBAL_ENTRY(unw_init_running)
1337 .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(2)
1338 alloc loc1=ar.pfs,2,3,3,0
1339 ;;
1340 ld8 loc2=[in0],8
1341 mov loc0=rp
1342 mov r16=loc1
1343 DO_SAVE_SWITCH_STACK
1344 .body
1345
1346 .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(2)
1347 .fframe IA64_SWITCH_STACK_SIZE+EXTRA_FRAME_SIZE
1348 SWITCH_STACK_SAVES(EXTRA_FRAME_SIZE)
1349 adds sp=-EXTRA_FRAME_SIZE,sp
1350 .body
1351 ;;
1352 adds out0=16,sp // &info
1353 mov out1=r13 // current
1354 adds out2=16+EXTRA_FRAME_SIZE,sp // &switch_stack
1355 br.call.sptk.many rp=unw_init_frame_info
1356 1: adds out0=16,sp // &info
1357 mov b6=loc2
1358 mov loc2=gp // save gp across indirect function call
1359 ;;
1360 ld8 gp=[in0]
1361 mov out1=in1 // arg
1362 br.call.sptk.many rp=b6 // invoke the callback function
1363 1: mov gp=loc2 // restore gp
1364
1365 // For now, we don't allow changing registers from within
1366 // unw_init_running; if we ever want to allow that, we'd
1367 // have to do a load_switch_stack here:
1368 .restore sp
1369 adds sp=IA64_SWITCH_STACK_SIZE+EXTRA_FRAME_SIZE,sp
1370
1371 mov ar.pfs=loc1
1372 mov rp=loc0
1373 br.ret.sptk.many rp
1374 END(unw_init_running)
1375
1376 #ifdef CONFIG_FUNCTION_TRACER
1377 #ifdef CONFIG_DYNAMIC_FTRACE
1378 GLOBAL_ENTRY(_mcount)
1379 br ftrace_stub
1380 END(_mcount)
1381
1382 .here:
1383 br.ret.sptk.many b0
1384
1385 GLOBAL_ENTRY(ftrace_caller)
1386 alloc out0 = ar.pfs, 8, 0, 4, 0
1387 mov out3 = r0
1388 ;;
1389 mov out2 = b0
1390 add r3 = 0x20, r3
1391 mov out1 = r1;
1392 br.call.sptk.many b0 = ftrace_patch_gp
1393 //this might be called from module, so we must patch gp
1394 ftrace_patch_gp:
1395 movl gp=__gp
1396 mov b0 = r3
1397 ;;
1398 .global ftrace_call;
1399 ftrace_call:
1400 {
1401 .mlx
1402 nop.m 0x0
1403 movl r3 = .here;;
1404 }
1405 alloc loc0 = ar.pfs, 4, 4, 2, 0
1406 ;;
1407 mov loc1 = b0
1408 mov out0 = b0
1409 mov loc2 = r8
1410 mov loc3 = r15
1411 ;;
1412 adds out0 = -MCOUNT_INSN_SIZE, out0
1413 mov out1 = in2
1414 mov b6 = r3
1415
1416 br.call.sptk.many b0 = b6
1417 ;;
1418 mov ar.pfs = loc0
1419 mov b0 = loc1
1420 mov r8 = loc2
1421 mov r15 = loc3
1422 br ftrace_stub
1423 ;;
1424 END(ftrace_caller)
1425
1426 #else
1427 GLOBAL_ENTRY(_mcount)
1428 movl r2 = ftrace_stub
1429 movl r3 = ftrace_trace_function;;
1430 ld8 r3 = [r3];;
1431 ld8 r3 = [r3];;
1432 cmp.eq p7,p0 = r2, r3
1433 (p7) br.sptk.many ftrace_stub
1434 ;;
1435
1436 alloc loc0 = ar.pfs, 4, 4, 2, 0
1437 ;;
1438 mov loc1 = b0
1439 mov out0 = b0
1440 mov loc2 = r8
1441 mov loc3 = r15
1442 ;;
1443 adds out0 = -MCOUNT_INSN_SIZE, out0
1444 mov out1 = in2
1445 mov b6 = r3
1446
1447 br.call.sptk.many b0 = b6
1448 ;;
1449 mov ar.pfs = loc0
1450 mov b0 = loc1
1451 mov r8 = loc2
1452 mov r15 = loc3
1453 br ftrace_stub
1454 ;;
1455 END(_mcount)
1456 #endif
1457
1458 GLOBAL_ENTRY(ftrace_stub)
1459 mov r3 = b0
1460 movl r2 = _mcount_ret_helper
1461 ;;
1462 mov b6 = r2
1463 mov b7 = r3
1464 br.ret.sptk.many b6
1465
1466 _mcount_ret_helper:
1467 mov b0 = r42
1468 mov r1 = r41
1469 mov ar.pfs = r40
1470 br b7
1471 END(ftrace_stub)
1472
1473 #endif /* CONFIG_FUNCTION_TRACER */
1474
1475 .rodata
1476 .align 8
1477 .globl sys_call_table
1478 sys_call_table:
1479 data8 sys_ni_syscall // This must be sys_ni_syscall! See ivt.S.
1480 data8 sys_exit // 1025
1481 data8 sys_read
1482 data8 sys_write
1483 data8 sys_open
1484 data8 sys_close
1485 data8 sys_creat // 1030
1486 data8 sys_link
1487 data8 sys_unlink
1488 data8 ia64_execve
1489 data8 sys_chdir
1490 data8 sys_fchdir // 1035
1491 data8 sys_utimes
1492 data8 sys_mknod
1493 data8 sys_chmod
1494 data8 sys_chown
1495 data8 sys_lseek // 1040
1496 data8 sys_getpid
1497 data8 sys_getppid
1498 data8 sys_mount
1499 data8 sys_umount
1500 data8 sys_setuid // 1045
1501 data8 sys_getuid
1502 data8 sys_geteuid
1503 data8 sys_ptrace
1504 data8 sys_access
1505 data8 sys_sync // 1050
1506 data8 sys_fsync
1507 data8 sys_fdatasync
1508 data8 sys_kill
1509 data8 sys_rename
1510 data8 sys_mkdir // 1055
1511 data8 sys_rmdir
1512 data8 sys_dup
1513 data8 sys_ia64_pipe
1514 data8 sys_times
1515 data8 ia64_brk // 1060
1516 data8 sys_setgid
1517 data8 sys_getgid
1518 data8 sys_getegid
1519 data8 sys_acct
1520 data8 sys_ioctl // 1065
1521 data8 sys_fcntl
1522 data8 sys_umask
1523 data8 sys_chroot
1524 data8 sys_ustat
1525 data8 sys_dup2 // 1070
1526 data8 sys_setreuid
1527 data8 sys_setregid
1528 data8 sys_getresuid
1529 data8 sys_setresuid
1530 data8 sys_getresgid // 1075
1531 data8 sys_setresgid
1532 data8 sys_getgroups
1533 data8 sys_setgroups
1534 data8 sys_getpgid
1535 data8 sys_setpgid // 1080
1536 data8 sys_setsid
1537 data8 sys_getsid
1538 data8 sys_sethostname
1539 data8 sys_setrlimit
1540 data8 sys_getrlimit // 1085
1541 data8 sys_getrusage
1542 data8 sys_gettimeofday
1543 data8 sys_settimeofday
1544 data8 sys_select
1545 data8 sys_poll // 1090
1546 data8 sys_symlink
1547 data8 sys_readlink
1548 data8 sys_uselib
1549 data8 sys_swapon
1550 data8 sys_swapoff // 1095
1551 data8 sys_reboot
1552 data8 sys_truncate
1553 data8 sys_ftruncate
1554 data8 sys_fchmod
1555 data8 sys_fchown // 1100
1556 data8 ia64_getpriority
1557 data8 sys_setpriority
1558 data8 sys_statfs
1559 data8 sys_fstatfs
1560 data8 sys_gettid // 1105
1561 data8 sys_semget
1562 data8 sys_semop
1563 data8 sys_semctl
1564 data8 sys_msgget
1565 data8 sys_msgsnd // 1110
1566 data8 sys_msgrcv
1567 data8 sys_msgctl
1568 data8 sys_shmget
1569 data8 sys_shmat
1570 data8 sys_shmdt // 1115
1571 data8 sys_shmctl
1572 data8 sys_syslog
1573 data8 sys_setitimer
1574 data8 sys_getitimer
1575 data8 sys_ni_syscall // 1120 /* was: ia64_oldstat */
1576 data8 sys_ni_syscall /* was: ia64_oldlstat */
1577 data8 sys_ni_syscall /* was: ia64_oldfstat */
1578 data8 sys_vhangup
1579 data8 sys_lchown
1580 data8 sys_remap_file_pages // 1125
1581 data8 sys_wait4
1582 data8 sys_sysinfo
1583 data8 sys_clone
1584 data8 sys_setdomainname
1585 data8 sys_newuname // 1130
1586 data8 sys_adjtimex
1587 data8 sys_ni_syscall /* was: ia64_create_module */
1588 data8 sys_init_module
1589 data8 sys_delete_module
1590 data8 sys_ni_syscall // 1135 /* was: sys_get_kernel_syms */
1591 data8 sys_ni_syscall /* was: sys_query_module */
1592 data8 sys_quotactl
1593 data8 sys_bdflush
1594 data8 sys_sysfs
1595 data8 sys_personality // 1140
1596 data8 sys_ni_syscall // sys_afs_syscall
1597 data8 sys_setfsuid
1598 data8 sys_setfsgid
1599 data8 sys_getdents
1600 data8 sys_flock // 1145
1601 data8 sys_readv
1602 data8 sys_writev
1603 data8 sys_pread64
1604 data8 sys_pwrite64
1605 data8 sys_sysctl // 1150
1606 data8 sys_mmap
1607 data8 sys_munmap
1608 data8 sys_mlock
1609 data8 sys_mlockall
1610 data8 sys_mprotect // 1155
1611 data8 ia64_mremap
1612 data8 sys_msync
1613 data8 sys_munlock
1614 data8 sys_munlockall
1615 data8 sys_sched_getparam // 1160
1616 data8 sys_sched_setparam
1617 data8 sys_sched_getscheduler
1618 data8 sys_sched_setscheduler
1619 data8 sys_sched_yield
1620 data8 sys_sched_get_priority_max // 1165
1621 data8 sys_sched_get_priority_min
1622 data8 sys_sched_rr_get_interval
1623 data8 sys_nanosleep
1624 data8 sys_ni_syscall // old nfsservctl
1625 data8 sys_prctl // 1170
1626 data8 sys_getpagesize
1627 data8 sys_mmap2
1628 data8 sys_pciconfig_read
1629 data8 sys_pciconfig_write
1630 data8 sys_perfmonctl // 1175
1631 data8 sys_sigaltstack
1632 data8 sys_rt_sigaction
1633 data8 sys_rt_sigpending
1634 data8 sys_rt_sigprocmask
1635 data8 sys_rt_sigqueueinfo // 1180
1636 data8 sys_rt_sigreturn
1637 data8 sys_rt_sigsuspend
1638 data8 sys_rt_sigtimedwait
1639 data8 sys_getcwd
1640 data8 sys_capget // 1185
1641 data8 sys_capset
1642 data8 sys_sendfile64
1643 data8 sys_ni_syscall // sys_getpmsg (STREAMS)
1644 data8 sys_ni_syscall // sys_putpmsg (STREAMS)
1645 data8 sys_socket // 1190
1646 data8 sys_bind
1647 data8 sys_connect
1648 data8 sys_listen
1649 data8 sys_accept
1650 data8 sys_getsockname // 1195
1651 data8 sys_getpeername
1652 data8 sys_socketpair
1653 data8 sys_send
1654 data8 sys_sendto
1655 data8 sys_recv // 1200
1656 data8 sys_recvfrom
1657 data8 sys_shutdown
1658 data8 sys_setsockopt
1659 data8 sys_getsockopt
1660 data8 sys_sendmsg // 1205
1661 data8 sys_recvmsg
1662 data8 sys_pivot_root
1663 data8 sys_mincore
1664 data8 sys_madvise
1665 data8 sys_newstat // 1210
1666 data8 sys_newlstat
1667 data8 sys_newfstat
1668 data8 sys_clone2
1669 data8 sys_getdents64
1670 data8 sys_getunwind // 1215
1671 data8 sys_readahead
1672 data8 sys_setxattr
1673 data8 sys_lsetxattr
1674 data8 sys_fsetxattr
1675 data8 sys_getxattr // 1220
1676 data8 sys_lgetxattr
1677 data8 sys_fgetxattr
1678 data8 sys_listxattr
1679 data8 sys_llistxattr
1680 data8 sys_flistxattr // 1225
1681 data8 sys_removexattr
1682 data8 sys_lremovexattr
1683 data8 sys_fremovexattr
1684 data8 sys_tkill
1685 data8 sys_futex // 1230
1686 data8 sys_sched_setaffinity
1687 data8 sys_sched_getaffinity
1688 data8 sys_set_tid_address
1689 data8 sys_fadvise64_64
1690 data8 sys_tgkill // 1235
1691 data8 sys_exit_group
1692 data8 sys_lookup_dcookie
1693 data8 sys_io_setup
1694 data8 sys_io_destroy
1695 data8 sys_io_getevents // 1240
1696 data8 sys_io_submit
1697 data8 sys_io_cancel
1698 data8 sys_epoll_create
1699 data8 sys_epoll_ctl
1700 data8 sys_epoll_wait // 1245
1701 data8 sys_restart_syscall
1702 data8 sys_semtimedop
1703 data8 sys_timer_create
1704 data8 sys_timer_settime
1705 data8 sys_timer_gettime // 1250
1706 data8 sys_timer_getoverrun
1707 data8 sys_timer_delete
1708 data8 sys_clock_settime
1709 data8 sys_clock_gettime
1710 data8 sys_clock_getres // 1255
1711 data8 sys_clock_nanosleep
1712 data8 sys_fstatfs64
1713 data8 sys_statfs64
1714 data8 sys_mbind
1715 data8 sys_get_mempolicy // 1260
1716 data8 sys_set_mempolicy
1717 data8 sys_mq_open
1718 data8 sys_mq_unlink
1719 data8 sys_mq_timedsend
1720 data8 sys_mq_timedreceive // 1265
1721 data8 sys_mq_notify
1722 data8 sys_mq_getsetattr
1723 data8 sys_kexec_load
1724 data8 sys_ni_syscall // reserved for vserver
1725 data8 sys_waitid // 1270
1726 data8 sys_add_key
1727 data8 sys_request_key
1728 data8 sys_keyctl
1729 data8 sys_ioprio_set
1730 data8 sys_ioprio_get // 1275
1731 data8 sys_move_pages
1732 data8 sys_inotify_init
1733 data8 sys_inotify_add_watch
1734 data8 sys_inotify_rm_watch
1735 data8 sys_migrate_pages // 1280
1736 data8 sys_openat
1737 data8 sys_mkdirat
1738 data8 sys_mknodat
1739 data8 sys_fchownat
1740 data8 sys_futimesat // 1285
1741 data8 sys_newfstatat
1742 data8 sys_unlinkat
1743 data8 sys_renameat
1744 data8 sys_linkat
1745 data8 sys_symlinkat // 1290
1746 data8 sys_readlinkat
1747 data8 sys_fchmodat
1748 data8 sys_faccessat
1749 data8 sys_pselect6
1750 data8 sys_ppoll // 1295
1751 data8 sys_unshare
1752 data8 sys_splice
1753 data8 sys_set_robust_list
1754 data8 sys_get_robust_list
1755 data8 sys_sync_file_range // 1300
1756 data8 sys_tee
1757 data8 sys_vmsplice
1758 data8 sys_fallocate
1759 data8 sys_getcpu
1760 data8 sys_epoll_pwait // 1305
1761 data8 sys_utimensat
1762 data8 sys_signalfd
1763 data8 sys_ni_syscall
1764 data8 sys_eventfd
1765 data8 sys_timerfd_create // 1310
1766 data8 sys_timerfd_settime
1767 data8 sys_timerfd_gettime
1768 data8 sys_signalfd4
1769 data8 sys_eventfd2
1770 data8 sys_epoll_create1 // 1315
1771 data8 sys_dup3
1772 data8 sys_pipe2
1773 data8 sys_inotify_init1
1774 data8 sys_preadv
1775 data8 sys_pwritev // 1320
1776 data8 sys_rt_tgsigqueueinfo
1777 data8 sys_recvmmsg
1778 data8 sys_fanotify_init
1779 data8 sys_fanotify_mark
1780 data8 sys_prlimit64 // 1325
1781 data8 sys_name_to_handle_at
1782 data8 sys_open_by_handle_at
1783 data8 sys_clock_adjtime
1784 data8 sys_syncfs
1785 data8 sys_setns // 1330
1786 data8 sys_sendmmsg
1787 data8 sys_process_vm_readv
1788 data8 sys_process_vm_writev
1789 data8 sys_accept4
1790
1791 .org sys_call_table + 8*NR_syscalls // guard against failures to increase NR_syscalls
1792 #endif /* __IA64_ASM_PARAVIRTUALIZED_NATIVE */
ubuntu-bionic-kernel mirror