arch/parisc/lib/fixup.S

   1 /*
   2  * Linux/PA-RISC Project (http://www.parisc-linux.org/)
   3  *
   4  *  Copyright (C) 2004  Randolph Chung <tausq@debian.org>
   5  *
   6  *    This program is free software; you can redistribute it and/or modify
   7  *    it under the terms of the GNU General Public License as published by
   8  *    the Free Software Foundation; either version 2, or (at your option)
   9  *    any later version.
  10  *
  11  *    This program is distributed in the hope that it will be useful,
  12  *    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  *    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  *    GNU General Public License for more details.
  15  *
  16  *    You should have received a copy of the GNU General Public License
  17  *    along with this program; if not, write to the Free Software
  18  *    Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  19  *
  20  * Fixup routines for kernel exception handling.
  21  */
  22 #include <asm/asm-offsets.h>
  23 #include <asm/assembly.h>
  24 #include <asm/errno.h>
  25 #include <linux/linkage.h>
  26 #include <linux/init.h>
  27
  28 #ifdef CONFIG_SMP
  29         .macro  get_fault_ip t1 t2
  30         addil LT%__per_cpu_offset,%r27
  31         LDREG RT%__per_cpu_offset(%r1),\t1
  32         /* t2 = smp_processor_id() */
  33         mfctl 30,\t2
  34         ldw TI_CPU(\t2),\t2
  35 #ifdef CONFIG_64BIT
  36         extrd,u \t2,63,32,\t2
  37 #endif
  38         /* t2 = &__per_cpu_offset[smp_processor_id()]; */
  39         LDREGX \t2(\t1),\t2
  40         addil LT%per_cpu__exception_data,%r27
  41         LDREG RT%per_cpu__exception_data(%r1),\t1
  42         /* t1 = &__get_cpu_var(exception_data) */
  43         add,l \t1,\t2,\t1
  44         /* t1 = t1->fault_ip */
  45         LDREG EXCDATA_IP(\t1), \t1
  46         .endm
  47 #else
  48         .macro  get_fault_ip t1 t2
  49         /* t1 = &__get_cpu_var(exception_data) */
  50         addil LT%per_cpu__exception_data,%r27
  51         LDREG RT%per_cpu__exception_data(%r1),\t2
  52         /* t1 = t2->fault_ip */
  53         LDREG EXCDATA_IP(\t2), \t1
  54         .endm
  55 #endif
  56
  57         .level LEVEL
  58
  59         __HEAD
  60         .section .fixup, "ax"
  61
  62         /* get_user() fixups, store -EFAULT in r8, and 0 in r9 */
  63 ENTRY(fixup_get_user_skip_1)
  64         get_fault_ip %r1,%r8
  65         ldo 4(%r1), %r1
  66         ldi -EFAULT, %r8
  67         bv %r0(%r1)
  68         copy %r0, %r9
  69 ENDPROC(fixup_get_user_skip_1)
  70
  71 ENTRY(fixup_get_user_skip_2)
  72         get_fault_ip %r1,%r8
  73         ldo 8(%r1), %r1
  74         ldi -EFAULT, %r8
  75         bv %r0(%r1)
  76         copy %r0, %r9
  77 ENDPROC(fixup_get_user_skip_2)
  78
  79         /* put_user() fixups, store -EFAULT in r8 */
  80 ENTRY(fixup_put_user_skip_1)
  81         get_fault_ip %r1,%r8
  82         ldo 4(%r1), %r1
  83         bv %r0(%r1)
  84         ldi -EFAULT, %r8
  85 ENDPROC(fixup_put_user_skip_1)
  86
  87 ENTRY(fixup_put_user_skip_2)
  88         get_fault_ip %r1,%r8
  89         ldo 8(%r1), %r1
  90         bv %r0(%r1)
  91         ldi -EFAULT, %r8
  92 ENDPROC(fixup_put_user_skip_2)
  93