arch/s390/kernel/vdso64/vdso64.lds.S

   1 /*
   2  * This is the infamous ld script for the 64 bits vdso
   3  * library
   4  */
   5
   6 #include <asm/page.h>
   7 #include <asm/vdso.h>
   8
   9 OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
  10 OUTPUT_ARCH(s390:64-bit)
  11 ENTRY(_start)
  12
  13 SECTIONS
  14 {
  15         . = VDSO64_LBASE + SIZEOF_HEADERS;
  16
  17         .hash           : { *(.hash) }                  :text
  18         .gnu.hash       : { *(.gnu.hash) }
  19         .dynsym         : { *(.dynsym) }
  20         .dynstr         : { *(.dynstr) }
  21         .gnu.version    : { *(.gnu.version) }
  22         .gnu.version_d  : { *(.gnu.version_d) }
  23         .gnu.version_r  : { *(.gnu.version_r) }
  24
  25         .note           : { *(.note.*) }                :text   :note
  26
  27         . = ALIGN(16);
  28         .text           : {
  29                 *(.text .stub .text.* .gnu.linkonce.t.*)
  30         } :text
  31         PROVIDE(__etext = .);
  32         PROVIDE(_etext = .);
  33         PROVIDE(etext = .);
  34
  35         /*
  36          * Other stuff is appended to the text segment:
  37          */
  38         .rodata         : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  39         .rodata1        : { *(.rodata1) }
  40
  41         .dynamic        : { *(.dynamic) }               :text   :dynamic
  42
  43         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  44         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  45         .gcc_except_table : { *(.gcc_except_table .gcc_except_table.*) }
  46
  47         .rela.dyn ALIGN(8) : { *(.rela.dyn) }
  48         .got ALIGN(8)   : { *(.got .toc) }
  49
  50         _end = .;
  51         PROVIDE(end = .);
  52
  53         /*
  54          * Stabs debugging sections are here too.
  55          */
  56         .stab          0 : { *(.stab) }
  57         .stabstr       0 : { *(.stabstr) }
  58         .stab.excl     0 : { *(.stab.excl) }
  59         .stab.exclstr  0 : { *(.stab.exclstr) }
  60         .stab.index    0 : { *(.stab.index) }
  61         .stab.indexstr 0 : { *(.stab.indexstr) }
  62         .comment       0 : { *(.comment) }
  63
  64         /*
  65          * DWARF debug sections.
  66          * Symbols in the DWARF debugging sections are relative to the
  67          * beginning of the section so we begin them at 0.
  68          */
  69         /* DWARF 1 */
  70         .debug          0 : { *(.debug) }
  71         .line           0 : { *(.line) }
  72         /* GNU DWARF 1 extensions */
  73         .debug_srcinfo  0 : { *(.debug_srcinfo) }
  74         .debug_sfnames  0 : { *(.debug_sfnames) }
  75         /* DWARF 1.1 and DWARF 2 */
  76         .debug_aranges  0 : { *(.debug_aranges) }
  77         .debug_pubnames 0 : { *(.debug_pubnames) }
  78         /* DWARF 2 */
  79         .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
  80         .debug_abbrev   0 : { *(.debug_abbrev) }
  81         .debug_line     0 : { *(.debug_line) }
  82         .debug_frame    0 : { *(.debug_frame) }
  83         .debug_str      0 : { *(.debug_str) }
  84         .debug_loc      0 : { *(.debug_loc) }
  85         .debug_macinfo  0 : { *(.debug_macinfo) }
  86         /* SGI/MIPS DWARF 2 extensions */
  87         .debug_weaknames 0 : { *(.debug_weaknames) }
  88         .debug_funcnames 0 : { *(.debug_funcnames) }
  89         .debug_typenames 0 : { *(.debug_typenames) }
  90         .debug_varnames  0 : { *(.debug_varnames) }
  91         /* DWARF 3 */
  92         .debug_pubtypes 0 : { *(.debug_pubtypes) }
  93         .debug_ranges   0 : { *(.debug_ranges) }
  94         .gnu.attributes 0 : { KEEP (*(.gnu.attributes)) }
  95
  96         . = ALIGN(PAGE_SIZE);
  97         PROVIDE(_vdso_data = .);
  98
  99         /DISCARD/       : {
 100                 *(.note.GNU-stack)
 101                 *(.branch_lt)
 102                 *(.data .data.* .gnu.linkonce.d.* .sdata*)
 103                 *(.bss .sbss .dynbss .dynsbss)
 104         }
 105 }
 106
 107 /*
 108  * Very old versions of ld do not recognize this name token; use the constant.
 109  */
 110 #define PT_GNU_EH_FRAME 0x6474e550
 111
 112 /*
 113  * We must supply the ELF program headers explicitly to get just one
 114  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 115  */
 116 PHDRS
 117 {
 118         text            PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
 119         dynamic         PT_DYNAMIC FLAGS(4);            /* PF_R */
 120         note            PT_NOTE FLAGS(4);               /* PF_R */
 121         eh_frame_hdr    PT_GNU_EH_FRAME;
 122 }
 123
 124 /*
 125  * This controls what symbols we export from the DSO.
 126  */
 127 VERSION
 128 {
 129         VDSO_VERSION_STRING {
 130         global:
 131                 /*
 132                  * Has to be there for the kernel to find
 133                  */
 134                 __kernel_gettimeofday;
 135                 __kernel_clock_gettime;
 136                 __kernel_clock_getres;
 137                 __kernel_getcpu;
 138
 139         local: *;
 140         };
 141 }