arch/parisc/kernel/vmlinux.lds.S

   1 /*    Kernel link layout for various "sections"
   2  *
   3  *    Copyright (C) 1999-2003 Matthew Wilcox <willy at parisc-linux.org>
   4  *    Copyright (C) 2000-2003 Paul Bame <bame at parisc-linux.org>
   5  *    Copyright (C) 2000 John Marvin <jsm at parisc-linux.org>
   6  *    Copyright (C) 2000 Michael Ang <mang with subcarrier.org>
   7  *    Copyright (C) 2002 Randolph Chung <tausq with parisc-linux.org>
   8  *    Copyright (C) 2003 James Bottomley <jejb with parisc-linux.org>
   9  *    Copyright (C) 2006-2013 Helge Deller <deller@gmx.de>
  10  */
  11
  12 /*
  13  * Put page table entries (swapper_pg_dir) as the first thing in .bss. This
  14  * will ensure that it has .bss alignment (PAGE_SIZE).
  15  */
  16 #define BSS_FIRST_SECTIONS      *(.data..vm0.pmd) \
  17                                 *(.data..vm0.pgd) \
  18                                 *(.data..vm0.pte)
  19
  20 #include <asm-generic/vmlinux.lds.h>
  21
  22 /* needed for the processor specific cache alignment size */
  23 #include <asm/cache.h>
  24 #include <asm/page.h>
  25 #include <asm/asm-offsets.h>
  26 #include <asm/thread_info.h>
  27
  28 /* ld script to make hppa Linux kernel */
  29 #ifndef CONFIG_64BIT
  30 OUTPUT_FORMAT("elf32-hppa-linux")
  31 OUTPUT_ARCH(hppa)
  32 #else
  33 OUTPUT_FORMAT("elf64-hppa-linux")
  34 OUTPUT_ARCH(hppa:hppa2.0w)
  35 #endif
  36
  37 ENTRY(parisc_kernel_start)
  38 #ifndef CONFIG_64BIT
  39 jiffies = jiffies_64 + 4;
  40 #else
  41 jiffies = jiffies_64;
  42 #endif
  43 SECTIONS
  44 {
  45         . = KERNEL_BINARY_TEXT_START;
  46
  47         __init_begin = .;
  48         HEAD_TEXT_SECTION
  49         INIT_TEXT_SECTION(8)
  50
  51         . = ALIGN(PAGE_SIZE);
  52         INIT_DATA_SECTION(PAGE_SIZE)
  53         /* we have to discard exit text and such at runtime, not link time */
  54         .exit.text :
  55         {
  56                 EXIT_TEXT
  57         }
  58         .exit.data :
  59         {
  60                 EXIT_DATA
  61         }
  62         PERCPU_SECTION(8)
  63         . = ALIGN(HUGEPAGE_SIZE);
  64         __init_end = .;
  65         /* freed after init ends here */
  66
  67         _text = .;              /* Text and read-only data */
  68         _stext = .;
  69         .text ALIGN(PAGE_SIZE) : {
  70                 TEXT_TEXT
  71                 SCHED_TEXT
  72                 CPUIDLE_TEXT
  73                 LOCK_TEXT
  74                 KPROBES_TEXT
  75                 IRQENTRY_TEXT
  76                 SOFTIRQENTRY_TEXT
  77                 *(.text.do_softirq)
  78                 *(.text.sys_exit)
  79                 *(.text.do_sigaltstack)
  80                 *(.text.do_fork)
  81                 *(.text.*)
  82                 *(.fixup)
  83                 *(.lock.text)           /* out-of-line lock text */
  84                 *(.gnu.warning)
  85         }
  86         . = ALIGN(PAGE_SIZE);
  87         _etext = .;
  88         /* End of text section */
  89
  90         /* Start of data section */
  91         _sdata = .;
  92
  93         RO_DATA_SECTION(8)
  94
  95 #ifdef CONFIG_64BIT
  96         . = ALIGN(16);
  97         /* Linkage tables */
  98         .opd : {
  99                 *(.opd)
 100         } PROVIDE (__gp = .);
 101         .plt : {
 102                 *(.plt)
 103         }
 104         .dlt : {
 105                 *(.dlt)
 106         }
 107 #endif
 108
 109         /* unwind info */
 110         .PARISC.unwind : {
 111                 __start___unwind = .;
 112                 *(.PARISC.unwind)
 113                 __stop___unwind = .;
 114         }
 115
 116         /* writeable */
 117         /* Make sure this is page aligned so
 118          * that we can properly leave these
 119          * as writable
 120          */
 121         . = ALIGN(HUGEPAGE_SIZE);
 122         data_start = .;
 123
 124         EXCEPTION_TABLE(8)
 125         NOTES
 126
 127         /* Data */
 128         RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, PAGE_SIZE)
 129
 130         /* PA-RISC locks requires 16-byte alignment */
 131         . = ALIGN(16);
 132         .data..lock_aligned : {
 133                 *(.data..lock_aligned)
 134         }
 135
 136         /* End of data section */
 137         _edata = .;
 138
 139         /* BSS */
 140         BSS_SECTION(PAGE_SIZE, PAGE_SIZE, PAGE_SIZE)
 141
 142         . = ALIGN(HUGEPAGE_SIZE);
 143         _end = . ;
 144
 145         STABS_DEBUG
 146         .note 0 : { *(.note) }
 147
 148         /* Sections to be discarded */
 149         DISCARDS
 150         /DISCARD/ : {
 151 #ifdef CONFIG_64BIT
 152                 /* temporary hack until binutils is fixed to not emit these
 153                  * for static binaries
 154                  */
 155                 *(.interp)
 156                 *(.dynsym)
 157                 *(.dynstr)
 158                 *(.dynamic)
 159                 *(.hash)
 160                 *(.gnu.hash)
 161 #endif
 162         }
 163 }