arch/sh/kernel/head.S

   1 /* $Id: head.S,v 1.7 2003/09/01 17:58:19 lethal Exp $
   2  *
   3  *  arch/sh/kernel/head.S
   4  *
   5  *  Copyright (C) 1999, 2000  Niibe Yutaka & Kaz Kojima
   6  *
   7  * This file is subject to the terms and conditions of the GNU General Public
   8  * License.  See the file "COPYING" in the main directory of this archive
   9  * for more details.
  10  *
  11  * Head.S contains the SH exception handlers and startup code.
  12  */
  13 #include <linux/linkage.h>
  14
  15         .section        .empty_zero_page, "aw"
  16 ENTRY(empty_zero_page)
  17         .long   1               /* MOUNT_ROOT_RDONLY */
  18         .long   0               /* RAMDISK_FLAGS */
  19         .long   0x0200          /* ORIG_ROOT_DEV */
  20         .long   1               /* LOADER_TYPE */
  21         .long   0x00360000      /* INITRD_START */
  22         .long   0x000a0000      /* INITRD_SIZE */
  23         .long   0
  24         .balign 4096,0,4096
  25
  26         .text
  27 /*
  28  * Condition at the entry of _stext:
  29  *
  30  *   BSC has already been initialized.
  31  *   INTC may or may not be initialized.
  32  *   VBR may or may not be initialized.
  33  *   MMU may or may not be initialized.
  34  *   Cache may or may not be initialized.
  35  *   Hardware (including on-chip modules) may or may not be initialized.
  36  *
  37  */
  38 ENTRY(_stext)
  39         !                       Initialize Status Register
  40         mov.l   1f, r0          ! MD=1, RB=0, BL=0, IMASK=0xF
  41         ldc     r0, sr
  42         !                       Initialize global interrupt mask
  43         mov     #0, r0
  44         ldc     r0, r6_bank
  45         !
  46         mov.l   2f, r0
  47         mov     r0, r15         ! Set initial r15 (stack pointer)
  48         mov     #0x20, r1       !
  49         shll8   r1              ! r1 = 8192
  50         sub     r1, r0          !
  51         ldc     r0, r7_bank     ! ... and initial thread_info
  52         !
  53         !                       Additional CPU initialization
  54         mov.l   6f, r0
  55         jsr     @r0
  56          nop
  57         !                       Clear BSS area
  58         mov.l   3f, r1
  59         add     #4, r1
  60         mov.l   4f, r2
  61         mov     #0, r0
  62 9:      cmp/hs  r2, r1
  63         bf/s    9b              ! while (r1 < r2)
  64          mov.l  r0,@-r2
  65         !                       Start kernel
  66         mov.l   5f, r0
  67         jmp     @r0
  68          nop
  69
  70         .balign 4
  71 1:      .long   0x400080F0              ! MD=1, RB=0, BL=0, FD=1, IMASK=0xF
  72 2:      .long   stack
  73 3:      .long   __bss_start
  74 4:      .long   _end
  75 5:      .long   start_kernel
  76 6:      .long   sh_cpu_init