arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58
  59 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  60 #include <linux/elf-em.h>
  61 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  62 #define __AUDIT_ARCH_64BIT 0x80000000
  63 #define __AUDIT_ARCH_LE    0x40000000
  64
  65         .code64
  66         .section .entry.text, "ax"
  67
  68 #ifdef CONFIG_FUNCTION_TRACER
  69 #ifdef CONFIG_DYNAMIC_FTRACE
  70 ENTRY(mcount)
  71         retq
  72 END(mcount)
  73
  74 ENTRY(ftrace_caller)
  75         cmpl $0, function_trace_stop
  76         jne  ftrace_stub
  77
  78         MCOUNT_SAVE_FRAME
  79
  80         movq 0x38(%rsp), %rdi
  81         movq 8(%rbp), %rsi
  82         subq $MCOUNT_INSN_SIZE, %rdi
  83
  84 GLOBAL(ftrace_call)
  85         call ftrace_stub
  86
  87         MCOUNT_RESTORE_FRAME
  88
  89 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  90 GLOBAL(ftrace_graph_call)
  91         jmp ftrace_stub
  92 #endif
  93
  94 GLOBAL(ftrace_stub)
  95         retq
  96 END(ftrace_caller)
  97
  98 #else /* ! CONFIG_DYNAMIC_FTRACE */
  99 ENTRY(mcount)
 100         cmpl $0, function_trace_stop
 101         jne  ftrace_stub
 102
 103         cmpq $ftrace_stub, ftrace_trace_function
 104         jnz trace
 105
 106 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 107         cmpq $ftrace_stub, ftrace_graph_return
 108         jnz ftrace_graph_caller
 109
 110         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 111         jnz ftrace_graph_caller
 112 #endif
 113
 114 GLOBAL(ftrace_stub)
 115         retq
 116
 117 trace:
 118         MCOUNT_SAVE_FRAME
 119
 120         movq 0x38(%rsp), %rdi
 121         movq 8(%rbp), %rsi
 122         subq $MCOUNT_INSN_SIZE, %rdi
 123
 124         call   *ftrace_trace_function
 125
 126         MCOUNT_RESTORE_FRAME
 127
 128         jmp ftrace_stub
 129 END(mcount)
 130 #endif /* CONFIG_DYNAMIC_FTRACE */
 131 #endif /* CONFIG_FUNCTION_TRACER */
 132
 133 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 134 ENTRY(ftrace_graph_caller)
 135         cmpl $0, function_trace_stop
 136         jne ftrace_stub
 137
 138         MCOUNT_SAVE_FRAME
 139
 140         leaq 8(%rbp), %rdi
 141         movq 0x38(%rsp), %rsi
 142         movq (%rbp), %rdx
 143         subq $MCOUNT_INSN_SIZE, %rsi
 144
 145         call    prepare_ftrace_return
 146
 147         MCOUNT_RESTORE_FRAME
 148
 149         retq
 150 END(ftrace_graph_caller)
 151
 152 GLOBAL(return_to_handler)
 153         subq  $24, %rsp
 154
 155         /* Save the return values */
 156         movq %rax, (%rsp)
 157         movq %rdx, 8(%rsp)
 158         movq %rbp, %rdi
 159
 160         call ftrace_return_to_handler
 161
 162         movq %rax, %rdi
 163         movq 8(%rsp), %rdx
 164         movq (%rsp), %rax
 165         addq $24, %rsp
 166         jmp *%rdi
 167 #endif
 168
 169
 170 #ifndef CONFIG_PREEMPT
 171 #define retint_kernel retint_restore_args
 172 #endif
 173
 174 #ifdef CONFIG_PARAVIRT
 175 ENTRY(native_usergs_sysret64)
 176         swapgs
 177         sysretq
 178 ENDPROC(native_usergs_sysret64)
 179 #endif /* CONFIG_PARAVIRT */
 180
 181
 182 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 183 #ifdef CONFIG_TRACE_IRQFLAGS
 184         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 185         jnc  1f
 186         TRACE_IRQS_ON
 187 1:
 188 #endif
 189 .endm
 190
 191 /*
 192  * C code is not supposed to know about undefined top of stack. Every time
 193  * a C function with an pt_regs argument is called from the SYSCALL based
 194  * fast path FIXUP_TOP_OF_STACK is needed.
 195  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 196  * manipulation.
 197  */
 198
 199         /* %rsp:at FRAMEEND */
 200         .macro FIXUP_TOP_OF_STACK tmp offset=0
 201         movq PER_CPU_VAR(old_rsp),\tmp
 202         movq \tmp,RSP+\offset(%rsp)
 203         movq $__USER_DS,SS+\offset(%rsp)
 204         movq $__USER_CS,CS+\offset(%rsp)
 205         movq $-1,RCX+\offset(%rsp)
 206         movq R11+\offset(%rsp),\tmp  /* get eflags */
 207         movq \tmp,EFLAGS+\offset(%rsp)
 208         .endm
 209
 210         .macro RESTORE_TOP_OF_STACK tmp offset=0
 211         movq RSP+\offset(%rsp),\tmp
 212         movq \tmp,PER_CPU_VAR(old_rsp)
 213         movq EFLAGS+\offset(%rsp),\tmp
 214         movq \tmp,R11+\offset(%rsp)
 215         .endm
 216
 217         .macro FAKE_STACK_FRAME child_rip
 218         /* push in order ss, rsp, eflags, cs, rip */
 219         xorl %eax, %eax
 220         pushq_cfi $__KERNEL_DS /* ss */
 221         /*CFI_REL_OFFSET        ss,0*/
 222         pushq_cfi %rax /* rsp */
 223         CFI_REL_OFFSET  rsp,0
 224         pushq_cfi $X86_EFLAGS_IF /* eflags - interrupts on */
 225         /*CFI_REL_OFFSET        rflags,0*/
 226         pushq_cfi $__KERNEL_CS /* cs */
 227         /*CFI_REL_OFFSET        cs,0*/
 228         pushq_cfi \child_rip /* rip */
 229         CFI_REL_OFFSET  rip,0
 230         pushq_cfi %rax /* orig rax */
 231         .endm
 232
 233         .macro UNFAKE_STACK_FRAME
 234         addq $8*6, %rsp
 235         CFI_ADJUST_CFA_OFFSET   -(6*8)
 236         .endm
 237
 238 /*
 239  * initial frame state for interrupts (and exceptions without error code)
 240  */
 241         .macro EMPTY_FRAME start=1 offset=0
 242         .if \start
 243         CFI_STARTPROC simple
 244         CFI_SIGNAL_FRAME
 245         CFI_DEF_CFA rsp,8+\offset
 246         .else
 247         CFI_DEF_CFA_OFFSET 8+\offset
 248         .endif
 249         .endm
 250
 251 /*
 252  * initial frame state for interrupts (and exceptions without error code)
 253  */
 254         .macro INTR_FRAME start=1 offset=0
 255         EMPTY_FRAME \start, SS+8+\offset-RIP
 256         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 257         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 258         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 259         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 260         CFI_REL_OFFSET rip, RIP+\offset-RIP
 261         .endm
 262
 263 /*
 264  * initial frame state for exceptions with error code (and interrupts
 265  * with vector already pushed)
 266  */
 267         .macro XCPT_FRAME start=1 offset=0
 268         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 269         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 270         .endm
 271
 272 /*
 273  * frame that enables calling into C.
 274  */
 275         .macro PARTIAL_FRAME start=1 offset=0
 276         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 277         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 278         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 283         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 286         .endm
 287
 288 /*
 289  * frame that enables passing a complete pt_regs to a C function.
 290  */
 291         .macro DEFAULT_FRAME start=1 offset=0
 292         PARTIAL_FRAME \start, R11+\offset-R15
 293         CFI_REL_OFFSET rbx, RBX+\offset
 294         CFI_REL_OFFSET rbp, RBP+\offset
 295         CFI_REL_OFFSET r12, R12+\offset
 296         CFI_REL_OFFSET r13, R13+\offset
 297         CFI_REL_OFFSET r14, R14+\offset
 298         CFI_REL_OFFSET r15, R15+\offset
 299         .endm
 300
 301 /* save partial stack frame */
 302         .pushsection .kprobes.text, "ax"
 303 ENTRY(save_args)
 304         XCPT_FRAME
 305         cld
 306         /*
 307          * start from rbp in pt_regs and jump over
 308          * return address.
 309          */
 310         movq_cfi rdi, RDI+8-RBP
 311         movq_cfi rsi, RSI+8-RBP
 312         movq_cfi rdx, RDX+8-RBP
 313         movq_cfi rcx, RCX+8-RBP
 314         movq_cfi rax, RAX+8-RBP
 315         movq_cfi  r8,  R8+8-RBP
 316         movq_cfi  r9,  R9+8-RBP
 317         movq_cfi r10, R10+8-RBP
 318         movq_cfi r11, R11+8-RBP
 319
 320         leaq -RBP+8(%rsp),%rdi  /* arg1 for handler */
 321         movq_cfi rbp, 8         /* push %rbp */
 322         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 323         testl $3, CS(%rdi)
 324         je 1f
 325         SWAPGS
 326         /*
 327          * irq_count is used to check if a CPU is already on an interrupt stack
 328          * or not. While this is essentially redundant with preempt_count it is
 329          * a little cheaper to use a separate counter in the PDA (short of
 330          * moving irq_enter into assembly, which would be too much work)
 331          */
 332 1:      incl PER_CPU_VAR(irq_count)
 333         jne 2f
 334         popq_cfi %rax                   /* move return address... */
 335         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 336         EMPTY_FRAME 0
 337         pushq_cfi %rbp                  /* backlink for unwinder */
 338         pushq_cfi %rax                  /* ... to the new stack */
 339         /*
 340          * We entered an interrupt context - irqs are off:
 341          */
 342 2:      TRACE_IRQS_OFF
 343         ret
 344         CFI_ENDPROC
 345 END(save_args)
 346         .popsection
 347
 348 ENTRY(save_rest)
 349         PARTIAL_FRAME 1 REST_SKIP+8
 350         movq 5*8+16(%rsp), %r11 /* save return address */
 351         movq_cfi rbx, RBX+16
 352         movq_cfi rbp, RBP+16
 353         movq_cfi r12, R12+16
 354         movq_cfi r13, R13+16
 355         movq_cfi r14, R14+16
 356         movq_cfi r15, R15+16
 357         movq %r11, 8(%rsp)      /* return address */
 358         FIXUP_TOP_OF_STACK %r11, 16
 359         ret
 360         CFI_ENDPROC
 361 END(save_rest)
 362
 363 /* save complete stack frame */
 364         .pushsection .kprobes.text, "ax"
 365 ENTRY(save_paranoid)
 366         XCPT_FRAME 1 RDI+8
 367         cld
 368         movq_cfi rdi, RDI+8
 369         movq_cfi rsi, RSI+8
 370         movq_cfi rdx, RDX+8
 371         movq_cfi rcx, RCX+8
 372         movq_cfi rax, RAX+8
 373         movq_cfi r8, R8+8
 374         movq_cfi r9, R9+8
 375         movq_cfi r10, R10+8
 376         movq_cfi r11, R11+8
 377         movq_cfi rbx, RBX+8
 378         movq_cfi rbp, RBP+8
 379         movq_cfi r12, R12+8
 380         movq_cfi r13, R13+8
 381         movq_cfi r14, R14+8
 382         movq_cfi r15, R15+8
 383         movl $1,%ebx
 384         movl $MSR_GS_BASE,%ecx
 385         rdmsr
 386         testl %edx,%edx
 387         js 1f   /* negative -> in kernel */
 388         SWAPGS
 389         xorl %ebx,%ebx
 390 1:      ret
 391         CFI_ENDPROC
 392 END(save_paranoid)
 393         .popsection
 394
 395 /*
 396  * A newly forked process directly context switches into this address.
 397  *
 398  * rdi: prev task we switched from
 399  */
 400 ENTRY(ret_from_fork)
 401         DEFAULT_FRAME
 402
 403         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 404
 405         pushq_cfi kernel_eflags(%rip)
 406         popfq_cfi                               # reset kernel eflags
 407
 408         call schedule_tail                      # rdi: 'prev' task parameter
 409
 410         GET_THREAD_INFO(%rcx)
 411
 412         RESTORE_REST
 413
 414         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 415         je   int_ret_from_sys_call
 416
 417         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 418         jnz  int_ret_from_sys_call
 419
 420         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 421         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 422
 423         CFI_ENDPROC
 424 END(ret_from_fork)
 425
 426 /*
 427  * System call entry. Up to 6 arguments in registers are supported.
 428  *
 429  * SYSCALL does not save anything on the stack and does not change the
 430  * stack pointer.
 431  */
 432
 433 /*
 434  * Register setup:
 435  * rax  system call number
 436  * rdi  arg0
 437  * rcx  return address for syscall/sysret, C arg3
 438  * rsi  arg1
 439  * rdx  arg2
 440  * r10  arg3    (--> moved to rcx for C)
 441  * r8   arg4
 442  * r9   arg5
 443  * r11  eflags for syscall/sysret, temporary for C
 444  * r12-r15,rbp,rbx saved by C code, not touched.
 445  *
 446  * Interrupts are off on entry.
 447  * Only called from user space.
 448  *
 449  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 450  *      and report it properly in ps. Unfortunately we haven't.
 451  *
 452  * When user can change the frames always force IRET. That is because
 453  * it deals with uncanonical addresses better. SYSRET has trouble
 454  * with them due to bugs in both AMD and Intel CPUs.
 455  */
 456
 457 ENTRY(system_call)
 458         CFI_STARTPROC   simple
 459         CFI_SIGNAL_FRAME
 460         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 461         CFI_REGISTER    rip,rcx
 462         /*CFI_REGISTER  rflags,r11*/
 463         SWAPGS_UNSAFE_STACK
 464         /*
 465          * A hypervisor implementation might want to use a label
 466          * after the swapgs, so that it can do the swapgs
 467          * for the guest and jump here on syscall.
 468          */
 469 ENTRY(system_call_after_swapgs)
 470
 471         movq    %rsp,PER_CPU_VAR(old_rsp)
 472         movq    PER_CPU_VAR(kernel_stack),%rsp
 473         /*
 474          * No need to follow this irqs off/on section - it's straight
 475          * and short:
 476          */
 477         ENABLE_INTERRUPTS(CLBR_NONE)
 478         SAVE_ARGS 8,1
 479         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 480         movq  %rcx,RIP-ARGOFFSET(%rsp)
 481         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 482         GET_THREAD_INFO(%rcx)
 483         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 484         jnz tracesys
 485 system_call_fastpath:
 486         cmpq $__NR_syscall_max,%rax
 487         ja badsys
 488         movq %r10,%rcx
 489         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 490         movq %rax,RAX-ARGOFFSET(%rsp)
 491 /*
 492  * Syscall return path ending with SYSRET (fast path)
 493  * Has incomplete stack frame and undefined top of stack.
 494  */
 495 ret_from_sys_call:
 496         movl $_TIF_ALLWORK_MASK,%edi
 497         /* edi: flagmask */
 498 sysret_check:
 499         LOCKDEP_SYS_EXIT
 500         GET_THREAD_INFO(%rcx)
 501         DISABLE_INTERRUPTS(CLBR_NONE)
 502         TRACE_IRQS_OFF
 503         movl TI_flags(%rcx),%edx
 504         andl %edi,%edx
 505         jnz  sysret_careful
 506         CFI_REMEMBER_STATE
 507         /*
 508          * sysretq will re-enable interrupts:
 509          */
 510         TRACE_IRQS_ON
 511         movq RIP-ARGOFFSET(%rsp),%rcx
 512         CFI_REGISTER    rip,rcx
 513         RESTORE_ARGS 0,-ARG_SKIP,1
 514         /*CFI_REGISTER  rflags,r11*/
 515         movq    PER_CPU_VAR(old_rsp), %rsp
 516         USERGS_SYSRET64
 517
 518         CFI_RESTORE_STATE
 519         /* Handle reschedules */
 520         /* edx: work, edi: workmask */
 521 sysret_careful:
 522         bt $TIF_NEED_RESCHED,%edx
 523         jnc sysret_signal
 524         TRACE_IRQS_ON
 525         ENABLE_INTERRUPTS(CLBR_NONE)
 526         pushq_cfi %rdi
 527         call schedule
 528         popq_cfi %rdi
 529         jmp sysret_check
 530
 531         /* Handle a signal */
 532 sysret_signal:
 533         TRACE_IRQS_ON
 534         ENABLE_INTERRUPTS(CLBR_NONE)
 535 #ifdef CONFIG_AUDITSYSCALL
 536         bt $TIF_SYSCALL_AUDIT,%edx
 537         jc sysret_audit
 538 #endif
 539         /*
 540          * We have a signal, or exit tracing or single-step.
 541          * These all wind up with the iret return path anyway,
 542          * so just join that path right now.
 543          */
 544         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 545         jmp int_check_syscall_exit_work
 546
 547 badsys:
 548         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 549         jmp ret_from_sys_call
 550
 551 #ifdef CONFIG_AUDITSYSCALL
 552         /*
 553          * Fast path for syscall audit without full syscall trace.
 554          * We just call audit_syscall_entry() directly, and then
 555          * jump back to the normal fast path.
 556          */
 557 auditsys:
 558         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 559         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 560         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 561         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 562         movq %rax,%rsi                  /* 2nd arg: syscall number */
 563         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 564         call audit_syscall_entry
 565         LOAD_ARGS 0             /* reload call-clobbered registers */
 566         jmp system_call_fastpath
 567
 568         /*
 569          * Return fast path for syscall audit.  Call audit_syscall_exit()
 570          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 571          * masked off.
 572          */
 573 sysret_audit:
 574         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 575         cmpq $0,%rsi            /* is it < 0? */
 576         setl %al                /* 1 if so, 0 if not */
 577         movzbl %al,%edi         /* zero-extend that into %edi */
 578         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 579         call audit_syscall_exit
 580         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 581         jmp sysret_check
 582 #endif  /* CONFIG_AUDITSYSCALL */
 583
 584         /* Do syscall tracing */
 585 tracesys:
 586 #ifdef CONFIG_AUDITSYSCALL
 587         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 588         jz auditsys
 589 #endif
 590         SAVE_REST
 591         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 592         FIXUP_TOP_OF_STACK %rdi
 593         movq %rsp,%rdi
 594         call syscall_trace_enter
 595         /*
 596          * Reload arg registers from stack in case ptrace changed them.
 597          * We don't reload %rax because syscall_trace_enter() returned
 598          * the value it wants us to use in the table lookup.
 599          */
 600         LOAD_ARGS ARGOFFSET, 1
 601         RESTORE_REST
 602         cmpq $__NR_syscall_max,%rax
 603         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 604         movq %r10,%rcx  /* fixup for C */
 605         call *sys_call_table(,%rax,8)
 606         movq %rax,RAX-ARGOFFSET(%rsp)
 607         /* Use IRET because user could have changed frame */
 608
 609 /*
 610  * Syscall return path ending with IRET.
 611  * Has correct top of stack, but partial stack frame.
 612  */
 613 GLOBAL(int_ret_from_sys_call)
 614         DISABLE_INTERRUPTS(CLBR_NONE)
 615         TRACE_IRQS_OFF
 616         testl $3,CS-ARGOFFSET(%rsp)
 617         je retint_restore_args
 618         movl $_TIF_ALLWORK_MASK,%edi
 619         /* edi: mask to check */
 620 GLOBAL(int_with_check)
 621         LOCKDEP_SYS_EXIT_IRQ
 622         GET_THREAD_INFO(%rcx)
 623         movl TI_flags(%rcx),%edx
 624         andl %edi,%edx
 625         jnz   int_careful
 626         andl    $~TS_COMPAT,TI_status(%rcx)
 627         jmp   retint_swapgs
 628
 629         /* Either reschedule or signal or syscall exit tracking needed. */
 630         /* First do a reschedule test. */
 631         /* edx: work, edi: workmask */
 632 int_careful:
 633         bt $TIF_NEED_RESCHED,%edx
 634         jnc  int_very_careful
 635         TRACE_IRQS_ON
 636         ENABLE_INTERRUPTS(CLBR_NONE)
 637         pushq_cfi %rdi
 638         call schedule
 639         popq_cfi %rdi
 640         DISABLE_INTERRUPTS(CLBR_NONE)
 641         TRACE_IRQS_OFF
 642         jmp int_with_check
 643
 644         /* handle signals and tracing -- both require a full stack frame */
 645 int_very_careful:
 646         TRACE_IRQS_ON
 647         ENABLE_INTERRUPTS(CLBR_NONE)
 648 int_check_syscall_exit_work:
 649         SAVE_REST
 650         /* Check for syscall exit trace */
 651         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 652         jz int_signal
 653         pushq_cfi %rdi
 654         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 655         call syscall_trace_leave
 656         popq_cfi %rdi
 657         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 658         jmp int_restore_rest
 659
 660 int_signal:
 661         testl $_TIF_DO_NOTIFY_MASK,%edx
 662         jz 1f
 663         movq %rsp,%rdi          # &ptregs -> arg1
 664         xorl %esi,%esi          # oldset -> arg2
 665         call do_notify_resume
 666 1:      movl $_TIF_WORK_MASK,%edi
 667 int_restore_rest:
 668         RESTORE_REST
 669         DISABLE_INTERRUPTS(CLBR_NONE)
 670         TRACE_IRQS_OFF
 671         jmp int_with_check
 672         CFI_ENDPROC
 673 END(system_call)
 674
 675 /*
 676  * Certain special system calls that need to save a complete full stack frame.
 677  */
 678         .macro PTREGSCALL label,func,arg
 679 ENTRY(\label)
 680         PARTIAL_FRAME 1 8               /* offset 8: return address */
 681         subq $REST_SKIP, %rsp
 682         CFI_ADJUST_CFA_OFFSET REST_SKIP
 683         call save_rest
 684         DEFAULT_FRAME 0 8               /* offset 8: return address */
 685         leaq 8(%rsp), \arg      /* pt_regs pointer */
 686         call \func
 687         jmp ptregscall_common
 688         CFI_ENDPROC
 689 END(\label)
 690         .endm
 691
 692         PTREGSCALL stub_clone, sys_clone, %r8
 693         PTREGSCALL stub_fork, sys_fork, %rdi
 694         PTREGSCALL stub_vfork, sys_vfork, %rdi
 695         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 696         PTREGSCALL stub_iopl, sys_iopl, %rsi
 697
 698 ENTRY(ptregscall_common)
 699         DEFAULT_FRAME 1 8       /* offset 8: return address */
 700         RESTORE_TOP_OF_STACK %r11, 8
 701         movq_cfi_restore R15+8, r15
 702         movq_cfi_restore R14+8, r14
 703         movq_cfi_restore R13+8, r13
 704         movq_cfi_restore R12+8, r12
 705         movq_cfi_restore RBP+8, rbp
 706         movq_cfi_restore RBX+8, rbx
 707         ret $REST_SKIP          /* pop extended registers */
 708         CFI_ENDPROC
 709 END(ptregscall_common)
 710
 711 ENTRY(stub_execve)
 712         CFI_STARTPROC
 713         addq $8, %rsp
 714         PARTIAL_FRAME 0
 715         SAVE_REST
 716         FIXUP_TOP_OF_STACK %r11
 717         movq %rsp, %rcx
 718         call sys_execve
 719         RESTORE_TOP_OF_STACK %r11
 720         movq %rax,RAX(%rsp)
 721         RESTORE_REST
 722         jmp int_ret_from_sys_call
 723         CFI_ENDPROC
 724 END(stub_execve)
 725
 726 /*
 727  * sigreturn is special because it needs to restore all registers on return.
 728  * This cannot be done with SYSRET, so use the IRET return path instead.
 729  */
 730 ENTRY(stub_rt_sigreturn)
 731         CFI_STARTPROC
 732         addq $8, %rsp
 733         PARTIAL_FRAME 0
 734         SAVE_REST
 735         movq %rsp,%rdi
 736         FIXUP_TOP_OF_STACK %r11
 737         call sys_rt_sigreturn
 738         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 739         RESTORE_REST
 740         jmp int_ret_from_sys_call
 741         CFI_ENDPROC
 742 END(stub_rt_sigreturn)
 743
 744 /*
 745  * Build the entry stubs and pointer table with some assembler magic.
 746  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 747  * single cache line on all modern x86 implementations.
 748  */
 749         .section .init.rodata,"a"
 750 ENTRY(interrupt)
 751         .section .entry.text
 752         .p2align 5
 753         .p2align CONFIG_X86_L1_CACHE_SHIFT
 754 ENTRY(irq_entries_start)
 755         INTR_FRAME
 756 vector=FIRST_EXTERNAL_VECTOR
 757 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 758         .balign 32
 759   .rept 7
 760     .if vector < NR_VECTORS
 761       .if vector <> FIRST_EXTERNAL_VECTOR
 762         CFI_ADJUST_CFA_OFFSET -8
 763       .endif
 764 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 765       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 766         jmp 2f
 767       .endif
 768       .previous
 769         .quad 1b
 770       .section .entry.text
 771 vector=vector+1
 772     .endif
 773   .endr
 774 2:      jmp common_interrupt
 775 .endr
 776         CFI_ENDPROC
 777 END(irq_entries_start)
 778
 779 .previous
 780 END(interrupt)
 781 .previous
 782
 783 /*
 784  * Interrupt entry/exit.
 785  *
 786  * Interrupt entry points save only callee clobbered registers in fast path.
 787  *
 788  * Entry runs with interrupts off.
 789  */
 790
 791 /* 0(%rsp): ~(interrupt number) */
 792         .macro interrupt func
 793         /* reserve pt_regs for scratch regs and rbp */
 794         subq $ORIG_RAX-RBP, %rsp
 795         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 796         call save_args
 797         PARTIAL_FRAME 0
 798         call \func
 799         .endm
 800
 801 /*
 802  * Interrupt entry/exit should be protected against kprobes
 803  */
 804         .pushsection .kprobes.text, "ax"
 805         /*
 806          * The interrupt stubs push (~vector+0x80) onto the stack and
 807          * then jump to common_interrupt.
 808          */
 809         .p2align CONFIG_X86_L1_CACHE_SHIFT
 810 common_interrupt:
 811         XCPT_FRAME
 812         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 813         interrupt do_IRQ
 814         /* 0(%rsp): old_rsp-ARGOFFSET */
 815 ret_from_intr:
 816         DISABLE_INTERRUPTS(CLBR_NONE)
 817         TRACE_IRQS_OFF
 818         decl PER_CPU_VAR(irq_count)
 819         leaveq
 820
 821         CFI_RESTORE             rbp
 822         CFI_DEF_CFA_REGISTER    rsp
 823         CFI_ADJUST_CFA_OFFSET   -8
 824
 825         /* we did not save rbx, restore only from ARGOFFSET */
 826         addq $8, %rsp
 827         CFI_ADJUST_CFA_OFFSET   -8
 828 exit_intr:
 829         GET_THREAD_INFO(%rcx)
 830         testl $3,CS-ARGOFFSET(%rsp)
 831         je retint_kernel
 832
 833         /* Interrupt came from user space */
 834         /*
 835          * Has a correct top of stack, but a partial stack frame
 836          * %rcx: thread info. Interrupts off.
 837          */
 838 retint_with_reschedule:
 839         movl $_TIF_WORK_MASK,%edi
 840 retint_check:
 841         LOCKDEP_SYS_EXIT_IRQ
 842         movl TI_flags(%rcx),%edx
 843         andl %edi,%edx
 844         CFI_REMEMBER_STATE
 845         jnz  retint_careful
 846
 847 retint_swapgs:          /* return to user-space */
 848         /*
 849          * The iretq could re-enable interrupts:
 850          */
 851         DISABLE_INTERRUPTS(CLBR_ANY)
 852         TRACE_IRQS_IRETQ
 853         SWAPGS
 854         jmp restore_args
 855
 856 retint_restore_args:    /* return to kernel space */
 857         DISABLE_INTERRUPTS(CLBR_ANY)
 858         /*
 859          * The iretq could re-enable interrupts:
 860          */
 861         TRACE_IRQS_IRETQ
 862 restore_args:
 863         RESTORE_ARGS 0,8,0
 864
 865 irq_return:
 866         INTERRUPT_RETURN
 867
 868         .section __ex_table, "a"
 869         .quad irq_return, bad_iret
 870         .previous
 871
 872 #ifdef CONFIG_PARAVIRT
 873 ENTRY(native_iret)
 874         iretq
 875
 876         .section __ex_table,"a"
 877         .quad native_iret, bad_iret
 878         .previous
 879 #endif
 880
 881         .section .fixup,"ax"
 882 bad_iret:
 883         /*
 884          * The iret traps when the %cs or %ss being restored is bogus.
 885          * We've lost the original trap vector and error code.
 886          * #GPF is the most likely one to get for an invalid selector.
 887          * So pretend we completed the iret and took the #GPF in user mode.
 888          *
 889          * We are now running with the kernel GS after exception recovery.
 890          * But error_entry expects us to have user GS to match the user %cs,
 891          * so swap back.
 892          */
 893         pushq $0
 894
 895         SWAPGS
 896         jmp general_protection
 897
 898         .previous
 899
 900         /* edi: workmask, edx: work */
 901 retint_careful:
 902         CFI_RESTORE_STATE
 903         bt    $TIF_NEED_RESCHED,%edx
 904         jnc   retint_signal
 905         TRACE_IRQS_ON
 906         ENABLE_INTERRUPTS(CLBR_NONE)
 907         pushq_cfi %rdi
 908         call  schedule
 909         popq_cfi %rdi
 910         GET_THREAD_INFO(%rcx)
 911         DISABLE_INTERRUPTS(CLBR_NONE)
 912         TRACE_IRQS_OFF
 913         jmp retint_check
 914
 915 retint_signal:
 916         testl $_TIF_DO_NOTIFY_MASK,%edx
 917         jz    retint_swapgs
 918         TRACE_IRQS_ON
 919         ENABLE_INTERRUPTS(CLBR_NONE)
 920         SAVE_REST
 921         movq $-1,ORIG_RAX(%rsp)
 922         xorl %esi,%esi          # oldset
 923         movq %rsp,%rdi          # &pt_regs
 924         call do_notify_resume
 925         RESTORE_REST
 926         DISABLE_INTERRUPTS(CLBR_NONE)
 927         TRACE_IRQS_OFF
 928         GET_THREAD_INFO(%rcx)
 929         jmp retint_with_reschedule
 930
 931 #ifdef CONFIG_PREEMPT
 932         /* Returning to kernel space. Check if we need preemption */
 933         /* rcx:  threadinfo. interrupts off. */
 934 ENTRY(retint_kernel)
 935         cmpl $0,TI_preempt_count(%rcx)
 936         jnz  retint_restore_args
 937         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 938         jnc  retint_restore_args
 939         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 940         jnc  retint_restore_args
 941         call preempt_schedule_irq
 942         jmp exit_intr
 943 #endif
 944
 945         CFI_ENDPROC
 946 END(common_interrupt)
 947 /*
 948  * End of kprobes section
 949  */
 950        .popsection
 951
 952 /*
 953  * APIC interrupts.
 954  */
 955 .macro apicinterrupt num sym do_sym
 956 ENTRY(\sym)
 957         INTR_FRAME
 958         pushq_cfi $~(\num)
 959         interrupt \do_sym
 960         jmp ret_from_intr
 961         CFI_ENDPROC
 962 END(\sym)
 963 .endm
 964
 965 #ifdef CONFIG_SMP
 966 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 967         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 968 apicinterrupt REBOOT_VECTOR \
 969         reboot_interrupt smp_reboot_interrupt
 970 #endif
 971
 972 #ifdef CONFIG_X86_UV
 973 apicinterrupt UV_BAU_MESSAGE \
 974         uv_bau_message_intr1 uv_bau_message_interrupt
 975 #endif
 976 apicinterrupt LOCAL_TIMER_VECTOR \
 977         apic_timer_interrupt smp_apic_timer_interrupt
 978 apicinterrupt X86_PLATFORM_IPI_VECTOR \
 979         x86_platform_ipi smp_x86_platform_ipi
 980
 981 #ifdef CONFIG_SMP
 982 .irp idx,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
 983         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
 984 .if NUM_INVALIDATE_TLB_VECTORS > \idx
 985 apicinterrupt (INVALIDATE_TLB_VECTOR_START)+\idx \
 986         invalidate_interrupt\idx smp_invalidate_interrupt
 987 .endif
 988 .endr
 989 #endif
 990
 991 apicinterrupt THRESHOLD_APIC_VECTOR \
 992         threshold_interrupt smp_threshold_interrupt
 993 apicinterrupt THERMAL_APIC_VECTOR \
 994         thermal_interrupt smp_thermal_interrupt
 995
 996 #ifdef CONFIG_X86_MCE
 997 apicinterrupt MCE_SELF_VECTOR \
 998         mce_self_interrupt smp_mce_self_interrupt
 999 #endif
