arch/mips/lib/strnlen_user.S

   1 /*
   2  * This file is subject to the terms and conditions of the GNU General Public
   3  * License.  See the file "COPYING" in the main directory of this archive
   4  * for more details.
   5  *
   6  * Copyright (c) 1996, 1998, 1999, 2004 by Ralf Baechle
   7  * Copyright (c) 1999 Silicon Graphics, Inc.
   8  */
   9 #include <asm/asm.h>
  10 #include <asm/asm-offsets.h>
  11 #include <asm/regdef.h>
  12
  13 #define EX(insn,reg,addr,handler)                       \
  14 9:      insn    reg, addr;                              \
  15         .section __ex_table,"a";                        \
  16         PTR     9b, handler;                            \
  17         .previous
  18
  19 /*
  20  * Return the size of a string including the ending NUL character up to a
  21  * maximum of a1 or 0 in case of error.
  22  *
  23  * Note: for performance reasons we deliberately accept that a user may
  24  *       make strlen_user and strnlen_user access the first few KSEG0
  25  *       bytes.  There's nothing secret there.  On 64-bit accessing beyond
  26  *       the maximum is a tad hairier ...
  27  */
  28         .macro __BUILD_STRNLEN_ASM func
  29 LEAF(__strnlen_\func\()_asm)
  30         LONG_L          v0, TI_ADDR_LIMIT($28)  # pointer ok?
  31         and             v0, a0
  32         bnez            v0, .Lfault\@
  33
  34 FEXPORT(__strnlen_\func\()_nocheck_asm)
  35         move            v0, a0
  36         PTR_ADDU        a1, a0                  # stop pointer
  37 1:
  38 #ifdef CONFIG_CPU_DADDI_WORKAROUNDS
  39         .set            noat
  40         li              AT, 1
  41 #endif
  42         beq             v0, a1, 1f              # limit reached?
  43 .ifeqs "\func", "kernel"
  44         EX(lb, t0, (v0), .Lfault\@)
  45 .else
  46         EX(lbe, t0, (v0), .Lfault\@)
  47 .endif
  48         .set            noreorder
  49         bnez            t0, 1b
  50 1:
  51 #ifndef CONFIG_CPU_DADDI_WORKAROUNDS
  52          PTR_ADDIU      v0, 1
  53 #else
  54          PTR_ADDU       v0, AT
  55         .set            at
  56 #endif
  57         .set            reorder
  58         PTR_SUBU        v0, a0
  59         jr              ra
  60         END(__strnlen_\func\()_asm)
  61
  62 .Lfault\@:
  63         move            v0, zero
  64         jr              ra
  65         .endm
  66
  67 #ifndef CONFIG_EVA
  68         /* Set aliases */
  69         .global __strnlen_user_asm
  70         .global __strnlen_user_nocheck_asm
  71         .set __strnlen_user_asm, __strnlen_kernel_asm
  72         .set __strnlen_user_nocheck_asm, __strnlen_kernel_nocheck_asm
  73 #endif
  74
  75 __BUILD_STRNLEN_ASM kernel
  76
  77 #ifdef CONFIG_EVA
  78
  79         .set push
  80         .set eva
  81 __BUILD_STRNLEN_ASM user
  82         .set pop
  83 #endif