arch/x86/kernel/vmlinux.lds.S

   1 /*
   2  * ld script for the x86 kernel
   3  *
   4  * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  *
   6  * Modernisation, unification and other changes and fixes:
   7  *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
   8  *
   9  *
  10  * Don't define absolute symbols until and unless you know that symbol
  11  * value is should remain constant even if kernel image is relocated
  12  * at run time. Absolute symbols are not relocated. If symbol value should
  13  * change if kernel is relocated, make the symbol section relative and
  14  * put it inside the section definition.
  15  */
  16
  17 #ifdef CONFIG_X86_32
  18 #define LOAD_OFFSET __PAGE_OFFSET
  19 #else
  20 #define LOAD_OFFSET __START_KERNEL_map
  21 #endif
  22
  23 #include <asm-generic/vmlinux.lds.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/thread_info.h>
  26 #include <asm/page_types.h>
  27 #include <asm/cache.h>
  28 #include <asm/boot.h>
  29
  30 #undef i386     /* in case the preprocessor is a 32bit one */
  31
  32 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
  33
  34 #ifdef CONFIG_X86_32
  35 OUTPUT_ARCH(i386)
  36 ENTRY(phys_startup_32)
  37 jiffies = jiffies_64;
  38 #else
  39 OUTPUT_ARCH(i386:x86-64)
  40 ENTRY(phys_startup_64)
  41 jiffies_64 = jiffies;
  42 #endif
  43
  44 #if defined(CONFIG_X86_64) && defined(CONFIG_DEBUG_RODATA)
  45 /*
  46  * On 64-bit, align RODATA to 2MB so that even with CONFIG_DEBUG_RODATA
  47  * we retain large page mappings for boundaries spanning kernel text, rodata
  48  * and data sections.
  49  *
  50  * However, kernel identity mappings will have different RWX permissions
  51  * to the pages mapping to text and to the pages padding (which are freed) the
  52  * text section. Hence kernel identity mappings will be broken to smaller
  53  * pages. For 64-bit, kernel text and kernel identity mappings are different,
  54  * so we can enable protection checks that come with CONFIG_DEBUG_RODATA,
  55  * as well as retain 2MB large page mappings for kernel text.
  56  */
  57 #define X64_ALIGN_DEBUG_RODATA_BEGIN    . = ALIGN(HPAGE_SIZE);
  58
  59 #define X64_ALIGN_DEBUG_RODATA_END                              \
  60                 . = ALIGN(HPAGE_SIZE);                          \
  61                 __end_rodata_hpage_align = .;
  62
  63 #else
  64
  65 #define X64_ALIGN_DEBUG_RODATA_BEGIN
  66 #define X64_ALIGN_DEBUG_RODATA_END
  67
  68 #endif
  69
  70 PHDRS {
  71         text PT_LOAD FLAGS(5);          /* R_E */
  72         data PT_LOAD FLAGS(6);          /* RW_ */
  73 #ifdef CONFIG_X86_64
  74         user PT_LOAD FLAGS(5);          /* R_E */
  75 #ifdef CONFIG_SMP
  76         percpu PT_LOAD FLAGS(6);        /* RW_ */
  77 #endif
  78         init PT_LOAD FLAGS(7);          /* RWE */
  79 #endif
  80         note PT_NOTE FLAGS(0);          /* ___ */
  81 }
  82
  83 SECTIONS
  84 {
  85 #ifdef CONFIG_X86_32
  86         . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  87         phys_startup_32 = startup_32 - LOAD_OFFSET;
  88 #else
  89         . = __START_KERNEL;
  90         phys_startup_64 = startup_64 - LOAD_OFFSET;
  91 #endif
  92
  93         /* Text and read-only data */
  94         .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  95                 _text = .;
  96                 /* bootstrapping code */
  97                 HEAD_TEXT
  98 #ifdef CONFIG_X86_32
  99                 . = ALIGN(PAGE_SIZE);
 100                 *(.text..page_aligned)
 101 #endif
 102                 . = ALIGN(8);
 103                 _stext = .;
 104                 TEXT_TEXT
 105                 SCHED_TEXT
 106                 LOCK_TEXT
 107                 KPROBES_TEXT
 108                 ENTRY_TEXT
 109                 IRQENTRY_TEXT
 110                 *(.fixup)
 111                 *(.gnu.warning)
 112                 /* End of text section */
 113                 _etext = .;
 114         } :text = 0x9090
 115
 116         NOTES :text :note
 117
 118         EXCEPTION_TABLE(16) :text = 0x9090
 119
 120 #if defined(CONFIG_DEBUG_RODATA)
 121         /* .text should occupy whole number of pages */
 122         . = ALIGN(PAGE_SIZE);
 123 #endif
 124         X64_ALIGN_DEBUG_RODATA_BEGIN
 125         RO_DATA(PAGE_SIZE)
 126         X64_ALIGN_DEBUG_RODATA_END
 127
 128         /* Data */
 129         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 130                 /* Start of data section */
 131                 _sdata = .;
 132
 133                 /* init_task */
 134                 INIT_TASK_DATA(THREAD_SIZE)
 135
 136 #ifdef CONFIG_X86_32
 137                 /* 32 bit has nosave before _edata */
 138                 NOSAVE_DATA
 139 #endif
 140
 141                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 142
 143                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 144
 145                 DATA_DATA
 146                 CONSTRUCTORS
 147
 148                 /* rarely changed data like cpu maps */
 149                 READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
 150
 151                 /* End of data section */
 152                 _edata = .;
 153         } :data
 154
 155 #ifdef CONFIG_X86_64
 156
 157         . = ALIGN(PAGE_SIZE);
 158         __vvar_page = .;
 159
 160         .vvar : AT(ADDR(.vvar) - LOAD_OFFSET) {
 161                 /* work around gold bug 13023 */
 162                 __vvar_beginning_hack = .;
 163
 164                 /* Place all vvars at the offsets in asm/vvar.h. */
 165 #define EMIT_VVAR(name, offset)                         \
 166                 . = __vvar_beginning_hack + offset;     \
 167                 *(.vvar_ ## name)
 168 #define __VVAR_KERNEL_LDS
 169 #include <asm/vvar.h>
 170 #undef __VVAR_KERNEL_LDS
 171 #undef EMIT_VVAR
 172
 173         } :data
 174
 175        . = ALIGN(__vvar_page + PAGE_SIZE, PAGE_SIZE);
 176
 177 #define VSYSCALL_ADDR (-10*1024*1024)
 178
 179 #define VLOAD_OFFSET (VSYSCALL_ADDR - __vsyscall_0 + LOAD_OFFSET)
 180 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
 181
 182 #define VVIRT_OFFSET (VSYSCALL_ADDR - __vsyscall_0)
 183 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
 184
 185         __vsyscall_0 = .;
 186
 187         . = VSYSCALL_ADDR;
 188         .vsyscall : AT(VLOAD(.vsyscall)) {
 189                 /* work around gold bug 13023 */
 190                 __vsyscall_beginning_hack = .;
 191                 *(.vsyscall_0)
 192
 193                 . = __vsyscall_beginning_hack + 1024;
 194                 *(.vsyscall_1)
 195
 196                 . = __vsyscall_beginning_hack + 2048;
 197                 *(.vsyscall_2)
 198
 199                 . = __vsyscall_beginning_hack + 4096;  /* Pad the whole page. */
 200         } :user =0xcc
 201         . = ALIGN(__vsyscall_0 + PAGE_SIZE, PAGE_SIZE);
 202
 203 #undef VSYSCALL_ADDR
 204 #undef VLOAD_OFFSET
 205 #undef VLOAD
 206 #undef VVIRT_OFFSET
 207 #undef VVIRT
 208
 209 #endif /* CONFIG_X86_64 */
 210
 211         /* Init code and data - will be freed after init */
 212         . = ALIGN(PAGE_SIZE);
 213         .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
 214                 __init_begin = .; /* paired with __init_end */
 215         }
 216
 217 #if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
 218         /*
 219          * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
 220          * output PHDR, so the next output section - .init.text - should
 221          * start another segment - init.
 222          */
 223         PERCPU_VADDR(INTERNODE_CACHE_BYTES, 0, :percpu)
 224 #endif
 225
 226         INIT_TEXT_SECTION(PAGE_SIZE)
 227 #ifdef CONFIG_X86_64
 228         :init
 229 #endif
 230
 231         INIT_DATA_SECTION(16)
 232
 233         /*
 234          * Code and data for a variety of lowlevel trampolines, to be
 235          * copied into base memory (< 1 MiB) during initialization.
 236          * Since it is copied early, the main copy can be discarded
 237          * afterwards.
 238          */
 239          .x86_trampoline : AT(ADDR(.x86_trampoline) - LOAD_OFFSET) {
 240                 x86_trampoline_start = .;
 241                 *(.x86_trampoline)
 242                 x86_trampoline_end = .;
 243         }
 244
 245         .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 246                 __x86_cpu_dev_start = .;
 247                 *(.x86_cpu_dev.init)
 248                 __x86_cpu_dev_end = .;
 249         }
 250
 251         /*
 252          * start address and size of operations which during runtime
 253          * can be patched with virtualization friendly instructions or
 254          * baremetal native ones. Think page table operations.
 255          * Details in paravirt_types.h
 256          */
 257         . = ALIGN(8);
 258         .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 259                 __parainstructions = .;
 260                 *(.parainstructions)
 261                 __parainstructions_end = .;
 262         }
 263
 264         /*
 265          * struct alt_inst entries. From the header (alternative.h):
 266          * "Alternative instructions for different CPU types or capabilities"
 267          * Think locking instructions on spinlocks.
 268          */
 269         . = ALIGN(8);
 270         .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 271                 __alt_instructions = .;
 272                 *(.altinstructions)
 273                 __alt_instructions_end = .;
 274         }
 275
 276         /*
 277          * And here are the replacement instructions. The linker sticks
 278          * them as binary blobs. The .altinstructions has enough data to
 279          * get the address and the length of them to patch the kernel safely.
 280          */
 281         .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 282                 *(.altinstr_replacement)
 283         }
 284
 285         /*
 286          * struct iommu_table_entry entries are injected in this section.
 287          * It is an array of IOMMUs which during run time gets sorted depending
 288          * on its dependency order. After rootfs_initcall is complete
 289          * this section can be safely removed.
 290          */
 291         .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
 292                 __iommu_table = .;
 293                 *(.iommu_table)
 294                 __iommu_table_end = .;
 295         }
 296
 297         . = ALIGN(8);
 298         .apicdrivers : AT(ADDR(.apicdrivers) - LOAD_OFFSET) {
 299                 __apicdrivers = .;
 300                 *(.apicdrivers);
 301                 __apicdrivers_end = .;
 302         }
 303
 304         . = ALIGN(8);
 305         /*
 306          * .exit.text is discard at runtime, not link time, to deal with
 307          *  references from .altinstructions and .eh_frame
 308          */
 309         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 310                 EXIT_TEXT
 311         }
 312
 313         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 314                 EXIT_DATA
 315         }
 316
 317 #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
 318         PERCPU_SECTION(INTERNODE_CACHE_BYTES)
 319 #endif
 320
 321         . = ALIGN(PAGE_SIZE);
 322
 323         /* freed after init ends here */
 324         .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
 325                 __init_end = .;
 326         }
 327
 328         /*
 329          * smp_locks might be freed after init
 330          * start/end must be page aligned
 331          */
 332         . = ALIGN(PAGE_SIZE);
 333         .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 334                 __smp_locks = .;
 335                 *(.smp_locks)
 336                 . = ALIGN(PAGE_SIZE);
 337                 __smp_locks_end = .;
 338         }
 339
 340 #ifdef CONFIG_X86_64
 341         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 342                 NOSAVE_DATA
 343         }
 344 #endif
 345
 346         /* BSS */
 347         . = ALIGN(PAGE_SIZE);
 348         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 349                 __bss_start = .;
 350                 *(.bss..page_aligned)
 351                 *(.bss)
 352                 . = ALIGN(PAGE_SIZE);
 353                 __bss_stop = .;
 354         }
 355
 356         . = ALIGN(PAGE_SIZE);
 357         .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
 358                 __brk_base = .;
 359                 . += 64 * 1024;         /* 64k alignment slop space */
 360                 *(.brk_reservation)     /* areas brk users have reserved */
 361                 __brk_limit = .;
 362         }
 363
 364         _end = .;
 365
 366         STABS_DEBUG
 367         DWARF_DEBUG
 368
 369         /* Sections to be discarded */
 370         DISCARDS
 371         /DISCARD/ : { *(.eh_frame) }
 372 }
 373
 374
 375 #ifdef CONFIG_X86_32
 376 /*
 377  * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
 378  */
 379 . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
 380            "kernel image bigger than KERNEL_IMAGE_SIZE");
 381 #else
 382 /*
 383  * Per-cpu symbols which need to be offset from __per_cpu_load
 384  * for the boot processor.
 385  */
 386 #define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load
 387 INIT_PER_CPU(gdt_page);
 388 INIT_PER_CPU(irq_stack_union);
 389
 390 /*
 391  * Build-time check on the image size:
 392  */
 393 . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 394            "kernel image bigger than KERNEL_IMAGE_SIZE");
 395
 396 #ifdef CONFIG_SMP
 397 . = ASSERT((irq_stack_union == 0),
 398            "irq_stack_union is not at start of per-cpu area");
 399 #endif
 400
 401 #endif /* CONFIG_X86_32 */
 402
 403 #ifdef CONFIG_KEXEC
 404 #include <asm/kexec.h>
 405
 406 . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
 407            "kexec control code size is too big");
 408 #endif
 409