arch/s390/kernel/vdso64/clock_gettime.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * Userland implementation of clock_gettime() for 64 bits processes in a
   4  * s390 kernel for use in the vDSO
   5  *
   6  *  Copyright IBM Corp. 2008
   7  *  Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com)
   8  *
   9  * This program is free software; you can redistribute it and/or modify
  10  * it under the terms of the GNU General Public License (version 2 only)
  11  * as published by the Free Software Foundation.
  12  */
  13 #include <asm/vdso.h>
  14 #include <asm/asm-offsets.h>
  15 #include <asm/unistd.h>
  16
  17         .text
  18         .align 4
  19         .globl __kernel_clock_gettime
  20         .type  __kernel_clock_gettime,@function
  21 __kernel_clock_gettime:
  22         .cfi_startproc
  23         aghi    %r15,-16
  24         larl    %r5,_vdso_data
  25         cghi    %r2,__CLOCK_REALTIME_COARSE
  26         je      4f
  27         cghi    %r2,__CLOCK_REALTIME
  28         je      5f
  29         cghi    %r2,-3          /* Per-thread CPUCLOCK with PID=0, VIRT=1 */
  30         je      9f
  31         cghi    %r2,__CLOCK_MONOTONIC_COARSE
  32         je      3f
  33         cghi    %r2,__CLOCK_MONOTONIC
  34         jne     12f
  35
  36         /* CLOCK_MONOTONIC */
  37 0:      lg      %r4,__VDSO_UPD_COUNT(%r5)       /* load update counter */
  38         tmll    %r4,0x0001                      /* pending update ? loop */
  39         jnz     0b
  40         stcke   0(%r15)                         /* Store TOD clock */
  41         lgf     %r2,__VDSO_TK_SHIFT(%r5)        /* Timekeeper shift */
  42         lg      %r0,__VDSO_WTOM_SEC(%r5)
  43         lg      %r1,1(%r15)
  44         sg      %r1,__VDSO_XTIME_STAMP(%r5)     /* TOD - cycle_last */
  45         msgf    %r1,__VDSO_TK_MULT(%r5)         /*  * tk->mult */
  46         alg     %r1,__VDSO_WTOM_NSEC(%r5)
  47         srlg    %r1,%r1,0(%r2)                  /*  >> tk->shift */
  48         clg     %r4,__VDSO_UPD_COUNT(%r5)       /* check update counter */
  49         jne     0b
  50         larl    %r5,13f
  51 1:      clg     %r1,0(%r5)
  52         jl      2f
  53         slg     %r1,0(%r5)
  54         aghi    %r0,1
  55         j       1b
  56 2:      stg     %r0,0(%r3)                      /* store tp->tv_sec */
  57         stg     %r1,8(%r3)                      /* store tp->tv_nsec */
  58         lghi    %r2,0
  59         aghi    %r15,16
  60         br      %r14
  61
  62         /* CLOCK_MONOTONIC_COARSE */
  63 3:      lg      %r4,__VDSO_UPD_COUNT(%r5)       /* load update counter */
  64         tmll    %r4,0x0001                      /* pending update ? loop */
  65         jnz     3b
  66         lg      %r0,__VDSO_WTOM_CRS_SEC(%r5)
  67         lg      %r1,__VDSO_WTOM_CRS_NSEC(%r5)
  68         clg     %r4,__VDSO_UPD_COUNT(%r5)       /* check update counter */
  69         jne     3b
  70         j       2b
  71
  72         /* CLOCK_REALTIME_COARSE */
  73 4:      lg      %r4,__VDSO_UPD_COUNT(%r5)       /* load update counter */
  74         tmll    %r4,0x0001                      /* pending update ? loop */
  75         jnz     4b
  76         lg      %r0,__VDSO_XTIME_CRS_SEC(%r5)
  77         lg      %r1,__VDSO_XTIME_CRS_NSEC(%r5)
  78         clg     %r4,__VDSO_UPD_COUNT(%r5)       /* check update counter */
  79         jne     4b
  80         j       7f
  81
  82         /* CLOCK_REALTIME */
  83 5:      lg      %r4,__VDSO_UPD_COUNT(%r5)       /* load update counter */
  84         tmll    %r4,0x0001                      /* pending update ? loop */
  85         jnz     5b
  86         stcke   0(%r15)                         /* Store TOD clock */
  87         lg      %r1,1(%r15)
  88         lg      %r0,__VDSO_TS_END(%r5)          /* TOD steering end time */
  89         slgr    %r0,%r1                         /* now - ts_steering_end */
  90         ltgr    %r0,%r0                         /* past end of steering ? */
  91         jm      17f
  92         srlg    %r0,%r0,15                      /* 1 per 2^16 */
  93         tm      __VDSO_TS_DIR+3(%r5),0x01       /* steering direction? */
  94         jz      18f
  95         lcgr    %r0,%r0                         /* negative TOD offset */
  96 18:     algr    %r1,%r0                         /* add steering offset */
  97 17:     lgf     %r2,__VDSO_TK_SHIFT(%r5)        /* Timekeeper shift */
  98         sg      %r1,__VDSO_XTIME_STAMP(%r5)     /* TOD - cycle_last */
  99         msgf    %r1,__VDSO_TK_MULT(%r5)         /*  * tk->mult */
 100         alg     %r1,__VDSO_XTIME_NSEC(%r5)      /*  + tk->xtime_nsec */
 101         srlg    %r1,%r1,0(%r2)                  /*  >> tk->shift */
 102         lg      %r0,__VDSO_XTIME_SEC(%r5)       /* tk->xtime_sec */
 103         clg     %r4,__VDSO_UPD_COUNT(%r5)       /* check update counter */
 104         jne     5b
 105         larl    %r5,13f
 106 6:      clg     %r1,0(%r5)
 107         jl      7f
 108         slg     %r1,0(%r5)
 109         aghi    %r0,1
 110         j       6b
 111 7:      stg     %r0,0(%r3)                      /* store tp->tv_sec */
 112         stg     %r1,8(%r3)                      /* store tp->tv_nsec */
 113         lghi    %r2,0
 114         aghi    %r15,16
 115         br      %r14
 116
 117         /* CPUCLOCK_VIRT for this thread */
 118 9:      lghi    %r4,0
 119         icm     %r0,15,__VDSO_ECTG_OK(%r5)
 120         jz      12f
 121         sacf    256                             /* Magic ectg instruction */
 122         .insn   ssf,0xc80100000000,__VDSO_ECTG_BASE(4),__VDSO_ECTG_USER(4),4
 123         sacf    0
 124         algr    %r1,%r0                         /* r1 = cputime as TOD value */
 125         mghi    %r1,1000                        /* convert to nanoseconds */
 126         srlg    %r1,%r1,12                      /* r1 = cputime in nanosec */
 127         lgr     %r4,%r1
 128         larl    %r5,13f
 129         srlg    %r1,%r1,9                       /* divide by 1000000000 */
 130         mlg     %r0,8(%r5)
 131         srlg    %r0,%r0,11                      /* r0 = tv_sec */
 132         stg     %r0,0(%r3)
 133         msg     %r0,0(%r5)                      /* calculate tv_nsec */
 134         slgr    %r4,%r0                         /* r4 = tv_nsec */
 135         stg     %r4,8(%r3)
 136         lghi    %r2,0
 137         aghi    %r15,16
 138         br      %r14
 139
 140         /* Fallback to system call */
 141 12:     lghi    %r1,__NR_clock_gettime
 142         svc     0
 143         aghi    %r15,16
 144         br      %r14
 145
 146 13:     .quad   1000000000
 147 14:     .quad   19342813113834067
 148         .cfi_endproc
 149         .size   __kernel_clock_gettime,.-__kernel_clock_gettime