arch/x86/power/hibernate_asm_64.S

   1 /*
   2  * Hibernation support for x86-64
   3  *
   4  * Distribute under GPLv2.
   5  *
   6  * Copyright 2007 Rafael J. Wysocki <rjw@sisk.pl>
   7  * Copyright 2005 Andi Kleen <ak@suse.de>
   8  * Copyright 2004 Pavel Machek <pavel@suse.cz>
   9  *
  10  * swsusp_arch_resume must not use any stack or any nonlocal variables while
  11  * copying pages:
  12  *
  13  * Its rewriting one kernel image with another. What is stack in "old"
  14  * image could very well be data page in "new" image, and overwriting
  15  * your own stack under you is bad idea.
  16  */
  17
  18         .text
  19 #include <linux/linkage.h>
  20 #include <asm/segment.h>
  21 #include <asm/page_types.h>
  22 #include <asm/asm-offsets.h>
  23 #include <asm/processor-flags.h>
  24 #include <asm/frame.h>
  25
  26 ENTRY(swsusp_arch_suspend)
  27         movq    $saved_context, %rax
  28         movq    %rsp, pt_regs_sp(%rax)
  29         movq    %rbp, pt_regs_bp(%rax)
  30         movq    %rsi, pt_regs_si(%rax)
  31         movq    %rdi, pt_regs_di(%rax)
  32         movq    %rbx, pt_regs_bx(%rax)
  33         movq    %rcx, pt_regs_cx(%rax)
  34         movq    %rdx, pt_regs_dx(%rax)
  35         movq    %r8, pt_regs_r8(%rax)
  36         movq    %r9, pt_regs_r9(%rax)
  37         movq    %r10, pt_regs_r10(%rax)
  38         movq    %r11, pt_regs_r11(%rax)
  39         movq    %r12, pt_regs_r12(%rax)
  40         movq    %r13, pt_regs_r13(%rax)
  41         movq    %r14, pt_regs_r14(%rax)
  42         movq    %r15, pt_regs_r15(%rax)
  43         pushfq
  44         popq    pt_regs_flags(%rax)
  45
  46         /* save cr3 */
  47         movq    %cr3, %rax
  48         movq    %rax, restore_cr3(%rip)
  49
  50         FRAME_BEGIN
  51         call swsusp_save
  52         FRAME_END
  53         ret
  54 ENDPROC(swsusp_arch_suspend)
  55
  56 ENTRY(restore_image)
  57         /* prepare to jump to the image kernel */
  58         movq    restore_jump_address(%rip), %r8
  59         movq    restore_cr3(%rip), %r9
  60
  61         /* prepare to switch to temporary page tables */
  62         movq    temp_level4_pgt(%rip), %rax
  63         movq    mmu_cr4_features(%rip), %rbx
  64
  65         /* prepare to copy image data to their original locations */
  66         movq    restore_pblist(%rip), %rdx
  67
  68         /* jump to relocated restore code */
  69         movq    relocated_restore_code(%rip), %rcx
  70         jmpq    *%rcx
  71
  72         /* code below has been relocated to a safe page */
  73 ENTRY(core_restore_code)
  74         /* switch to temporary page tables */
  75         movq    %rax, %cr3
  76         /* flush TLB */
  77         movq    %rbx, %rcx
  78         andq    $~(X86_CR4_PGE), %rcx
  79         movq    %rcx, %cr4;  # turn off PGE
  80         movq    %cr3, %rcx;  # flush TLB
  81         movq    %rcx, %cr3;
  82         movq    %rbx, %cr4;  # turn PGE back on
  83 .Lloop:
  84         testq   %rdx, %rdx
  85         jz      .Ldone
  86
  87         /* get addresses from the pbe and copy the page */
  88         movq    pbe_address(%rdx), %rsi
  89         movq    pbe_orig_address(%rdx), %rdi
  90         movq    $(PAGE_SIZE >> 3), %rcx
  91         rep
  92         movsq
  93
  94         /* progress to the next pbe */
  95         movq    pbe_next(%rdx), %rdx
  96         jmp     .Lloop
  97
  98 .Ldone:
  99         /* jump to the restore_registers address from the image header */
 100         jmpq    *%r8
 101
 102          /* code below belongs to the image kernel */
 103         .align PAGE_SIZE
 104 ENTRY(restore_registers)
 105         /* go back to the original page tables */
 106         movq    %r9, %cr3
 107
 108         /* Flush TLB, including "global" things (vmalloc) */
 109         movq    mmu_cr4_features(%rip), %rax
 110         movq    %rax, %rdx
 111         andq    $~(X86_CR4_PGE), %rdx
 112         movq    %rdx, %cr4;  # turn off PGE
 113         movq    %cr3, %rcx;  # flush TLB
 114         movq    %rcx, %cr3
 115         movq    %rax, %cr4;  # turn PGE back on
 116
 117         /* We don't restore %rax, it must be 0 anyway */
 118         movq    $saved_context, %rax
 119         movq    pt_regs_sp(%rax), %rsp
 120         movq    pt_regs_bp(%rax), %rbp
 121         movq    pt_regs_si(%rax), %rsi
 122         movq    pt_regs_di(%rax), %rdi
 123         movq    pt_regs_bx(%rax), %rbx
 124         movq    pt_regs_cx(%rax), %rcx
 125         movq    pt_regs_dx(%rax), %rdx
 126         movq    pt_regs_r8(%rax), %r8
 127         movq    pt_regs_r9(%rax), %r9
 128         movq    pt_regs_r10(%rax), %r10
 129         movq    pt_regs_r11(%rax), %r11
 130         movq    pt_regs_r12(%rax), %r12
 131         movq    pt_regs_r13(%rax), %r13
 132         movq    pt_regs_r14(%rax), %r14
 133         movq    pt_regs_r15(%rax), %r15
 134         pushq   pt_regs_flags(%rax)
 135         popfq
 136
 137         /* Saved in save_processor_state. */
 138         lgdt    saved_context_gdt_desc(%rax)
 139
 140         xorq    %rax, %rax
 141
 142         /* tell the hibernation core that we've just restored the memory */
 143         movq    %rax, in_suspend(%rip)
 144
 145         ret
 146 ENDPROC(restore_registers)