1000
1001 #ifdef CONFIG_SMP
1002 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1003         call_function_single_interrupt smp_call_function_single_interrupt
1004 apicinterrupt CALL_FUNCTION_VECTOR \
1005         call_function_interrupt smp_call_function_interrupt
1006 apicinterrupt RESCHEDULE_VECTOR \
1007         reschedule_interrupt smp_reschedule_interrupt
1008 #endif
1009
1010 apicinterrupt ERROR_APIC_VECTOR \
1011         error_interrupt smp_error_interrupt
1012 apicinterrupt SPURIOUS_APIC_VECTOR \
1013         spurious_interrupt smp_spurious_interrupt
1014
1015 #ifdef CONFIG_IRQ_WORK
1016 apicinterrupt IRQ_WORK_VECTOR \
1017         irq_work_interrupt smp_irq_work_interrupt
1018 #endif
1019
1020 /*
1021  * Exception entry points.
1022  */
1023 .macro zeroentry sym do_sym
1024 ENTRY(\sym)
1025         INTR_FRAME
1026         PARAVIRT_ADJUST_EXCEPTION_FRAME
1027         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1028         subq $ORIG_RAX-R15, %rsp
1029         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1030         call error_entry
1031         DEFAULT_FRAME 0
1032         movq %rsp,%rdi          /* pt_regs pointer */
1033         xorl %esi,%esi          /* no error code */
1034         call \do_sym
1035         jmp error_exit          /* %ebx: no swapgs flag */
1036         CFI_ENDPROC
1037 END(\sym)
1038 .endm
1039
1040 .macro paranoidzeroentry sym do_sym
1041 ENTRY(\sym)
1042         INTR_FRAME
1043         PARAVIRT_ADJUST_EXCEPTION_FRAME
1044         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1045         subq $ORIG_RAX-R15, %rsp
1046         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1047         call save_paranoid
1048         TRACE_IRQS_OFF
1049         movq %rsp,%rdi          /* pt_regs pointer */
1050         xorl %esi,%esi          /* no error code */
1051         call \do_sym
1052         jmp paranoid_exit       /* %ebx: no swapgs flag */
1053         CFI_ENDPROC
1054 END(\sym)
1055 .endm
1056
1057 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1058 .macro paranoidzeroentry_ist sym do_sym ist
1059 ENTRY(\sym)
1060         INTR_FRAME
1061         PARAVIRT_ADJUST_EXCEPTION_FRAME
1062         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1063         subq $ORIG_RAX-R15, %rsp
1064         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1065         call save_paranoid
1066         TRACE_IRQS_OFF
1067         movq %rsp,%rdi          /* pt_regs pointer */
1068         xorl %esi,%esi          /* no error code */
1069         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1070         call \do_sym
1071         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1072         jmp paranoid_exit       /* %ebx: no swapgs flag */
1073         CFI_ENDPROC
1074 END(\sym)
1075 .endm
1076
1077 .macro errorentry sym do_sym
1078 ENTRY(\sym)
1079         XCPT_FRAME
1080         PARAVIRT_ADJUST_EXCEPTION_FRAME
1081         subq $ORIG_RAX-R15, %rsp
1082         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1083         call error_entry
1084         DEFAULT_FRAME 0
1085         movq %rsp,%rdi                  /* pt_regs pointer */
1086         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1087         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1088         call \do_sym
1089         jmp error_exit                  /* %ebx: no swapgs flag */
1090         CFI_ENDPROC
1091 END(\sym)
1092 .endm
1093
1094         /* error code is on the stack already */
1095 .macro paranoiderrorentry sym do_sym
1096 ENTRY(\sym)
1097         XCPT_FRAME
1098         PARAVIRT_ADJUST_EXCEPTION_FRAME
1099         subq $ORIG_RAX-R15, %rsp
1100         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1101         call save_paranoid
1102         DEFAULT_FRAME 0
1103         TRACE_IRQS_OFF
1104         movq %rsp,%rdi                  /* pt_regs pointer */
1105         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1106         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1107         call \do_sym
1108         jmp paranoid_exit               /* %ebx: no swapgs flag */
1109         CFI_ENDPROC
1110 END(\sym)
1111 .endm
1112
1113 zeroentry divide_error do_divide_error
1114 zeroentry overflow do_overflow
1115 zeroentry bounds do_bounds
1116 zeroentry invalid_op do_invalid_op
1117 zeroentry device_not_available do_device_not_available
1118 paranoiderrorentry double_fault do_double_fault
1119 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1120 errorentry invalid_TSS do_invalid_TSS
1121 errorentry segment_not_present do_segment_not_present
1122 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1123 zeroentry coprocessor_error do_coprocessor_error
1124 errorentry alignment_check do_alignment_check
1125 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1126
1127
1128         /* Reload gs selector with exception handling */
1129         /* edi:  new selector */
1130 ENTRY(native_load_gs_index)
1131         CFI_STARTPROC
1132         pushfq_cfi
1133         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1134         SWAPGS
1135 gs_change:
1136         movl %edi,%gs
1137 2:      mfence          /* workaround */
1138         SWAPGS
1139         popfq_cfi
1140         ret
1141         CFI_ENDPROC
1142 END(native_load_gs_index)
1143
1144         .section __ex_table,"a"
1145         .align 8
1146         .quad gs_change,bad_gs
1147         .previous
1148         .section .fixup,"ax"
1149         /* running with kernelgs */
1150 bad_gs:
1151         SWAPGS                  /* switch back to user gs */
1152         xorl %eax,%eax
1153         movl %eax,%gs
1154         jmp  2b
1155         .previous
1156
1157 ENTRY(kernel_thread_helper)
1158         pushq $0                # fake return address
1159         CFI_STARTPROC
1160         /*
1161          * Here we are in the child and the registers are set as they were
1162          * at kernel_thread() invocation in the parent.
1163          */
1164         call *%rsi
1165         # exit
1166         mov %eax, %edi
1167         call do_exit
1168         ud2                     # padding for call trace
1169         CFI_ENDPROC
1170 END(kernel_thread_helper)
1171
1172 /*
1173  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1174  *
1175  * C extern interface:
1176  *       extern long execve(const char *name, char **argv, char **envp)
1177  *
1178  * asm input arguments:
1179  *      rdi: name, rsi: argv, rdx: envp
1180  *
1181  * We want to fallback into:
1182  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1183  *
1184  * do_sys_execve asm fallback arguments:
1185  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1186  */
1187 ENTRY(kernel_execve)
1188         CFI_STARTPROC
1189         FAKE_STACK_FRAME $0
1190         SAVE_ALL
1191         movq %rsp,%rcx
1192         call sys_execve
1193         movq %rax, RAX(%rsp)
1194         RESTORE_REST
1195         testq %rax,%rax
1196         je int_ret_from_sys_call
1197         RESTORE_ARGS
1198         UNFAKE_STACK_FRAME
1199         ret
1200         CFI_ENDPROC
1201 END(kernel_execve)
1202
1203 /* Call softirq on interrupt stack. Interrupts are off. */
1204 ENTRY(call_softirq)
1205         CFI_STARTPROC
1206         pushq_cfi %rbp
1207         CFI_REL_OFFSET rbp,0
1208         mov  %rsp,%rbp
1209         CFI_DEF_CFA_REGISTER rbp
1210         incl PER_CPU_VAR(irq_count)
1211         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1212         push  %rbp                      # backlink for old unwinder
1213         call __do_softirq
1214         leaveq
1215         CFI_RESTORE             rbp
1216         CFI_DEF_CFA_REGISTER    rsp
1217         CFI_ADJUST_CFA_OFFSET   -8
1218         decl PER_CPU_VAR(irq_count)
1219         ret
1220         CFI_ENDPROC
1221 END(call_softirq)
1222
1223 #ifdef CONFIG_XEN
1224 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1225
1226 /*
1227  * A note on the "critical region" in our callback handler.
1228  * We want to avoid stacking callback handlers due to events occurring
1229  * during handling of the last event. To do this, we keep events disabled
1230  * until we've done all processing. HOWEVER, we must enable events before
1231  * popping the stack frame (can't be done atomically) and so it would still
1232  * be possible to get enough handler activations to overflow the stack.
1233  * Although unlikely, bugs of that kind are hard to track down, so we'd
1234  * like to avoid the possibility.
1235  * So, on entry to the handler we detect whether we interrupted an
1236  * existing activation in its critical region -- if so, we pop the current
1237  * activation and restart the handler using the previous one.
1238  */
1239 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1240         CFI_STARTPROC
1241 /*
1242  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1243  * see the correct pointer to the pt_regs
1244  */
1245         movq %rdi, %rsp            # we don't return, adjust the stack frame
1246         CFI_ENDPROC
1247         DEFAULT_FRAME
1248 11:     incl PER_CPU_VAR(irq_count)
1249         movq %rsp,%rbp
1250         CFI_DEF_CFA_REGISTER rbp
1251         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1252         pushq %rbp                      # backlink for old unwinder
1253         call xen_evtchn_do_upcall
1254         popq %rsp
1255         CFI_DEF_CFA_REGISTER rsp
1256         decl PER_CPU_VAR(irq_count)
1257         jmp  error_exit
1258         CFI_ENDPROC
1259 END(xen_do_hypervisor_callback)
1260
1261 /*
1262  * Hypervisor uses this for application faults while it executes.
1263  * We get here for two reasons:
1264  *  1. Fault while reloading DS, ES, FS or GS
1265  *  2. Fault while executing IRET
1266  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1267  * registers that could be reloaded and zeroed the others.
1268  * Category 2 we fix up by killing the current process. We cannot use the
1269  * normal Linux return path in this case because if we use the IRET hypercall
1270  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1271  * We distinguish between categories by comparing each saved segment register
1272  * with its current contents: any discrepancy means we in category 1.
1273  */
1274 ENTRY(xen_failsafe_callback)
1275         INTR_FRAME 1 (6*8)
1276         /*CFI_REL_OFFSET gs,GS*/
1277         /*CFI_REL_OFFSET fs,FS*/
1278         /*CFI_REL_OFFSET es,ES*/
1279         /*CFI_REL_OFFSET ds,DS*/
1280         CFI_REL_OFFSET r11,8
1281         CFI_REL_OFFSET rcx,0
1282         movw %ds,%cx
1283         cmpw %cx,0x10(%rsp)
1284         CFI_REMEMBER_STATE
1285         jne 1f
1286         movw %es,%cx
1287         cmpw %cx,0x18(%rsp)
1288         jne 1f
1289         movw %fs,%cx
1290         cmpw %cx,0x20(%rsp)
1291         jne 1f
1292         movw %gs,%cx
1293         cmpw %cx,0x28(%rsp)
1294         jne 1f
1295         /* All segments match their saved values => Category 2 (Bad IRET). */
1296         movq (%rsp),%rcx
1297         CFI_RESTORE rcx
1298         movq 8(%rsp),%r11
1299         CFI_RESTORE r11
1300         addq $0x30,%rsp
1301         CFI_ADJUST_CFA_OFFSET -0x30
1302         pushq_cfi $0    /* RIP */
1303         pushq_cfi %r11
1304         pushq_cfi %rcx
1305         jmp general_protection
1306         CFI_RESTORE_STATE
1307 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1308         movq (%rsp),%rcx
1309         CFI_RESTORE rcx
1310         movq 8(%rsp),%r11
1311         CFI_RESTORE r11
1312         addq $0x30,%rsp
1313         CFI_ADJUST_CFA_OFFSET -0x30
1314         pushq_cfi $0
1315         SAVE_ALL
1316         jmp error_exit
1317         CFI_ENDPROC
1318 END(xen_failsafe_callback)
1319
1320 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1321         xen_hvm_callback_vector xen_evtchn_do_upcall
1322
1323 #endif /* CONFIG_XEN */
1324
1325 /*
1326  * Some functions should be protected against kprobes
1327  */
1328         .pushsection .kprobes.text, "ax"
1329
1330 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1331 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1332 paranoiderrorentry stack_segment do_stack_segment
1333 #ifdef CONFIG_XEN
1334 zeroentry xen_debug do_debug
1335 zeroentry xen_int3 do_int3
1336 errorentry xen_stack_segment do_stack_segment
1337 #endif
1338 errorentry general_protection do_general_protection
1339 errorentry page_fault do_page_fault
1340 #ifdef CONFIG_KVM_GUEST
1341 errorentry async_page_fault do_async_page_fault
1342 #endif
1343 #ifdef CONFIG_X86_MCE
1344 paranoidzeroentry machine_check *machine_check_vector(%rip)
1345 #endif
1346
1347         /*
1348          * "Paranoid" exit path from exception stack.
1349          * Paranoid because this is used by NMIs and cannot take
1350          * any kernel state for granted.
1351          * We don't do kernel preemption checks here, because only
1352          * NMI should be common and it does not enable IRQs and
1353          * cannot get reschedule ticks.
1354          *
1355          * "trace" is 0 for the NMI handler only, because irq-tracing
1356          * is fundamentally NMI-unsafe. (we cannot change the soft and
1357          * hard flags at once, atomically)
1358          */
1359
1360         /* ebx: no swapgs flag */
1361 ENTRY(paranoid_exit)
1362         DEFAULT_FRAME
1363         DISABLE_INTERRUPTS(CLBR_NONE)
1364         TRACE_IRQS_OFF
1365         testl %ebx,%ebx                         /* swapgs needed? */
1366         jnz paranoid_restore
1367         testl $3,CS(%rsp)
1368         jnz   paranoid_userspace
1369 paranoid_swapgs:
1370         TRACE_IRQS_IRETQ 0
1371         SWAPGS_UNSAFE_STACK
1372         RESTORE_ALL 8
1373         jmp irq_return
1374 paranoid_restore:
1375         TRACE_IRQS_IRETQ 0
1376         RESTORE_ALL 8
1377         jmp irq_return
1378 paranoid_userspace:
1379         GET_THREAD_INFO(%rcx)
1380         movl TI_flags(%rcx),%ebx
1381         andl $_TIF_WORK_MASK,%ebx
1382         jz paranoid_swapgs
1383         movq %rsp,%rdi                  /* &pt_regs */
1384         call sync_regs
1385         movq %rax,%rsp                  /* switch stack for scheduling */
1386         testl $_TIF_NEED_RESCHED,%ebx
1387         jnz paranoid_schedule
1388         movl %ebx,%edx                  /* arg3: thread flags */
1389         TRACE_IRQS_ON
1390         ENABLE_INTERRUPTS(CLBR_NONE)
1391         xorl %esi,%esi                  /* arg2: oldset */
1392         movq %rsp,%rdi                  /* arg1: &pt_regs */
1393         call do_notify_resume
1394         DISABLE_INTERRUPTS(CLBR_NONE)
1395         TRACE_IRQS_OFF
1396         jmp paranoid_userspace
1397 paranoid_schedule:
1398         TRACE_IRQS_ON
1399         ENABLE_INTERRUPTS(CLBR_ANY)
1400         call schedule
1401         DISABLE_INTERRUPTS(CLBR_ANY)
1402         TRACE_IRQS_OFF
1403         jmp paranoid_userspace
1404         CFI_ENDPROC
1405 END(paranoid_exit)
1406
1407 /*
1408  * Exception entry point. This expects an error code/orig_rax on the stack.
1409  * returns in "no swapgs flag" in %ebx.
1410  */
1411 ENTRY(error_entry)
1412         XCPT_FRAME
1413         CFI_ADJUST_CFA_OFFSET 15*8
1414         /* oldrax contains error code */
1415         cld
1416         movq_cfi rdi, RDI+8
1417         movq_cfi rsi, RSI+8
1418         movq_cfi rdx, RDX+8
1419         movq_cfi rcx, RCX+8
1420         movq_cfi rax, RAX+8
1421         movq_cfi  r8,  R8+8
1422         movq_cfi  r9,  R9+8
1423         movq_cfi r10, R10+8
1424         movq_cfi r11, R11+8
1425         movq_cfi rbx, RBX+8
1426         movq_cfi rbp, RBP+8
1427         movq_cfi r12, R12+8
1428         movq_cfi r13, R13+8
1429         movq_cfi r14, R14+8
1430         movq_cfi r15, R15+8
1431         xorl %ebx,%ebx
1432         testl $3,CS+8(%rsp)
1433         je error_kernelspace
1434 error_swapgs:
1435         SWAPGS
1436 error_sti:
1437         TRACE_IRQS_OFF
1438         ret
1439
1440 /*
1441  * There are two places in the kernel that can potentially fault with
1442  * usergs. Handle them here. The exception handlers after iret run with
1443  * kernel gs again, so don't set the user space flag. B stepping K8s
1444  * sometimes report an truncated RIP for IRET exceptions returning to
1445  * compat mode. Check for these here too.
1446  */
1447 error_kernelspace:
1448         incl %ebx
1449         leaq irq_return(%rip),%rcx
1450         cmpq %rcx,RIP+8(%rsp)
1451         je error_swapgs
1452         movl %ecx,%eax  /* zero extend */
1453         cmpq %rax,RIP+8(%rsp)
1454         je bstep_iret
1455         cmpq $gs_change,RIP+8(%rsp)
1456         je error_swapgs
1457         jmp error_sti
1458
1459 bstep_iret:
1460         /* Fix truncated RIP */
1461         movq %rcx,RIP+8(%rsp)
1462         jmp error_swapgs
1463         CFI_ENDPROC
1464 END(error_entry)
1465
1466
1467 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1468 ENTRY(error_exit)
1469         DEFAULT_FRAME
1470         movl %ebx,%eax
1471         RESTORE_REST
1472         DISABLE_INTERRUPTS(CLBR_NONE)
1473         TRACE_IRQS_OFF
1474         GET_THREAD_INFO(%rcx)
1475         testl %eax,%eax
1476         jne retint_kernel
1477         LOCKDEP_SYS_EXIT_IRQ
1478         movl TI_flags(%rcx),%edx
1479         movl $_TIF_WORK_MASK,%edi
1480         andl %edi,%edx
1481         jnz retint_careful
1482         jmp retint_swapgs
1483         CFI_ENDPROC
1484 END(error_exit)
1485
1486
1487         /* runs on exception stack */
1488 ENTRY(nmi)
1489         INTR_FRAME
1490         PARAVIRT_ADJUST_EXCEPTION_FRAME
1491         pushq_cfi $-1
1492         subq $ORIG_RAX-R15, %rsp
1493         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1494         call save_paranoid
1495         DEFAULT_FRAME 0
1496         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1497         movq %rsp,%rdi
1498         movq $-1,%rsi
1499         call do_nmi
1500 #ifdef CONFIG_TRACE_IRQFLAGS
1501         /* paranoidexit; without TRACE_IRQS_OFF */
1502         /* ebx: no swapgs flag */
1503         DISABLE_INTERRUPTS(CLBR_NONE)
1504         testl %ebx,%ebx                         /* swapgs needed? */
1505         jnz nmi_restore
1506         testl $3,CS(%rsp)
1507         jnz nmi_userspace
1508 nmi_swapgs:
1509         SWAPGS_UNSAFE_STACK
1510 nmi_restore:
1511         RESTORE_ALL 8
1512         jmp irq_return
1513 nmi_userspace:
1514         GET_THREAD_INFO(%rcx)
1515         movl TI_flags(%rcx),%ebx
1516         andl $_TIF_WORK_MASK,%ebx
1517         jz nmi_swapgs
1518         movq %rsp,%rdi                  /* &pt_regs */
1519         call sync_regs
1520         movq %rax,%rsp                  /* switch stack for scheduling */
1521         testl $_TIF_NEED_RESCHED,%ebx
1522         jnz nmi_schedule
1523         movl %ebx,%edx                  /* arg3: thread flags */
1524         ENABLE_INTERRUPTS(CLBR_NONE)
1525         xorl %esi,%esi                  /* arg2: oldset */
1526         movq %rsp,%rdi                  /* arg1: &pt_regs */
1527         call do_notify_resume
1528         DISABLE_INTERRUPTS(CLBR_NONE)
1529         jmp nmi_userspace
1530 nmi_schedule:
1531         ENABLE_INTERRUPTS(CLBR_ANY)
1532         call schedule
1533         DISABLE_INTERRUPTS(CLBR_ANY)
1534         jmp nmi_userspace
1535         CFI_ENDPROC
1536 #else
1537         jmp paranoid_exit
1538         CFI_ENDPROC
1539 #endif
1540 END(nmi)
1541
1542 ENTRY(ignore_sysret)
1543         CFI_STARTPROC
1544         mov $-ENOSYS,%eax
1545         sysret
1546         CFI_ENDPROC
1547 END(ignore_sysret)
1548
1549 /*
1550  * End of kprobes section
1551  */
1552         .popsection