arch/x86/kernel/vmlinux.lds.S

   1 /*
   2  * ld script for the x86 kernel
   3  *
   4  * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  *
   6  * Modernisation, unification and other changes and fixes:
   7  *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
   8  *
   9  *
  10  * Don't define absolute symbols until and unless you know that symbol
  11  * value is should remain constant even if kernel image is relocated
  12  * at run time. Absolute symbols are not relocated. If symbol value should
  13  * change if kernel is relocated, make the symbol section relative and
  14  * put it inside the section definition.
  15  */
  16
  17 #ifdef CONFIG_X86_32
  18 #define LOAD_OFFSET __PAGE_OFFSET
  19 #else
  20 #define LOAD_OFFSET __START_KERNEL_map
  21 #endif
  22
  23 #include <asm-generic/vmlinux.lds.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/thread_info.h>
  26 #include <asm/page_types.h>
  27 #include <asm/cache.h>
  28 #include <asm/boot.h>
  29
  30 #undef i386     /* in case the preprocessor is a 32bit one */
  31
  32 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
  33
  34 #ifdef CONFIG_X86_32
  35 OUTPUT_ARCH(i386)
  36 ENTRY(phys_startup_32)
  37 jiffies = jiffies_64;
  38 #else
  39 OUTPUT_ARCH(i386:x86-64)
  40 ENTRY(phys_startup_64)
  41 jiffies_64 = jiffies;
  42 #endif
  43
  44 #if defined(CONFIG_X86_64)
  45 /*
  46  * On 64-bit, align RODATA to 2MB so we retain large page mappings for
  47  * boundaries spanning kernel text, rodata and data sections.
  48  *
  49  * However, kernel identity mappings will have different RWX permissions
  50  * to the pages mapping to text and to the pages padding (which are freed) the
  51  * text section. Hence kernel identity mappings will be broken to smaller
  52  * pages. For 64-bit, kernel text and kernel identity mappings are different,
  53  * so we can enable protection checks as well as retain 2MB large page
  54  * mappings for kernel text.
  55  */
  56 #define X64_ALIGN_RODATA_BEGIN  . = ALIGN(HPAGE_SIZE);
  57
  58 #define X64_ALIGN_RODATA_END                                    \
  59                 . = ALIGN(HPAGE_SIZE);                          \
  60                 __end_rodata_hpage_align = .;
  61
  62 #else
  63
  64 #define X64_ALIGN_RODATA_BEGIN
  65 #define X64_ALIGN_RODATA_END
  66
  67 #endif
  68
  69 PHDRS {
  70         text PT_LOAD FLAGS(5);          /* R_E */
  71         data PT_LOAD FLAGS(6);          /* RW_ */
  72 #ifdef CONFIG_X86_64
  73 #ifdef CONFIG_SMP
  74         percpu PT_LOAD FLAGS(6);        /* RW_ */
  75 #endif
  76         init PT_LOAD FLAGS(7);          /* RWE */
  77 #endif
  78         note PT_NOTE FLAGS(0);          /* ___ */
  79 }
  80
  81 SECTIONS
  82 {
  83 #ifdef CONFIG_X86_32
  84         . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  85         phys_startup_32 = ABSOLUTE(startup_32 - LOAD_OFFSET);
  86 #else
  87         . = __START_KERNEL;
  88         phys_startup_64 = ABSOLUTE(startup_64 - LOAD_OFFSET);
  89 #endif
  90
  91         /* Text and read-only data */
  92         .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  93                 _text = .;
  94                 _stext = .;
  95                 /* bootstrapping code */
  96                 HEAD_TEXT
  97                 . = ALIGN(8);
  98                 TEXT_TEXT
  99                 SCHED_TEXT
 100                 CPUIDLE_TEXT
 101                 LOCK_TEXT
 102                 KPROBES_TEXT
 103                 ENTRY_TEXT
 104                 IRQENTRY_TEXT
 105                 SOFTIRQENTRY_TEXT
 106                 *(.fixup)
 107                 *(.gnu.warning)
 108                 /* End of text section */
 109                 _etext = .;
 110         } :text = 0x9090
 111
 112         NOTES :text :note
 113
 114         EXCEPTION_TABLE(16) :text = 0x9090
 115
 116         /* .text should occupy whole number of pages */
 117         . = ALIGN(PAGE_SIZE);
 118         X64_ALIGN_RODATA_BEGIN
 119         RO_DATA(PAGE_SIZE)
 120         X64_ALIGN_RODATA_END
 121
 122         /* Data */
 123         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 124                 /* Start of data section */
 125                 _sdata = .;
 126
 127                 /* init_task */
 128                 INIT_TASK_DATA(THREAD_SIZE)
 129
 130 #ifdef CONFIG_X86_32
 131                 /* 32 bit has nosave before _edata */
 132                 NOSAVE_DATA
 133 #endif
 134
 135                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 136
 137                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 138
 139                 DATA_DATA
 140                 CONSTRUCTORS
 141
 142                 /* rarely changed data like cpu maps */
 143                 READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
 144
 145                 /* End of data section */
 146                 _edata = .;
 147         } :data
 148
 149         BUG_TABLE
 150
 151         . = ALIGN(PAGE_SIZE);
 152         __vvar_page = .;
 153
 154         .vvar : AT(ADDR(.vvar) - LOAD_OFFSET) {
 155                 /* work around gold bug 13023 */
 156                 __vvar_beginning_hack = .;
 157
 158                 /* Place all vvars at the offsets in asm/vvar.h. */
 159 #define EMIT_VVAR(name, offset)                         \
 160                 . = __vvar_beginning_hack + offset;     \
 161                 *(.vvar_ ## name)
 162 #define __VVAR_KERNEL_LDS
 163 #include <asm/vvar.h>
 164 #undef __VVAR_KERNEL_LDS
 165 #undef EMIT_VVAR
 166
 167                 /*
 168                  * Pad the rest of the page with zeros.  Otherwise the loader
 169                  * can leave garbage here.
 170                  */
 171                 . = __vvar_beginning_hack + PAGE_SIZE;
 172         } :data
 173
 174        . = ALIGN(__vvar_page + PAGE_SIZE, PAGE_SIZE);
 175
 176         /* Init code and data - will be freed after init */
 177         . = ALIGN(PAGE_SIZE);
 178         .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
 179                 __init_begin = .; /* paired with __init_end */
 180         }
 181
 182 #if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
 183         /*
 184          * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
 185          * output PHDR, so the next output section - .init.text - should
 186          * start another segment - init.
 187          */
 188         PERCPU_VADDR(INTERNODE_CACHE_BYTES, 0, :percpu)
 189         ASSERT(SIZEOF(.data..percpu) < CONFIG_PHYSICAL_START,
 190                "per-CPU data too large - increase CONFIG_PHYSICAL_START")
 191 #endif
 192
 193         INIT_TEXT_SECTION(PAGE_SIZE)
 194 #ifdef CONFIG_X86_64
 195         :init
 196 #endif
 197
 198         /*
 199          * Section for code used exclusively before alternatives are run. All
 200          * references to such code must be patched out by alternatives, normally
 201          * by using X86_FEATURE_ALWAYS CPU feature bit.
 202          *
 203          * See static_cpu_has() for an example.
 204          */
 205         .altinstr_aux : AT(ADDR(.altinstr_aux) - LOAD_OFFSET) {
 206                 *(.altinstr_aux)
 207         }
 208
 209         INIT_DATA_SECTION(16)
 210
 211         .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 212                 __x86_cpu_dev_start = .;
 213                 *(.x86_cpu_dev.init)
 214                 __x86_cpu_dev_end = .;
 215         }
 216
 217 #ifdef CONFIG_X86_INTEL_MID
 218         .x86_intel_mid_dev.init : AT(ADDR(.x86_intel_mid_dev.init) - \
 219                                                                 LOAD_OFFSET) {
 220                 __x86_intel_mid_dev_start = .;
 221                 *(.x86_intel_mid_dev.init)
 222                 __x86_intel_mid_dev_end = .;
 223         }
 224 #endif
 225
 226         /*
 227          * start address and size of operations which during runtime
 228          * can be patched with virtualization friendly instructions or
 229          * baremetal native ones. Think page table operations.
 230          * Details in paravirt_types.h
 231          */
 232         . = ALIGN(8);
 233         .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 234                 __parainstructions = .;
 235                 *(.parainstructions)
 236                 __parainstructions_end = .;
 237         }
 238
 239         /*
 240          * struct alt_inst entries. From the header (alternative.h):
 241          * "Alternative instructions for different CPU types or capabilities"
 242          * Think locking instructions on spinlocks.
 243          */
 244         . = ALIGN(8);
 245         .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 246                 __alt_instructions = .;
 247                 *(.altinstructions)
 248                 __alt_instructions_end = .;
 249         }
 250
 251         /*
 252          * And here are the replacement instructions. The linker sticks
 253          * them as binary blobs. The .altinstructions has enough data to
 254          * get the address and the length of them to patch the kernel safely.
 255          */
 256         .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 257                 *(.altinstr_replacement)
 258         }
 259
 260         /*
 261          * struct iommu_table_entry entries are injected in this section.
 262          * It is an array of IOMMUs which during run time gets sorted depending
 263          * on its dependency order. After rootfs_initcall is complete
 264          * this section can be safely removed.
 265          */
 266         .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
 267                 __iommu_table = .;
 268                 *(.iommu_table)
 269                 __iommu_table_end = .;
 270         }
 271
 272         . = ALIGN(8);
 273         .apicdrivers : AT(ADDR(.apicdrivers) - LOAD_OFFSET) {
 274                 __apicdrivers = .;
 275                 *(.apicdrivers);
 276                 __apicdrivers_end = .;
 277         }
 278
 279         . = ALIGN(8);
 280         /*
 281          * .exit.text is discard at runtime, not link time, to deal with
 282          *  references from .altinstructions and .eh_frame
 283          */
 284         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 285                 EXIT_TEXT
 286         }
 287
 288         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 289                 EXIT_DATA
 290         }
 291
 292 #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
 293         PERCPU_SECTION(INTERNODE_CACHE_BYTES)
 294 #endif
 295
 296         . = ALIGN(PAGE_SIZE);
 297
 298         /* freed after init ends here */
 299         .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
 300                 __init_end = .;
 301         }
 302
 303         /*
 304          * smp_locks might be freed after init
 305          * start/end must be page aligned
 306          */
 307         . = ALIGN(PAGE_SIZE);
 308         .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 309                 __smp_locks = .;
 310                 *(.smp_locks)
 311                 . = ALIGN(PAGE_SIZE);
 312                 __smp_locks_end = .;
 313         }
 314
 315 #ifdef CONFIG_X86_64
 316         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 317                 NOSAVE_DATA
 318         }
 319 #endif
 320
 321         /* BSS */
 322         . = ALIGN(PAGE_SIZE);
 323         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 324                 __bss_start = .;
 325                 *(.bss..page_aligned)
 326                 *(.bss)
 327                 . = ALIGN(PAGE_SIZE);
 328                 __bss_stop = .;
 329         }
 330
 331         . = ALIGN(PAGE_SIZE);
 332         .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
 333                 __brk_base = .;
 334                 . += 64 * 1024;         /* 64k alignment slop space */
 335                 *(.brk_reservation)     /* areas brk users have reserved */
 336                 __brk_limit = .;
 337         }
 338
 339         . = ALIGN(PAGE_SIZE);           /* keep VO_INIT_SIZE page aligned */
 340         _end = .;
 341
 342         STABS_DEBUG
 343         DWARF_DEBUG
 344
 345         /* Sections to be discarded */
 346         DISCARDS
 347         /DISCARD/ : {
 348                 *(.eh_frame)
 349         }
 350 }
 351
 352
 353 #ifdef CONFIG_X86_32
 354 /*
 355  * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
 356  */
 357 . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
 358            "kernel image bigger than KERNEL_IMAGE_SIZE");
 359 #else
 360 /*
 361  * Per-cpu symbols which need to be offset from __per_cpu_load
 362  * for the boot processor.
 363  */
 364 #define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load
 365 INIT_PER_CPU(gdt_page);
 366 INIT_PER_CPU(irq_stack_union);
 367
 368 /*
 369  * Build-time check on the image size:
 370  */
 371 . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 372            "kernel image bigger than KERNEL_IMAGE_SIZE");
 373
 374 #ifdef CONFIG_SMP
 375 . = ASSERT((irq_stack_union == 0),
 376            "irq_stack_union is not at start of per-cpu area");
 377 #endif
 378
 379 #endif /* CONFIG_X86_32 */
 380
 381 #ifdef CONFIG_KEXEC_CORE
 382 #include <asm/kexec.h>
 383
 384 . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
 385            "kexec control code size is too big");
 386 #endif
 387