arch/nios2/kernel/entry.S

   1 /*
   2  * linux/arch/nios2/kernel/entry.S
   3  *
   4  * Copyright (C) 2013-2014  Altera Corporation
   5  * Copyright (C) 2009, Wind River Systems Inc
   6  *
   7  * Implemented by fredrik.markstrom@gmail.com and ivarholmqvist@gmail.com
   8  *
   9  *  Copyright (C) 1999-2002, Greg Ungerer (gerg@snapgear.com)
  10  *  Copyright (C) 1998  D. Jeff Dionne <jeff@lineo.ca>,
  11  *                      Kenneth Albanowski <kjahds@kjahds.com>,
  12  *  Copyright (C) 2000  Lineo Inc. (www.lineo.com)
  13  *  Copyright (C) 2004  Microtronix Datacom Ltd.
  14  *
  15  * This file is subject to the terms and conditions of the GNU General Public
  16  * License.  See the file "COPYING" in the main directory of this archive
  17  * for more details.
  18  *
  19  * Linux/m68k support by Hamish Macdonald
  20  *
  21  * 68060 fixes by Jesper Skov
  22  * ColdFire support by Greg Ungerer (gerg@snapgear.com)
  23  * 5307 fixes by David W. Miller
  24  * linux 2.4 support David McCullough <davidm@snapgear.com>
  25  */
  26
  27 #include <linux/sys.h>
  28 #include <linux/linkage.h>
  29 #include <asm/asm-offsets.h>
  30 #include <asm/asm-macros.h>
  31 #include <asm/thread_info.h>
  32 #include <asm/errno.h>
  33 #include <asm/setup.h>
  34 #include <asm/entry.h>
  35 #include <asm/unistd.h>
  36 #include <asm/processor.h>
  37
  38 .macro GET_THREAD_INFO reg
  39 .if THREAD_SIZE & 0xffff0000
  40         andhi   \reg, sp, %hi(~(THREAD_SIZE-1))
  41 .else
  42         addi    \reg, r0, %lo(~(THREAD_SIZE-1))
  43         and     \reg, \reg, sp
  44 .endif
  45 .endm
  46
  47 .macro  kuser_cmpxchg_check
  48         /*
  49          * Make sure our user space atomic helper is restarted if it was
  50          * interrupted in a critical region.
  51          * ea-4 = address of interrupted insn (ea must be preserved).
  52          * sp = saved regs.
  53          * cmpxchg_ldw = first critical insn, cmpxchg_stw = last critical insn.
  54          * If ea <= cmpxchg_stw and ea > cmpxchg_ldw then saved EA is set to
  55          * cmpxchg_ldw + 4.
  56         */
  57         /* et = cmpxchg_stw + 4 */
  58         movui   et, (KUSER_BASE + 4 + (cmpxchg_stw - __kuser_helper_start))
  59         bgtu    ea, et, 1f
  60
  61         subi    et, et, (cmpxchg_stw - cmpxchg_ldw) /* et = cmpxchg_ldw + 4 */
  62         bltu    ea, et, 1f
  63         stw     et, PT_EA(sp)   /* fix up EA */
  64         mov     ea, et
  65 1:
  66 .endm
  67
  68 .section .rodata
  69 .align 4
  70 exception_table:
  71         .word unhandled_exception       /* 0 - Reset */
  72         .word unhandled_exception       /* 1 - Processor-only Reset */
  73         .word external_interrupt        /* 2 - Interrupt */
  74         .word handle_trap               /* 3 - Trap Instruction */
  75
  76         .word instruction_trap          /* 4 - Unimplemented instruction */
  77         .word handle_illegal            /* 5 - Illegal instruction */
  78         .word handle_unaligned          /* 6 - Misaligned data access */
  79         .word handle_unaligned          /* 7 - Misaligned destination address */
  80
  81         .word handle_diverror           /* 8 - Division error */
  82         .word protection_exception_ba   /* 9 - Supervisor-only instr. address */
  83         .word protection_exception_instr /* 10 - Supervisor only instruction */
  84         .word protection_exception_ba   /* 11 - Supervisor only data address */
  85
  86         .word unhandled_exception       /* 12 - Double TLB miss (data) */
  87         .word protection_exception_pte  /* 13 - TLB permission violation (x) */
  88         .word protection_exception_pte  /* 14 - TLB permission violation (r) */
  89         .word protection_exception_pte  /* 15 - TLB permission violation (w) */
  90
  91         .word unhandled_exception       /* 16 - MPU region violation */
  92
  93 trap_table:
  94         .word   handle_system_call      /* 0  */
  95         .word   instruction_trap        /* 1  */
  96         .word   instruction_trap        /* 2  */
  97         .word   instruction_trap        /* 3  */
  98         .word   instruction_trap        /* 4  */
  99         .word   instruction_trap        /* 5  */
 100         .word   instruction_trap        /* 6  */
 101         .word   instruction_trap        /* 7  */
 102         .word   instruction_trap        /* 8  */
 103         .word   instruction_trap        /* 9  */
 104         .word   instruction_trap        /* 10 */
 105         .word   instruction_trap        /* 11 */
 106         .word   instruction_trap        /* 12 */
 107         .word   instruction_trap        /* 13 */
 108         .word   instruction_trap        /* 14 */
 109         .word   instruction_trap        /* 15 */
 110         .word   instruction_trap        /* 16 */
 111         .word   instruction_trap        /* 17 */
 112         .word   instruction_trap        /* 18 */
 113         .word   instruction_trap        /* 19 */
 114         .word   instruction_trap        /* 20 */
 115         .word   instruction_trap        /* 21 */
 116         .word   instruction_trap        /* 22 */
 117         .word   instruction_trap        /* 23 */
 118         .word   instruction_trap        /* 24 */
 119         .word   instruction_trap        /* 25 */
 120         .word   instruction_trap        /* 26 */
 121         .word   instruction_trap        /* 27 */
 122         .word   instruction_trap        /* 28 */
 123         .word   instruction_trap        /* 29 */
 124         .word   instruction_trap        /* 30 */
 125         .word   handle_breakpoint       /* 31 */
 126
 127 .text
 128 .set noat
 129 .set nobreak
 130
 131 ENTRY(inthandler)
 132         SAVE_ALL
 133
 134         kuser_cmpxchg_check
 135
 136         /* Clear EH bit before we get a new excpetion in the kernel
 137          * and after we have saved it to the exception frame. This is done
 138          * whether it's trap, tlb-miss or interrupt. If we don't do this
 139          * estatus is not updated the next exception.
 140          */
 141         rdctl   r24, status
 142         movi    r9, %lo(~STATUS_EH)
 143         and     r24, r24, r9
 144         wrctl   status, r24
 145
 146         /* Read cause and vector and branch to the associated handler */
 147         mov     r4, sp
 148         rdctl   r5, exception
 149         movia   r9, exception_table
 150         add     r24, r9, r5
 151         ldw     r24, 0(r24)
 152         jmp     r24
 153
 154
 155 /***********************************************************************
 156  * Handle traps
 157  ***********************************************************************
 158  */
 159 ENTRY(handle_trap)
 160         ldw     r24, -4(ea)     /* instruction that caused the exception */
 161         srli    r24, r24, 4
 162         andi    r24, r24, 0x7c
 163         movia   r9,trap_table
 164         add     r24, r24, r9
 165         ldw     r24, 0(r24)
 166         jmp     r24
 167
 168
 169 /***********************************************************************
 170  * Handle system calls
 171  ***********************************************************************
 172  */
 173 ENTRY(handle_system_call)
 174         /* Enable interrupts */
 175         rdctl   r10, status
 176         ori     r10, r10, STATUS_PIE
 177         wrctl   status, r10
 178
 179         /* Reload registers destroyed by common code. */
 180         ldw     r4, PT_R4(sp)
 181         ldw     r5, PT_R5(sp)
 182
 183 local_restart:
 184         /* Check that the requested system call is within limits */
 185         movui   r1, __NR_syscalls
 186         bgeu    r2, r1, ret_invsyscall
 187         slli    r1, r2, 2
 188         movhi   r11, %hiadj(sys_call_table)
 189         add     r1, r1, r11
 190         ldw     r1, %lo(sys_call_table)(r1)
 191         beq     r1, r0, ret_invsyscall
 192
 193         /* Check if we are being traced */
 194         GET_THREAD_INFO r11
 195         ldw     r11,TI_FLAGS(r11)
 196         BTBNZ   r11,r11,TIF_SYSCALL_TRACE,traced_system_call
 197
 198         /* Execute the system call */
 199         callr   r1
 200
 201         /* If the syscall returns a negative result:
 202          *   Set r7 to 1 to indicate error,
 203          *   Negate r2 to get a positive error code
 204          * If the syscall returns zero or a positive value:
 205          *   Set r7 to 0.
 206          * The sigreturn system calls will skip the code below by
 207          * adding to register ra. To avoid destroying registers
 208          */
 209 translate_rc_and_ret:
 210         movi    r1, 0
 211         bge     r2, zero, 3f
 212         sub     r2, zero, r2
 213         movi    r1, 1
 214 3:
 215         stw     r2, PT_R2(sp)
 216         stw     r1, PT_R7(sp)
 217 end_translate_rc_and_ret:
 218
 219 ret_from_exception:
 220         ldw     r1, PT_ESTATUS(sp)
 221         /* if so, skip resched, signals */
 222         TSTBNZ  r1, r1, ESTATUS_EU, Luser_return
 223
 224 restore_all:
 225         rdctl   r10, status                     /* disable intrs */
 226         andi    r10, r10, %lo(~STATUS_PIE)
 227         wrctl   status, r10
 228         RESTORE_ALL
 229         eret
 230
 231         /* If the syscall number was invalid return ENOSYS */
 232 ret_invsyscall:
 233         movi    r2, -ENOSYS
 234         br      translate_rc_and_ret
 235
 236         /* This implements the same as above, except it calls
 237          * do_syscall_trace_enter and do_syscall_trace_exit before and after the
 238          * syscall in order for utilities like strace and gdb to work.
 239          */
 240 traced_system_call:
 241         SAVE_SWITCH_STACK
 242         call    do_syscall_trace_enter
 243         RESTORE_SWITCH_STACK
 244
 245         /* Create system call register arguments. The 5th and 6th
 246            arguments on stack are already in place at the beginning
 247            of pt_regs. */
 248         ldw     r2, PT_R2(sp)
 249         ldw     r4, PT_R4(sp)
 250         ldw     r5, PT_R5(sp)
 251         ldw     r6, PT_R6(sp)
 252         ldw     r7, PT_R7(sp)
 253
 254         /* Fetch the syscall function, we don't need to check the boundaries
 255          * since this is already done.
 256          */
 257         slli    r1, r2, 2
 258         movhi   r11,%hiadj(sys_call_table)
 259         add     r1, r1, r11
 260         ldw     r1, %lo(sys_call_table)(r1)
 261
 262         callr   r1
 263
 264         /* If the syscall returns a negative result:
 265          *   Set r7 to 1 to indicate error,
 266          *   Negate r2 to get a positive error code
 267          * If the syscall returns zero or a positive value:
 268          *   Set r7 to 0.
 269          * The sigreturn system calls will skip the code below by
 270          * adding to register ra. To avoid destroying registers
 271          */
 272 translate_rc_and_ret2:
 273         movi    r1, 0
 274         bge     r2, zero, 4f
 275         sub     r2, zero, r2
 276         movi    r1, 1
 277 4:
 278         stw     r2, PT_R2(sp)
 279         stw     r1, PT_R7(sp)
 280 end_translate_rc_and_ret2:
 281         SAVE_SWITCH_STACK
 282         call    do_syscall_trace_exit
 283         RESTORE_SWITCH_STACK
 284         br      ret_from_exception
 285
 286 Luser_return:
 287         GET_THREAD_INFO r11                     /* get thread_info pointer */
 288         ldw     r10, TI_FLAGS(r11)              /* get thread_info->flags */
 289         ANDI32  r11, r10, _TIF_WORK_MASK
 290         beq     r11, r0, restore_all            /* Nothing to do */
 291         BTBZ    r1, r10, TIF_NEED_RESCHED, Lsignal_return
 292
 293         /* Reschedule work */
 294         call    schedule
 295         br      ret_from_exception
 296
 297 Lsignal_return:
 298         ANDI32  r1, r10, _TIF_SIGPENDING | _TIF_NOTIFY_RESUME
 299         beq     r1, r0, restore_all
 300         mov     r4, sp                  /* pt_regs */
 301         SAVE_SWITCH_STACK
 302         call    do_notify_resume
 303         beq     r2, r0, no_work_pending
 304         RESTORE_SWITCH_STACK
 305         /* prepare restart syscall here without leaving kernel */
 306         ldw     r2, PT_R2(sp)   /* reload syscall number in r2 */
 307         ldw     r4, PT_R4(sp)   /* reload syscall arguments r4-r9 */
 308         ldw     r5, PT_R5(sp)
 309         ldw     r6, PT_R6(sp)
 310         ldw     r7, PT_R7(sp)
 311         ldw     r8, PT_R8(sp)
 312         ldw     r9, PT_R9(sp)
 313         br      local_restart   /* restart syscall */
 314
 315 no_work_pending:
 316         RESTORE_SWITCH_STACK
 317         br      ret_from_exception
 318
 319 /***********************************************************************
 320  * Handle external interrupts.
 321  ***********************************************************************
 322  */
 323 /*
 324  * This is the generic interrupt handler (for all hardware interrupt
 325  * sources). It figures out the vector number and calls the appropriate
 326  * interrupt service routine directly.
 327  */
 328 external_interrupt:
 329         rdctl   r12, ipending
 330         rdctl   r9, ienable
 331         and     r12, r12, r9
 332         /* skip if no interrupt is pending */
 333         beq     r12, r0, ret_from_interrupt
 334
 335         movi    r24, -1
 336         stw     r24, PT_ORIG_R2(sp)
 337
 338         /*
 339          * Process an external hardware interrupt.
 340          */
 341
 342         addi    ea, ea, -4      /* re-issue the interrupted instruction */
 343         stw     ea, PT_EA(sp)
 344 2:      movi    r4, %lo(-1)     /* Start from bit position 0,
 345                                         highest priority */
 346                                 /* This is the IRQ # for handler call */
 347 1:      andi    r10, r12, 1     /* Isolate bit we are interested in */
 348         srli    r12, r12, 1     /* shift count is costly without hardware
 349                                         multiplier */
 350         addi    r4, r4, 1
 351         beq     r10, r0, 1b
 352         mov     r5, sp          /* Setup pt_regs pointer for handler call */
 353         call    do_IRQ
 354         rdctl   r12, ipending   /* check again if irq still pending */
 355         rdctl   r9, ienable     /* Isolate possible interrupts */
 356         and     r12, r12, r9
 357         bne     r12, r0, 2b
 358         /* br   ret_from_interrupt */ /* fall through to ret_from_interrupt */
 359
 360 ENTRY(ret_from_interrupt)
 361         ldw     r1, PT_ESTATUS(sp)      /* check if returning to kernel */
 362         TSTBNZ  r1, r1, ESTATUS_EU, Luser_return
 363
 364 #ifdef CONFIG_PREEMPT
 365         GET_THREAD_INFO r1
 366         ldw     r4, TI_PREEMPT_COUNT(r1)
 367         bne     r4, r0, restore_all
 368
 369 need_resched:
 370         ldw     r4, TI_FLAGS(r1)                /* ? Need resched set */
 371         BTBZ    r10, r4, TIF_NEED_RESCHED, restore_all
 372         ldw     r4, PT_ESTATUS(sp)      /* ? Interrupts off */
 373         andi    r10, r4, ESTATUS_EPIE
 374         beq     r10, r0, restore_all
 375         movia   r4, PREEMPT_ACTIVE
 376         stw     r4, TI_PREEMPT_COUNT(r1)
 377         rdctl   r10, status             /* enable intrs again */
 378         ori     r10, r10 ,STATUS_PIE
 379         wrctl   status, r10
 380         PUSH    r1
 381         call    schedule
 382         POP     r1
 383         mov     r4, r0
 384         stw     r4, TI_PREEMPT_COUNT(r1)
 385         rdctl   r10, status             /* disable intrs */
 386         andi    r10, r10, %lo(~STATUS_PIE)
 387         wrctl   status, r10
 388         br      need_resched
 389 #else
 390         br      restore_all
 391 #endif
 392
 393 /***********************************************************************
 394  * A few syscall wrappers
 395  ***********************************************************************
 396  */
 397 /*
 398  * int clone(unsigned long clone_flags, unsigned long newsp,
 399  *              int __user * parent_tidptr, int __user * child_tidptr,
 400  *              int tls_val)
 401  */
 402 ENTRY(sys_clone)
 403         SAVE_SWITCH_STACK
 404         addi    sp, sp, -4
 405         stw     r7, 0(sp)       /* Pass 5th arg thru stack */
 406         mov     r7, r6          /* 4th arg is 3rd of clone() */
 407         mov     r6, zero        /* 3rd arg always 0 */
 408         call    do_fork
 409         addi    sp, sp, 4
 410         RESTORE_SWITCH_STACK
 411         ret
 412
 413 ENTRY(sys_rt_sigreturn)
 414         SAVE_SWITCH_STACK
 415         mov     r4, sp
 416         call    do_rt_sigreturn
 417         RESTORE_SWITCH_STACK
 418         addi    ra, ra, (end_translate_rc_and_ret - translate_rc_and_ret)
 419         ret
 420
 421 /***********************************************************************
 422  * A few other wrappers and stubs
 423  ***********************************************************************
 424  */
 425 protection_exception_pte:
 426         rdctl   r6, pteaddr
 427         slli    r6, r6, 10
 428         call    do_page_fault
 429         br      ret_from_exception
 430
 431 protection_exception_ba:
 432         rdctl   r6, badaddr
 433         call    do_page_fault
 434         br      ret_from_exception
 435
 436 protection_exception_instr:
 437         call    handle_supervisor_instr
 438         br      ret_from_exception
 439
 440 handle_breakpoint:
 441         call    breakpoint_c
 442         br      ret_from_exception
 443
 444 #ifdef CONFIG_NIOS2_ALIGNMENT_TRAP
 445 handle_unaligned:
 446         SAVE_SWITCH_STACK
 447         call    handle_unaligned_c
 448         RESTORE_SWITCH_STACK
 449         br      ret_from_exception
 450 #else
 451 handle_unaligned:
 452         call    handle_unaligned_c
 453         br      ret_from_exception
 454 #endif
 455
 456 handle_illegal:
 457         call    handle_illegal_c
 458         br      ret_from_exception
 459
 460 handle_diverror:
 461         call    handle_diverror_c
 462         br      ret_from_exception
 463
 464 /*
 465  * Beware - when entering resume, prev (the current task) is
 466  * in r4, next (the new task) is in r5, don't change these
 467  * registers.
 468  */
 469 ENTRY(resume)
 470
 471         rdctl   r7, status                      /* save thread status reg */
 472         stw     r7, TASK_THREAD + THREAD_KPSR(r4)
 473
 474         andi    r7, r7, %lo(~STATUS_PIE)        /* disable interrupts */
 475         wrctl   status, r7
 476
 477         SAVE_SWITCH_STACK
 478         stw     sp, TASK_THREAD + THREAD_KSP(r4)/* save kernel stack pointer */
 479         ldw     sp, TASK_THREAD + THREAD_KSP(r5)/* restore new thread stack */
 480         movia   r24, _current_thread            /* save thread */
 481         GET_THREAD_INFO r1
 482         stw     r1, 0(r24)
 483         RESTORE_SWITCH_STACK
 484
 485         ldw     r7, TASK_THREAD + THREAD_KPSR(r5)/* restore thread status reg */
 486         wrctl   status, r7
 487         ret
 488
 489 ENTRY(ret_from_fork)
 490         call    schedule_tail
 491         br      ret_from_exception
 492
 493 ENTRY(ret_from_kernel_thread)
 494         call    schedule_tail
 495         mov     r4,r17  /* arg */
 496         callr   r16     /* function */
 497         br      ret_from_exception
 498
 499 /*
 500  * Kernel user helpers.
 501  *
 502  * Each segment is 64-byte aligned and will be mapped to the <User space>.
 503  * New segments (if ever needed) must be added after the existing ones.
 504  * This mechanism should be used only for things that are really small and
 505  * justified, and not be abused freely.
 506  *
 507  */
 508
 509  /* Filling pads with undefined instructions. */
 510 .macro  kuser_pad sym size
 511         .if     ((. - \sym) & 3)
 512         .rept   (4 - (. - \sym) & 3)
 513         .byte   0
 514         .endr
 515         .endif
 516         .rept   ((\size - (. - \sym)) / 4)
 517         .word   0xdeadbeef
 518         .endr
 519 .endm
 520
 521         .align  6
 522         .globl  __kuser_helper_start
 523 __kuser_helper_start:
 524
 525 __kuser_helper_version:                         /* @ 0x1000 */
 526         .word   ((__kuser_helper_end - __kuser_helper_start) >> 6)
 527
 528 __kuser_cmpxchg:                                /* @ 0x1004 */
 529         /*
 530          * r4 pointer to exchange variable
 531          * r5 old value
 532          * r6 new value
 533          */
 534 cmpxchg_ldw:
 535         ldw     r2, 0(r4)                       /* load current value */
 536         sub     r2, r2, r5                      /* compare with old value */
 537         bne     r2, zero, cmpxchg_ret
 538
 539         /* We had a match, store the new value */
 540 cmpxchg_stw:
 541         stw     r6, 0(r4)
 542 cmpxchg_ret:
 543         ret
 544
 545         kuser_pad __kuser_cmpxchg, 64
 546
 547         .globl  __kuser_sigtramp
 548 __kuser_sigtramp:
 549         movi    r2, __NR_rt_sigreturn
 550         trap
 551
 552         kuser_pad __kuser_sigtramp, 64
 553
 554         .globl  __kuser_helper_end
 555 __kuser_helper_end: