arch/x86/kernel/vmlinux.lds.S

   1 /*
   2  * ld script for the x86 kernel
   3  *
   4  * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  *
   6  * Modernisation, unification and other changes and fixes:
   7  *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
   8  *
   9  *
  10  * Don't define absolute symbols until and unless you know that symbol
  11  * value is should remain constant even if kernel image is relocated
  12  * at run time. Absolute symbols are not relocated. If symbol value should
  13  * change if kernel is relocated, make the symbol section relative and
  14  * put it inside the section definition.
  15  */
  16
  17 #ifdef CONFIG_X86_32
  18 #define LOAD_OFFSET __PAGE_OFFSET
  19 #else
  20 #define LOAD_OFFSET __START_KERNEL_map
  21 #endif
  22
  23 #include <asm-generic/vmlinux.lds.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/thread_info.h>
  26 #include <asm/page_types.h>
  27 #include <asm/orc_lookup.h>
  28 #include <asm/cache.h>
  29 #include <asm/boot.h>
  30
  31 #undef i386     /* in case the preprocessor is a 32bit one */
  32
  33 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
  34
  35 #ifdef CONFIG_X86_32
  36 OUTPUT_ARCH(i386)
  37 ENTRY(phys_startup_32)
  38 jiffies = jiffies_64;
  39 #else
  40 OUTPUT_ARCH(i386:x86-64)
  41 ENTRY(phys_startup_64)
  42 jiffies_64 = jiffies;
  43 #endif
  44
  45 #if defined(CONFIG_X86_64)
  46 /*
  47  * On 64-bit, align RODATA to 2MB so we retain large page mappings for
  48  * boundaries spanning kernel text, rodata and data sections.
  49  *
  50  * However, kernel identity mappings will have different RWX permissions
  51  * to the pages mapping to text and to the pages padding (which are freed) the
  52  * text section. Hence kernel identity mappings will be broken to smaller
  53  * pages. For 64-bit, kernel text and kernel identity mappings are different,
  54  * so we can enable protection checks as well as retain 2MB large page
  55  * mappings for kernel text.
  56  */
  57 #define X64_ALIGN_RODATA_BEGIN  . = ALIGN(HPAGE_SIZE);
  58
  59 #define X64_ALIGN_RODATA_END                                    \
  60                 . = ALIGN(HPAGE_SIZE);                          \
  61                 __end_rodata_hpage_align = .;
  62
  63 #else
  64
  65 #define X64_ALIGN_RODATA_BEGIN
  66 #define X64_ALIGN_RODATA_END
  67
  68 #endif
  69
  70 PHDRS {
  71         text PT_LOAD FLAGS(5);          /* R_E */
  72         data PT_LOAD FLAGS(6);          /* RW_ */
  73 #ifdef CONFIG_X86_64
  74 #ifdef CONFIG_SMP
  75         percpu PT_LOAD FLAGS(6);        /* RW_ */
  76 #endif
  77         init PT_LOAD FLAGS(7);          /* RWE */
  78 #endif
  79         note PT_NOTE FLAGS(0);          /* ___ */
  80 }
  81
  82 SECTIONS
  83 {
  84 #ifdef CONFIG_X86_32
  85         . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  86         phys_startup_32 = ABSOLUTE(startup_32 - LOAD_OFFSET);
  87 #else
  88         . = __START_KERNEL;
  89         phys_startup_64 = ABSOLUTE(startup_64 - LOAD_OFFSET);
  90 #endif
  91
  92         /* Text and read-only data */
  93         .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  94                 _text = .;
  95                 _stext = .;
  96                 /* bootstrapping code */
  97                 HEAD_TEXT
  98                 . = ALIGN(8);
  99                 TEXT_TEXT
 100                 SCHED_TEXT
 101                 CPUIDLE_TEXT
 102                 LOCK_TEXT
 103                 KPROBES_TEXT
 104                 ENTRY_TEXT
 105                 IRQENTRY_TEXT
 106                 SOFTIRQENTRY_TEXT
 107                 *(.fixup)
 108                 *(.gnu.warning)
 109                 /* End of text section */
 110                 _etext = .;
 111         } :text = 0x9090
 112
 113         NOTES :text :note
 114
 115         EXCEPTION_TABLE(16) :text = 0x9090
 116
 117         /* .text should occupy whole number of pages */
 118         . = ALIGN(PAGE_SIZE);
 119         X64_ALIGN_RODATA_BEGIN
 120         RO_DATA(PAGE_SIZE)
 121         X64_ALIGN_RODATA_END
 122
 123         /* Data */
 124         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 125                 /* Start of data section */
 126                 _sdata = .;
 127
 128                 /* init_task */
 129                 INIT_TASK_DATA(THREAD_SIZE)
 130
 131 #ifdef CONFIG_X86_32
 132                 /* 32 bit has nosave before _edata */
 133                 NOSAVE_DATA
 134 #endif
 135
 136                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 137
 138                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 139
 140                 DATA_DATA
 141                 CONSTRUCTORS
 142
 143                 /* rarely changed data like cpu maps */
 144                 READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
 145
 146                 /* End of data section */
 147                 _edata = .;
 148         } :data
 149
 150         BUG_TABLE
 151
 152         ORC_UNWIND_TABLE
 153
 154         . = ALIGN(PAGE_SIZE);
 155         __vvar_page = .;
 156
 157         .vvar : AT(ADDR(.vvar) - LOAD_OFFSET) {
 158                 /* work around gold bug 13023 */
 159                 __vvar_beginning_hack = .;
 160
 161                 /* Place all vvars at the offsets in asm/vvar.h. */
 162 #define EMIT_VVAR(name, offset)                         \
 163                 . = __vvar_beginning_hack + offset;     \
 164                 *(.vvar_ ## name)
 165 #define __VVAR_KERNEL_LDS
 166 #include <asm/vvar.h>
 167 #undef __VVAR_KERNEL_LDS
 168 #undef EMIT_VVAR
 169
 170                 /*
 171                  * Pad the rest of the page with zeros.  Otherwise the loader
 172                  * can leave garbage here.
 173                  */
 174                 . = __vvar_beginning_hack + PAGE_SIZE;
 175         } :data
 176
 177        . = ALIGN(__vvar_page + PAGE_SIZE, PAGE_SIZE);
 178
 179         /* Init code and data - will be freed after init */
 180         . = ALIGN(PAGE_SIZE);
 181         .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
 182                 __init_begin = .; /* paired with __init_end */
 183         }
 184
 185 #if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
 186         /*
 187          * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
 188          * output PHDR, so the next output section - .init.text - should
 189          * start another segment - init.
 190          */
 191         PERCPU_VADDR(INTERNODE_CACHE_BYTES, 0, :percpu)
 192         ASSERT(SIZEOF(.data..percpu) < CONFIG_PHYSICAL_START,
 193                "per-CPU data too large - increase CONFIG_PHYSICAL_START")
 194 #endif
 195
 196         INIT_TEXT_SECTION(PAGE_SIZE)
 197 #ifdef CONFIG_X86_64
 198         :init
 199 #endif
 200
 201         /*
 202          * Section for code used exclusively before alternatives are run. All
 203          * references to such code must be patched out by alternatives, normally
 204          * by using X86_FEATURE_ALWAYS CPU feature bit.
 205          *
 206          * See static_cpu_has() for an example.
 207          */
 208         .altinstr_aux : AT(ADDR(.altinstr_aux) - LOAD_OFFSET) {
 209                 *(.altinstr_aux)
 210         }
 211
 212         INIT_DATA_SECTION(16)
 213
 214         .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 215                 __x86_cpu_dev_start = .;
 216                 *(.x86_cpu_dev.init)
 217                 __x86_cpu_dev_end = .;
 218         }
 219
 220 #ifdef CONFIG_X86_INTEL_MID
 221         .x86_intel_mid_dev.init : AT(ADDR(.x86_intel_mid_dev.init) - \
 222                                                                 LOAD_OFFSET) {
 223                 __x86_intel_mid_dev_start = .;
 224                 *(.x86_intel_mid_dev.init)
 225                 __x86_intel_mid_dev_end = .;
 226         }
 227 #endif
 228
 229         /*
 230          * start address and size of operations which during runtime
 231          * can be patched with virtualization friendly instructions or
 232          * baremetal native ones. Think page table operations.
 233          * Details in paravirt_types.h
 234          */
 235         . = ALIGN(8);
 236         .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 237                 __parainstructions = .;
 238                 *(.parainstructions)
 239                 __parainstructions_end = .;
 240         }
 241
 242         /*
 243          * struct alt_inst entries. From the header (alternative.h):
 244          * "Alternative instructions for different CPU types or capabilities"
 245          * Think locking instructions on spinlocks.
 246          */
 247         . = ALIGN(8);
 248         .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 249                 __alt_instructions = .;
 250                 *(.altinstructions)
 251                 __alt_instructions_end = .;
 252         }
 253
 254         /*
 255          * And here are the replacement instructions. The linker sticks
 256          * them as binary blobs. The .altinstructions has enough data to
 257          * get the address and the length of them to patch the kernel safely.
 258          */
 259         .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 260                 *(.altinstr_replacement)
 261         }
 262
 263         /*
 264          * struct iommu_table_entry entries are injected in this section.
 265          * It is an array of IOMMUs which during run time gets sorted depending
 266          * on its dependency order. After rootfs_initcall is complete
 267          * this section can be safely removed.
 268          */
 269         .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
 270                 __iommu_table = .;
 271                 *(.iommu_table)
 272                 __iommu_table_end = .;
 273         }
 274
 275         . = ALIGN(8);
 276         .apicdrivers : AT(ADDR(.apicdrivers) - LOAD_OFFSET) {
 277                 __apicdrivers = .;
 278                 *(.apicdrivers);
 279                 __apicdrivers_end = .;
 280         }
 281
 282         . = ALIGN(8);
 283         /*
 284          * .exit.text is discard at runtime, not link time, to deal with
 285          *  references from .altinstructions and .eh_frame
 286          */
 287         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 288                 EXIT_TEXT
 289         }
 290
 291         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 292                 EXIT_DATA
 293         }
 294
 295 #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
 296         PERCPU_SECTION(INTERNODE_CACHE_BYTES)
 297 #endif
 298
 299         . = ALIGN(PAGE_SIZE);
 300
 301         /* freed after init ends here */
 302         .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
 303                 __init_end = .;
 304         }
 305
 306         /*
 307          * smp_locks might be freed after init
 308          * start/end must be page aligned
 309          */
 310         . = ALIGN(PAGE_SIZE);
 311         .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 312                 __smp_locks = .;
 313                 *(.smp_locks)
 314                 . = ALIGN(PAGE_SIZE);
 315                 __smp_locks_end = .;
 316         }
 317
 318 #ifdef CONFIG_X86_64
 319         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 320                 NOSAVE_DATA
 321         }
 322 #endif
 323
 324         /* BSS */
 325         . = ALIGN(PAGE_SIZE);
 326         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 327                 __bss_start = .;
 328                 *(.bss..page_aligned)
 329                 *(.bss)
 330                 . = ALIGN(PAGE_SIZE);
 331                 __bss_stop = .;
 332         }
 333
 334         . = ALIGN(PAGE_SIZE);
 335         .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
 336                 __brk_base = .;
 337                 . += 64 * 1024;         /* 64k alignment slop space */
 338                 *(.brk_reservation)     /* areas brk users have reserved */
 339                 __brk_limit = .;
 340         }
 341
 342         . = ALIGN(PAGE_SIZE);           /* keep VO_INIT_SIZE page aligned */
 343         _end = .;
 344
 345         STABS_DEBUG
 346         DWARF_DEBUG
 347
 348         /* Sections to be discarded */
 349         DISCARDS
 350         /DISCARD/ : {
 351                 *(.eh_frame)
 352         }
 353 }
 354
 355
 356 #ifdef CONFIG_X86_32
 357 /*
 358  * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
 359  */
 360 . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
 361            "kernel image bigger than KERNEL_IMAGE_SIZE");
 362 #else
 363 /*
 364  * Per-cpu symbols which need to be offset from __per_cpu_load
 365  * for the boot processor.
 366  */
 367 #define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load
 368 INIT_PER_CPU(gdt_page);
 369 INIT_PER_CPU(irq_stack_union);
 370
 371 /*
 372  * Build-time check on the image size:
 373  */
 374 . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 375            "kernel image bigger than KERNEL_IMAGE_SIZE");
 376
 377 #ifdef CONFIG_SMP
 378 . = ASSERT((irq_stack_union == 0),
 379            "irq_stack_union is not at start of per-cpu area");
 380 #endif
 381
 382 #endif /* CONFIG_X86_32 */
 383
 384 #ifdef CONFIG_KEXEC_CORE
 385 #include <asm/kexec.h>
 386
 387 . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
 388            "kexec control code size is too big");
 389 #endif
 390