cmake/Modules/SelectHTTPSBackend.cmake

   1 # Select the backend to use
   2
   3 # We try to find any packages our backends might use
   4 FIND_PACKAGE(OpenSSL)
   5 FIND_PACKAGE(mbedTLS)
   6 IF (CMAKE_SYSTEM_NAME MATCHES "Darwin")
   7         FIND_PACKAGE(Security)
   8         FIND_PACKAGE(CoreFoundation)
   9 ENDIF()
  10
  11 # Auto-select TLS backend
  12 IF (USE_HTTPS STREQUAL ON)
  13         IF (SECURITY_FOUND)
  14                 IF (SECURITY_HAS_SSLCREATECONTEXT)
  15                         SET(HTTPS_BACKEND "SecureTransport")
  16                 ELSE()
  17                         MESSAGE(STATUS "Security framework is too old, falling back to OpenSSL")
  18                         SET(HTTPS_BACKEND "OpenSSL")
  19                 ENDIF()
  20         ELSEIF (WINHTTP)
  21                 SET(HTTPS_BACKEND "WinHTTP")
  22         ELSEIF(OPENSSL_FOUND)
  23                 SET(HTTPS_BACKEND "OpenSSL")
  24         ELSEIF(MBEDTLS_FOUND)
  25                 SET(HTTPS_BACKEND "mbedTLS")
  26         ELSE()
  27                 MESSAGE(FATAL_ERROR "Unable to autodetect a usable HTTPS backend."
  28                         "Please pass the backend name explicitly (-DUSE_HTTPS=backend)")
  29         ENDIF()
  30 ELSEIF(USE_HTTPS)
  31         # HTTPS backend was explicitly set
  32         SET(HTTPS_BACKEND ${USE_HTTPS})
  33 ELSE()
  34         SET(HTTPS_BACKEND NO)
  35 ENDIF()
  36
  37 IF(HTTPS_BACKEND)
  38         # Check that we can find what's required for the selected backend
  39         IF (HTTPS_BACKEND STREQUAL "SecureTransport")
  40                 IF (NOT COREFOUNDATION_FOUND)
  41                         MESSAGE(FATAL_ERROR "Cannot use SecureTransport backend, CoreFoundation.framework not found")
  42                 ENDIF()
  43                 IF (NOT SECURITY_FOUND)
  44                         MESSAGE(FATAL_ERROR "Cannot use SecureTransport backend, Security.framework not found")
  45                 ENDIF()
  46                 IF (NOT SECURITY_HAS_SSLCREATECONTEXT)
  47                         MESSAGE(FATAL_ERROR "Cannot use SecureTransport backend, SSLCreateContext not supported")
  48                 ENDIF()
  49
  50                 SET(GIT_SECURE_TRANSPORT 1)
  51                 LIST(APPEND LIBGIT2_SYSTEM_INCLUDES ${SECURITY_INCLUDE_DIR})
  52                 LIST(APPEND LIBGIT2_LIBS ${COREFOUNDATION_LDFLAGS} ${SECURITY_LDFLAGS})
  53                 LIST(APPEND LIBGIT2_PC_LIBS ${COREFOUNDATION_LDFLAGS} ${SECURITY_LDFLAGS})
  54         ELSEIF (HTTPS_BACKEND STREQUAL "OpenSSL")
  55                 IF (NOT OPENSSL_FOUND)
  56                         MESSAGE(FATAL_ERROR "Asked for OpenSSL TLS backend, but it wasn't found")
  57                 ENDIF()
  58
  59                 SET(GIT_OPENSSL 1)
  60                 LIST(APPEND LIBGIT2_SYSTEM_INCLUDES ${OPENSSL_INCLUDE_DIR})
  61                 LIST(APPEND LIBGIT2_LIBS ${OPENSSL_LIBRARIES})
  62                 LIST(APPEND LIBGIT2_PC_LIBS ${OPENSSL_LDFLAGS})
  63                 LIST(APPEND LIBGIT2_PC_REQUIRES "openssl")
  64         ELSEIF(HTTPS_BACKEND STREQUAL "mbedTLS")
  65                 IF (NOT MBEDTLS_FOUND)
  66                         MESSAGE(FATAL_ERROR "Asked for mbedTLS backend, but it wasn't found")
  67                 ENDIF()
  68
  69                 IF(NOT CERT_LOCATION)
  70                         MESSAGE(STATUS "Auto-detecting default certificates location")
  71                         IF(CMAKE_SYSTEM_NAME MATCHES Darwin)
  72                                 # Check for an Homebrew installation
  73                                 SET(OPENSSL_CMD "/usr/local/opt/openssl/bin/openssl")
  74                         ELSE()
  75                                 SET(OPENSSL_CMD "openssl")
  76                         ENDIF()
  77                         EXECUTE_PROCESS(COMMAND ${OPENSSL_CMD} version -d OUTPUT_VARIABLE OPENSSL_DIR OUTPUT_STRIP_TRAILING_WHITESPACE)
  78                         IF(OPENSSL_DIR)
  79                                 STRING(REGEX REPLACE "^OPENSSLDIR: \"(.*)\"$" "\\1/" OPENSSL_DIR ${OPENSSL_DIR})
  80
  81                                 SET(OPENSSL_CA_LOCATIONS
  82                                         "ca-bundle.pem"             # OpenSUSE Leap 42.1
  83                                         "cert.pem"                  # Ubuntu 14.04, FreeBSD
  84                                         "certs/ca-certificates.crt" # Ubuntu 16.04
  85                                         "certs/ca.pem"              # Debian 7
  86                                 )
  87                                 FOREACH(SUFFIX IN LISTS OPENSSL_CA_LOCATIONS)
  88                                         SET(LOC "${OPENSSL_DIR}${SUFFIX}")
  89                                         IF(NOT CERT_LOCATION AND EXISTS "${OPENSSL_DIR}${SUFFIX}")
  90                                                 SET(CERT_LOCATION ${LOC})
  91                                         ENDIF()
  92                                 ENDFOREACH()
  93                         ELSE()
  94                                 MESSAGE(FATAL_ERROR "Unable to find OpenSSL executable. Please provide default certificate location via CERT_LOCATION")
  95                         ENDIF()
  96                 ENDIF()
  97
  98                 IF(CERT_LOCATION)
  99                         IF(NOT EXISTS ${CERT_LOCATION})
 100                                 MESSAGE(FATAL_ERROR "Cannot use CERT_LOCATION=${CERT_LOCATION} as it doesn't exist")
 101                         ENDIF()
 102                         ADD_FEATURE_INFO(CERT_LOCATION ON "using certificates from ${CERT_LOCATION}")
 103                         ADD_DEFINITIONS(-DGIT_DEFAULT_CERT_LOCATION="${CERT_LOCATION}")
 104                 ENDIF()
 105
 106                 SET(GIT_MBEDTLS 1)
 107                 LIST(APPEND LIBGIT2_SYSTEM_INCLUDES ${MBEDTLS_INCLUDE_DIR})
 108                 LIST(APPEND LIBGIT2_LIBS ${MBEDTLS_LIBRARIES})
 109                 # mbedTLS has no pkgconfig file, hence we can't require it
 110                 # https://github.com/ARMmbed/mbedtls/issues/228
 111                 # For now, pass its link flags as our own
 112                 LIST(APPEND LIBGIT2_PC_LIBS ${MBEDTLS_LIBRARIES})
 113         ELSEIF (HTTPS_BACKEND STREQUAL "WinHTTP")
 114                 # WinHTTP setup was handled in the WinHTTP-specific block above
 115         ELSE()
 116                 MESSAGE(FATAL_ERROR "Asked for backend ${HTTPS_BACKEND} but it wasn't found")
 117         ENDIF()
 118
 119         SET(GIT_HTTPS 1)
 120         ADD_FEATURE_INFO(HTTPS GIT_HTTPS "using ${HTTPS_BACKEND}")
 121 ELSE()
 122         SET(GIT_HTTPS 0)
 123         ADD_FEATURE_INFO(HTTPS NO "")
 124 ENDIF()