bin/pmgpolicy

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use Getopt::Long;
   6 use POSIX qw(errno_h signal_h);
   7
   8 use Net::Server::PreForkSimple;
   9 use Net::DNS::Resolver;
  10 use Mail::SPF;
  11 use Fcntl;
  12 use Fcntl ':flock';
  13 use IO::Multiplex;
  14 use Time::HiRes qw(gettimeofday);
  15
  16 use PVE::INotify;
  17 use PVE::Tools;
  18 use PVE::SafeSyslog;
  19
  20 use PMG::Utils;
  21 use PMG::RuleDB;
  22 use PMG::DBTools;
  23 use PMG::RuleCache;
  24 use PMG::Config;
  25 use PMG::ClusterConfig;
  26
  27 use base qw(Net::Server::PreForkSimple);
  28
  29 my $greylist_delay = 3*60;            # greylist window
  30 my $greylist_lifetime = 3600*24*2;    # retry window
  31 my $greylist_awlifetime = 3600*24*36; # expire window
  32
  33 my $opt_commandline = [$0, @ARGV];
  34 my $opt_policy_port = 10022;
  35 my $opt_max_dequeue = 1;
  36 my $opt_dequeue_time = 60*2;
  37
  38 my $opt_testmode;
  39 my $opt_pidfile;
  40 my $opt_database;
  41
  42 if (!GetOptions ('pidfile=s' => \$opt_pidfile,
  43                  'testmode' => \$opt_testmode,
  44                  'database=s' => \$opt_database)) {
  45     die "usage error\n";
  46     exit (-1);
  47 }
  48
  49 $opt_pidfile = "/var/run/pmgpolicy.pid" if !$opt_pidfile;
  50 $opt_max_dequeue = 0 if $opt_testmode;
  51
  52 initlog('pmgpolicy', 'mail');
  53
  54 my $max_servers = 5;
  55
  56 if (!$opt_testmode) {
  57
  58     my $pmg_cfg = PMG::Config->new ();
  59     my $demo = $pmg_cfg->get('admin', 'demo');
  60     $max_servers = $pmg_cfg->get('mail', 'max_policy');
  61
  62     if ($demo) {
  63         syslog('info', 'demo mode detected - not starting server');
  64         exit(0);
  65     }
  66 }
  67
  68 my $daemonize = 1;
  69 if (defined ($ENV{BOUND_SOCKETS})) {
  70     $daemonize = undef;
  71 }
  72
  73
  74 my $server_attr = {
  75     port => [ $opt_policy_port ],
  76     host => '127.0.0.1',
  77     max_servers => $max_servers,
  78     max_dequeue => $opt_max_dequeue,
  79     check_for_dequeue => $opt_dequeue_time,
  80     log_level => 3,
  81     pid_file => $opt_pidfile,
  82     commandline => $opt_commandline,
  83     no_close_by_child => 1,
  84     setsid => $daemonize,
  85 };
  86
  87 my $database;
  88 if (defined($opt_database)) {
  89     $database = $opt_database;
  90 } else {
  91     $database = "Proxmox_ruledb";
  92 }
  93
  94 $SIG{'__WARN__'} = sub {
  95     my $err = $@;
  96     my $t = $_[0];
  97     chomp $t;
  98     syslog('warning', "WARNING: %s", $t);
  99     $@ = $err;
 100 };
 101
 102 sub run_dequeue {
 103     my $self = shift;
 104
 105     $self->log(2, "starting greylist database maintainance");
 106
 107     my ($csec, $usec) = gettimeofday ();
 108
 109     my $cinfo = PVE::INotify::read_file("cluster.conf");
 110     my $lcid = $cinfo->{local}->{cid};
 111     my $role = $cinfo->{local}->{type} // '-';
 112
 113     my $dbh;
 114
 115     eval {
 116         $dbh = PMG::DBTools::open_ruledb($database);
 117     };
 118     my $err = $@;
 119
 120     if ($err) {
 121         $self->log(0, "ERROR: $err");
 122         return;
 123     }
 124
 125     my $now = time();
 126
 127     my $ecount = 0;
 128
 129     eval {
 130
 131         $dbh->begin_work;
 132
 133         # we do not lock the table here to avoid delays
 134         # but that is OK, because we only touch expired records
 135         # which do not change nornmally
 136         ## $dbh->do ("LOCK TABLE CGreylist IN ROW EXCLUSIVE MODE");
 137
 138         # move expired and undelivered records from Greylist to Statistic
 139
 140         my $rntxt = '';
 141         if (!$lcid) {
 142             $rntxt = "AND CID = 0";
 143         } else {
 144             if ($role eq 'master') {
 145                 # master is responsible for all non-cluster (deleted) nodes
 146                 foreach my $rcid (@{$cinfo->{remnodes}}) {
 147                     $rntxt .= $rntxt ? " AND CID != $rcid" : "AND (CID != $rcid";
 148                 }
 149                 $rntxt .= ")" if $rntxt;
 150             } else {
 151                 $rntxt = "AND (CID = 0 OR CID = $lcid)";
 152             }
 153         }
 154
 155
 156         my $cmds = '';
 157
 158         my $sth = $dbh->prepare(
 159             "SELECT distinct instance, sender FROM CGreylist " .
 160             "WHERE passed = 0 AND extime < ? $rntxt");
 161
 162         $sth->execute ($now);
 163
 164
 165         while (my $ref = $sth->fetchrow_hashref()) {
 166             my $sth2 = $dbh->prepare(
 167                 "SELECT * FROM CGreylist WHERE instance = ? AND sender = ?");
 168             $sth2->execute ($ref->{instance}, $ref->{sender});
 169             my $rctime;
 170             my @rcvrs;
 171             my $bc = 0;
 172
 173             while (my $ref2 = $sth2->fetchrow_hashref()) {
 174                 $rctime = $ref2->{rctime} if !$rctime;
 175                 $bc += $ref2->{blocked};
 176                 push  @rcvrs, $ref2->{receiver};
 177             }
 178
 179             $sth2->finish();
 180
 181             # hack: sometimes query sth2 does not return anything - maybe a
 182             # postgres bug? We simply ignore (when rctime is undefined) it
 183             # to avoid problems.
 184
 185             if ($rctime) {
 186                 $cmds .=  "SELECT nextval ('cstatistic_id_seq');" .
 187                     "INSERT INTO CStatistic " .
 188                     "(CID, RID, ID, Time, Bytes, Direction, Spamlevel, VirusInfo, PTime, Sender) VALUES (" .
 189                     "$lcid, currval ('cstatistic_id_seq'), currval ('cstatistic_id_seq'), ";
 190
 191                 my $sl = $bc >= 100000 ? 4 : 5;
 192                 $cmds .= $rctime . ", 0, '1', $sl, NULL, 0, ";
 193                 $cmds .= $dbh->quote ($ref->{sender}) . ');';
 194
 195                 foreach my $r (@rcvrs) {
 196                     my $tmp = $dbh->quote ($r);
 197                     $cmds .= "INSERT INTO CReceivers (CStatistic_CID, CStatistic_RID, Receiver, Blocked) ".
 198                         "VALUES ($lcid, currval ('cstatistic_id_seq'), $tmp, '1'); ";
 199                 }
 200             }
 201
 202             if (length ($cmds) > 100000) {
 203                 $dbh->do ($cmds);
 204                 $cmds = '';
 205             }
 206
 207             $ecount++;
 208
 209             # this produces too much log traffic
 210             # my $targets = join (", ", @rcvrs);
 211             #my $msg = "expire mail $ref->{instance} from $ref->{sender} to $targets";
 212             #$self->log (0, $msg);
 213         }
 214
 215         $dbh->do ($cmds) if $cmds;
 216
 217         $sth->finish();
 218
 219         if ($ecount > 0) {
 220             my $msg = "found $ecount expired mails in greylisting database";
 221             $self->log (0, $msg);
 222         }
 223
 224         $dbh->do ("DELETE FROM CGreylist WHERE extime < $now");
 225
 226         $dbh->commit;
 227     };
 228
 229     $err = $@;
 230
 231     my ($csec_end, $usec_end) = gettimeofday ();
 232     my $ptime = int (($csec_end-$csec)*1000 + ($usec_end - $usec)/1000);
 233
 234     if ($err) {
 235         $dbh->rollback if $dbh;
 236         $self->log(0, $err);
 237     } else {
 238         $self->log(2, "end greylist database maintainance ($ptime ms)");
 239     }
 240
 241     $dbh->disconnect() if $dbh;
 242 }
 243
 244 sub pre_loop_hook {
 245     my $self = shift;
 246
 247     my $prop = $self->{server};
 248
 249     $prop->{log_level} = 3;
 250
 251     $self->log(0, "Policy daemon (re)started");
 252
 253     $SIG{'USR1'} = sub {
 254         # reloading server configuration
 255         if (defined $prop->{children}) {
 256             foreach my $pid (keys %{$prop->{children}}) {
 257                 kill(10, $pid); # SIGUSR1 childs
 258             }
 259         }
 260     };
 261
 262     my $sig_set = POSIX::SigSet->new;
 263     $sig_set->addset (&POSIX::SIGHUP);
 264     $sig_set->addset (&POSIX::SIGCHLD);
 265     my $old_sig_set = POSIX::SigSet->new();
 266
 267     sigprocmask (SIG_UNBLOCK, $sig_set, $old_sig_set);
 268 }
 269
 270 sub load_config {
 271     my $self = shift;
 272
 273     my $prop = $self->{server};
 274
 275     if ($self->{ruledb}) {
 276         $self->log(0, "reloading configuration $database");
 277         $self->{ruledb}->close();
 278     }
 279
 280     my $pmg_cfg = PMG::Config->new ();
 281     $self->{use_spf} = $pmg_cfg->get('mail', 'spf');
 282     $self->{use_greylist} = $pmg_cfg->get('mail', 'greylist');
 283
 284     if ($opt_testmode) {
 285         $self->{use_spf} = 1;
 286         $self->{use_greylist} = 1;
 287     }
 288
 289     my $nodename = PVE::INotify::nodename();
 290     my $resolv = PVE::INotify::read_file('resolvconf');
 291     my $domain = $resolv->{search};
 292     $self->{fqdn} = "$nodename.$domain";
 293
 294     my $cinfo = PVE::INotify::read_file("cluster.conf");
 295     my $lcid = $cinfo->{local}->{cid};
 296     $self->{cinfo} = $cinfo;
 297     $self->{lcid} = $lcid;
 298
 299     my $dbh;
 300
 301     eval {
 302         $dbh = PMG::DBTools::open_ruledb($database);
 303         $self->{ruledb} = PMG::RuleDB->new($dbh);
 304         $self->{rulecache} = PMG::RuleCache->new($self->{ruledb});
 305     };
 306     if (my $err = $@) {
 307         $self->log(0, "ERROR: unable to load database : $err");
 308     }
 309
 310     $self->{reload_config} = 0;
 311 }
 312
 313 sub child_init_hook {
 314     my $self = shift;
 315
 316     my $prop = $self->{server};
 317
 318     $0 = 'pmgpolicy child';
 319
 320     setup_fork_signal_mask(0); # unblocking signals for children
 321
 322     eval {
 323         $self->load_config();
 324
 325         $self->{mux} = IO::Multiplex->new();
 326         $self->{mux}->set_callback_object($self);
 327
 328         my %dnsargs = (
 329             tcp_timeout => 3,
 330             udp_timeout => 3,
 331             retry => 1,
 332             retrans => 0,
 333             dnsrch => 0,
 334             defnames => 0,
 335             );
 336
 337         if ($opt_testmode) {
 338             # $dnsargs{nameservers} = [ qw (213.129.232.1 213.129.226.2) ];
 339         }
 340
 341         $self->{dns_resolver} = Net::DNS::Resolver->new(%dnsargs);
 342
 343         $self->{spf_server} = Mail::SPF::Server->new(
 344             hostname => $self->{fqdn}, dns_resolver => $self->{dns_resolver});
 345     };
 346     if (my $err = $@) {
 347         $self->log(0, $err);
 348         $self->child_finish_hook;
 349         exit(-1);
 350     }
 351
 352     $SIG{'USR1'} = sub {
 353         $self->{reload_config} = 1;
 354     }
 355 }
 356
 357 sub child_finish_hook {
 358     my $self = shift;
 359
 360     my $prop = $self->{server};
 361
 362     $self->{ruledb}->close() if $self->{ruledb};
 363 }
 364
 365 sub get_spf_result {
 366     my ($self, $instance, $ip, $helo, $sender) = @_;
 367
 368     my $result;
 369     my $spf_header;
 370     my $local_expl;
 371     my $auth_expl;
 372
 373     # we only use helo tests when we have no sender,
 374     # helo is sometimes empty, so we cant use SPF helo tests
 375     # in that case - strange
 376     if ($helo && !$sender) {
 377         my $query;
 378
 379         if (defined ($self->{cache}->{$instance}) &&
 380             defined ($self->{cache}->{$instance}->{spf_helo_result})) {
 381
 382             $query = $self->{cache}->{$instance}->{spf_helo_result};
 383
 384         } else {
 385             my $request = Mail::SPF::Request->new(
 386                 scope => 'helo', identity => $helo, ip_address => $ip);
 387
 388             $query = $self->{cache}->{$instance}->{spf_helo_result} =
 389                 $self->{spf_server}->process ($request);
 390         }
 391
 392         $result = $query->code;
 393         $spf_header = $query->received_spf_header;
 394         $local_expl = $query->local_explanation;
 395         $auth_expl = $query->authority_explanation if $query->is_code('fail');
 396
 397         # return if we get a definitive result
 398         if ($result eq 'pass' || $result eq 'fail' || $result eq 'temperror') {
 399             return ($result, $spf_header, $local_expl, $auth_expl);
 400         }
 401     }
 402
 403     if ($sender) {
 404
 405         my $query;
 406
 407         if (defined ($self->{cache}->{$instance}) &&
 408             defined ($self->{cache}->{$instance}->{spf_mfrom_result})) {
 409
 410             $query = $self->{cache}->{$instance}->{spf_mfrom_result};
 411
 412         } else {
 413
 414             my $request = Mail::SPF::Request->new(
 415                 scope => 'mfrom', identity => $sender,
 416                 ip_address => $ip, helo_identity => $helo);
 417
 418             $query = $self->{cache}->{$instance}->{spf_mfrom_result} =
 419                 $self->{spf_server}->process($request);
 420         }
 421
 422         $result = $query->code;
 423         $spf_header = $query->received_spf_header;
 424         $local_expl = $query->local_explanation;
 425         $auth_expl = $query->authority_explanation if $query->is_code('fail');
 426
 427         return ($result, $spf_header, $local_expl, $auth_expl);
 428     }
 429
 430     return undef;
 431 }
 432
 433 sub is_backup_mx {
 434     my ($self, $ip, $receiver) = @_;
 435
 436     my ($rdomain) = $receiver =~ /([^@]+)$/;
 437
 438     my $dkey = "BKMX:$rdomain";
 439
 440     if (defined ($self->{cache}->{$dkey}) &&
 441         ($self->{cache}->{$dkey}->{status} == 1)) {
 442         return $self->{cache}->{$dkey}->{$ip};
 443     }
 444
 445     my $resolver = $self->{dns_resolver};
 446
 447     if (my $mx = $resolver->send($rdomain, 'MX')) {
 448         $self->{cache}->{$dkey}->{status} = 1;
 449         my @mxa = grep { $_->type eq 'MX' } $mx->answer;
 450         my @mxl = sort { $a->preference <=> $b->preference } @mxa;
 451         # shift @mxl; # optionaly skip primary MX ?
 452         foreach my $rr (@mxl) {
 453             my $a = $resolver->send ($rr->exchange, 'A');
 454             if ($a) {
 455                 foreach my $rra ($a->answer) {
 456                     if ($rra->type eq 'A') {
 457                         $self->{cache}->{$dkey}->{$rra->address} = 1;
 458                     }
 459                 }
 460             }
 461         }
 462     } else {
 463         $self->{cache}->{$dkey}->{status} = 0;
 464     }
 465
 466     return $self->{cache}->{$dkey}->{$ip};
 467 }
 468
 469 sub greylist_value {
 470     my ($self, $ctime, $helo, $ip, $sender, $rcpt, $instance) = @_;
 471
 472     my $rulecache = $self->{rulecache};
 473
 474     my $dbh = $self->{ruledb}->{dbh};
 475
 476     # try to reconnect if database connection is broken
 477     if (!$dbh->ping) {
 478         $self->log(0, 'Database connection broken - trying to reconnect');
 479         my $dbh;
 480         eval {
 481             $dbh = PMG::DBTools::open_ruledb($database);
 482         };
 483         my $err = $@;
 484         if ($err) {
 485             $self->log(0, "unable to reconnect to database server: $err");
 486             return 'dunno';
 487         }
 488         $self->{ruledb} = PMG::RuleDB->new($dbh);
 489     }
 490
 491     # some sender substitutions
 492     my ($user, $domain) = split('@', $sender, 2);
 493     if (defined ($user) && defined ($domain)) {
 494         # see http://cr.yp.to/proto/verp.txt
 495         $user =~ s/\+.*//; # strip extensions  (mailing-list VERP)
 496         $user =~ s/\b\d+\b/#/g; #replace nubmers in VERP address
 497         $sender = "$user\@$domain";
 498     }
 499
 500     if ($self->is_backup_mx($ip, $rcpt)) {
 501         $self->log(3, "accept mails from backup MX host - $ip");
 502         return 'dunno';
 503     }
 504
 505     # greylist exclusion (sender whitelist)
 506     if ($rulecache->greylist_match ($sender, $ip)) {
 507         $self->log(3, "accept mails from whitelist - $ip");
 508         return 'dunno';
 509     }
 510
 511     # greylist exclusion (receiver whitelist)
 512     if ($rulecache->greylist_match_receiver ($rcpt)) {
 513         $self->log(3, "accept mails to whitelist - <$rcpt>");
 514         return 'dunno';
 515     }
 516
 517     my ($net, $host) = $ip =~ m/(\d+\.\d+\.\d+)\.(\d+)/;
 518     my $spf_header;
 519
 520     if ((!$opt_testmode && $self->{use_spf}) ||
 521         ($opt_testmode && ($rcpt =~ m/^testspf/))) {
 522
 523         # ask SPF
 524         my $spf_result;
 525         my $local_expl,
 526         my $auth_expl;
 527
 528         my $previous_alarm;
 529
 530         my ($result, $smtp_comment, $header_comment);
 531
 532         eval {
 533             $previous_alarm = alarm(10);
 534             local $SIG{ALRM} = sub { die "SPF timeout\n" };
 535
 536             ($result, $spf_header, $local_expl, $auth_expl) =
 537                 $self->get_spf_result($instance, $ip, $helo, $sender);
 538
 539             alarm(0); # avoid race condition
 540         };
 541         my $err = $@;
 542
 543         alarm($previous_alarm) if defined($previous_alarm);
 544
 545         if ($err) {
 546             $err = $err->text if UNIVERSAL::isa ($err, 'Mail::SPF::Exception');
 547             $self->log (0, $err);
 548         } else {
 549
 550             if ($result && $result eq 'pass') {
 551                 $self->log(3, "SPF says $result");
 552                 $spf_result = $spf_header ? "prepend $spf_header" : 'dunno';
 553             }
 554
 555             if ($result && $result eq 'fail') {
 556                 $self->log(3, "SPF says $result");
 557                 $spf_result = "reject ${auth_expl}";
 558
 559                 eval {
 560
 561                     $dbh->begin_work;
 562
 563                     # try to avoid locks everywhere - we use merge instead of insert
 564                     #$dbh->do ("LOCK TABLE CGreylist IN ROW EXCLUSIVE MODE");
 565
 566                     # check if there is already a record in the GL database
 567                     my $sth = $dbh->prepare(
 568                         "SELECT * FROM CGreylist " .
 569                         "where IPNet = ? AND Sender = ? AND Receiver = ?");
 570
 571                     $sth->execute($net, $sender, $rcpt);
 572                     my $ref = $sth->fetchrow_hashref();
 573                     $sth->finish();
 574
 575                     # else add an entry to the GL Database with short
 576                     # expiration time. run_dequeue() moves those entries into the statistic
 577                     # table later. We set 'blocked' to 100000 to identify those entries.
 578
 579                     if (!defined($ref->{rctime})) {
 580
 581                         $dbh->do("SELECT merge_greylist(?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?)", undef,
 582                                  $net, $host, $sender, $rcpt, $instance,
 583                                  $ctime, $ctime + 10, 0, 100000, 0, $ctime, $self->{lcid});
 584                     }
 585
 586                     $dbh->commit;
 587                 };
 588                 if (my $err = $@) {
 589                     $dbh->rollback;
 590                     $self->log(0, $err);
 591                 }
 592             }
 593         }
 594
 595         return $spf_result if $spf_result;
 596     }
 597
 598
 599     my $res = $spf_header ? "prepend $spf_header" : 'dunno';
 600
 601     return $res if !$self->{use_greylist};
 602
 603     my $defer_res = "defer_if_permit Service is unavailable (try later)";
 604
 605     eval {
 606
 607         # we dont use alarm here, because it does not work with DBI
 608
 609         $dbh->begin_work;
 610
 611         # try to avoid locks everywhere - we use merge instead of insert
 612         #$dbh->do ("LOCK TABLE CGreylist IN ROW EXCLUSIVE MODE");
 613
 614         my $sth = $dbh->prepare(
 615             "SELECT * FROM CGreylist " .
 616             "where IPNet = ? AND Sender = ? AND Receiver = ?");
 617
 618         $sth->execute($net, $sender, $rcpt);
 619
 620         my $ref = $sth->fetchrow_hashref();
 621
 622         $sth->finish();
 623
 624         if (!defined($ref->{rctime})) {
 625
 626             $dbh->do ("SELECT merge_greylist(?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?)", undef,
 627                       $net, $host, $sender, $rcpt, $instance,
 628                       $ctime, $ctime + $greylist_lifetime, 0, 1, 0, $ctime, $self->{lcid});
 629
 630             $res = $defer_res;
 631             $self->log(3, "defer greylisted mail");
 632         } else {
 633             my $age = $ctime - $ref->{rctime};
 634
 635             if ($age < $greylist_delay) {
 636                 # defer (resent within greylist_delay window)
 637                 $res = $defer_res;
 638                 $self->log(3, "defer greylisted mail");
 639                 $dbh->do("UPDATE CGreylist " .
 640                          "SET  Blocked = Blocked + 1, Host = ?, MTime = ? " .
 641                          "WHERE IPNet = ? AND Sender = ? AND Receiver = ?", undef,
 642                          $host, $ctime, $net, $sender, $rcpt);
 643             } else {
 644                 if ($ctime < $ref->{extime}) {
 645                     # accept (not expired)
 646                     my $lifetime = $sender eq "" ? 0 : $greylist_awlifetime;
 647                     my $delay = $ref->{passed} ? "" : "Delay = $age, ";
 648                     $dbh->do("UPDATE CGreylist " .
 649                              "SET  Passed =  Passed + 1, $delay Host = ?, ExTime = ?, MTime = ? " .
 650                              "WHERE IPNet =  ? AND Sender = ? AND Receiver = ?", undef,
 651                              $host, $ctime + $lifetime, $ctime, $net, $sender, $rcpt);
 652                 } else {
 653                     # defer (record is expired)
 654                     $res = $defer_res;
 655                     $dbh->do("UPDATE CGreylist " .
 656                              "SET  Host = ?, RCTime = ?, ExTime = ?, MTime = ?, Instance = ?, " .
 657                              "Blocked = 1, Passed = 0 " .
 658                              "WHERE IPNet =  ? AND Sender = ? AND Receiver = ?", undef,
 659                              $host, $ctime, $ctime + $greylist_lifetime, $ctime, $instance,
 660                              $net, $sender, $rcpt);
 661                 }
 662             }
 663         }
 664
 665         $dbh->commit;
 666     };
 667     if (my $err = $@) {
 668         $dbh->rollback;
 669         $self->log (0, $err);
 670     }
 671
 672     return $res;
 673 }
 674
 675 # shutdown connections: we need this - else file handles are
 676 # not closed and we run out of handles
 677 sub mux_eof {
 678     my ($self, $mux, $fh) = @_;
 679
 680     $mux->shutdown($fh, 1);
 681 }
 682
 683 sub mux_input {
 684     my ($self, $mux, $fh, $dataref) = @_;
 685     my $prop = $self->{server};
 686
 687     my $attribute = {};
 688
 689     eval {
 690         $self->load_config() if $self->{reload_config};
 691
 692         while ($$dataref =~ s/^([^\r\n]*)\r?\n//) {
 693             my $line = $1;
 694             next if !defined ($line);
 695
 696             if ($line =~ m/([^=]+)=(.*)/) {
 697                 $attribute->{substr($1, 0, 255)} = substr($2, 0, 255);
 698             } elsif ($line eq '') {
 699                 my $res = 'dunno';
 700                 my $ctime = time;
 701
 702                 if ($opt_testmode) {
 703                     die "undefined test time :ERROR" if !defined $attribute->{testtime};
 704                     $ctime = $attribute->{testtime};
 705                 }
 706
 707                 if ($attribute->{instance} && $attribute->{recipient} &&
 708                     $attribute->{client_address} && $attribute->{request} &&
 709                     $attribute->{request} eq 'smtpd_access_policy') {
 710
 711                     eval {
 712
 713                         $res = $self->greylist_value(
 714                             $ctime,
 715                             lc ($attribute->{helo_name}),
 716                             lc ($attribute->{client_address}),
 717                             lc ($attribute->{sender}),
 718                             lc ($attribute->{recipient}),
 719                             lc ($attribute->{instance}));
 720                     };
 721                     if (my $err = $@) {
 722                         $self->log(0, $err);
 723                     }
 724                 }
 725
 726                 print $fh "action=$res\n\n";
 727
 728                 $attribute = {};
 729             } else {
 730                 $self->log(0, "greylist policy protocol error - got '%s'", $line);
 731             }
 732         }
 733     };
 734     my $err = $@;
 735
 736     # remove remaining data, if any
 737     if ($$dataref ne '') {
 738         $self->log(0, "greylist policy protocol error - unused data '%s'", $$dataref);
 739         $$dataref = '';
 740     }
 741
 742     $self->log(0, $err) if $err;
 743 }
 744
 745 sub restart_close_hook {
 746     my $self = shift;
 747
 748     my $sig_set = POSIX::SigSet->new;
 749     $sig_set->addset(&POSIX::SIGHUP);
 750     $sig_set->addset(&POSIX::SIGCHLD); # to avoid zombies
 751     my $old_sig_set = POSIX::SigSet->new();
 752
 753     sigprocmask(SIG_BLOCK, $sig_set, $old_sig_set);
 754 }
 755
 756 sub pre_server_close_hook {
 757     my $self = shift;
 758
 759     my $prop = $self->{server};
 760
 761     if (defined $prop->{_HUP}) {
 762         undef $prop->{pid_file_unlink};
 763     }
 764
 765     if (defined $prop->{children}) {
 766         foreach my $pid (keys %{$prop->{children}}) {
 767             kill(1, $pid); # HUP childs
 768         }
 769     }
 770
 771     # nicely shutdown childs (give them max 30 seconds to shut down)
 772     my $previous_alarm = alarm(30);
 773     eval {
 774         local $SIG{ALRM} = sub { die "Timed Out!\n" };
 775
 776         my $pid;
 777         1 while ((($pid = waitpid(-1, 0)) > 0) || ($! == EINTR));
 778
 779         alarm(0); # avoid race
 780     };
 781     alarm ($previous_alarm);
 782 }
 783
 784 sub setup_fork_signal_mask {
 785     my $block = shift;
 786
 787     my $sig_set = POSIX::SigSet->new;
 788     $sig_set->addset(&POSIX::SIGINT);
 789     $sig_set->addset(&POSIX::SIGTERM);
 790     $sig_set->addset(&POSIX::SIGQUIT);
 791     $sig_set->addset(&POSIX::SIGHUP);
 792     my $old_sig_set = POSIX::SigSet->new();
 793
 794     if ($block) {
 795         sigprocmask (SIG_BLOCK, $sig_set, $old_sig_set);
 796     } else {
 797         sigprocmask (SIG_UNBLOCK, $sig_set, $old_sig_set);
 798     }
 799 }
 800
 801 # subroutine to start up a specified number of children.
 802 # We need to block signals until handlers are set up correctly.
 803 # Else its possible that HUP occurs after fork, which triggers
 804 # singal TERM at childs and calls server_close() instead of
 805 # simply exit the child.
 806 # Note: on server startup signals are setup to trigger
 807 # asynchronously for a short period of time (in PreForkSimple]::loop,
 808 # run_n_children is called before run_parent)
 809 # Net::Server::PreFork does not have this problem, because it is using
 810 # signal HUP stop children
 811 sub run_n_children {
 812     my ($self, $n)  = @_;
 813
 814     my $prop  = $self->{server};
 815
 816     setup_fork_signal_mask(1); # block signals
 817
 818     $self->SUPER::run_n_children($n);
 819
 820     setup_fork_signal_mask(0); # unblocking signals for parent
 821 }
 822
 823 # test sig_hup with: for ((;;)) ;do kill -HUP  `cat /var/run/pmgpolicy.pid`; done;
 824 # wrapper to avoid multiple calls to sig_hup
 825 sub sig_hup {
 826     my $self = shift;
 827
 828     my $prop = $self->{server};
 829
 830     return if defined($prop->{_HUP}); # do not call twice
 831
 832     $self->SUPER::sig_hup();
 833 }
 834
 835 ### child process which will accept on the port
 836 sub run_child {
 837     my $self = shift;
 838
 839     my $prop = $self->{server};
 840
 841     $self->log(4, "Child Preforked ($$)\n");
 842
 843     # set correct signal handlers before enabling signals again
 844     $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = sub {
 845         $self->child_finish_hook;
 846         exit;
 847     };
 848
 849     delete $prop->{children};
 850
 851     $self->child_init_hook;
 852
 853     # accept connections
 854
 855     my $sock = $prop->{sock}->[0];
 856
 857     # make sure we got a good sock
 858     if (!defined ($sock)){
 859         $self->log(0, "ERROR: Received a bad socket");
 860         exit (-1);
 861     }
 862
 863     # sometimes the socket is not usable, don't know why
 864     my $flags = fcntl($sock, F_GETFL, 0);
 865     if (!$flags) {
 866         $self->log(0, "socket not ready - $!");
 867         exit (-1);
 868     }
 869
 870     # cache is limited, because postfix does max. 100 queries
 871     $self->{cache} = {};
 872
 873     eval {
 874         my $mux = $self->{mux};
 875         $mux->listen ($sock);
 876         $mux->loop;
 877     };
 878     if (my $err = $@) {
 879         $self->log(0, "ERROR: $err");
 880     }
 881
 882     $self->child_finish_hook;
 883
 884     exit;
 885 }
 886
 887 my $syslog_map = {
 888     0 => 'err',
 889     1 => 'warning',
 890     2 => 'notice',
 891     3 => 'info',
 892     4 => 'debug'
 893 };
 894
 895 sub log {
 896     my ($self, $level, $msg, @therest) = @_;
 897
 898     my $prop = $self->{server};
 899
 900     return if $level =~ /^\d+$/ && $level > $prop->{log_level};
 901
 902     $level = $syslog_map->{$level} || $level;
 903     if (@therest) {
 904         syslog($level, $msg, @therest);
 905     } else {
 906         syslog ($level, $msg);
 907     }
 908 }
 909
 910 my $server = bless {
 911     server => $server_attr,
 912 };
 913
 914 $server->sig_chld(); # avoid zombies after restart
 915
 916 $server->run ();
 917
 918 exit (0);
 919
 920 __END__
 921
 922 =head1 NAME
 923
 924 pmgpolicy - The Proxmox policy daemon
 925
 926 =head1 SYNOPSIS
 927
 928 pmgpolicy
 929
 930 =head1 DESCRIPTION
 931
 932 Documentation is available at www.proxmox.com