arch/x86/kernel/entry_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  */
   5
   6 /*
   7  * entry.S contains the system-call and fault low-level handling routines.
   8  * This also contains the timer-interrupt handler, as well as all interrupts
   9  * and faults that can result in a task-switch.
  10  *
  11  * NOTE: This code handles signal-recognition, which happens every time
  12  * after a timer-interrupt and after each system call.
  13  *
  14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  15  * on a 486.
  16  *
  17  * Stack layout in 'syscall_exit':
  18  *      ptrace needs to have all regs on the stack.
  19  *      if the order here is changed, it needs to be
  20  *      updated in fork.c:copy_process, signal.c:do_signal,
  21  *      ptrace.c and ptrace.h
  22  *
  23  *       0(%esp) - %ebx
  24  *       4(%esp) - %ecx
  25  *       8(%esp) - %edx
  26  *       C(%esp) - %esi
  27  *      10(%esp) - %edi
  28  *      14(%esp) - %ebp
  29  *      18(%esp) - %eax
  30  *      1C(%esp) - %ds
  31  *      20(%esp) - %es
  32  *      24(%esp) - %fs
  33  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  34  *      2C(%esp) - orig_eax
  35  *      30(%esp) - %eip
  36  *      34(%esp) - %cs
  37  *      38(%esp) - %eflags
  38  *      3C(%esp) - %oldesp
  39  *      40(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <asm/thread_info.h>
  46 #include <asm/irqflags.h>
  47 #include <asm/errno.h>
  48 #include <asm/segment.h>
  49 #include <asm/smp.h>
  50 #include <asm/page_types.h>
  51 #include <asm/desc.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include <asm/processor-flags.h>
  55 #include <asm/ftrace.h>
  56 #include <asm/irq_vectors.h>
  57
  58 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  59 #include <linux/elf-em.h>
  60 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  61 #define __AUDIT_ARCH_LE    0x40000000
  62
  63 #ifndef CONFIG_AUDITSYSCALL
  64 #define sysenter_audit  syscall_trace_entry
  65 #define sysexit_audit   syscall_exit_work
  66 #endif
  67
  68 /*
  69  * We use macros for low-level operations which need to be overridden
  70  * for paravirtualization.  The following will never clobber any registers:
  71  *   INTERRUPT_RETURN (aka. "iret")
  72  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  73  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  74  *
  75  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  76  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  77  * Allowing a register to be clobbered can shrink the paravirt replacement
  78  * enough to patch inline, increasing performance.
  79  */
  80
  81 #define nr_syscalls ((syscall_table_size)/4)
  82
  83 #ifdef CONFIG_PREEMPT
  84 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  85 #else
  86 #define preempt_stop(clobbers)
  87 #define resume_kernel           restore_nocheck
  88 #endif
  89
  90 .macro TRACE_IRQS_IRET
  91 #ifdef CONFIG_TRACE_IRQFLAGS
  92         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
  93         jz 1f
  94         TRACE_IRQS_ON
  95 1:
  96 #endif
  97 .endm
  98
  99 #ifdef CONFIG_VM86
 100 #define resume_userspace_sig    check_userspace
 101 #else
 102 #define resume_userspace_sig    resume_userspace
 103 #endif
 104
 105 /*
 106  * User gs save/restore
 107  *
 108  * %gs is used for userland TLS and kernel only uses it for stack
 109  * canary which is required to be at %gs:20 by gcc.  Read the comment
 110  * at the top of stackprotector.h for more info.
 111  *
 112  * Local labels 98 and 99 are used.
 113  */
 114 #ifdef CONFIG_X86_32_LAZY_GS
 115
 116  /* unfortunately push/pop can't be no-op */
 117 .macro PUSH_GS
 118         pushl $0
 119         CFI_ADJUST_CFA_OFFSET 4
 120 .endm
 121 .macro POP_GS pop=0
 122         addl $(4 + \pop), %esp
 123         CFI_ADJUST_CFA_OFFSET -(4 + \pop)
 124 .endm
 125 .macro POP_GS_EX
 126 .endm
 127
 128  /* all the rest are no-op */
 129 .macro PTGS_TO_GS
 130 .endm
 131 .macro PTGS_TO_GS_EX
 132 .endm
 133 .macro GS_TO_REG reg
 134 .endm
 135 .macro REG_TO_PTGS reg
 136 .endm
 137 .macro SET_KERNEL_GS reg
 138 .endm
 139
 140 #else   /* CONFIG_X86_32_LAZY_GS */
 141
 142 .macro PUSH_GS
 143         pushl %gs
 144         CFI_ADJUST_CFA_OFFSET 4
 145         /*CFI_REL_OFFSET gs, 0*/
 146 .endm
 147
 148 .macro POP_GS pop=0
 149 98:     popl %gs
 150         CFI_ADJUST_CFA_OFFSET -4
 151         /*CFI_RESTORE gs*/
 152   .if \pop <> 0
 153         add $\pop, %esp
 154         CFI_ADJUST_CFA_OFFSET -\pop
 155   .endif
 156 .endm
 157 .macro POP_GS_EX
 158 .pushsection .fixup, "ax"
 159 99:     movl $0, (%esp)
 160         jmp 98b
 161 .section __ex_table, "a"
 162         .align 4
 163         .long 98b, 99b
 164 .popsection
 165 .endm
 166
 167 .macro PTGS_TO_GS
 168 98:     mov PT_GS(%esp), %gs
 169 .endm
 170 .macro PTGS_TO_GS_EX
 171 .pushsection .fixup, "ax"
 172 99:     movl $0, PT_GS(%esp)
 173         jmp 98b
 174 .section __ex_table, "a"
 175         .align 4
 176         .long 98b, 99b
 177 .popsection
 178 .endm
 179
 180 .macro GS_TO_REG reg
 181         movl %gs, \reg
 182         /*CFI_REGISTER gs, \reg*/
 183 .endm
 184 .macro REG_TO_PTGS reg
 185         movl \reg, PT_GS(%esp)
 186         /*CFI_REL_OFFSET gs, PT_GS*/
 187 .endm
 188 .macro SET_KERNEL_GS reg
 189         movl $(__KERNEL_STACK_CANARY), \reg
 190         movl \reg, %gs
 191 .endm
 192
 193 #endif  /* CONFIG_X86_32_LAZY_GS */
 194
 195 .macro SAVE_ALL
 196         cld
 197         PUSH_GS
 198         pushl %fs
 199         CFI_ADJUST_CFA_OFFSET 4
 200         /*CFI_REL_OFFSET fs, 0;*/
 201         pushl %es
 202         CFI_ADJUST_CFA_OFFSET 4
 203         /*CFI_REL_OFFSET es, 0;*/
 204         pushl %ds
 205         CFI_ADJUST_CFA_OFFSET 4
 206         /*CFI_REL_OFFSET ds, 0;*/
 207         pushl %eax
 208         CFI_ADJUST_CFA_OFFSET 4
 209         CFI_REL_OFFSET eax, 0
 210         pushl %ebp
 211         CFI_ADJUST_CFA_OFFSET 4
 212         CFI_REL_OFFSET ebp, 0
 213         pushl %edi
 214         CFI_ADJUST_CFA_OFFSET 4
 215         CFI_REL_OFFSET edi, 0
 216         pushl %esi
 217         CFI_ADJUST_CFA_OFFSET 4
 218         CFI_REL_OFFSET esi, 0
 219         pushl %edx
 220         CFI_ADJUST_CFA_OFFSET 4
 221         CFI_REL_OFFSET edx, 0
 222         pushl %ecx
 223         CFI_ADJUST_CFA_OFFSET 4
 224         CFI_REL_OFFSET ecx, 0
 225         pushl %ebx
 226         CFI_ADJUST_CFA_OFFSET 4
 227         CFI_REL_OFFSET ebx, 0
 228         movl $(__USER_DS), %edx
 229         movl %edx, %ds
 230         movl %edx, %es
 231         movl $(__KERNEL_PERCPU), %edx
 232         movl %edx, %fs
 233         SET_KERNEL_GS %edx
 234 .endm
 235
 236 .macro RESTORE_INT_REGS
 237         popl %ebx
 238         CFI_ADJUST_CFA_OFFSET -4
 239         CFI_RESTORE ebx
 240         popl %ecx
 241         CFI_ADJUST_CFA_OFFSET -4
 242         CFI_RESTORE ecx
 243         popl %edx
 244         CFI_ADJUST_CFA_OFFSET -4
 245         CFI_RESTORE edx
 246         popl %esi
 247         CFI_ADJUST_CFA_OFFSET -4
 248         CFI_RESTORE esi
 249         popl %edi
 250         CFI_ADJUST_CFA_OFFSET -4
 251         CFI_RESTORE edi
 252         popl %ebp
 253         CFI_ADJUST_CFA_OFFSET -4
 254         CFI_RESTORE ebp
 255         popl %eax
 256         CFI_ADJUST_CFA_OFFSET -4
 257         CFI_RESTORE eax
 258 .endm
 259
 260 .macro RESTORE_REGS pop=0
 261         RESTORE_INT_REGS
 262 1:      popl %ds
 263         CFI_ADJUST_CFA_OFFSET -4
 264         /*CFI_RESTORE ds;*/
 265 2:      popl %es
 266         CFI_ADJUST_CFA_OFFSET -4
 267         /*CFI_RESTORE es;*/
 268 3:      popl %fs
 269         CFI_ADJUST_CFA_OFFSET -4
 270         /*CFI_RESTORE fs;*/
 271         POP_GS \pop
 272 .pushsection .fixup, "ax"
 273 4:      movl $0, (%esp)
 274         jmp 1b
 275 5:      movl $0, (%esp)
 276         jmp 2b
 277 6:      movl $0, (%esp)
 278         jmp 3b
 279 .section __ex_table, "a"
 280         .align 4
 281         .long 1b, 4b
 282         .long 2b, 5b
 283         .long 3b, 6b
 284 .popsection
 285         POP_GS_EX
 286 .endm
 287
 288 .macro RING0_INT_FRAME
 289         CFI_STARTPROC simple
 290         CFI_SIGNAL_FRAME
 291         CFI_DEF_CFA esp, 3*4
 292         /*CFI_OFFSET cs, -2*4;*/
 293         CFI_OFFSET eip, -3*4
 294 .endm
 295
 296 .macro RING0_EC_FRAME
 297         CFI_STARTPROC simple
 298         CFI_SIGNAL_FRAME
 299         CFI_DEF_CFA esp, 4*4
 300         /*CFI_OFFSET cs, -2*4;*/
 301         CFI_OFFSET eip, -3*4
 302 .endm
 303
 304 .macro RING0_PTREGS_FRAME
 305         CFI_STARTPROC simple
 306         CFI_SIGNAL_FRAME
 307         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
 308         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
 309         CFI_OFFSET eip, PT_EIP-PT_OLDESP
 310         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
 311         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
 312         CFI_OFFSET eax, PT_EAX-PT_OLDESP
 313         CFI_OFFSET ebp, PT_EBP-PT_OLDESP
 314         CFI_OFFSET edi, PT_EDI-PT_OLDESP
 315         CFI_OFFSET esi, PT_ESI-PT_OLDESP
 316         CFI_OFFSET edx, PT_EDX-PT_OLDESP
 317         CFI_OFFSET ecx, PT_ECX-PT_OLDESP
 318         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 319 .endm
 320
 321 ENTRY(ret_from_fork)
 322         CFI_STARTPROC
 323         pushl %eax
 324         CFI_ADJUST_CFA_OFFSET 4
 325         call schedule_tail
 326         GET_THREAD_INFO(%ebp)
 327         popl %eax
 328         CFI_ADJUST_CFA_OFFSET -4
 329         pushl $0x0202                   # Reset kernel eflags
 330         CFI_ADJUST_CFA_OFFSET 4
 331         popfl
 332         CFI_ADJUST_CFA_OFFSET -4
 333         jmp syscall_exit
 334         CFI_ENDPROC
 335 END(ret_from_fork)
 336
 337 /*
 338  * Return to user mode is not as complex as all this looks,
 339  * but we want the default path for a system call return to
 340  * go as quickly as possible which is why some of this is
 341  * less clear than it otherwise should be.
 342  */
 343
 344         # userspace resumption stub bypassing syscall exit tracing
 345         ALIGN
 346         RING0_PTREGS_FRAME
 347 ret_from_exception:
 348         preempt_stop(CLBR_ANY)
 349 ret_from_intr:
 350         GET_THREAD_INFO(%ebp)
 351 check_userspace:
 352         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 353         movb PT_CS(%esp), %al
 354         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 355         cmpl $USER_RPL, %eax
 356         jb resume_kernel                # not returning to v8086 or userspace
 357
 358 ENTRY(resume_userspace)
 359         LOCKDEP_SYS_EXIT
 360         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 361                                         # setting need_resched or sigpending
 362                                         # between sampling and the iret
 363         TRACE_IRQS_OFF
 364         movl TI_flags(%ebp), %ecx
 365         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 366                                         # int/exception return?
 367         jne work_pending
 368         jmp restore_all
 369 END(ret_from_exception)
 370
 371 #ifdef CONFIG_PREEMPT
 372 ENTRY(resume_kernel)
 373         DISABLE_INTERRUPTS(CLBR_ANY)
 374         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 375         jnz restore_nocheck
 376 need_resched:
 377         movl TI_flags(%ebp), %ecx       # need_resched set ?
 378         testb $_TIF_NEED_RESCHED, %cl
 379         jz restore_all
 380         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
 381         jz restore_all
 382         call preempt_schedule_irq
 383         jmp need_resched
 384 END(resume_kernel)
 385 #endif
 386         CFI_ENDPROC
 387
 388 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 389    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 390
 391         # sysenter call handler stub
 392 ENTRY(ia32_sysenter_target)
 393         CFI_STARTPROC simple
 394         CFI_SIGNAL_FRAME
 395         CFI_DEF_CFA esp, 0
 396         CFI_REGISTER esp, ebp
 397         movl TSS_sysenter_sp0(%esp),%esp
 398 sysenter_past_esp:
 399         /*
 400          * Interrupts are disabled here, but we can't trace it until
 401          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 402          * we immediately enable interrupts at that point anyway.
 403          */
 404         pushl $(__USER_DS)
 405         CFI_ADJUST_CFA_OFFSET 4
 406         /*CFI_REL_OFFSET ss, 0*/
 407         pushl %ebp
 408         CFI_ADJUST_CFA_OFFSET 4
 409         CFI_REL_OFFSET esp, 0
 410         pushfl
 411         orl $X86_EFLAGS_IF, (%esp)
 412         CFI_ADJUST_CFA_OFFSET 4
 413         pushl $(__USER_CS)
 414         CFI_ADJUST_CFA_OFFSET 4
 415         /*CFI_REL_OFFSET cs, 0*/
 416         /*
 417          * Push current_thread_info()->sysenter_return to the stack.
 418          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 419          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 420          */
 421         pushl (TI_sysenter_return-THREAD_SIZE+8+4*4)(%esp)
 422         CFI_ADJUST_CFA_OFFSET 4
 423         CFI_REL_OFFSET eip, 0
 424
 425         pushl %eax
 426         CFI_ADJUST_CFA_OFFSET 4
 427         SAVE_ALL
 428         ENABLE_INTERRUPTS(CLBR_NONE)
 429
 430 /*
 431  * Load the potential sixth argument from user stack.
 432  * Careful about security.
 433  */
 434         cmpl $__PAGE_OFFSET-3,%ebp
 435         jae syscall_fault
 436 1:      movl (%ebp),%ebp
 437         movl %ebp,PT_EBP(%esp)
 438 .section __ex_table,"a"
 439         .align 4
 440         .long 1b,syscall_fault
 441 .previous
 442
 443         GET_THREAD_INFO(%ebp)
 444
 445         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 446         testw $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 447         jnz sysenter_audit
 448 sysenter_do_call:
 449         cmpl $(nr_syscalls), %eax
 450         jae syscall_badsys
 451         call *sys_call_table(,%eax,4)
 452         movl %eax,PT_EAX(%esp)
 453         LOCKDEP_SYS_EXIT
 454         DISABLE_INTERRUPTS(CLBR_ANY)
 455         TRACE_IRQS_OFF
 456         movl TI_flags(%ebp), %ecx
 457         testw $_TIF_ALLWORK_MASK, %cx
 458         jne sysexit_audit
 459 sysenter_exit:
 460 /* if something modifies registers it must also disable sysexit */
 461         movl PT_EIP(%esp), %edx
 462         movl PT_OLDESP(%esp), %ecx
 463         xorl %ebp,%ebp
 464         TRACE_IRQS_ON
 465 1:      mov  PT_FS(%esp), %fs
 466         PTGS_TO_GS
 467         ENABLE_INTERRUPTS_SYSEXIT
 468
 469 #ifdef CONFIG_AUDITSYSCALL
 470 sysenter_audit:
 471         testw $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 472         jnz syscall_trace_entry
 473         addl $4,%esp
 474         CFI_ADJUST_CFA_OFFSET -4
 475         /* %esi already in 8(%esp)         6th arg: 4th syscall arg */
 476         /* %edx already in 4(%esp)         5th arg: 3rd syscall arg */
 477         /* %ecx already in 0(%esp)         4th arg: 2nd syscall arg */
 478         movl %ebx,%ecx                  /* 3rd arg: 1st syscall arg */
 479         movl %eax,%edx                  /* 2nd arg: syscall number */
 480         movl $AUDIT_ARCH_I386,%eax      /* 1st arg: audit arch */
 481         call audit_syscall_entry
 482         pushl %ebx
 483         CFI_ADJUST_CFA_OFFSET 4
 484         movl PT_EAX(%esp),%eax          /* reload syscall number */
 485         jmp sysenter_do_call
 486
 487 sysexit_audit:
 488         testw $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %cx
 489         jne syscall_exit_work
 490         TRACE_IRQS_ON
 491         ENABLE_INTERRUPTS(CLBR_ANY)
 492         movl %eax,%edx          /* second arg, syscall return value */
 493         cmpl $0,%eax            /* is it < 0? */
 494         setl %al                /* 1 if so, 0 if not */
 495         movzbl %al,%eax         /* zero-extend that */
 496         inc %eax /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 497         call audit_syscall_exit
 498         DISABLE_INTERRUPTS(CLBR_ANY)
 499         TRACE_IRQS_OFF
 500         movl TI_flags(%ebp), %ecx
 501         testw $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %cx
 502         jne syscall_exit_work
 503         movl PT_EAX(%esp),%eax  /* reload syscall return value */
 504         jmp sysenter_exit
 505 #endif
 506
 507         CFI_ENDPROC
 508 .pushsection .fixup,"ax"
 509 2:      movl $0,PT_FS(%esp)
 510         jmp 1b
 511 .section __ex_table,"a"
 512         .align 4
 513         .long 1b,2b
 514 .popsection
 515         PTGS_TO_GS_EX
 516 ENDPROC(ia32_sysenter_target)
 517
 518         # system call handler stub
 519 ENTRY(system_call)
 520         RING0_INT_FRAME                 # can't unwind into user space anyway
 521         pushl %eax                      # save orig_eax
 522         CFI_ADJUST_CFA_OFFSET 4
 523         SAVE_ALL
 524         GET_THREAD_INFO(%ebp)
 525                                         # system call tracing in operation / emulation
 526         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 527         testw $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 528         jnz syscall_trace_entry
 529         cmpl $(nr_syscalls), %eax
 530         jae syscall_badsys
 531 syscall_call:
 532         call *sys_call_table(,%eax,4)
 533         movl %eax,PT_EAX(%esp)          # store the return value
 534 syscall_exit:
 535         LOCKDEP_SYS_EXIT
 536         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 537                                         # setting need_resched or sigpending
 538                                         # between sampling and the iret
 539         TRACE_IRQS_OFF
 540         movl TI_flags(%ebp), %ecx
 541         testw $_TIF_ALLWORK_MASK, %cx   # current->work
 542         jne syscall_exit_work
 543
 544 restore_all:
 545         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 546         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 547         # are returning to the kernel.
 548         # See comments in process.c:copy_thread() for details.
 549         movb PT_OLDSS(%esp), %ah
 550         movb PT_CS(%esp), %al
 551         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 552         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 553         CFI_REMEMBER_STATE
 554         je ldt_ss                       # returning to user-space with LDT SS
 555 restore_nocheck:
 556         TRACE_IRQS_IRET
 557 restore_nocheck_notrace:
 558         RESTORE_REGS 4                  # skip orig_eax/error_code
 559         CFI_ADJUST_CFA_OFFSET -4
 560 irq_return:
 561         INTERRUPT_RETURN
 562 .section .fixup,"ax"
 563 ENTRY(iret_exc)
 564         pushl $0                        # no error code
 565         pushl $do_iret_error
 566         jmp error_code
 567 .previous
 568 .section __ex_table,"a"
 569         .align 4
 570         .long irq_return,iret_exc
 571 .previous
 572
 573         CFI_RESTORE_STATE
 574 ldt_ss:
 575         larl PT_OLDSS(%esp), %eax
 576         jnz restore_nocheck
 577         testl $0x00400000, %eax         # returning to 32bit stack?
 578         jnz restore_nocheck             # allright, normal return
 579
 580 #ifdef CONFIG_PARAVIRT
 581         /*
 582          * The kernel can't run on a non-flat stack if paravirt mode
 583          * is active.  Rather than try to fixup the high bits of
 584          * ESP, bypass this code entirely.  This may break DOSemu
 585          * and/or Wine support in a paravirt VM, although the option
 586          * is still available to implement the setting of the high
 587          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 588          */
 589         cmpl $0, pv_info+PARAVIRT_enabled
 590         jne restore_nocheck
 591 #endif
 592
 593         /* If returning to userspace with 16bit stack,
 594          * try to fix the higher word of ESP, as the CPU
 595          * won't restore it.
 596          * This is an "official" bug of all the x86-compatible
 597          * CPUs, which we can try to work around to make
 598          * dosemu and wine happy. */
 599         movl PT_OLDESP(%esp), %eax
 600         movl %esp, %edx
 601         call patch_espfix_desc
 602         pushl $__ESPFIX_SS
 603         CFI_ADJUST_CFA_OFFSET 4
 604         pushl %eax
 605         CFI_ADJUST_CFA_OFFSET 4
 606         DISABLE_INTERRUPTS(CLBR_EAX)
 607         TRACE_IRQS_OFF
 608         lss (%esp), %esp
 609         CFI_ADJUST_CFA_OFFSET -8
 610         jmp restore_nocheck
 611         CFI_ENDPROC
 612 ENDPROC(system_call)
 613
 614         # perform work that needs to be done immediately before resumption
 615         ALIGN
 616         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 617 work_pending:
 618         testb $_TIF_NEED_RESCHED, %cl
 619         jz work_notifysig
 620 work_resched:
 621         call schedule
 622         LOCKDEP_SYS_EXIT
 623         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 624                                         # setting need_resched or sigpending
 625                                         # between sampling and the iret
 626         TRACE_IRQS_OFF
 627         movl TI_flags(%ebp), %ecx
 628         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 629                                         # than syscall tracing?
 630         jz restore_all
 631         testb $_TIF_NEED_RESCHED, %cl
 632         jnz work_resched
 633
 634 work_notifysig:                         # deal with pending signals and
 635                                         # notify-resume requests
 636 #ifdef CONFIG_VM86
 637         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
 638         movl %esp, %eax
 639         jne work_notifysig_v86          # returning to kernel-space or
 640                                         # vm86-space
 641         xorl %edx, %edx
 642         call do_notify_resume
 643         jmp resume_userspace_sig
 644
 645         ALIGN
 646 work_notifysig_v86:
 647         pushl %ecx                      # save ti_flags for do_notify_resume
 648         CFI_ADJUST_CFA_OFFSET 4
 649         call save_v86_state             # %eax contains pt_regs pointer
 650         popl %ecx
 651         CFI_ADJUST_CFA_OFFSET -4
 652         movl %eax, %esp
 653 #else
 654         movl %esp, %eax
 655 #endif
 656         xorl %edx, %edx
 657         call do_notify_resume
 658         jmp resume_userspace_sig
 659 END(work_pending)
 660
 661         # perform syscall exit tracing
 662         ALIGN
 663 syscall_trace_entry:
 664         movl $-ENOSYS,PT_EAX(%esp)
 665         movl %esp, %eax
 666         call syscall_trace_enter
 667         /* What it returned is what we'll actually use.  */
 668         cmpl $(nr_syscalls), %eax
 669         jnae syscall_call
 670         jmp syscall_exit
 671 END(syscall_trace_entry)
 672
 673         # perform syscall exit tracing
 674         ALIGN
 675 syscall_exit_work:
 676         testb $_TIF_WORK_SYSCALL_EXIT, %cl
 677         jz work_pending
 678         TRACE_IRQS_ON
 679         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
 680                                         # schedule() instead
 681         movl %esp, %eax
 682         call syscall_trace_leave
 683         jmp resume_userspace
 684 END(syscall_exit_work)
 685         CFI_ENDPROC
 686
 687         RING0_INT_FRAME                 # can't unwind into user space anyway
 688 syscall_fault:
 689         GET_THREAD_INFO(%ebp)
 690         movl $-EFAULT,PT_EAX(%esp)
 691         jmp resume_userspace
 692 END(syscall_fault)
 693
 694 syscall_badsys:
 695         movl $-ENOSYS,PT_EAX(%esp)
 696         jmp resume_userspace
 697 END(syscall_badsys)
 698         CFI_ENDPROC
 699
 700 /*
 701  * System calls that need a pt_regs pointer.
 702  */
 703 #define PTREGSCALL(name) \
 704         ALIGN; \
 705 ptregs_##name: \
 706         leal 4(%esp),%eax; \
 707         jmp sys_##name;
 708
 709 PTREGSCALL(iopl)
 710 PTREGSCALL(fork)
 711 PTREGSCALL(clone)
 712 PTREGSCALL(vfork)
 713 PTREGSCALL(execve)
 714 PTREGSCALL(sigaltstack)
 715 PTREGSCALL(sigreturn)
 716 PTREGSCALL(rt_sigreturn)
 717 PTREGSCALL(vm86)
 718 PTREGSCALL(vm86old)
 719
 720 .macro FIXUP_ESPFIX_STACK
 721         /* since we are on a wrong stack, we cant make it a C code :( */
 722         PER_CPU(gdt_page, %ebx)
 723         GET_DESC_BASE(GDT_ENTRY_ESPFIX_SS, %ebx, %eax, %ax, %al, %ah)
 724         addl %esp, %eax
 725         pushl $__KERNEL_DS
 726         CFI_ADJUST_CFA_OFFSET 4
 727         pushl %eax
 728         CFI_ADJUST_CFA_OFFSET 4
 729         lss (%esp), %esp
 730         CFI_ADJUST_CFA_OFFSET -8
 731 .endm
 732 .macro UNWIND_ESPFIX_STACK
 733         movl %ss, %eax
 734         /* see if on espfix stack */
 735         cmpw $__ESPFIX_SS, %ax
 736         jne 27f
 737         movl $__KERNEL_DS, %eax
 738         movl %eax, %ds
 739         movl %eax, %es
 740         /* switch to normal stack */
 741         FIXUP_ESPFIX_STACK
 742 27:
 743 .endm
 744
 745 /*
 746  * Build the entry stubs and pointer table with some assembler magic.
 747  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 748  * single cache line on all modern x86 implementations.
 749  */
 750 .section .init.rodata,"a"
 751 ENTRY(interrupt)
 752 .text
 753         .p2align 5
 754         .p2align CONFIG_X86_L1_CACHE_SHIFT
 755 ENTRY(irq_entries_start)
 756         RING0_INT_FRAME
 757 vector=FIRST_EXTERNAL_VECTOR
 758 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 759         .balign 32
 760   .rept 7
 761     .if vector < NR_VECTORS
 762       .if vector <> FIRST_EXTERNAL_VECTOR
 763         CFI_ADJUST_CFA_OFFSET -4
 764       .endif
 765 1:      pushl $(~vector+0x80)   /* Note: always in signed byte range */
 766         CFI_ADJUST_CFA_OFFSET 4
 767       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 768         jmp 2f
 769       .endif
 770       .previous
 771         .long 1b
 772       .text
 773 vector=vector+1
 774     .endif
 775   .endr
 776 2:      jmp common_interrupt
 777 .endr
 778 END(irq_entries_start)
 779
 780 .previous
 781 END(interrupt)
 782 .previous
 783
 784 /*
 785  * the CPU automatically disables interrupts when executing an IRQ vector,
 786  * so IRQ-flags tracing has to follow that:
 787  */
 788         .p2align CONFIG_X86_L1_CACHE_SHIFT
 789 common_interrupt:
 790         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
 791         SAVE_ALL
 792         TRACE_IRQS_OFF
 793         movl %esp,%eax
 794         call do_IRQ
 795         jmp ret_from_intr
 796 ENDPROC(common_interrupt)
 797         CFI_ENDPROC
 798
 799 #define BUILD_INTERRUPT3(name, nr, fn)  \
 800 ENTRY(name)                             \
 801         RING0_INT_FRAME;                \
 802         pushl $~(nr);                   \
 803         CFI_ADJUST_CFA_OFFSET 4;        \
 804         SAVE_ALL;                       \
 805         TRACE_IRQS_OFF                  \
 806         movl %esp,%eax;                 \
 807         call fn;                        \
 808         jmp ret_from_intr;              \
 809         CFI_ENDPROC;                    \
 810 ENDPROC(name)
 811
 812 #define BUILD_INTERRUPT(name, nr)       BUILD_INTERRUPT3(name, nr, smp_##name)
 813
 814 /* The include is where all of the SMP etc. interrupts come from */
 815 #include <asm/entry_arch.h>
 816
 817 ENTRY(coprocessor_error)
 818         RING0_INT_FRAME
 819         pushl $0
 820         CFI_ADJUST_CFA_OFFSET 4
 821         pushl $do_coprocessor_error
 822         CFI_ADJUST_CFA_OFFSET 4
 823         jmp error_code
 824         CFI_ENDPROC
 825 END(coprocessor_error)
 826
 827 ENTRY(simd_coprocessor_error)
 828         RING0_INT_FRAME
 829         pushl $0
 830         CFI_ADJUST_CFA_OFFSET 4
 831         pushl $do_simd_coprocessor_error
 832         CFI_ADJUST_CFA_OFFSET 4
 833         jmp error_code
 834         CFI_ENDPROC
 835 END(simd_coprocessor_error)
 836
 837 ENTRY(device_not_available)
 838         RING0_INT_FRAME
 839         pushl $-1                       # mark this as an int
 840         CFI_ADJUST_CFA_OFFSET 4
 841         pushl $do_device_not_available
 842         CFI_ADJUST_CFA_OFFSET 4
 843         jmp error_code
 844         CFI_ENDPROC
 845 END(device_not_available)
 846
 847 #ifdef CONFIG_PARAVIRT
 848 ENTRY(native_iret)
 849         iret
 850 .section __ex_table,"a"
 851         .align 4
 852         .long native_iret, iret_exc
 853 .previous
 854 END(native_iret)
 855
 856 ENTRY(native_irq_enable_sysexit)
 857         sti
 858         sysexit
 859 END(native_irq_enable_sysexit)
 860 #endif
 861
 862 ENTRY(overflow)
 863         RING0_INT_FRAME
 864         pushl $0
 865         CFI_ADJUST_CFA_OFFSET 4
 866         pushl $do_overflow
 867         CFI_ADJUST_CFA_OFFSET 4
 868         jmp error_code
 869         CFI_ENDPROC
 870 END(overflow)
 871
 872 ENTRY(bounds)
 873         RING0_INT_FRAME
 874         pushl $0
 875         CFI_ADJUST_CFA_OFFSET 4
 876         pushl $do_bounds
 877         CFI_ADJUST_CFA_OFFSET 4
 878         jmp error_code
 879         CFI_ENDPROC
 880 END(bounds)
 881
 882 ENTRY(invalid_op)
 883         RING0_INT_FRAME
 884         pushl $0
 885         CFI_ADJUST_CFA_OFFSET 4
 886         pushl $do_invalid_op
 887         CFI_ADJUST_CFA_OFFSET 4
 888         jmp error_code
 889         CFI_ENDPROC
 890 END(invalid_op)
 891
 892 ENTRY(coprocessor_segment_overrun)
 893         RING0_INT_FRAME
 894         pushl $0
 895         CFI_ADJUST_CFA_OFFSET 4
 896         pushl $do_coprocessor_segment_overrun
 897         CFI_ADJUST_CFA_OFFSET 4
 898         jmp error_code
 899         CFI_ENDPROC
 900 END(coprocessor_segment_overrun)
 901
 902 ENTRY(invalid_TSS)
 903         RING0_EC_FRAME
 904         pushl $do_invalid_TSS
 905         CFI_ADJUST_CFA_OFFSET 4
 906         jmp error_code
 907         CFI_ENDPROC
 908 END(invalid_TSS)
 909
 910 ENTRY(segment_not_present)
 911         RING0_EC_FRAME
 912         pushl $do_segment_not_present
 913         CFI_ADJUST_CFA_OFFSET 4
 914         jmp error_code
 915         CFI_ENDPROC
 916 END(segment_not_present)
 917
 918 ENTRY(stack_segment)
 919         RING0_EC_FRAME
 920         pushl $do_stack_segment
 921         CFI_ADJUST_CFA_OFFSET 4
 922         jmp error_code
 923         CFI_ENDPROC
 924 END(stack_segment)
 925
 926 ENTRY(alignment_check)
 927         RING0_EC_FRAME
 928         pushl $do_alignment_check
 929         CFI_ADJUST_CFA_OFFSET 4
 930         jmp error_code
 931         CFI_ENDPROC
 932 END(alignment_check)
 933
 934 ENTRY(divide_error)
 935         RING0_INT_FRAME
 936         pushl $0                        # no error code
 937         CFI_ADJUST_CFA_OFFSET 4
 938         pushl $do_divide_error
 939         CFI_ADJUST_CFA_OFFSET 4
 940         jmp error_code
 941         CFI_ENDPROC
 942 END(divide_error)
 943
 944 #ifdef CONFIG_X86_MCE
 945 ENTRY(machine_check)
 946         RING0_INT_FRAME
 947         pushl $0
 948         CFI_ADJUST_CFA_OFFSET 4
 949         pushl machine_check_vector
 950         CFI_ADJUST_CFA_OFFSET 4
 951         jmp error_code
 952         CFI_ENDPROC
 953 END(machine_check)
 954 #endif
 955
 956 ENTRY(spurious_interrupt_bug)
 957         RING0_INT_FRAME
 958         pushl $0
 959         CFI_ADJUST_CFA_OFFSET 4
 960         pushl $do_spurious_interrupt_bug
 961         CFI_ADJUST_CFA_OFFSET 4
 962         jmp error_code
 963         CFI_ENDPROC
 964 END(spurious_interrupt_bug)
 965
 966 ENTRY(kernel_thread_helper)
 967         pushl $0                # fake return address for unwinder
 968         CFI_STARTPROC
 969         movl %edx,%eax
 970         push %edx
 971         CFI_ADJUST_CFA_OFFSET 4
 972         call *%ebx
 973         push %eax
 974         CFI_ADJUST_CFA_OFFSET 4
 975         call do_exit
 976         ud2                     # padding for call trace
 977         CFI_ENDPROC
 978 ENDPROC(kernel_thread_helper)
 979
 980 #ifdef CONFIG_XEN
 981 /* Xen doesn't set %esp to be precisely what the normal sysenter
 982    entrypoint expects, so fix it up before using the normal path. */
 983 ENTRY(xen_sysenter_target)
 984         RING0_INT_FRAME
 985         addl $5*4, %esp         /* remove xen-provided frame */
 986         CFI_ADJUST_CFA_OFFSET -5*4
 987         jmp sysenter_past_esp
 988         CFI_ENDPROC
 989
 990 ENTRY(xen_hypervisor_callback)
 991         CFI_STARTPROC
 992         pushl $0
 993         CFI_ADJUST_CFA_OFFSET 4
 994         SAVE_ALL
 995         TRACE_IRQS_OFF
 996
 997         /* Check to see if we got the event in the critical
 998            region in xen_iret_direct, after we've reenabled
 999            events and checked for pending events.  This simulates
1000            iret instruction's behaviour where it delivers a
1001            pending interrupt when enabling interrupts. */
1002         movl PT_EIP(%esp),%eax
1003         cmpl $xen_iret_start_crit,%eax
1004         jb   1f
1005         cmpl $xen_iret_end_crit,%eax
1006         jae  1f
1007
1008         jmp  xen_iret_crit_fixup
1009
1010 ENTRY(xen_do_upcall)
1011 1:      mov %esp, %eax
1012         call xen_evtchn_do_upcall
1013         jmp  ret_from_intr
1014         CFI_ENDPROC
1015 ENDPROC(xen_hypervisor_callback)
1016
1017 # Hypervisor uses this for application faults while it executes.
1018 # We get here for two reasons:
1019 #  1. Fault while reloading DS, ES, FS or GS
1020 #  2. Fault while executing IRET
1021 # Category 1 we fix up by reattempting the load, and zeroing the segment
1022 # register if the load fails.
1023 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1024 # normal Linux return path in this case because if we use the IRET hypercall
1025 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1026 # We distinguish between categories by maintaining a status value in EAX.
1027 ENTRY(xen_failsafe_callback)
1028         CFI_STARTPROC
1029         pushl %eax
1030         CFI_ADJUST_CFA_OFFSET 4
1031         movl $1,%eax
1032 1:      mov 4(%esp),%ds
1033 2:      mov 8(%esp),%es
1034 3:      mov 12(%esp),%fs
1035 4:      mov 16(%esp),%gs
1036         testl %eax,%eax
1037         popl %eax
1038         CFI_ADJUST_CFA_OFFSET -4
1039         lea 16(%esp),%esp
1040         CFI_ADJUST_CFA_OFFSET -16
1041         jz 5f
1042         addl $16,%esp
1043         jmp iret_exc            # EAX != 0 => Category 2 (Bad IRET)
1044 5:      pushl $0                # EAX == 0 => Category 1 (Bad segment)
1045         CFI_ADJUST_CFA_OFFSET 4
1046         SAVE_ALL
1047         jmp ret_from_exception
1048         CFI_ENDPROC
1049
1050 .section .fixup,"ax"
1051 6:      xorl %eax,%eax
1052         movl %eax,4(%esp)
1053         jmp 1b
1054 7:      xorl %eax,%eax
1055         movl %eax,8(%esp)
1056         jmp 2b
1057 8:      xorl %eax,%eax
1058         movl %eax,12(%esp)
1059         jmp 3b
1060 9:      xorl %eax,%eax
1061         movl %eax,16(%esp)
1062         jmp 4b
1063 .previous
1064 .section __ex_table,"a"
1065         .align 4
1066         .long 1b,6b
1067         .long 2b,7b
1068         .long 3b,8b
1069         .long 4b,9b
1070 .previous
1071 ENDPROC(xen_failsafe_callback)
1072
1073 #endif  /* CONFIG_XEN */
1074
1075 #ifdef CONFIG_FUNCTION_TRACER
1076 #ifdef CONFIG_DYNAMIC_FTRACE
1077
1078 ENTRY(mcount)
1079         ret
1080 END(mcount)
1081
1082 ENTRY(ftrace_caller)
1083         cmpl $0, function_trace_stop
1084         jne  ftrace_stub
1085
1086         pushl %eax
1087         pushl %ecx
1088         pushl %edx
1089         movl 0xc(%esp), %eax
1090         movl 0x4(%ebp), %edx
1091         subl $MCOUNT_INSN_SIZE, %eax
1092
1093 .globl ftrace_call
1094 ftrace_call:
1095         call ftrace_stub
1096
1097         popl %edx
1098         popl %ecx
1099         popl %eax
1100 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1101 .globl ftrace_graph_call
1102 ftrace_graph_call:
1103         jmp ftrace_stub
1104 #endif
1105
1106 .globl ftrace_stub
1107 ftrace_stub:
1108         ret
1109 END(ftrace_caller)
1110
1111 #else /* ! CONFIG_DYNAMIC_FTRACE */
1112
1113 ENTRY(mcount)
1114         cmpl $0, function_trace_stop
1115         jne  ftrace_stub
1116
1117         cmpl $ftrace_stub, ftrace_trace_function
1118         jnz trace
1119 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1120         cmpl $ftrace_stub, ftrace_graph_return
1121         jnz ftrace_graph_caller
1122
1123         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1124         jnz ftrace_graph_caller
1125 #endif
1126 .globl ftrace_stub
1127 ftrace_stub:
1128         ret
1129
1130         /* taken from glibc */
1131 trace:
1132         pushl %eax
1133         pushl %ecx
1134         pushl %edx
1135         movl 0xc(%esp), %eax
1136         movl 0x4(%ebp), %edx
1137         subl $MCOUNT_INSN_SIZE, %eax
1138
1139         call *ftrace_trace_function
1140
1141         popl %edx
1142         popl %ecx
1143         popl %eax
1144         jmp ftrace_stub
1145 END(mcount)
1146 #endif /* CONFIG_DYNAMIC_FTRACE */
1147 #endif /* CONFIG_FUNCTION_TRACER */
1148
1149 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1150 ENTRY(ftrace_graph_caller)
1151         cmpl $0, function_trace_stop
1152         jne ftrace_stub
1153
1154         pushl %eax
1155         pushl %ecx
1156         pushl %edx
1157         movl 0xc(%esp), %edx
1158         lea 0x4(%ebp), %eax
1159         subl $MCOUNT_INSN_SIZE, %edx
1160         call prepare_ftrace_return
1161         popl %edx
1162         popl %ecx
1163         popl %eax
1164         ret
1165 END(ftrace_graph_caller)
1166
1167 .globl return_to_handler
1168 return_to_handler:
1169         pushl $0
1170         pushl %eax
1171         pushl %ecx
1172         pushl %edx
1173         call ftrace_return_to_handler
1174         movl %eax, 0xc(%esp)
1175         popl %edx
1176         popl %ecx
1177         popl %eax
1178         ret
1179 #endif
1180
1181 .section .rodata,"a"
1182 #include "syscall_table_32.S"
1183
1184 syscall_table_size=(.-sys_call_table)
1185
1186 /*
1187  * Some functions should be protected against kprobes
1188  */
1189         .pushsection .kprobes.text, "ax"
1190
1191 ENTRY(page_fault)
1192         RING0_EC_FRAME
1193         pushl $do_page_fault
1194         CFI_ADJUST_CFA_OFFSET 4
1195         ALIGN
1196 error_code:
1197         /* the function address is in %gs's slot on the stack */
1198         pushl %fs
1199         CFI_ADJUST_CFA_OFFSET 4
1200         /*CFI_REL_OFFSET fs, 0*/
1201         pushl %es
1202         CFI_ADJUST_CFA_OFFSET 4
1203         /*CFI_REL_OFFSET es, 0*/
1204         pushl %ds
1205         CFI_ADJUST_CFA_OFFSET 4
1206         /*CFI_REL_OFFSET ds, 0*/
1207         pushl %eax
1208         CFI_ADJUST_CFA_OFFSET 4
1209         CFI_REL_OFFSET eax, 0
1210         pushl %ebp
1211         CFI_ADJUST_CFA_OFFSET 4
1212         CFI_REL_OFFSET ebp, 0
1213         pushl %edi
1214         CFI_ADJUST_CFA_OFFSET 4
1215         CFI_REL_OFFSET edi, 0
1216         pushl %esi
1217         CFI_ADJUST_CFA_OFFSET 4
1218         CFI_REL_OFFSET esi, 0
1219         pushl %edx
1220         CFI_ADJUST_CFA_OFFSET 4
1221         CFI_REL_OFFSET edx, 0
1222         pushl %ecx
1223         CFI_ADJUST_CFA_OFFSET 4
1224         CFI_REL_OFFSET ecx, 0
1225         pushl %ebx
1226         CFI_ADJUST_CFA_OFFSET 4
1227         CFI_REL_OFFSET ebx, 0
1228         cld
1229         movl $(__KERNEL_PERCPU), %ecx
1230         movl %ecx, %fs
1231         UNWIND_ESPFIX_STACK
1232         GS_TO_REG %ecx
1233         movl PT_GS(%esp), %edi          # get the function address
1234         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1235         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1236         REG_TO_PTGS %ecx
1237         SET_KERNEL_GS %ecx
1238         movl $(__USER_DS), %ecx
1239         movl %ecx, %ds
1240         movl %ecx, %es
1241         TRACE_IRQS_OFF
1242         movl %esp,%eax                  # pt_regs pointer
1243         call *%edi
1244         jmp ret_from_exception
1245         CFI_ENDPROC
1246 END(page_fault)
1247
1248 /*
1249  * Debug traps and NMI can happen at the one SYSENTER instruction
1250  * that sets up the real kernel stack. Check here, since we can't
1251  * allow the wrong stack to be used.
1252  *
1253  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1254  * already pushed 3 words if it hits on the sysenter instruction:
1255  * eflags, cs and eip.
1256  *
1257  * We just load the right stack, and push the three (known) values
1258  * by hand onto the new stack - while updating the return eip past
1259  * the instruction that would have done it for sysenter.
1260  */
1261 .macro FIX_STACK offset ok label
1262         cmpw $__KERNEL_CS, 4(%esp)
1263         jne \ok
1264 \label:
1265         movl TSS_sysenter_sp0 + \offset(%esp), %esp
1266         CFI_DEF_CFA esp, 0
1267         CFI_UNDEFINED eip
1268         pushfl
1269         CFI_ADJUST_CFA_OFFSET 4
1270         pushl $__KERNEL_CS
1271         CFI_ADJUST_CFA_OFFSET 4
1272         pushl $sysenter_past_esp
1273         CFI_ADJUST_CFA_OFFSET 4
1274         CFI_REL_OFFSET eip, 0
1275 .endm
1276
1277 ENTRY(debug)
1278         RING0_INT_FRAME
1279         cmpl $ia32_sysenter_target,(%esp)
1280         jne debug_stack_correct
1281         FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1282 debug_stack_correct:
1283         pushl $-1                       # mark this as an int
1284         CFI_ADJUST_CFA_OFFSET 4
1285         SAVE_ALL
1286         TRACE_IRQS_OFF
1287         xorl %edx,%edx                  # error code 0
1288         movl %esp,%eax                  # pt_regs pointer
1289         call do_debug
1290         jmp ret_from_exception
1291         CFI_ENDPROC
1292 END(debug)
1293
1294 /*
1295  * NMI is doubly nasty. It can happen _while_ we're handling
1296  * a debug fault, and the debug fault hasn't yet been able to
1297  * clear up the stack. So we first check whether we got  an
1298  * NMI on the sysenter entry path, but after that we need to
1299  * check whether we got an NMI on the debug path where the debug
1300  * fault happened on the sysenter path.
1301  */
1302 ENTRY(nmi)
1303         RING0_INT_FRAME
1304         pushl %eax
1305         CFI_ADJUST_CFA_OFFSET 4
1306         movl %ss, %eax
1307         cmpw $__ESPFIX_SS, %ax
1308         popl %eax
1309         CFI_ADJUST_CFA_OFFSET -4
1310         je nmi_espfix_stack
1311         cmpl $ia32_sysenter_target,(%esp)
1312         je nmi_stack_fixup
1313         pushl %eax
1314         CFI_ADJUST_CFA_OFFSET 4
1315         movl %esp,%eax
1316         /* Do not access memory above the end of our stack page,
1317          * it might not exist.
1318          */
1319         andl $(THREAD_SIZE-1),%eax
1320         cmpl $(THREAD_SIZE-20),%eax
1321         popl %eax
1322         CFI_ADJUST_CFA_OFFSET -4
1323         jae nmi_stack_correct
1324         cmpl $ia32_sysenter_target,12(%esp)
1325         je nmi_debug_stack_check
1326 nmi_stack_correct:
1327         /* We have a RING0_INT_FRAME here */
1328         pushl %eax
1329         CFI_ADJUST_CFA_OFFSET 4
1330         SAVE_ALL
1331         xorl %edx,%edx          # zero error code
1332         movl %esp,%eax          # pt_regs pointer
1333         call do_nmi
1334         jmp restore_nocheck_notrace
1335         CFI_ENDPROC
1336
1337 nmi_stack_fixup:
1338         RING0_INT_FRAME
1339         FIX_STACK 12, nmi_stack_correct, 1
1340         jmp nmi_stack_correct
1341
1342 nmi_debug_stack_check:
1343         /* We have a RING0_INT_FRAME here */
1344         cmpw $__KERNEL_CS,16(%esp)
1345         jne nmi_stack_correct
1346         cmpl $debug,(%esp)
1347         jb nmi_stack_correct
1348         cmpl $debug_esp_fix_insn,(%esp)
1349         ja nmi_stack_correct
1350         FIX_STACK 24, nmi_stack_correct, 1
1351         jmp nmi_stack_correct
1352
1353 nmi_espfix_stack:
1354         /* We have a RING0_INT_FRAME here.
1355          *
1356          * create the pointer to lss back
1357          */
1358         pushl %ss
1359         CFI_ADJUST_CFA_OFFSET 4
1360         pushl %esp
1361         CFI_ADJUST_CFA_OFFSET 4
1362         addl $4, (%esp)
1363         /* copy the iret frame of 12 bytes */
1364         .rept 3
1365         pushl 16(%esp)
1366         CFI_ADJUST_CFA_OFFSET 4
1367         .endr
1368         pushl %eax
1369         CFI_ADJUST_CFA_OFFSET 4
1370         SAVE_ALL
1371         FIXUP_ESPFIX_STACK              # %eax == %esp
1372         xorl %edx,%edx                  # zero error code
1373         call do_nmi
1374         RESTORE_REGS
1375         lss 12+4(%esp), %esp            # back to espfix stack
1376         CFI_ADJUST_CFA_OFFSET -24
1377         jmp irq_return
1378         CFI_ENDPROC
1379 END(nmi)
1380
1381 ENTRY(int3)
1382         RING0_INT_FRAME
1383         pushl $-1                       # mark this as an int
1384         CFI_ADJUST_CFA_OFFSET 4
1385         SAVE_ALL
1386         TRACE_IRQS_OFF
1387         xorl %edx,%edx          # zero error code
1388         movl %esp,%eax          # pt_regs pointer
1389         call do_int3
1390         jmp ret_from_exception
1391         CFI_ENDPROC
1392 END(int3)
1393
1394 ENTRY(general_protection)
1395         RING0_EC_FRAME
1396         pushl $do_general_protection
1397         CFI_ADJUST_CFA_OFFSET 4
1398         jmp error_code
1399         CFI_ENDPROC
1400 END(general_protection)
1401
1402 /*
1403  * End of kprobes section
1404  */
1405         .popsection