arch/m68k/fpsp040/x_unsupp.S

   1 |
   2 |       x_unsupp.sa 3.3 7/1/91
   3 |
   4 |       fpsp_unsupp --- FPSP handler for unsupported data type exception
   5 |
   6 | Trap vector #55       (See table 8-1 Mc68030 User's manual).
   7 | Invoked when the user program encounters a data format (packed) that
   8 | hardware does not support or a data type (denormalized numbers or un-
   9 | normalized numbers).
  10 | Normalizes denorms and unnorms, unpacks packed numbers then stores
  11 | them back into the machine to let the 040 finish the operation.
  12 |
  13 | Unsupp calls two routines:
  14 |       1. get_op -  gets the operand(s)
  15 |       2. res_func - restore the function back into the 040 or
  16 |                       if fmove.p fpm,<ea> then pack source (fpm)
  17 |                       and store in users memory <ea>.
  18 |
  19 |  Input: Long fsave stack frame
  20 |
  21 |
  22
  23 |               Copyright (C) Motorola, Inc. 1990
  24 |                       All Rights Reserved
  25 |
  26 |       For details on the license for this file, please see the
  27 |       file, README, in this same directory.
  28
  29 X_UNSUPP:       |idnt    2,1 | Motorola 040 Floating Point Software Package
  30
  31         |section        8
  32
  33 #include "fpsp.h"
  34
  35         |xref   get_op
  36         |xref   res_func
  37         |xref   gen_except
  38         |xref   fpsp_fmt_error
  39
  40         .global fpsp_unsupp
  41 fpsp_unsupp:
  42 |
  43         link            %a6,#-LOCAL_SIZE
  44         fsave           -(%a7)
  45         moveml          %d0-%d1/%a0-%a1,USER_DA(%a6)
  46         fmovemx %fp0-%fp3,USER_FP0(%a6)
  47         fmoveml %fpcr/%fpsr/%fpiar,USER_FPCR(%a6)
  48
  49
  50         moveb           (%a7),VER_TMP(%a6) |save version number
  51         moveb           (%a7),%d0               |test for valid version num
  52         andib           #0xf0,%d0               |test for $4x
  53         cmpib           #VER_4,%d0      |must be $4x or exit
  54         bnel            fpsp_fmt_error
  55
  56         fmovel          #0,%FPSR                |clear all user status bits
  57         fmovel          #0,%FPCR                |clear all user control bits
  58 |
  59 |       The following lines are used to ensure that the FPSR
  60 |       exception byte and condition codes are clear before proceeding,
  61 |       except in the case of fmove, which leaves the cc's intact.
  62 |
  63 unsupp_con:
  64         movel           USER_FPSR(%a6),%d1
  65         btst            #5,CMDREG1B(%a6)        |looking for fmove out
  66         bne             fmove_con
  67         andl            #0xFF00FF,%d1   |clear all but aexcs and qbyte
  68         bras            end_fix
  69 fmove_con:
  70         andl            #0x0FFF40FF,%d1 |clear all but cc's, snan bit, aexcs, and qbyte
  71 end_fix:
  72         movel           %d1,USER_FPSR(%a6)
  73
  74         st              UFLG_TMP(%a6)   |set flag for unsupp data
  75
  76         bsrl            get_op          |everything okay, go get operand(s)
  77         bsrl            res_func        |fix up stack frame so can restore it
  78         clrl            -(%a7)
  79         moveb           VER_TMP(%a6),(%a7) |move idle fmt word to top of stack
  80         bral            gen_except
  81 |
  82         |end