arch/m68k/kernel/vmlinux-std.lds

   1 /* ld script to make m68k Linux kernel */
   2
   3 #include <asm-generic/vmlinux.lds.h>
   4 #include <asm/page.h>
   5 #include <asm/thread_info.h>
   6
   7 OUTPUT_FORMAT("elf32-m68k", "elf32-m68k", "elf32-m68k")
   8 OUTPUT_ARCH(m68k)
   9 ENTRY(_start)
  10 jiffies = jiffies_64 + 4;
  11 SECTIONS
  12 {
  13   . = 0x1000;
  14   _text = .;                    /* Text and read-only data */
  15   .text : {
  16         HEAD_TEXT
  17         TEXT_TEXT
  18         SCHED_TEXT
  19         CPUIDLE_TEXT
  20         LOCK_TEXT
  21         *(.fixup)
  22         *(.gnu.warning)
  23         } :text = 0x4e75
  24
  25   _etext = .;                   /* End of text section */
  26
  27   EXCEPTION_TABLE(16)
  28
  29   _sdata = .;                   /* Start of data section */
  30
  31   RODATA
  32
  33   RW_DATA_SECTION(16, PAGE_SIZE, THREAD_SIZE)
  34
  35   BSS_SECTION(0, 0, 0)
  36
  37   _edata = .;                   /* End of data section */
  38
  39   /* will be freed after init */
  40   . = ALIGN(PAGE_SIZE);         /* Init code and data */
  41   __init_begin = .;
  42   INIT_TEXT_SECTION(PAGE_SIZE) :data
  43   INIT_DATA_SECTION(16)
  44   .m68k_fixup : {
  45         __start_fixup = .;
  46         *(.m68k_fixup)
  47         __stop_fixup = .;
  48   }
  49   NOTES
  50   .init_end : {
  51         /* This ALIGN be in a section so that _end is at the end of the
  52            load segment. */
  53         . = ALIGN(PAGE_SIZE);
  54         __init_end = .;
  55   }
  56
  57   _end = . ;
  58
  59   STABS_DEBUG
  60   .comment 0 : { *(.comment) }
  61
  62   /* Sections to be discarded */
  63   DISCARDS
  64 }