arch/mips/dec/int-handler.S

   1 /*
   2  * arch/mips/dec/int-handler.S
   3  *
   4  * Copyright (C) 1995, 1996, 1997 Paul M. Antoine and Harald Koerfgen
   5  * Copyright (C) 2000, 2001, 2002, 2003, 2005  Maciej W. Rozycki
   6  *
   7  * Written by Ralf Baechle and Andreas Busse, modified for DECstation
   8  * support by Paul Antoine and Harald Koerfgen.
   9  *
  10  * completly rewritten:
  11  * Copyright (C) 1998 Harald Koerfgen
  12  *
  13  * Rewritten extensively for controller-driven IRQ support
  14  * by Maciej W. Rozycki.
  15  */
  16 #include <linux/config.h>
  17
  18 #include <asm/addrspace.h>
  19 #include <asm/asm.h>
  20 #include <asm/mipsregs.h>
  21 #include <asm/regdef.h>
  22 #include <asm/stackframe.h>
  23
  24 #include <asm/dec/interrupts.h>
  25 #include <asm/dec/ioasic_addrs.h>
  26 #include <asm/dec/ioasic_ints.h>
  27 #include <asm/dec/kn01.h>
  28 #include <asm/dec/kn02.h>
  29 #include <asm/dec/kn02xa.h>
  30 #include <asm/dec/kn03.h>
  31
  32 #define KN02_CSR_BASE           CKSEG1ADDR(KN02_SLOT_BASE + KN02_CSR)
  33 #define KN02XA_IOASIC_BASE      CKSEG1ADDR(KN02XA_SLOT_BASE + IOASIC_IOCTL)
  34 #define KN03_IOASIC_BASE        CKSEG1ADDR(KN03_SLOT_BASE + IOASIC_IOCTL)
  35
  36                 .text
  37                 .set    noreorder
  38 /*
  39  * plat_irq_dispatch: Interrupt handler for DECstations
  40  *
  41  * We follow the model in the Indy interrupt code by David Miller, where he
  42  * says: a lot of complication here is taken away because:
  43  *
  44  * 1) We handle one interrupt and return, sitting in a loop
  45  *    and moving across all the pending IRQ bits in the cause
  46  *    register is _NOT_ the answer, the common case is one
  47  *    pending IRQ so optimize in that direction.
  48  *
  49  * 2) We need not check against bits in the status register
  50  *    IRQ mask, that would make this routine slow as hell.
  51  *
  52  * 3) Linux only thinks in terms of all IRQs on or all IRQs
  53  *    off, nothing in between like BSD spl() brain-damage.
  54  *
  55  * Furthermore, the IRQs on the DECstations look basically (barring
  56  * software IRQs which we don't use at all) like...
  57  *
  58  * DS2100/3100's, aka kn01, aka Pmax:
  59  *
  60  *      MIPS IRQ        Source
  61  *      --------        ------
  62  *             0        Software (ignored)
  63  *             1        Software (ignored)
  64  *             2        SCSI
  65  *             3        Lance Ethernet
  66  *             4        DZ11 serial
  67  *             5        RTC
  68  *             6        Memory Controller & Video
  69  *             7        FPU
  70  *
  71  * DS5000/200, aka kn02, aka 3max:
  72  *
  73  *      MIPS IRQ        Source
  74  *      --------        ------
  75  *             0        Software (ignored)
  76  *             1        Software (ignored)
  77  *             2        TurboChannel
  78  *             3        RTC
  79  *             4        Reserved
  80  *             5        Memory Controller
  81  *             6        Reserved
  82  *             7        FPU
  83  *
  84  * DS5000/1xx's, aka kn02ba, aka 3min:
  85  *
  86  *      MIPS IRQ        Source
  87  *      --------        ------
  88  *             0        Software (ignored)
  89  *             1        Software (ignored)
  90  *             2        TurboChannel Slot 0
  91  *             3        TurboChannel Slot 1
  92  *             4        TurboChannel Slot 2
  93  *             5        TurboChannel Slot 3 (ASIC)
  94  *             6        Halt button
  95  *             7        FPU/R4k timer
  96  *
  97  * DS5000/2x's, aka kn02ca, aka maxine:
  98  *
  99  *      MIPS IRQ        Source
 100  *      --------        ------
 101  *             0        Software (ignored)
 102  *             1        Software (ignored)
 103  *             2        Periodic Interrupt (100usec)
 104  *             3        RTC
 105  *             4        I/O write timeout
 106  *             5        TurboChannel (ASIC)
 107  *             6        Halt Keycode from Access.Bus keyboard (CTRL-ALT-ENTER)
 108  *             7        FPU/R4k timer
 109  *
 110  * DS5000/2xx's, aka kn03, aka 3maxplus:
 111  *
 112  *      MIPS IRQ        Source
 113  *      --------        ------
 114  *             0        Software (ignored)
 115  *             1        Software (ignored)
 116  *             2        System Board (ASIC)
 117  *             3        RTC
 118  *             4        Reserved
 119  *             5        Memory
 120  *             6        Halt Button
 121  *             7        FPU/R4k timer
 122  *
 123  * We handle the IRQ according to _our_ priority (see setup.c),
 124  * then we just return.  If multiple IRQs are pending then we will
 125  * just take another exception, big deal.
 126  */
 127                 .align  5
 128                 NESTED(plat_irq_dispatch, PT_SIZE, ra)
 129                 .set    noreorder
 130
 131                 /*
 132                  * Get pending Interrupts
 133                  */
 134                 mfc0    t0,CP0_CAUSE            # get pending interrupts
 135                 mfc0    t1,CP0_STATUS
 136 #ifdef CONFIG_32BIT
 137                 lw      t2,cpu_fpu_mask
 138 #endif
 139                 andi    t0,ST0_IM               # CAUSE.CE may be non-zero!
 140                 and     t0,t1                   # isolate allowed ones
 141
 142                 beqz    t0,spurious
 143
 144 #ifdef CONFIG_32BIT
 145                  and    t2,t0
 146                 bnez    t2,fpu                  # handle FPU immediately
 147 #endif
 148
 149                 /*
 150                  * Find irq with highest priority
 151                  */
 152                  PTR_LA t1,cpu_mask_nr_tbl
 153 1:              lw      t2,(t1)
 154                 nop
 155                 and     t2,t0
 156                 beqz    t2,1b
 157                  addu   t1,2*PTRSIZE            # delay slot
 158
 159                 /*
 160                  * Do the low-level stuff
 161                  */
 162                 lw      a0,(-PTRSIZE)(t1)
 163                 nop
 164                 bgez    a0,handle_it            # irq_nr >= 0?
 165                                                 # irq_nr < 0: it is an address
 166                  nop
 167                 jr      a0
 168                                                 # a trick to save a branch:
 169                  lui    t2,(KN03_IOASIC_BASE>>16)&0xffff
 170                                                 # upper part of IOASIC Address
 171
 172 /*
 173  * Handle "IRQ Controller" Interrupts
 174  * Masked Interrupts are still visible and have to be masked "by hand".
 175  */
 176                 FEXPORT(kn02_io_int)            # 3max
 177                 lui     t0,(KN02_CSR_BASE>>16)&0xffff
 178                                                 # get interrupt status and mask
 179                 lw      t0,(t0)
 180                 nop
 181                 andi    t1,t0,KN02_IRQ_ALL
 182                 b       1f
 183                  srl    t0,16                   # shift interrupt mask
 184
 185                 FEXPORT(kn02xa_io_int)          # 3min/maxine
 186                 lui     t2,(KN02XA_IOASIC_BASE>>16)&0xffff
 187                                                 # upper part of IOASIC Address
 188
 189                 FEXPORT(kn03_io_int)            # 3max+ (t2 loaded earlier)
 190                 lw      t0,IO_REG_SIR(t2)       # get status: IOASIC sir
 191                 lw      t1,IO_REG_SIMR(t2)      # get mask:   IOASIC simr
 192                 nop
 193
 194 1:              and     t0,t1                   # mask out allowed ones
 195
 196                 beqz    t0,spurious
 197
 198                 /*
 199                  * Find irq with highest priority
 200                  */
 201                  PTR_LA t1,asic_mask_nr_tbl
 202 2:              lw      t2,(t1)
 203                 nop
 204                 and     t2,t0
 205                 beq     zero,t2,2b
 206                  addu   t1,2*PTRSIZE            # delay slot
 207
 208                 /*
 209                  * Do the low-level stuff
 210                  */
 211                 lw      a0,%lo(-PTRSIZE)(t1)
 212                 nop
 213                 bgez    a0,handle_it            # irq_nr >= 0?
 214                                                 # irq_nr < 0: it is an address
 215                  nop
 216                 jr      a0
 217                  nop                            # delay slot
 218
 219 /*
 220  * Dispatch low-priority interrupts.  We reconsider all status
 221  * bits again, which looks like a lose, but it makes the code
 222  * simple and O(log n), so it gets compensated.
 223  */
 224                 FEXPORT(cpu_all_int)            # HALT, timers, software junk
 225                 li      a0,DEC_CPU_IRQ_BASE
 226                 srl     t0,CAUSEB_IP
 227                 li      t1,CAUSEF_IP>>CAUSEB_IP # mask
 228                 b       1f
 229                  li     t2,4                    # nr of bits / 2
 230
 231                 FEXPORT(kn02_all_int)           # impossible ?
 232                 li      a0,KN02_IRQ_BASE
 233                 li      t1,KN02_IRQ_ALL         # mask
 234                 b       1f
 235                  li     t2,4                    # nr of bits / 2
 236
 237                 FEXPORT(asic_all_int)           # various I/O ASIC junk
 238                 li      a0,IO_IRQ_BASE
 239                 li      t1,IO_IRQ_ALL           # mask
 240                 b       1f
 241                  li     t2,8                    # nr of bits / 2
 242
 243 /*
 244  * Dispatch DMA interrupts -- O(log n).
 245  */
 246                 FEXPORT(asic_dma_int)           # I/O ASIC DMA events
 247                 li      a0,IO_IRQ_BASE+IO_INR_DMA
 248                 srl     t0,IO_INR_DMA
 249                 li      t1,IO_IRQ_DMA>>IO_INR_DMA # mask
 250                 li      t2,8                    # nr of bits / 2
 251
 252                 /*
 253                  * Find irq with highest priority.
 254                  * Highest irq number takes precedence.
 255                  */
 256 1:              srlv    t3,t1,t2
 257 2:              xor     t1,t3
 258                 and     t3,t0,t1
 259                 beqz    t3,3f
 260                  nop
 261                 move    t0,t3
 262                 addu    a0,t2
 263 3:              srl     t2,1
 264                 bnez    t2,2b
 265                  srlv   t3,t1,t2
 266
 267 handle_it:
 268                 jal     do_IRQ
 269                  move   a1,sp
 270
 271                 j       ret_from_irq
 272                  nop
 273
 274 #ifdef CONFIG_32BIT
 275 fpu:
 276                 j       handle_fpe_int
 277                  nop
 278 #endif
 279
 280 spurious:
 281                 jal     spurious_interrupt
 282                  nop
 283                 j       ret_from_irq
 284                  nop
 285                 END(plat_irq_dispatch)
 286
 287 /*
 288  * Generic unimplemented interrupt routines -- cpu_mask_nr_tbl
 289  * and asic_mask_nr_tbl are initialized to point all interrupts here.
 290  * The tables are then filled in by machine-specific initialisation
 291  * in dec_setup().
 292  */
 293                 FEXPORT(dec_intr_unimplemented)
 294                 move    a1,t0                   # cheats way of printing an arg!
 295                 PANIC("Unimplemented cpu interrupt! CP0_CAUSE: 0x%08x");
 296
 297                 FEXPORT(asic_intr_unimplemented)
 298                 move    a1,t0                   # cheats way of printing an arg!
 299                 PANIC("Unimplemented asic interrupt! ASIC ISR: 0x%08x");