audio/meson.build

   1 softmmu_ss.add([spice_headers, files('audio.c')])
   2 softmmu_ss.add(files(
   3   'audio-hmp-cmds.c',
   4   'audio_legacy.c',
   5   'mixeng.c',
   6   'noaudio.c',
   7   'wavaudio.c',
   8   'wavcapture.c',
   9 ))
  10
  11 softmmu_ss.add(when: coreaudio, if_true: files('coreaudio.m'))
  12 softmmu_ss.add(when: dsound, if_true: files('dsoundaudio.c', 'audio_win_int.c'))
  13
  14 audio_modules = {}
  15 foreach m : [
  16   ['alsa', alsa, files('alsaaudio.c')],
  17   ['oss', oss, files('ossaudio.c')],
  18   ['pa', pulse, files('paaudio.c')],
  19   ['sdl', sdl, files('sdlaudio.c')],
  20   ['jack', jack, files('jackaudio.c')],
  21   ['sndio', sndio, files('sndioaudio.c')],
  22   ['pipewire', pipewire, files('pwaudio.c')],
  23   ['spice', spice, files('spiceaudio.c')]
  24 ]
  25   if m[1].found()
  26     module_ss = ss.source_set()
  27     module_ss.add(m[1], m[2])
  28     audio_modules += {m[0] : module_ss}
  29   endif
  30 endforeach
  31
  32 if dbus_display
  33     module_ss = ss.source_set()
  34     module_ss.add(when: gio, if_true: files('dbusaudio.c'))
  35     audio_modules += {'dbus': module_ss}
  36 endif
  37
  38 modules += {'audio': audio_modules}