arch/x86/boot/compressed/head_64.S

   1 /*
   2  *  linux/boot/head.S
   3  *
   4  *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
   5  */
   6
   7 /*
   8  *  head.S contains the 32-bit startup code.
   9  *
  10  * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
  11  * the page directory will exist. The startup code will be overwritten by
  12  * the page directory. [According to comments etc elsewhere on a compressed
  13  * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
  14  *
  15  * Page 0 is deliberately kept safe, since System Management Mode code in
  16  * laptops may need to access the BIOS data stored there.  This is also
  17  * useful for future device drivers that either access the BIOS via VM86
  18  * mode.
  19  */
  20
  21 /*
  22  * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
  23  */
  24 .code32
  25 .text
  26
  27 #include <linux/linkage.h>
  28 #include <asm/segment.h>
  29 #include <asm/pgtable.h>
  30 #include <asm/page.h>
  31 #include <asm/msr.h>
  32 #include <asm/asm-offsets.h>
  33
  34 .section ".text.head"
  35         .code32
  36         .globl startup_32
  37
  38 startup_32:
  39         cld
  40         /* test KEEP_SEGMENTS flag to see if the bootloader is asking
  41          * us to not reload segments */
  42         testb $(1<<6), BP_loadflags(%esi)
  43         jnz 1f
  44
  45         cli
  46         movl    $(__KERNEL_DS), %eax
  47         movl    %eax, %ds
  48         movl    %eax, %es
  49         movl    %eax, %ss
  50 1:
  51
  52 /* Calculate the delta between where we were compiled to run
  53  * at and where we were actually loaded at.  This can only be done
  54  * with a short local call on x86.  Nothing  else will tell us what
  55  * address we are running at.  The reserved chunk of the real-mode
  56  * data at 0x1e4 (defined as a scratch field) are used as the stack
  57  * for this calculation. Only 4 bytes are needed.
  58  */
  59         leal    (0x1e4+4)(%esi), %esp
  60         call    1f
  61 1:      popl    %ebp
  62         subl    $1b, %ebp
  63
  64 /* setup a stack and make sure cpu supports long mode. */
  65         movl    $user_stack_end, %eax
  66         addl    %ebp, %eax
  67         movl    %eax, %esp
  68
  69         call    verify_cpu
  70         testl   %eax, %eax
  71         jnz     no_longmode
  72
  73 /* Compute the delta between where we were compiled to run at
  74  * and where the code will actually run at.
  75  */
  76 /* %ebp contains the address we are loaded at by the boot loader and %ebx
  77  * contains the address where we should move the kernel image temporarily
  78  * for safe in-place decompression.
  79  */
  80
  81 #ifdef CONFIG_RELOCATABLE
  82         movl    %ebp, %ebx
  83         addl    $(PMD_PAGE_SIZE -1), %ebx
  84         andl    $PMD_PAGE_MASK, %ebx
  85 #else
  86         movl    $CONFIG_PHYSICAL_START, %ebx
  87 #endif
  88
  89         /* Replace the compressed data size with the uncompressed size */
  90         subl    input_len(%ebp), %ebx
  91         movl    output_len(%ebp), %eax
  92         addl    %eax, %ebx
  93         /* Add 8 bytes for every 32K input block */
  94         shrl    $12, %eax
  95         addl    %eax, %ebx
  96         /* Add 32K + 18 bytes of extra slack and align on a 4K boundary */
  97         addl    $(32768 + 18 + 4095), %ebx
  98         andl    $~4095, %ebx
  99
 100 /*
 101  * Prepare for entering 64 bit mode
 102  */
 103
 104         /* Load new GDT with the 64bit segments using 32bit descriptor */
 105         leal    gdt(%ebp), %eax
 106         movl    %eax, gdt+2(%ebp)
 107         lgdt    gdt(%ebp)
 108
 109         /* Enable PAE mode */
 110         xorl    %eax, %eax
 111         orl     $(1 << 5), %eax
 112         movl    %eax, %cr4
 113
 114  /*
 115   * Build early 4G boot pagetable
 116   */
 117         /* Initialize Page tables to 0*/
 118         leal    pgtable(%ebx), %edi
 119         xorl    %eax, %eax
 120         movl    $((4096*6)/4), %ecx
 121         rep     stosl
 122
 123         /* Build Level 4 */
 124         leal    pgtable + 0(%ebx), %edi
 125         leal    0x1007 (%edi), %eax
 126         movl    %eax, 0(%edi)
 127
 128         /* Build Level 3 */
 129         leal    pgtable + 0x1000(%ebx), %edi
 130         leal    0x1007(%edi), %eax
 131         movl    $4, %ecx
 132 1:      movl    %eax, 0x00(%edi)
 133         addl    $0x00001000, %eax
 134         addl    $8, %edi
 135         decl    %ecx
 136         jnz     1b
 137
 138         /* Build Level 2 */
 139         leal    pgtable + 0x2000(%ebx), %edi
 140         movl    $0x00000183, %eax
 141         movl    $2048, %ecx
 142 1:      movl    %eax, 0(%edi)
 143         addl    $0x00200000, %eax
 144         addl    $8, %edi
 145         decl    %ecx
 146         jnz     1b
 147
 148         /* Enable the boot page tables */
 149         leal    pgtable(%ebx), %eax
 150         movl    %eax, %cr3
 151
 152         /* Enable Long mode in EFER (Extended Feature Enable Register) */
 153         movl    $MSR_EFER, %ecx
 154         rdmsr
 155         btsl    $_EFER_LME, %eax
 156         wrmsr
 157
 158         /* Setup for the jump to 64bit mode
 159          *
 160          * When the jump is performend we will be in long mode but
 161          * in 32bit compatibility mode with EFER.LME = 1, CS.L = 0, CS.D = 1
 162          * (and in turn EFER.LMA = 1).  To jump into 64bit mode we use
 163          * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
 164          * We place all of the values on our mini stack so lret can
 165          * used to perform that far jump.
 166          */
 167         pushl   $__KERNEL_CS
 168         leal    startup_64(%ebp), %eax
 169         pushl   %eax
 170
 171         /* Enter paged protected Mode, activating Long Mode */
 172         movl    $0x80000001, %eax /* Enable Paging and Protected mode */
 173         movl    %eax, %cr0
 174
 175         /* Jump from 32bit compatibility mode into 64bit mode. */
 176         lret
 177
 178 no_longmode:
 179         /* This isn't an x86-64 CPU so hang */
 180 1:
 181         hlt
 182         jmp     1b
 183
 184 #include "../../kernel/verify_cpu_64.S"
 185
 186         /* Be careful here startup_64 needs to be at a predictable
 187          * address so I can export it in an ELF header.  Bootloaders
 188          * should look at the ELF header to find this address, as
 189          * it may change in the future.
 190          */
 191         .code64
 192         .org 0x200
 193 ENTRY(startup_64)
 194         /* We come here either from startup_32 or directly from a
 195          * 64bit bootloader.  If we come here from a bootloader we depend on
 196          * an identity mapped page table being provied that maps our
 197          * entire text+data+bss and hopefully all of memory.
 198          */
 199
 200         /* Setup data segments. */
 201         xorl    %eax, %eax
 202         movl    %eax, %ds
 203         movl    %eax, %es
 204         movl    %eax, %ss
 205         movl    %eax, %fs
 206         movl    %eax, %gs
 207         lldt    %ax
 208         movl    $0x20, %eax
 209         ltr     %ax
 210
 211         /* Compute the decompressed kernel start address.  It is where
 212          * we were loaded at aligned to a 2M boundary. %rbp contains the
 213          * decompressed kernel start address.
 214          *
 215          * If it is a relocatable kernel then decompress and run the kernel
 216          * from load address aligned to 2MB addr, otherwise decompress and
 217          * run the kernel from CONFIG_PHYSICAL_START
 218          */
 219
 220         /* Start with the delta to where the kernel will run at. */
 221 #ifdef CONFIG_RELOCATABLE
 222         leaq    startup_32(%rip) /* - $startup_32 */, %rbp
 223         addq    $(PMD_PAGE_SIZE - 1), %rbp
 224         andq    $PMD_PAGE_MASK, %rbp
 225         movq    %rbp, %rbx
 226 #else
 227         movq    $CONFIG_PHYSICAL_START, %rbp
 228         movq    %rbp, %rbx
 229 #endif
 230
 231         /* Replace the compressed data size with the uncompressed size */
 232         movl    input_len(%rip), %eax
 233         subq    %rax, %rbx
 234         movl    output_len(%rip), %eax
 235         addq    %rax, %rbx
 236         /* Add 8 bytes for every 32K input block */
 237         shrq    $12, %rax
 238         addq    %rax, %rbx
 239         /* Add 32K + 18 bytes of extra slack and align on a 4K boundary */
 240         addq    $(32768 + 18 + 4095), %rbx
 241         andq    $~4095, %rbx
 242
 243 /* Copy the compressed kernel to the end of our buffer
 244  * where decompression in place becomes safe.
 245  */
 246         leaq    _end(%rip), %r8
 247         leaq    _end(%rbx), %r9
 248         movq    $_end /* - $startup_32 */, %rcx
 249 1:      subq    $8, %r8
 250         subq    $8, %r9
 251         movq    0(%r8), %rax
 252         movq    %rax, 0(%r9)
 253         subq    $8, %rcx
 254         jnz     1b
 255
 256 /*
 257  * Jump to the relocated address.
 258  */
 259         leaq    relocated(%rbx), %rax
 260         jmp     *%rax
 261
 262 .section ".text"
 263 relocated:
 264
 265 /*
 266  * Clear BSS
 267  */
 268         xorq    %rax, %rax
 269         leaq    _edata(%rbx), %rdi
 270         leaq    _end(%rbx), %rcx
 271         subq    %rdi, %rcx
 272         cld
 273         rep
 274         stosb
 275
 276         /* Setup the stack */
 277         leaq    user_stack_end(%rip), %rsp
 278
 279         /* zero EFLAGS after setting rsp */
 280         pushq   $0
 281         popfq
 282
 283 /*
 284  * Do the decompression, and jump to the new kernel..
 285  */
 286         pushq   %rsi                    # Save the real mode argument
 287         movq    %rsi, %rdi              # real mode address
 288         leaq    _heap(%rip), %rsi       # _heap
 289         leaq    input_data(%rip), %rdx  # input_data
 290         movl    input_len(%rip), %eax
 291         movq    %rax, %rcx              # input_len
 292         movq    %rbp, %r8               # output
 293         call    decompress_kernel
 294         popq    %rsi
 295
 296
 297 /*
 298  * Jump to the decompressed kernel.
 299  */
 300         jmp     *%rbp
 301
 302         .data
 303 gdt:
 304         .word   gdt_end - gdt
 305         .long   gdt
 306         .word   0
 307         .quad   0x0000000000000000      /* NULL descriptor */
 308         .quad   0x00af9a000000ffff      /* __KERNEL_CS */
 309         .quad   0x00cf92000000ffff      /* __KERNEL_DS */
 310         .quad   0x0080890000000000      /* TS descriptor */
 311         .quad   0x0000000000000000      /* TS continued */
 312 gdt_end:
 313         .bss
 314 /* Stack for uncompression */
 315         .balign 4
 316 user_stack:
 317         .fill 4096,4,0
 318 user_stack_end: